lib/SQL/Translator/Parser/PostgreSQL.pm

   1 package SQL::Translator::Parser::PostgreSQL;
   2
   3 # -------------------------------------------------------------------
   4 # $Id: PostgreSQL.pm,v 1.39 2004-08-11 22:00:39 kycl4rk Exp $
   5 # -------------------------------------------------------------------
   6 # Copyright (C) 2002-4 SQLFairy Authors
   7 #
   8 # This program is free software; you can redistribute it and/or
   9 # modify it under the terms of the GNU General Public License as
  10 # published by the Free Software Foundation; version 2.
  11 #
  12 # This program is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 # General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  20 # 02111-1307  USA
  21 # -------------------------------------------------------------------
  22
  23 =head1 NAME
  24
  25 SQL::Translator::Parser::PostgreSQL - parser for PostgreSQL
  26
  27 =head1 SYNOPSIS
  28
  29   use SQL::Translator;
  30   use SQL::Translator::Parser::PostgreSQL;
  31
  32   my $translator = SQL::Translator->new;
  33   $translator->parser("SQL::Translator::Parser::PostgreSQL");
  34
  35 =head1 DESCRIPTION
  36
  37 The grammar was started from the MySQL parsers.  Here is the description
  38 from PostgreSQL:
  39
  40 Table:
  41 (http://www.postgresql.org/docs/view.php?version=7.3&idoc=1&file=sql-createtable.html)
  42
  43   CREATE [ [ LOCAL ] { TEMPORARY | TEMP } ] TABLE table_name (
  44       { column_name data_type [ DEFAULT default_expr ]
  45          [ column_constraint [, ... ] ]
  46       | table_constraint }  [, ... ]
  47   )
  48   [ INHERITS ( parent_table [, ... ] ) ]
  49   [ WITH OIDS | WITHOUT OIDS ]
  50
  51   where column_constraint is:
  52
  53   [ CONSTRAINT constraint_name ]
  54   { NOT NULL | NULL | UNIQUE | PRIMARY KEY |
  55     CHECK (expression) |
  56     REFERENCES reftable [ ( refcolumn ) ] [ MATCH FULL | MATCH PARTIAL ]
  57       [ ON DELETE action ] [ ON UPDATE action ] }
  58   [ DEFERRABLE | NOT DEFERRABLE ]
  59   [ INITIALLY DEFERRED | INITIALLY IMMEDIATE ]
  60
  61   and table_constraint is:
  62
  63   [ CONSTRAINT constraint_name ]
  64   { UNIQUE ( column_name [, ... ] ) |
  65     PRIMARY KEY ( column_name [, ... ] ) |
  66     CHECK ( expression ) |
  67     FOREIGN KEY ( column_name [, ... ] )
  68      REFERENCES reftable [ ( refcolumn [, ... ] ) ]
  69       [ MATCH FULL | MATCH PARTIAL ]
  70       [ ON DELETE action ] [ ON UPDATE action ] }
  71   [ DEFERRABLE | NOT DEFERRABLE ]
  72   [ INITIALLY DEFERRED | INITIALLY IMMEDIATE ]
  73
  74 Index:
  75 (http://www.postgresql.org/docs/view.php?version=7.3&idoc=1&file=sql-createindex.html)
  76
  77   CREATE [ UNIQUE ] INDEX index_name ON table
  78       [ USING acc_method ] ( column [ ops_name ] [, ...] )
  79       [ WHERE predicate ]
  80   CREATE [ UNIQUE ] INDEX index_name ON table
  81       [ USING acc_method ] ( func_name( column [, ... ]) [ ops_name ] )
  82       [ WHERE predicate ]
  83
  84 Alter table:
  85
  86   ALTER TABLE [ ONLY ] table [ * ]
  87       ADD [ COLUMN ] column type [ column_constraint [ ... ] ]
  88   ALTER TABLE [ ONLY ] table [ * ]
  89       ALTER [ COLUMN ] column { SET DEFAULT value | DROP DEFAULT }
  90   ALTER TABLE [ ONLY ] table [ * ]
  91       ALTER [ COLUMN ] column SET STATISTICS integer
  92   ALTER TABLE [ ONLY ] table [ * ]
  93       RENAME [ COLUMN ] column TO newcolumn
  94   ALTER TABLE table
  95       RENAME TO new_table
  96   ALTER TABLE table
  97       ADD table_constraint_definition
  98   ALTER TABLE [ ONLY ] table
  99           DROP CONSTRAINT constraint { RESTRICT | CASCADE }
 100   ALTER TABLE table
 101           OWNER TO new_owner
 102
 103 View table:
 104
 105     CREATE [ OR REPLACE ] VIEW view [ ( column name list ) ] AS SELECT query
 106
 107 =cut
 108
 109 use strict;
 110 use vars qw[ $DEBUG $VERSION $GRAMMAR @EXPORT_OK ];
 111 $VERSION = sprintf "%d.%02d", q$Revision: 1.39 $ =~ /(\d+)\.(\d+)/;
 112 $DEBUG   = 0 unless defined $DEBUG;
 113
 114 use Data::Dumper;
 115 use Parse::RecDescent;
 116 use Exporter;
 117 use base qw(Exporter);
 118
 119 @EXPORT_OK = qw(parse);
 120
 121 # Enable warnings within the Parse::RecDescent module.
 122 $::RD_ERRORS = 1; # Make sure the parser dies when it encounters an error
 123 $::RD_WARN   = 1; # Enable warnings. This will warn on unused rules &c.
 124 $::RD_HINT   = 1; # Give out hints to help fix problems.
 125
 126 my $parser; # should we do this?  There's no programmic way to
 127             # change the grammar, so I think this is safe.
 128
 129 $GRAMMAR = q!
 130
 131 { my ( %tables, $table_order, $field_order, @table_comments) }
 132
 133 #
 134 # The "eofile" rule makes the parser fail if any "statement" rule
 135 # fails.  Otherwise, the first successful match by a "statement"
 136 # won't cause the failure needed to know that the parse, as a whole,
 137 # failed. -ky
 138 #
 139 startrule : statement(s) eofile { \%tables }
 140
 141 eofile : /^\Z/
 142
 143 statement : create
 144   | comment_on_table
 145   | comment_on_column
 146   | comment
 147   | alter
 148   | grant
 149   | revoke
 150   | drop
 151   | insert
 152   | connect
 153   | update
 154   | set
 155   | <error>
 156
 157 connect : /^\s*\\\connect.*\n/
 158
 159 set : /set/i /[^;]*/ ';'
 160
 161 revoke : /revoke/i WORD(s /,/) /on/i TABLE(?) table_name /from/i name_with_opt_quotes(s /,/) ';'
 162     {
 163         my $table_name = $item{'table_name'};
 164         push @{ $tables{ $table_name }{'permissions'} }, {
 165             type       => 'revoke',
 166             actions    => $item[2],
 167             users      => $item[7],
 168         }
 169     }
 170
 171 grant : /grant/i WORD(s /,/) /on/i TABLE(?) table_name /to/i name_with_opt_quotes(s /,/) ';'
 172     {
 173         my $table_name = $item{'table_name'};
 174         push @{ $tables{ $table_name }{'permissions'} }, {
 175             type       => 'grant',
 176             actions    => $item[2],
 177             users      => $item[7],
 178         }
 179     }
 180
 181 drop : /drop/i /[^;]*/ ';'
 182
 183 insert : /insert/i /[^;]*/ ';'
 184
 185 update : /update/i /[^;]*/ ';'
 186
 187 #
 188 # Create table.
 189 #
 190 create : create_table table_name '(' create_definition(s /,/) ')' table_option(s?) ';'
 191     {
 192         my $table_name                       = $item{'table_name'};
 193         $tables{ $table_name }{'order'}      = ++$table_order;
 194         $tables{ $table_name }{'table_name'} = $table_name;
 195
 196         if ( @table_comments ) {
 197             $tables{ $table_name }{'comments'} = [ @table_comments ];
 198             @table_comments = ();
 199         }
 200
 201         my @constraints;
 202         for my $definition ( @{ $item[4] } ) {
 203             if ( $definition->{'supertype'} eq 'field' ) {
 204                 my $field_name = $definition->{'name'};
 205                 $tables{ $table_name }{'fields'}{ $field_name } =
 206                     { %$definition, order => $field_order++ };
 207
 208                 for my $constraint ( @{ $definition->{'constraints'} || [] } ) {
 209                     $constraint->{'fields'} = [ $field_name ];
 210                     push @{ $tables{ $table_name }{'constraints'} },
 211                         $constraint;
 212                 }
 213             }
 214             elsif ( $definition->{'supertype'} eq 'constraint' ) {
 215                 push @{ $tables{ $table_name }{'constraints'} }, $definition;
 216             }
 217             elsif ( $definition->{'supertype'} eq 'index' ) {
 218                 push @{ $tables{ $table_name }{'indices'} }, $definition;
 219             }
 220         }
 221
 222         for my $option ( @{ $item[6] } ) {
 223             $tables{ $table_name }{'table_options(s?)'}{ $option->{'type'} } =
 224                 $option;
 225         }
 226
 227         1;
 228     }
 229
 230 create : CREATE unique(?) /(index|key)/i index_name /on/i table_name using_method(?) '(' field_name(s /,/) ')' where_predicate(?) ';'
 231     {
 232         push @{ $tables{ $item{'table_name'} }{'indices'} },
 233             {
 234                 name      => $item{'index_name'},
 235                 supertype => $item{'unique'}[0] ? 'constraint' : 'index',
 236                 type      => $item{'unique'}[0] ? 'unique'     : 'normal',
 237                 fields    => $item[9],
 238                 method    => $item{'using_method'}[0],
 239             }
 240         ;
 241
 242     }
 243
 244 #
 245 # Create anything else (e.g., domain, etc.)
 246 #
 247 create : CREATE WORD /[^;]+/ ';'
 248     { @table_comments = (); }
 249
 250 using_method : /using/i WORD { $item[2] }
 251
 252 where_predicate : /where/i /[^;]+/
 253
 254 create_definition : field
 255     | table_constraint
 256     | <error>
 257
 258 comment : /^\s*(?:#|-{2})(.*)\n/
 259     {
 260         my $comment =  $item[1];
 261         $comment    =~ s/^\s*(#|-*)\s*//;
 262         $comment    =~ s/\s*$//;
 263         $return     = $comment;
 264         push @table_comments, $comment;
 265     }
 266
 267 comment_on_table : /comment/i /on/i /table/i table_name /is/i comment_phrase ';'
 268     {
 269         push @{ $tables{ $item{'table_name'} }{'comments'} }, $item{'comment_phrase'};
 270     }
 271
 272 comment_on_column : /comment/i /on/i /column/i column_name /is/i comment_phrase ';'
 273     {
 274         my $table_name = $item[4]->{'table'};
 275         my $field_name = $item[4]->{'field'};
 276         push @{ $tables{ $table_name }{'fields'}{ $field_name }{'comments'} },
 277             $item{'comment_phrase'};
 278     }
 279
 280 column_name : NAME '.' NAME
 281     { $return = { table => $item[1], field => $item[3] } }
 282
 283 comment_phrase : /'.*?'|NULL/
 284     {
 285         my $val = $item[1] || '';
 286         $val =~ s/^'|'$//g;
 287         $return = $val;
 288     }
 289
 290 field : field_comment(s?) field_name data_type field_meta(s?) field_comment(s?)
 291     {
 292         my ( $default, @constraints, $is_pk );
 293         my $is_nullable = 1;
 294         for my $meta ( @{ $item[4] } ) {
 295             if ( $meta->{'type'} eq 'default' ) {
 296                 $default = $meta;
 297                 next;
 298             }
 299             elsif ( $meta->{'type'} eq 'not_null' ) {
 300                 $is_nullable = 0;
 301             }
 302             elsif ( $meta->{'type'} eq 'primary_key' ) {
 303                 $is_pk = 1;
 304             }
 305
 306             push @constraints, $meta if $meta->{'supertype'} eq 'constraint';
 307         }
 308
 309         my @comments = ( @{ $item[1] }, @{ $item[5] } );
 310
 311         $return = {
 312             supertype         => 'field',
 313             name              => $item{'field_name'},
 314             data_type         => $item{'data_type'}{'type'},
 315             size              => $item{'data_type'}{'size'},
 316             is_nullable       => $is_nullable,
 317             default           => $default->{'value'},
 318             constraints       => [ @constraints ],
 319             comments          => [ @comments ],
 320             is_primary_key    => $is_pk || 0,
 321             is_auto_increment => $item{'data_type'}{'is_auto_increment'},
 322         }
 323     }
 324     | <error>
 325
 326 field_comment : /^\s*(?:#|-{2})(.*)\n/
 327     {
 328         my $comment =  $item[1];
 329         $comment    =~ s/^\s*(#|-*)\s*//;
 330         $comment    =~ s/\s*$//;
 331         $return     = $comment;
 332     }
 333
 334 field_meta : default_val
 335     | column_constraint
 336
 337 column_constraint : constraint_name(?) column_constraint_type deferrable(?) deferred(?)
 338     {
 339         my $desc       = $item{'column_constraint_type'};
 340         my $type       = $desc->{'type'};
 341         my $fields     = $desc->{'fields'}     || [];
 342         my $expression = $desc->{'expression'} || '';
 343
 344         $return              =  {
 345             supertype        => 'constraint',
 346             name             => $item{'constraint_name'}[0] || '',
 347             type             => $type,
 348             expression       => $type eq 'check' ? $expression : '',
 349             deferrable       => $item{'deferrable'},
 350             deferred         => $item{'deferred'},
 351             reference_table  => $desc->{'reference_table'},
 352             reference_fields => $desc->{'reference_fields'},
 353             match_type       => $desc->{'match_type'},
 354             on_delete_do     => $desc->{'on_delete_do'},
 355             on_update_do     => $desc->{'on_update_do'},
 356         }
 357     }
 358
 359 constraint_name : /constraint/i name_with_opt_quotes { $item[2] }
 360
 361 column_constraint_type : /not null/i { $return = { type => 'not_null' } }
 362     |
 363     /null/i
 364         { $return = { type => 'null' } }
 365     |
 366     /unique/i
 367         { $return = { type => 'unique' } }
 368     |
 369     /primary key/i
 370         { $return = { type => 'primary_key' } }
 371     |
 372     /check/i '(' /[^)]+/ ')'
 373         { $return = { type => 'check', expression => $item[3] } }
 374     |
 375     /references/i table_name parens_word_list(?) match_type(?) key_action(s?)
 376     {
 377         my ( $on_delete, $on_update );
 378         for my $action ( @{ $item[5] || [] } ) {
 379             $on_delete = $action->{'action'} if $action->{'type'} eq 'delete';
 380             $on_update = $action->{'action'} if $action->{'type'} eq 'update';
 381         }
 382
 383         $return              =  {
 384             type             => 'foreign_key',
 385             reference_table  => $item[2],
 386             reference_fields => $item[3][0],
 387             match_type       => $item[4][0],
 388             on_delete_do     => $on_delete,
 389             on_update_do     => $on_update,
 390         }
 391     }
 392
 393 table_name : name_with_opt_quotes
 394
 395 field_name : name_with_opt_quotes
 396
 397 name_with_opt_quotes : double_quote(?) NAME double_quote(?) { $item[2] }
 398
 399 double_quote: /"/
 400
 401 index_name : WORD
 402
 403 data_type : pg_data_type parens_value_list(?)
 404     {
 405         my $data_type = $item[1];
 406
 407         #
 408         # We can deduce some sizes from the data type's name.
 409         #
 410         if ( my $size = $item[2][0] ) {
 411             $data_type->{'size'} = $size;
 412         }
 413
 414         $return  = $data_type;
 415     }
 416
 417 pg_data_type :
 418     /(bigint|int8)/i
 419         {
 420             $return = {
 421                 type => 'integer',
 422                 size => 20,
 423             };
 424         }
 425     |
 426     /(smallint|int2)/i
 427         {
 428             $return = {
 429                 type => 'integer',
 430                 size => 5,
 431             };
 432         }
 433     |
 434     /(integer|int4?)/i # interval must come before this
 435         {
 436             $return = {
 437                 type => 'integer',
 438                 size => 10,
 439             };
 440         }
 441     |
 442     /(real|float4)/i
 443         {
 444             $return = {
 445                 type => 'real',
 446                 size => 10,
 447             };
 448         }
 449     |
 450     /(double precision|float8?)/i
 451         {
 452             $return = {
 453                 type => 'float',
 454                 size => 20,
 455             };
 456         }
 457     |
 458     /(bigserial|serial8)/i
 459         {
 460             $return = {
 461                 type              => 'integer',
 462                 size              => 20,
 463                 is_auto_increment => 1,
 464             };
 465         }
 466     |
 467     /serial4?/i
 468         {
 469             $return = {
 470                 type              => 'integer',
 471                 size              => 11,
 472                 is_auto_increment => 1,
 473             };
 474         }
 475     |
 476     /(bit varying|varbit)/i
 477         {
 478             $return = { type => 'varbit' };
 479         }
 480     |
 481     /character varying/i
 482         {
 483             $return = { type => 'varchar' };
 484         }
 485     |
 486     /char(acter)?/i
 487         {
 488             $return = { type => 'char' };
 489         }
 490     |
 491     /bool(ean)?/i
 492         {
 493             $return = { type => 'boolean' };
 494         }
 495     |
 496     /bytea/i
 497         {
 498             $return = { type => 'bytea' };
 499         }
 500     |
 501     /(timestamptz|timestamp)/i
 502         {
 503             $return = { type => 'timestamp' };
 504         }
 505     |
 506     /text/i
 507         {
 508             $return = {
 509                 type => 'text',
 510                 size => 64_000,
 511             };
 512         }
 513     |
 514     /(bit|box|cidr|circle|date|inet|interval|line|lseg|macaddr|money|numeric|decimal|path|point|polygon|timetz|time|varchar)/i
 515         {
 516             $return = { type => $item[1] };
 517         }
 518
 519 parens_value_list : '(' VALUE(s /,/) ')'
 520     { $item[2] }
 521
 522 parens_word_list : '(' WORD(s /,/) ')'
 523     { $item[2] }
 524
 525 field_size : '(' num_range ')' { $item{'num_range'} }
 526
 527 num_range : DIGITS ',' DIGITS
 528     { $return = $item[1].','.$item[3] }
 529     | DIGITS
 530     { $return = $item[1] }
 531
 532 table_constraint : comment(s?) constraint_name(?) table_constraint_type deferrable(?) deferred(?) comment(s?)
 533     {
 534         my $desc       = $item{'table_constraint_type'};
 535         my $type       = $desc->{'type'};
 536         my $fields     = $desc->{'fields'};
 537         my $expression = $desc->{'expression'};
 538         my @comments   = ( @{ $item[1] }, @{ $item[-1] } );
 539
 540         $return              =  {
 541             name             => $item{'constraint_name'}[0] || '',
 542             supertype        => 'constraint',
 543             type             => $type,
 544             fields           => $type ne 'check' ? $fields : [],
 545             expression       => $type eq 'check' ? $expression : '',
 546             deferrable       => $item{'deferrable'},
 547             deferred         => $item{'deferred'},
 548             reference_table  => $desc->{'reference_table'},
 549             reference_fields => $desc->{'reference_fields'},
 550             match_type       => $desc->{'match_type'}[0],
 551             on_delete_do     => $desc->{'on_delete_do'},
 552             on_update_do     => $desc->{'on_update_do'},
 553             comments         => [ @comments ],
 554         }
 555     }
 556
 557 table_constraint_type : /primary key/i '(' name_with_opt_quotes(s /,/) ')'
 558     {
 559         $return = {
 560             type   => 'primary_key',
 561             fields => $item[3],
 562         }
 563     }
 564     |
 565     /unique/i '(' name_with_opt_quotes(s /,/) ')'
 566     {
 567         $return    =  {
 568             type   => 'unique',
 569             fields => $item[3],
 570         }
 571     }
 572     |
 573     /check/i '(' /[^)]+/ ')'
 574     {
 575         $return        =  {
 576             type       => 'check',
 577             expression => $item[3],
 578         }
 579     }
 580     |
 581     /foreign key/i '(' name_with_opt_quotes(s /,/) ')' /references/i table_name parens_word_list(?) match_type(?) key_action(s?)
 582     {
 583         my ( $on_delete, $on_update );
 584         for my $action ( @{ $item[9] || [] } ) {
 585             $on_delete = $action->{'action'} if $action->{'type'} eq 'delete';
 586             $on_update = $action->{'action'} if $action->{'type'} eq 'update';
 587         }
 588
 589         $return              =  {
 590             supertype        => 'constraint',
 591             type             => 'foreign_key',
 592             fields           => $item[3],
 593             reference_table  => $item[6],
 594             reference_fields => $item[7][0],
 595             match_type       => $item[8][0],
 596             on_delete_do     => $on_delete || '',
 597             on_update_do     => $on_update || '',
 598         }
 599     }
 600
 601 deferrable : /not/i /deferrable/i
 602     {
 603         $return = ( $item[1] =~ /not/i ) ? 0 : 1;
 604     }
 605
 606 deferred : /initially/i /(deferred|immediate)/i { $item[2] }
 607
 608 match_type : /match full/i { 'match_full' }
 609     |
 610     /match partial/i { 'match_partial' }
 611
 612 key_action : key_delete
 613     |
 614     key_update
 615
 616 key_delete : /on delete/i key_mutation
 617     {
 618         $return = {
 619             type   => 'delete',
 620             action => $item[2],
 621         };
 622     }
 623
 624 key_update : /on update/i key_mutation
 625     {
 626         $return = {
 627             type   => 'update',
 628             action => $item[2],
 629         };
 630     }
 631
 632 key_mutation : /no action/i { $return = 'no_action' }
 633     |
 634     /restrict/i { $return = 'restrict' }
 635     |
 636     /cascade/i { $return = 'cascade' }
 637     |
 638     /set null/i { $return = 'set null' }
 639     |
 640     /set default/i { $return = 'set default' }
 641
 642 alter : alter_table table_name add_column field ';'
 643     {
 644         my $field_def = $item[4];
 645         $tables{ $item[2] }{'fields'}{ $field_def->{'name'} } = {
 646             %$field_def, order => $field_order++
 647         };
 648         1;
 649     }
 650
 651 alter : alter_table table_name ADD table_constraint ';'
 652     {
 653         my $table_name = $item[2];
 654         my $constraint = $item[4];
 655         push @{ $tables{ $table_name }{'constraints'} }, $constraint;
 656         1;
 657     }
 658
 659 alter : alter_table table_name drop_column NAME restrict_or_cascade(?) ';'
 660     {
 661         $tables{ $item[2] }{'fields'}{ $item[4] }{'drop'} = 1;
 662         1;
 663     }
 664
 665 alter : alter_table table_name alter_column NAME alter_default_val ';'
 666     {
 667         $tables{ $item[2] }{'fields'}{ $item[4] }{'default'} =
 668             $item[5]->{'value'};
 669         1;
 670     }
 671
 672 #
 673 # These will just parse for now but won't affect the structure. - ky
 674 #
 675 alter : alter_table table_name /rename/i /to/i NAME ';'
 676     { 1 }
 677
 678 alter : alter_table table_name alter_column NAME SET /statistics/i INTEGER ';'
 679     { 1 }
 680
 681 alter : alter_table table_name alter_column NAME SET /storage/i storage_type ';'
 682     { 1 }
 683
 684 alter : alter_table table_name rename_column NAME /to/i NAME ';'
 685     { 1 }
 686
 687 alter : alter_table table_name DROP /constraint/i NAME restrict_or_cascade ';'
 688     { 1 }
 689
 690 alter : alter_table table_name /owner/i /to/i NAME ';'
 691     { 1 }
 692
 693 storage_type : /(plain|external|extended|main)/i
 694
 695 alter_default_val : SET default_val
 696     {
 697         $return = { value => $item[2]->{'value'} }
 698     }
 699     | DROP DEFAULT
 700     {
 701         $return = { value => undef }
 702     }
 703
 704 #
 705 # This is a little tricky to get right, at least WRT to making the
 706 # tests pass.  The problem is that the constraints are stored just as
 707 # a list (no name access), and the tests expect the constraints in a
 708 # particular order.  I'm going to leave the rule but disable the code
 709 # for now. - ky
 710 #
 711 alter : alter_table table_name alter_column NAME alter_nullable ';'
 712     {
 713 #        my $table_name  = $item[2];
 714 #        my $field_name  = $item[4];
 715 #        my $is_nullable = $item[5]->{'is_nullable'};
 716 #
 717 #        $tables{ $table_name }{'fields'}{ $field_name }{'is_nullable'} =
 718 #            $is_nullable;
 719 #
 720 #        if ( $is_nullable ) {
 721 #            1;
 722 #            push @{ $tables{ $table_name }{'constraints'} }, {
 723 #                type   => 'not_null',
 724 #                fields => [ $field_name ],
 725 #            };
 726 #        }
 727 #        else {
 728 #            for my $i (
 729 #                0 .. $#{ $tables{ $table_name }{'constraints'} || [] }
 730 #            ) {
 731 #                my $c = $tables{ $table_name }{'constraints'}[ $i ] or next;
 732 #                my $fields = join( '', @{ $c->{'fields'} || [] } ) or next;
 733 #                if ( $c->{'type'} eq 'not_null' && $fields eq $field_name ) {
 734 #                    delete $tables{ $table_name }{'constraints'}[ $i ];
 735 #                    last;
 736 #                }
 737 #            }
 738 #        }
 739
 740         1;
 741     }
 742
 743 alter_nullable : SET not_null
 744     {
 745         $return = { is_nullable => 0 }
 746     }
 747     | DROP not_null
 748     {
 749         $return = { is_nullable => 1 }
 750     }
 751
 752 not_null : /not/i /null/i
 753
 754 add_column : ADD COLUMN(?)
 755
 756 alter_table : ALTER TABLE ONLY(?)
 757
 758 drop_column : DROP COLUMN(?)
 759
 760 alter_column : ALTER COLUMN(?)
 761
 762 rename_column : /rename/i COLUMN(?)
 763
 764 restrict_or_cascade : /restrict/i |
 765     /cascade/i
 766
 767 #
 768 # End basically useless stuff. - ky
 769 #
 770
 771 create_table : CREATE TABLE
 772
 773 create_index : CREATE /index/i
 774
 775 default_val  : DEFAULT /(\d+|'[^']*'|\w+\(.*?\))|\w+/
 776     {
 777         my $val =  defined $item[2] ? $item[2] : '';
 778         $val    =~ s/^'|'$//g;
 779         $return =  {
 780             supertype => 'constraint',
 781             type      => 'default',
 782             value     => $val,
 783         }
 784     }
 785     | /null/i
 786     {
 787         $return =  {
 788             supertype => 'constraint',
 789             type      => 'default',
 790             value     => 'NULL',
 791         }
 792     }
 793
 794 name_with_opt_paren : NAME parens_value_list(s?)
 795     { $item[2][0] ? "$item[1]($item[2][0][0])" : $item[1] }
 796
 797 unique : /unique/i { 1 }
 798
 799 key : /key/i | /index/i
 800
 801 table_option : /inherits/i '(' name_with_opt_quotes(s /,/) ')'
 802     {
 803         $return = { type => 'inherits', table_name => $item[3] }
 804     }
 805     |
 806     /with(out)? oids/i
 807     {
 808         $return = { type => $item[1] =~ /out/i ? 'without_oids' : 'with_oids' }
 809     }
 810
 811 ADD : /add/i
 812
 813 ALTER : /alter/i
 814
 815 CREATE : /create/i
 816
 817 ONLY : /only/i
 818
 819 DEFAULT : /default/i
 820
 821 DROP : /drop/i
 822
 823 COLUMN : /column/i
 824
 825 TABLE : /table/i
 826
 827 SEMICOLON : /\s*;\n?/
 828
 829 INTEGER : /\d+/
 830
 831 WORD : /\w+/
 832
 833 DIGITS : /\d+/
 834
 835 COMMA : ','
 836
 837 SET : /set/i
 838
 839 NAME    : "`" /\w+/ "`"
 840     { $item[2] }
 841     | /\w+/
 842     { $item[1] }
 843     | /[\$\w]+/
 844     { $item[1] }
 845
 846 VALUE   : /[-+]?\.?\d+(?:[eE]\d+)?/
 847     { $item[1] }
 848     | /'.*?'/   # XXX doesn't handle embedded quotes
 849     { $item[1] }
 850     | /null/i
 851     { 'NULL' }
 852
 853 !;
 854
 855 # -------------------------------------------------------------------
 856 sub parse {
 857     my ( $translator, $data ) = @_;
 858     $parser ||= Parse::RecDescent->new($GRAMMAR);
 859
 860     $::RD_TRACE  = $translator->trace ? 1 : undef;
 861     $DEBUG       = $translator->debug;
 862
 863     unless (defined $parser) {
 864         return $translator->error("Error instantiating Parse::RecDescent ".
 865             "instance: Bad grammer");
 866     }
 867
 868     my $result = $parser->startrule($data);
 869     die "Parse failed.\n" unless defined $result;
 870     warn Dumper($result) if $DEBUG;
 871
 872     my $schema = $translator->schema;
 873     my @tables = sort {
 874         $result->{ $a }->{'order'} <=> $result->{ $b }->{'order'}
 875     } keys %{ $result };
 876
 877     for my $table_name ( @tables ) {
 878         my $tdata =  $result->{ $table_name };
 879         my $table =  $schema->add_table(
 880             name  => $tdata->{'table_name'},
 881         ) or die "Couldn't create table '$table_name': " . $schema->error;
 882
 883         $table->comments( $tdata->{'comments'} );
 884
 885         my @fields = sort {
 886             $tdata->{'fields'}->{ $a }->{'order'}
 887             <=>
 888             $tdata->{'fields'}->{ $b }->{'order'}
 889         } keys %{ $tdata->{'fields'} };
 890
 891         for my $fname ( @fields ) {
 892             my $fdata = $tdata->{'fields'}{ $fname };
 893             next if $fdata->{'drop'};
 894             my $field = $table->add_field(
 895                 name              => $fdata->{'name'},
 896                 data_type         => $fdata->{'data_type'},
 897                 size              => $fdata->{'size'},
 898                 default_value     => $fdata->{'default'},
 899                 is_auto_increment => $fdata->{'is_auto_increment'},
 900                 is_nullable       => $fdata->{'is_nullable'},
 901                 comments          => $fdata->{'comments'},
 902             ) or die $table->error;
 903
 904             $table->primary_key( $field->name ) if $fdata->{'is_primary_key'};
 905
 906             for my $cdata ( @{ $fdata->{'constraints'} } ) {
 907                 next unless $cdata->{'type'} eq 'foreign_key';
 908                 $cdata->{'fields'} ||= [ $field->name ];
 909                 push @{ $tdata->{'constraints'} }, $cdata;
 910             }
 911         }
 912
 913         for my $idata ( @{ $tdata->{'indices'} || [] } ) {
 914             my $index  =  $table->add_index(
 915                 name   => $idata->{'name'},
 916                 type   => uc $idata->{'type'},
 917                 fields => $idata->{'fields'},
 918             ) or die $table->error;
 919         }
 920
 921         for my $cdata ( @{ $tdata->{'constraints'} || [] } ) {
 922             my $constraint       =  $table->add_constraint(
 923                 name             => $cdata->{'name'},
 924                 type             => $cdata->{'type'},
 925                 fields           => $cdata->{'fields'},
 926                 reference_table  => $cdata->{'reference_table'},
 927                 reference_fields => $cdata->{'reference_fields'},
 928                 match_type       => $cdata->{'match_type'} || '',
 929                 on_delete        => $cdata->{'on_delete_do'},
 930                 on_update        => $cdata->{'on_update_do'},
 931                 expression       => $cdata->{'expression'},
 932             ) or die "Can't add constraint of type '" .
 933                 $cdata->{'type'} .  "' to table '" . $table->name .
 934                 "': " . $table->error;
 935         }
 936     }
 937
 938     return 1;
 939 }
 940
 941 1;
 942
 943 # -------------------------------------------------------------------
 944 # Rescue the drowning and tie your shoestrings.
 945 # Henry David Thoreau
 946 # -------------------------------------------------------------------
 947
 948 =pod
 949
 950 =head1 AUTHORS
 951
 952 Ken Y. Clark E<lt>kclark@cpan.orgE<gt>,
 953 Allen Day E<lt>allenday@ucla.eduE<gt>.
 954
 955 =head1 SEE ALSO
 956
 957 perl(1), Parse::RecDescent.
 958
 959 =cut