lib/SQL/Translator/Parser/Oracle.pm

   1 package SQL::Translator::Parser::Oracle;
   2
   3 # -------------------------------------------------------------------
   4 # $Id: Oracle.pm,v 1.21 2005-08-10 15:17:48 duality72 Exp $
   5 # -------------------------------------------------------------------
   6 # Copyright (C) 2002-4 SQLFairy Authors
   7 #
   8 # This program is free software; you can redistribute it and/or
   9 # modify it under the terms of the GNU General Public License as
  10 # published by the Free Software Foundation; version 2.
  11 #
  12 # This program is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 # General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  20 # 02111-1307  USA
  21 # -------------------------------------------------------------------
  22
  23 =head1 NAME
  24
  25 SQL::Translator::Parser::Oracle - parser for Oracle
  26
  27 =head1 SYNOPSIS
  28
  29   use SQL::Translator;
  30   use SQL::Translator::Parser::Oracle;
  31
  32   my $translator = SQL::Translator->new;
  33   $translator->parser("SQL::Translator::Parser::Oracle");
  34
  35 =head1 DESCRIPTION
  36
  37 From http://www.ss64.com/ora/table_c.html:
  38
  39  CREATE [GLOBAL TEMPORARY] TABLE [schema.]table (tbl_defs,...)
  40      [ON COMMIT {DELETE|PRESERVE} ROWS]
  41          [storage_options | CLUSTER cluster_name (col1, col2,... )
  42             | ORGANIZATION {HEAP [storage_options]
  43             | INDEX idx_organized_tbl_clause}]
  44                [LOB_storage_clause][varray_clause][nested_storage_clause]
  45                    partitioning_options
  46                       [[NO]CACHE] [[NO]MONITORING] [PARALLEL parallel_clause]
  47                          [ENABLE enable_clause | DISABLE disable_clause]
  48                              [AS subquery]
  49
  50 tbl_defs:
  51    column datatype [DEFAULT expr] [column_constraint(s)]
  52    table_ref_constraint
  53
  54 storage_options:
  55    PCTFREE int
  56    PCTUSED int
  57    INITTRANS int
  58    MAXTRANS int
  59    STORAGE storage_clause
  60    TABLESPACE tablespace
  61    [LOGGING|NOLOGGING]
  62
  63 idx_organized_tbl_clause:
  64    storage_option(s) [PCTTHRESHOLD int]
  65      [COMPRESS int|NOCOMPRESS]
  66          [ [INCLUDING column_name] OVERFLOW [storage_option(s)] ]
  67
  68 nested_storage_clause:
  69    NESTED TABLE nested_item STORE AS storage_table
  70       [RETURN AS {LOCATOR|VALUE} ]
  71
  72 partitioning_options:
  73    Partition_clause {ENABLE|DISABLE} ROW MOVEMENT
  74
  75 Column Constraints
  76 (http://www.ss64.com/ora/clause_constraint_col.html)
  77
  78    CONSTRAINT constrnt_name {UNIQUE|PRIMARY KEY} constrnt_state
  79
  80    CONSTRAINT constrnt_name CHECK(condition) constrnt_state
  81
  82    CONSTRAINT constrnt_name [NOT] NULL constrnt_state
  83
  84    CONSTRAINT constrnt_name REFERENCES [schema.]table[(column)]
  85       [ON DELETE {CASCADE|SET NULL}] constrnt_state
  86
  87 constrnt_state
  88     [[NOT] DEFERRABLE] [INITIALLY {IMMEDIATE|DEFERRED}]
  89        [RELY | NORELY] [USING INDEX using_index_clause]
  90           [ENABLE|DISABLE] [VALIDATE|NOVALIDATE]
  91               [EXCEPTIONS INTO [schema.]table]
  92
  93 Note that probably not all of the above syntax is supported, but the grammar
  94 was altered to better handle the syntax created by DDL::Oracle.
  95
  96 =cut
  97
  98 use strict;
  99 use vars qw[ $DEBUG $VERSION $GRAMMAR @EXPORT_OK ];
 100 $VERSION = sprintf "%d.%02d", q$Revision: 1.21 $ =~ /(\d+)\.(\d+)/;
 101 $DEBUG   = 0 unless defined $DEBUG;
 102
 103 use Data::Dumper;
 104 use Parse::RecDescent;
 105 use Exporter;
 106 use base qw(Exporter);
 107
 108 @EXPORT_OK = qw(parse);
 109
 110 # Enable warnings within the Parse::RecDescent module.
 111 $::RD_ERRORS = 1; # Make sure the parser dies when it encounters an error
 112 $::RD_WARN   = 1; # Enable warnings. This will warn on unused rules &c.
 113 $::RD_HINT   = 1; # Give out hints to help fix problems.
 114
 115 my $parser;
 116
 117 $GRAMMAR = q`
 118
 119 { my ( %tables, %indices, %constraints, $table_order, @table_comments ) }
 120
 121 #
 122 # The "eofile" rule makes the parser fail if any "statement" rule
 123 # fails.  Otherwise, the first successful match by a "statement"
 124 # won't cause the failure needed to know that the parse, as a whole,
 125 # failed. -ky
 126 #
 127 startrule : statement(s) eofile
 128     {
 129         $return = {
 130             tables      => \%tables,
 131             indices     => \%indices,
 132             constraints => \%constraints,
 133         };
 134     }
 135
 136 eofile : /^\Z/
 137
 138 statement : remark
 139         | run
 140     | prompt
 141     | create
 142     | table_comment
 143     | comment_on_table
 144     | comment_on_column
 145     | alter
 146     | drop
 147     | <error>
 148
 149 alter : /alter/i WORD /[^;]+/ ';'
 150     { @table_comments = () }
 151
 152 drop : /drop/i TABLE ';'
 153
 154 drop : /drop/i WORD(s) ';'
 155     { @table_comments = () }
 156
 157 create : create_table table_name '(' create_definition(s /,/) ')' table_option(s?) ';'
 158     {
 159         my $table_name                       = $item{'table_name'};
 160         $tables{ $table_name }{'order'}      = ++$table_order;
 161         $tables{ $table_name }{'table_name'} = $table_name;
 162
 163         if ( @table_comments ) {
 164             $tables{ $table_name }{'comments'} = [ @table_comments ];
 165             @table_comments = ();
 166         }
 167
 168         my $i = 1;
 169         my @constraints;
 170         for my $definition ( @{ $item[4] } ) {
 171             if ( $definition->{'type'} eq 'field' ) {
 172                 my $field_name = $definition->{'name'};
 173                 $tables{ $table_name }{'fields'}{ $field_name } =
 174                     { %$definition, order => $i };
 175                 $i++;
 176
 177                 for my $constraint ( @{ $definition->{'constraints'} || [] } ) {
 178                     $constraint->{'fields'} = [ $field_name ];
 179                     push @{ $tables{ $table_name }{'constraints'} },
 180                         $constraint;
 181                 }
 182             }
 183             elsif ( $definition->{'type'} eq 'constraint' ) {
 184                 $definition->{'type'} = $definition->{'constraint_type'};
 185                 push @{ $tables{ $table_name }{'constraints'} }, $definition;
 186             }
 187             else {
 188                 push @{ $tables{ $table_name }{'indices'} }, $definition;
 189             }
 190         }
 191
 192         for my $option ( @{ $item[6] } ) {
 193             push @{ $tables{ $table_name }{'table_options'} }, $option;
 194         }
 195
 196         1;
 197     }
 198
 199 create : create_index index_name /on/i table_name parens_word_list table_option(?) ';'
 200     {
 201         my $table_name = $item[4];
 202         if ( $item[1] ) {
 203             push @{ $constraints{ $table_name } }, {
 204                 name   => $item[2],
 205                 type   => 'unique',
 206                 fields => $item[5],
 207             };
 208         }
 209         else {
 210             push @{ $indices{ $table_name } }, {
 211                 name   => $item[2],
 212                 type   => 'normal',
 213                 fields => $item[5],
 214             };
 215         }
 216     }
 217
 218 # Create anything else (e.g., domain, function, etc.)
 219 create : ...!create_table ...!create_index /create/i WORD /[^;]+/ ';'
 220     { @table_comments = () }
 221
 222 create_index : /create/i UNIQUE(?) /index/i
 223         { $return = $item[2] }
 224
 225 index_name : NAME '.' NAME
 226     { $item[3] }
 227     | NAME
 228     { $item[1] }
 229
 230 global_temporary: /global/i /temporary/i
 231
 232 table_name : NAME '.' NAME
 233     { $item[3] }
 234     | NAME
 235     { $item[1] }
 236
 237 create_definition : field
 238     | table_constraint
 239     | <error>
 240
 241 table_comment : comment
 242     {
 243         my $comment = $item[1];
 244         $return     = $comment;
 245         push @table_comments, $comment;
 246     }
 247
 248 comment : /^\s*(?:#|-{2}).*\n/
 249     {
 250         my $comment =  $item[1];
 251         $comment    =~ s/^\s*(#|-{2})\s*//;
 252         $comment    =~ s/\s*$//;
 253         $return     = $comment;
 254     }
 255
 256 comment : /\/\*/ /[^\*]+/ /\*\//
 257     {
 258         my $comment = $item[2];
 259         $comment    =~ s/^\s*|\s*$//g;
 260         $return = $comment;
 261     }
 262
 263 remark : /^REM\s+.*\n/
 264
 265 run : /^(RUN|\/)\s+.*\n/
 266
 267 prompt : /prompt/i /(table|index|sequence|trigger)/i ';'
 268
 269 prompt : /prompt\s+create\s+.*\n/i
 270
 271 comment_on_table : /comment/i /on/i /table/i table_name /is/i comment_phrase ';'
 272     {
 273         push @{ $tables{ $item{'table_name'} }{'comments'} }, $item{'comment_phrase'};
 274     }
 275
 276 comment_on_column : /comment/i /on/i /column/i column_name /is/i comment_phrase ';'
 277     {
 278         my $table_name = $item[4]->{'table'};
 279         my $field_name = $item[4]->{'field'};
 280         push @{ $tables{ $table_name }{'fields'}{ $field_name }{'comments'} },
 281             $item{'comment_phrase'};
 282     }
 283
 284 column_name : NAME '.' NAME
 285     { $return = { table => $item[1], field => $item[3] } }
 286
 287 comment_phrase : /'.*?'/
 288     {
 289         my $val = $item[1];
 290         $val =~ s/^'|'$//g;
 291         $return = $val;
 292     }
 293
 294 field : comment(s?) field_name data_type field_meta(s?) comment(s?)
 295     {
 296         my ( $is_pk, $default, @constraints );
 297         my $null = 1;
 298         for my $meta ( @{ $item[4] } ) {
 299             if ( $meta->{'type'} eq 'default' ) {
 300                 $default = $meta;
 301                 next;
 302             }
 303             elsif ( $meta->{'type'} eq 'not_null' ) {
 304                 $null = 0;
 305                 next;
 306             }
 307             elsif ( $meta->{'type'} eq 'primary_key' ) {
 308                 $is_pk = 1;
 309             }
 310
 311             push @constraints, $meta if $meta->{'supertype'} eq 'constraint';
 312         }
 313
 314         my @comments = ( @{ $item[1] }, @{ $item[5] } );
 315
 316         $return = {
 317             type           => 'field',
 318             name           => $item{'field_name'},
 319             data_type      => $item{'data_type'}{'type'},
 320             size           => $item{'data_type'}{'size'},
 321             null           => $null,
 322             default        => $default->{'value'},
 323             is_primary_key => $is_pk,
 324             constraints    => [ @constraints ],
 325             comments       => [ @comments ],
 326         }
 327     }
 328     | <error>
 329
 330 field_name : NAME
 331
 332 data_type : ora_data_type parens_value_list(?)
 333     {
 334         $return  = {
 335             type => $item[1],
 336             size => $item[2][0] || '',
 337         }
 338     }
 339
 340 column_constraint : constraint_name(?) column_constraint_type constraint_state(s?)
 341     {
 342         my $desc       = $item{'column_constraint_type'};
 343         my $type       = $desc->{'type'};
 344         my $fields     = $desc->{'fields'}     || [];
 345         my $expression = $desc->{'expression'} || '';
 346
 347         $return              =  {
 348             supertype        => 'constraint',
 349             name             => $item{'constraint_name(?)'}[0] || '',
 350             type             => $type,
 351             expression       => $type eq 'check' ? $expression : '',
 352             deferrable       => $item{'deferrable'},
 353             deferred         => $item{'deferred'},
 354             reference_table  => $desc->{'reference_table'},
 355             reference_fields => $desc->{'reference_fields'},
 356 #            match_type       => $desc->{'match_type'},
 357 #            on_update        => $desc->{'on_update'},
 358         }
 359     }
 360
 361 constraint_name : /constraint/i NAME { $item[2] }
 362
 363 column_constraint_type : /not\s+null/i { $return = { type => 'not_null' } }
 364     | /null/
 365         { $return = { type => 'null' } }
 366     | /unique/
 367         { $return = { type => 'unique' } }
 368     | /primary\s+key/i
 369         { $return = { type => 'primary_key' } }
 370     | /check/i '(' /[^)]+/ ')'
 371         { $return = { type => 'check', expression => $item[3] } }
 372     | /references/i table_name parens_word_list(?) on_delete(?)
 373     {
 374         $return              =  {
 375             type             => 'foreign_key',
 376             reference_table  => $item[2],
 377             reference_fields => $item[3][0],
 378 #            match_type       => $item[4][0],
 379             on_delete     => $item[5][0],
 380         }
 381     }
 382
 383 constraint_state : deferrable { $return = { type => $item[1] } }
 384     | deferred { $return = { type => $item[1] } }
 385     | /(no)?rely/i { $return = { type => $item[1] } }
 386 #    | /using/i /index/i using_index_clause
 387 #        { $return = { type => 'using_index', index => $item[3] } }
 388     | /(dis|en)able/i { $return = { type => $item[1] } }
 389     | /(no)?validate/i { $return = { type => $item[1] } }
 390     | /exceptions/i /into/i table_name
 391         { $return = { type => 'exceptions_into', table => $item[3] } }
 392
 393 deferrable : /not/i /deferrable/i
 394     { $return = 'not_deferrable' }
 395     | /deferrable/i
 396     { $return = 'deferrable' }
 397
 398 deferred : /initially/i /(deferred|immediate)/i { $item[2] }
 399
 400 ora_data_type :
 401     /(n?varchar2|varchar)/i { $return = 'varchar2' }
 402     |
 403     /n?char/i { $return = 'character' }
 404     |
 405         /n?dec/i { $return = 'decimal' }
 406         |
 407     /number/i { $return = 'number' }
 408     |
 409     /integer/i { $return = 'integer' }
 410     |
 411     /(pls_integer|binary_integer)/i { $return = 'integer' }
 412     |
 413     /interval\s+day/i { $return = 'interval day' }
 414     |
 415     /interval\s+year/i { $return = 'interval year' }
 416     |
 417     /long\s+raw/i { $return = 'long raw' }
 418     |
 419     /(long|date|timestamp|raw|rowid|urowid|mlslabel|clob|nclob|blob|bfile|float)/i { $item[1] }
 420
 421 parens_value_list : '(' VALUE(s /,/) ')'
 422     { $item[2] }
 423
 424 parens_word_list : '(' WORD(s /,/) ')'
 425     { $item[2] }
 426
 427 field_meta : default_val
 428     | column_constraint
 429
 430 default_val  : /default/i /(?:')?[\w\d.-]*(?:')?/
 431     {
 432         my $val =  $item[2];
 433         $val    =~ s/'//g if defined $val;
 434         $return =  {
 435             supertype => 'constraint',
 436             type      => 'default',
 437             value     => $val,
 438         }
 439     }
 440
 441 create_table : /create/i global_temporary(?) /table/i
 442
 443 table_option : /organization/i WORD
 444     {
 445         $return = { 'ORGANIZATION' => $item[2] }
 446     }
 447
 448 table_option : /nomonitoring/i
 449     {
 450         $return = { 'NOMONITORING' => undef }
 451     }
 452
 453 table_option : /parallel/i '(' key_value(s) ')'
 454     {
 455         $return = { 'PARALLEL' => $item[3] }
 456     }
 457
 458 key_value : WORD VALUE
 459     {
 460         $return = { $item[1], $item[2] }
 461     }
 462
 463 table_option : /[^;]+/
 464
 465 table_constraint : comment(s?) constraint_name(?) table_constraint_type deferrable(?) deferred(?) constraint_state(s?) comment(s?)
 466     {
 467         my $desc       = $item{'table_constraint_type'};
 468         my $type       = $desc->{'type'};
 469         my $fields     = $desc->{'fields'};
 470         my $expression = $desc->{'expression'};
 471         my @comments   = ( @{ $item[1] }, @{ $item[-1] } );
 472
 473         $return              =  {
 474             name             => $item{'constraint_name(?)'}[0] || '',
 475             type             => 'constraint',
 476             constraint_type  => $type,
 477             fields           => $type ne 'check' ? $fields : [],
 478             expression       => $type eq 'check' ? $expression : '',
 479             deferrable       => $item{'deferrable(?)'},
 480             deferred         => $item{'deferred(?)'},
 481             reference_table  => $desc->{'reference_table'},
 482             reference_fields => $desc->{'reference_fields'},
 483 #            match_type       => $desc->{'match_type'}[0],
 484             on_delete        => $desc->{'on_delete'} || $desc->{'on_delete_do'},
 485             on_update        => $desc->{'on_update'} || $desc->{'on_update_do'},
 486             comments         => [ @comments ],
 487         }
 488     }
 489
 490 table_constraint_type : /primary key/i '(' NAME(s /,/) ')'
 491     {
 492         $return = {
 493             type   => 'primary_key',
 494             fields => $item[3],
 495         }
 496     }
 497     |
 498     /unique/i '(' NAME(s /,/) ')'
 499     {
 500         $return    =  {
 501             type   => 'unique',
 502             fields => $item[3],
 503         }
 504     }
 505     |
 506     /check/ '(' /(.+)/ ')'
 507     {
 508         $return        =  {
 509             type       => 'check',
 510             expression => $item[3],
 511         }
 512     }
 513     |
 514     /foreign key/i '(' NAME(s /,/) ')' /references/i table_name parens_word_list(?) on_delete(?)
 515     {
 516         $return              =  {
 517             type             => 'foreign_key',
 518             fields           => $item[3],
 519             reference_table  => $item[6],
 520             reference_fields => $item[7][0],
 521             match_type       => $item[8][0],
 522             on_delete     => $item[9][0],
 523             on_update     => $item[10][0],
 524         }
 525     }
 526
 527 on_delete : /on delete/i WORD(s)
 528     { $item[2] }
 529
 530 UNIQUE : /unique/i { $return = 1 }
 531
 532 WORD : /\w+/
 533
 534 NAME : /\w+/ { $item[1] }
 535
 536 TABLE : /table/i
 537
 538 VALUE   : /[-+]?\.?\d+(?:[eE]\d+)?/
 539     { $item[1] }
 540     | /'.*?'/   # XXX doesn't handle embedded quotes
 541     { $item[1] }
 542     | /NULL/
 543     { 'NULL' }
 544
 545 `;
 546
 547 # -------------------------------------------------------------------
 548 sub parse {
 549     my ( $translator, $data ) = @_;
 550     $parser ||= Parse::RecDescent->new($GRAMMAR);
 551
 552     local $::RD_TRACE = $translator->trace ? 1 : undef;
 553     local $DEBUG      = $translator->debug;
 554
 555     unless (defined $parser) {
 556         return $translator->error("Error instantiating Parse::RecDescent ".
 557             "instance: Bad grammer");
 558     }
 559
 560     my $result = $parser->startrule( $data );
 561     die "Parse failed.\n" unless defined $result;
 562     if ( $DEBUG ) {
 563         warn "Parser results =\n", Dumper($result), "\n";
 564     }
 565
 566     my $schema      = $translator->schema;
 567     my $indices     = $result->{'indices'};
 568     my $constraints = $result->{'constraints'};
 569     my @tables      = sort {
 570         $result->{'tables'}{ $a }{'order'}
 571         <=>
 572         $result->{'tables'}{ $b }{'order'}
 573     } keys %{ $result->{'tables'} };
 574
 575     for my $table_name ( @tables ) {
 576         my $tdata    =  $result->{'tables'}{ $table_name };
 577         next unless $tdata->{'table_name'};
 578         my $table    =  $schema->add_table(
 579             name     => $tdata->{'table_name'},
 580             comments => $tdata->{'comments'},
 581         ) or die $schema->error;
 582
 583         $table->options( $tdata->{'table_options'} );
 584
 585         my @fields = sort {
 586             $tdata->{'fields'}->{$a}->{'order'}
 587             <=>
 588             $tdata->{'fields'}->{$b}->{'order'}
 589         } keys %{ $tdata->{'fields'} };
 590
 591         for my $fname ( @fields ) {
 592             my $fdata = $tdata->{'fields'}{ $fname };
 593             my $field = $table->add_field(
 594                 name              => $fdata->{'name'},
 595                 data_type         => $fdata->{'data_type'},
 596                 size              => $fdata->{'size'},
 597                 default_value     => $fdata->{'default'},
 598                 is_auto_increment => $fdata->{'is_auto_inc'},
 599                 is_nullable       => $fdata->{'null'},
 600                 comments          => $fdata->{'comments'},
 601             ) or die $table->error;
 602         }
 603
 604         push @{ $tdata->{'indices'} }, @{ $indices->{ $table_name } || [] };
 605         push @{ $tdata->{'constraints'} },
 606              @{ $constraints->{ $table_name } || [] };
 607
 608         for my $idata ( @{ $tdata->{'indices'} || [] } ) {
 609             my $index  =  $table->add_index(
 610                 name   => $idata->{'name'},
 611                 type   => uc $idata->{'type'},
 612                 fields => $idata->{'fields'},
 613             ) or die $table->error;
 614         }
 615
 616         for my $cdata ( @{ $tdata->{'constraints'} || [] } ) {
 617             my $constraint       =  $table->add_constraint(
 618                 name             => $cdata->{'name'},
 619                 type             => $cdata->{'type'},
 620                 fields           => $cdata->{'fields'},
 621                 reference_table  => $cdata->{'reference_table'},
 622                 reference_fields => $cdata->{'reference_fields'},
 623                 match_type       => $cdata->{'match_type'} || '',
 624                 on_delete        => $cdata->{'on_delete'} || $cdata->{'on_delete_do'},
 625                 on_update        => $cdata->{'on_update'} || $cdata->{'on_update_do'},
 626             ) or die $table->error;
 627         }
 628     }
 629
 630     return 1;
 631 }
 632
 633 1;
 634
 635 # -------------------------------------------------------------------
 636 # Something there is that doesn't love a wall.
 637 # Robert Frost
 638 # -------------------------------------------------------------------
 639
 640 =pod
 641
 642 =head1 AUTHOR
 643
 644 Ken Y. Clark E<lt>kclark@cpan.orgE<gt>.
 645
 646 =head1 SEE ALSO
 647
 648 SQL::Translator, Parse::RecDescent, DDL::Oracle.
 649
 650 =cut