lib/SQL/Translator/Parser/DBI/PostgreSQL.pm

   1 package SQL::Translator::Parser::DBI::PostgreSQL;
   2
   3 # -------------------------------------------------------------------
   4 # Copyright (C) 2002-2009 SQLFairy Authors
   5 #
   6 # This program is free software; you can redistribute it and/or
   7 # modify it under the terms of the GNU General Public License as
   8 # published by the Free Software Foundation; version 2.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18 # 02111-1307  USA
  19 # -------------------------------------------------------------------
  20
  21 =head1 NAME
  22
  23 SQL::Translator::Parser::DBI::PostgreSQL - parser for DBD::Pg
  24
  25 =head1 SYNOPSIS
  26
  27 See SQL::Translator::Parser::DBI.
  28
  29 =head1 DESCRIPTION
  30
  31 Uses DBI to query PostgreSQL system tables to determine schema structure.
  32
  33 =cut
  34
  35 use strict;
  36 use DBI;
  37 use Data::Dumper;
  38 use SQL::Translator::Schema::Constants;
  39
  40 use vars qw[ $DEBUG $VERSION @EXPORT_OK ];
  41 $VERSION = '1.59';
  42 $DEBUG   = 0 unless defined $DEBUG;
  43
  44 my $actions = {c => 'cascade',
  45                r => 'restrict',
  46                a => 'no action',
  47                n => 'set null',
  48                d => 'set default',
  49            };
  50
  51 # -------------------------------------------------------------------
  52 sub parse {
  53     my ( $tr, $dbh ) = @_;
  54
  55     my $schema = $tr->schema;
  56
  57     my $column_select = $dbh->prepare(
  58       "SELECT a.attname, format_type(t.oid, a.atttypmod) as typname, a.attnum,
  59               a.atttypmod as length, a.attnotnull, a.atthasdef, d.adsrc
  60        FROM pg_type t,pg_attribute a
  61        LEFT JOIN pg_attrdef d ON (d.adrelid = a.attrelid AND a.attnum = d.adnum)
  62        WHERE a.attrelid=? AND attnum>0
  63          AND a.atttypid=t.oid
  64        ORDER BY a.attnum"
  65     );
  66
  67     my $index_select  = $dbh->prepare(
  68       "SELECT oid, c.relname, i.indkey, i.indnatts, i.indisunique,
  69               ARRAY(SELECT a.attname
  70                   FROM pg_attribute a
  71                   WHERE a.attrelid=i.indrelid AND a.attnum = ANY(i.indkey)
  72               ) AS attname,
  73               i.indisprimary, pg_get_indexdef(oid) AS create_string
  74        FROM pg_class c,pg_index i
  75        WHERE c.relnamespace IN (SELECT oid FROM pg_namespace WHERE nspname='public') AND c.relkind='i'
  76          AND c.oid=i.indexrelid AND i.indrelid=?"
  77     );
  78
  79     my $table_select  = $dbh->prepare(
  80       "SELECT oid,relname FROM pg_class WHERE relnamespace IN
  81           (SELECT oid FROM pg_namespace WHERE nspname='public')
  82           AND relkind='r';"
  83     );
  84
  85     my $fk_select = $dbh->prepare(
  86         q/
  87 SELECT r.conname,
  88        c.relname,
  89        d.relname AS frelname,
  90        r.conkey,
  91        ARRAY(SELECT column_name::varchar
  92                FROM information_schema.columns
  93               WHERE ordinal_position = ANY  (r.conkey)
  94                 AND table_schema = n.nspname
  95                 AND table_name   =   c.relname ) AS fields,
  96        r.confkey,
  97        ARRAY(SELECT column_name::varchar
  98                FROM information_schema.columns
  99               WHERE ordinal_position = ANY  (r.confkey)
 100                 AND table_schema =   n.nspname
 101                 AND table_name   =   d.relname ) AS reference_fields,
 102        r.confupdtype,
 103        r.confdeltype,
 104        r.confmatchtype
 105
 106 FROM pg_catalog.pg_constraint r
 107
 108 JOIN pg_catalog.pg_class c
 109   ON c.oid = r.conrelid
 110  AND r.contype = 'f'
 111
 112 JOIN pg_catalog.pg_class d
 113   ON d.oid = r.confrelid
 114
 115 JOIN pg_catalog.pg_namespace n
 116   ON n.oid = c.relnamespace
 117
 118 WHERE pg_catalog.pg_table_is_visible(c.oid)
 119   AND n.nspname = ?
 120   AND c.relname = ?
 121 ORDER BY 1;
 122         /) or die "Can't prepare: $@";
 123
 124     $table_select->execute();
 125
 126     while ( my $tablehash = $table_select->fetchrow_hashref ) {
 127
 128         my $table_name = $$tablehash{'relname'};
 129         my $table_oid  = $$tablehash{'oid'};
 130
 131         my $table = $schema->add_table(
 132                                        name => $table_name,
 133               #what is type?               type => $table_info->{TABLE_TYPE},
 134                                           ) || die $schema->error;
 135
 136         $column_select->execute($table_oid);
 137
 138         while (my $columnhash = $column_select->fetchrow_hashref ) {
 139
 140             #data_type seems to not be populated; perhaps there needs to
 141             #be a mapping of query output to reserved constants in sqlt?
 142
 143             my $col = $table->add_field(
 144                               name        => $$columnhash{'attname'},
 145                               default_value => $$columnhash{'adsrc'},
 146                               data_type   => $$columnhash{'typname'},
 147                               order       => $$columnhash{'attnum'},
 148                              ) || die $table->error;
 149
 150             $col->{size} = [$$columnhash{'length'}]
 151                 if $$columnhash{'length'}>0 && $$columnhash{'length'}<=0xFFFF;
 152             $col->{is_nullable} = $$columnhash{'attnotnull'} ? 0 : 1;
 153         }
 154
 155         $index_select->execute($table_oid);
 156
 157         my @column_names = $table->field_names();
 158         while (my $indexhash = $index_select->fetchrow_hashref ) {
 159               #don't deal with function indexes at the moment
 160             next if ($$indexhash{'indkey'} eq ''
 161                      or !defined($$indexhash{'indkey'}) );
 162
 163             my $type;
 164             if      ($$indexhash{'indisprimary'}) {
 165                 $type = UNIQUE; #PRIMARY_KEY;
 166
 167                 #tell sqlt that this is the primary key:
 168                 my $col_name=$column_names[($$indexhash{'indkey'} - 1)];
 169                 $table->get_field($col_name)->{is_primary_key}=1;
 170
 171             } elsif ($$indexhash{'indisunique'}) {
 172                 $type = UNIQUE;
 173             } else {
 174                 $type = NORMAL;
 175             }
 176
 177
 178             my @column_ids = split /\s+/, $$indexhash{'indkey'};
 179             my @columns = split /\s+/, $$indexhash{'attname'};
 180
 181             $table->add_index(
 182                               name         => $$indexhash{'relname'},
 183                               type         => $type,
 184                               fields       => \@columns,
 185                              ) || die $table->error;
 186         }
 187
 188         $fk_select->execute('public',$table_name) or die "Can't execute: $@";
 189         my $fkeys = $fk_select->fetchall_arrayref({});
 190         $DEBUG and print Dumper $fkeys;
 191         for my $con (@$fkeys){
 192             my $con_name         = $con->{conname};
 193             my $fields           = $con->{fields};
 194             my $reference_fields = $con->{reference_fields};
 195             my $reference_table  = $con->{frelname};
 196             my $on_upd           = $con->{confupdtype};
 197             my $on_del           = $con->{confdeltype};
 198             $table->add_constraint(
 199                                    name   => $con_name,
 200                                    type   => 'foreign_key',
 201                                    fields =>  $fields,
 202                                    reference_fields => $reference_fields,
 203                                    reference_table => $reference_table,
 204                                    on_delete  => $actions->{$on_upd},
 205                                    on_update  => $actions->{$on_del},
 206                                );
 207         }
 208     }
 209
 210
 211     return 1;
 212 }
 213
 214 1;
 215
 216 # -------------------------------------------------------------------
 217 # Time is a waste of money.
 218 # Oscar Wilde
 219 # -------------------------------------------------------------------
 220
 221 =pod
 222
 223 =head1 AUTHOR
 224
 225 Scott Cain E<lt>cain@cshl.eduE<gt>, previous author:
 226 Paul Harrington E<lt>harringp@deshaw.comE<gt>.
 227
 228 =head1 SEE ALSO
 229
 230 SQL::Translator, DBD::Pg.
 231
 232 =cut