lib/SQL/Abstract.pm

   1 package SQL::Abstract; # see doc at end of file
   2
   3 # LDNOTE : this code is heavy refactoring from original SQLA.
   4 # Several design decisions will need discussion during
   5 # the test / diffusion / acceptance phase; those are marked with flag
   6 # 'LDNOTE' (note by laurent.dami AT free.fr)
   7
   8 use strict;
   9 use warnings;
  10 use Carp ();
  11 use List::Util ();
  12 use Scalar::Util ();
  13 use Data::Query::Constants qw(
  14   DQ_IDENTIFIER DQ_OPERATOR DQ_VALUE DQ_LITERAL
  15 );
  16
  17 #======================================================================
  18 # GLOBALS
  19 #======================================================================
  20
  21 our $VERSION  = '1.72';
  22
  23 # This would confuse some packagers
  24 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
  25
  26 our $AUTOLOAD;
  27
  28 # special operators (-in, -between). May be extended/overridden by user.
  29 # See section WHERE: BUILTIN SPECIAL OPERATORS below for implementation
  30 my @BUILTIN_SPECIAL_OPS = (
  31   {regex => qr/^ (?: not \s )? between $/ix, handler => '_where_field_BETWEEN'},
  32   {regex => qr/^ (?: not \s )? in      $/ix, handler => '_where_field_IN'},
  33   {regex => qr/^ ident                 $/ix, handler => '_where_op_IDENT'},
  34   {regex => qr/^ value                 $/ix, handler => '_where_op_VALUE'},
  35 );
  36
  37 # unaryish operators - key maps to handler
  38 my @BUILTIN_UNARY_OPS = (
  39   # the digits are backcompat stuff
  40   { regex => qr/^ and  (?: [_\s]? \d+ )? $/xi, handler => '_where_op_ANDOR' },
  41   { regex => qr/^ or   (?: [_\s]? \d+ )? $/xi, handler => '_where_op_ANDOR' },
  42   { regex => qr/^ nest (?: [_\s]? \d+ )? $/xi, handler => '_where_op_NEST' },
  43   { regex => qr/^ (?: not \s )? bool     $/xi, handler => '_where_op_BOOL' },
  44   { regex => qr/^ ident                  $/xi, handler => '_where_op_IDENT' },
  45   { regex => qr/^ value                  $/ix, handler => '_where_op_VALUE' },
  46 );
  47
  48 #======================================================================
  49 # DEBUGGING AND ERROR REPORTING
  50 #======================================================================
  51
  52 sub _debug {
  53   return unless $_[0]->{debug}; shift; # a little faster
  54   my $func = (caller(1))[3];
  55   warn "[$func] ", @_, "\n";
  56 }
  57
  58 sub belch (@) {
  59   my($func) = (caller(1))[3];
  60   Carp::carp "[$func] Warning: ", @_;
  61 }
  62
  63 sub puke (@) {
  64   my($func) = (caller(1))[3];
  65   Carp::croak "[$func] Fatal: ", @_;
  66 }
  67
  68
  69 #======================================================================
  70 # NEW
  71 #======================================================================
  72
  73 sub new {
  74   my $self = shift;
  75   my $class = ref($self) || $self;
  76   my %opt = (ref $_[0] eq 'HASH') ? %{$_[0]} : @_;
  77
  78   # choose our case by keeping an option around
  79   delete $opt{case} if $opt{case} && $opt{case} ne 'lower';
  80
  81   # default logic for interpreting arrayrefs
  82   $opt{logic} = $opt{logic} ? uc $opt{logic} : 'OR';
  83
  84   # how to return bind vars
  85   # LDNOTE: changed nwiger code : why this 'delete' ??
  86   # $opt{bindtype} ||= delete($opt{bind_type}) || 'normal';
  87   $opt{bindtype} ||= 'normal';
  88
  89   # default comparison is "=", but can be overridden
  90   $opt{cmp} ||= '=';
  91
  92   # try to recognize which are the 'equality' and 'unequality' ops
  93   # (temporary quickfix, should go through a more seasoned API)
  94   $opt{equality_op}   = qr/^(\Q$opt{cmp}\E|is|(is\s+)?like)$/i;
  95   $opt{inequality_op} = qr/^(!=|<>|(is\s+)?not(\s+like)?)$/i;
  96
  97   # SQL booleans
  98   $opt{sqltrue}  ||= '1=1';
  99   $opt{sqlfalse} ||= '0=1';
 100
 101   # special operators
 102   $opt{special_ops} ||= [];
 103   # regexes are applied in order, thus push after user-defines
 104   push @{$opt{special_ops}}, @BUILTIN_SPECIAL_OPS;
 105
 106   # unary operators
 107   $opt{unary_ops} ||= [];
 108   push @{$opt{unary_ops}}, @BUILTIN_UNARY_OPS;
 109
 110   # rudimentary saniy-check for user supplied bits treated as functions/operators
 111   # If a purported  function matches this regular expression, an exception is thrown.
 112   # Literal SQL is *NOT* subject to this check, only functions (and column names
 113   # when quoting is not in effect)
 114
 115   # FIXME
 116   # need to guard against ()'s in column names too, but this will break tons of
 117   # hacks... ideas anyone?
 118   $opt{injection_guard} ||= qr/
 119     \;
 120       |
 121     ^ \s* go \s
 122   /xmi;
 123
 124   $opt{name_sep} ||= '.';
 125
 126   $opt{renderer} ||= do {
 127     require Data::Query::Renderer::SQL::Naive;
 128     my ($always, $chars);
 129     for ($opt{quote_char}) {
 130       $chars = defined() ? (ref() ? $_ : [$_]) : ['',''];
 131       $always = defined;
 132     }
 133     Data::Query::Renderer::SQL::Naive->new({
 134       quote_chars => $chars, always_quote => $always,
 135     });
 136   };
 137
 138   return bless \%opt, $class;
 139 }
 140
 141 sub _render_dq {
 142   my ($self, $dq) = @_;
 143   my ($sql, @bind) = @{$self->{renderer}->render($dq)};
 144   wantarray ? ($sql, map $_->{value}, @bind) : $sql;
 145 }
 146
 147 sub _assert_pass_injection_guard {
 148   if ($_[1] =~ $_[0]->{injection_guard}) {
 149     my $class = ref $_[0];
 150     puke "Possible SQL injection attempt '$_[1]'. If this is indeed a part of the "
 151      . "desired SQL use literal SQL ( \'...' or \[ '...' ] ) or supply your own "
 152      . "{injection_guard} attribute to ${class}->new()"
 153   }
 154 }
 155
 156
 157 #======================================================================
 158 # INSERT methods
 159 #======================================================================
 160
 161 sub insert {
 162   my $self    = shift;
 163   my $table   = $self->_table(shift);
 164   my $data    = shift || return;
 165   my $options = shift;
 166
 167   my $method       = $self->_METHOD_FOR_refkind("_insert", $data);
 168   my ($sql, @bind) = $self->$method($data);
 169   $sql = join " ", $self->_sqlcase('insert into'), $table, $sql;
 170
 171   if ($options->{returning}) {
 172     my ($s, @b) = $self->_insert_returning ($options);
 173     $sql .= $s;
 174     push @bind, @b;
 175   }
 176
 177   return wantarray ? ($sql, @bind) : $sql;
 178 }
 179
 180 sub _insert_returning {
 181   my ($self, $options) = @_;
 182
 183   my $f = $options->{returning};
 184
 185   my $fieldlist = $self->_SWITCH_refkind($f, {
 186     ARRAYREF     => sub {join ', ', map { $self->_quote($_) } @$f;},
 187     SCALAR       => sub {$self->_quote($f)},
 188     SCALARREF    => sub {$$f},
 189   });
 190   return $self->_sqlcase(' returning ') . $fieldlist;
 191 }
 192
 193 sub _insert_HASHREF { # explicit list of fields and then values
 194   my ($self, $data) = @_;
 195
 196   my @fields = sort keys %$data;
 197
 198   my ($sql, @bind) = $self->_insert_values($data);
 199
 200   # assemble SQL
 201   $_ = $self->_quote($_) foreach @fields;
 202   $sql = "( ".join(", ", @fields).") ".$sql;
 203
 204   return ($sql, @bind);
 205 }
 206
 207 sub _insert_ARRAYREF { # just generate values(?,?) part (no list of fields)
 208   my ($self, $data) = @_;
 209
 210   # no names (arrayref) so can't generate bindtype
 211   $self->{bindtype} ne 'columns'
 212     or belch "can't do 'columns' bindtype when called with arrayref";
 213
 214   # fold the list of values into a hash of column name - value pairs
 215   # (where the column names are artificially generated, and their
 216   # lexicographical ordering keep the ordering of the original list)
 217   my $i = "a";  # incremented values will be in lexicographical order
 218   my $data_in_hash = { map { ($i++ => $_) } @$data };
 219
 220   return $self->_insert_values($data_in_hash);
 221 }
 222
 223 sub _insert_ARRAYREFREF { # literal SQL with bind
 224   my ($self, $data) = @_;
 225
 226   my ($sql, @bind) = @${$data};
 227   $self->_assert_bindval_matches_bindtype(@bind);
 228
 229   return ($sql, @bind);
 230 }
 231
 232
 233 sub _insert_SCALARREF { # literal SQL without bind
 234   my ($self, $data) = @_;
 235
 236   return ($$data);
 237 }
 238
 239 sub _insert_values {
 240   my ($self, $data) = @_;
 241
 242   my (@values, @all_bind);
 243   foreach my $column (sort keys %$data) {
 244     my $v = $data->{$column};
 245
 246     $self->_SWITCH_refkind($v, {
 247
 248       ARRAYREF => sub {
 249         if ($self->{array_datatypes}) { # if array datatype are activated
 250           push @values, '?';
 251           push @all_bind, $self->_bindtype($column, $v);
 252         }
 253         else {                          # else literal SQL with bind
 254           my ($sql, @bind) = @$v;
 255           $self->_assert_bindval_matches_bindtype(@bind);
 256           push @values, $sql;
 257           push @all_bind, @bind;
 258         }
 259       },
 260
 261       ARRAYREFREF => sub { # literal SQL with bind
 262         my ($sql, @bind) = @${$v};
 263         $self->_assert_bindval_matches_bindtype(@bind);
 264         push @values, $sql;
 265         push @all_bind, @bind;
 266       },
 267
 268       # THINK : anything useful to do with a HASHREF ?
 269       HASHREF => sub {  # (nothing, but old SQLA passed it through)
 270         #TODO in SQLA >= 2.0 it will die instead
 271         belch "HASH ref as bind value in insert is not supported";
 272         push @values, '?';
 273         push @all_bind, $self->_bindtype($column, $v);
 274       },
 275
 276       SCALARREF => sub {  # literal SQL without bind
 277         push @values, $$v;
 278       },
 279
 280       SCALAR_or_UNDEF => sub {
 281         push @values, '?';
 282         push @all_bind, $self->_bindtype($column, $v);
 283       },
 284
 285      });
 286
 287   }
 288
 289   my $sql = $self->_sqlcase('values')." ( ".join(", ", @values)." )";
 290   return ($sql, @all_bind);
 291 }
 292
 293
 294
 295 #======================================================================
 296 # UPDATE methods
 297 #======================================================================
 298
 299
 300 sub update {
 301   my $self  = shift;
 302   my $table = $self->_table(shift);
 303   my $data  = shift || return;
 304   my $where = shift;
 305
 306   # first build the 'SET' part of the sql statement
 307   my (@set, @all_bind);
 308   puke "Unsupported data type specified to \$sql->update"
 309     unless ref $data eq 'HASH';
 310
 311   for my $k (sort keys %$data) {
 312     my $v = $data->{$k};
 313     my $r = ref $v;
 314     my $label = $self->_quote($k);
 315
 316     $self->_SWITCH_refkind($v, {
 317       ARRAYREF => sub {
 318         if ($self->{array_datatypes}) { # array datatype
 319           push @set, "$label = ?";
 320           push @all_bind, $self->_bindtype($k, $v);
 321         }
 322         else {                          # literal SQL with bind
 323           my ($sql, @bind) = @$v;
 324           $self->_assert_bindval_matches_bindtype(@bind);
 325           push @set, "$label = $sql";
 326           push @all_bind, @bind;
 327         }
 328       },
 329       ARRAYREFREF => sub { # literal SQL with bind
 330         my ($sql, @bind) = @${$v};
 331         $self->_assert_bindval_matches_bindtype(@bind);
 332         push @set, "$label = $sql";
 333         push @all_bind, @bind;
 334       },
 335       SCALARREF => sub {  # literal SQL without bind
 336         push @set, "$label = $$v";
 337       },
 338       HASHREF => sub {
 339         my ($op, $arg, @rest) = %$v;
 340
 341         puke 'Operator calls in update must be in the form { -op => $arg }'
 342           if (@rest or not $op =~ /^\-(.+)/);
 343
 344         local $self->{_nested_func_lhs} = $k;
 345         my ($sql, @bind) = $self->_where_unary_op ($1, $arg);
 346
 347         push @set, "$label = $sql";
 348         push @all_bind, @bind;
 349       },
 350       SCALAR_or_UNDEF => sub {
 351         push @set, "$label = ?";
 352         push @all_bind, $self->_bindtype($k, $v);
 353       },
 354     });
 355   }
 356
 357   # generate sql
 358   my $sql = $self->_sqlcase('update') . " $table " . $self->_sqlcase('set ')
 359           . join ', ', @set;
 360
 361   if ($where) {
 362     my($where_sql, @where_bind) = $self->where($where);
 363     $sql .= $where_sql;
 364     push @all_bind, @where_bind;
 365   }
 366
 367   return wantarray ? ($sql, @all_bind) : $sql;
 368 }
 369
 370
 371
 372
 373 #======================================================================
 374 # SELECT
 375 #======================================================================
 376
 377
 378 sub select {
 379   my $self   = shift;
 380   my $table  = $self->_table(shift);
 381   my $fields = shift || '*';
 382   my $where  = shift;
 383   my $order  = shift;
 384
 385   my($where_sql, @bind) = $self->where($where, $order);
 386
 387   my $f = (ref $fields eq 'ARRAY') ? join ', ', map { $self->_quote($_) } @$fields
 388                                    : $fields;
 389   my $sql = join(' ', $self->_sqlcase('select'), $f,
 390                       $self->_sqlcase('from'),   $table)
 391           . $where_sql;
 392
 393   return wantarray ? ($sql, @bind) : $sql;
 394 }
 395
 396 #======================================================================
 397 # DELETE
 398 #======================================================================
 399
 400
 401 sub delete {
 402   my $self  = shift;
 403   my $table = $self->_table(shift);
 404   my $where = shift;
 405
 406
 407   my($where_sql, @bind) = $self->where($where);
 408   my $sql = $self->_sqlcase('delete from') . " $table" . $where_sql;
 409
 410   return wantarray ? ($sql, @bind) : $sql;
 411 }
 412
 413
 414 #======================================================================
 415 # WHERE: entry point
 416 #======================================================================
 417
 418
 419
 420 # Finally, a separate routine just to handle WHERE clauses
 421 sub where {
 422   my ($self, $where, $order) = @_;
 423
 424   # where ?
 425   my ($sql, @bind) = $self->_recurse_where($where);
 426   $sql = $sql ? $self->_sqlcase(' where ') . "( $sql )" : '';
 427
 428   # order by?
 429   if ($order) {
 430     $sql .= $self->_order_by($order);
 431   }
 432
 433   return wantarray ? ($sql, @bind) : $sql;
 434 }
 435
 436
 437 sub _recurse_where {
 438   my ($self, $where, $logic) = @_;
 439
 440   # dispatch on appropriate method according to refkind of $where
 441   my $method = $self->_METHOD_FOR_refkind("_where", $where);
 442
 443   my ($sql, @bind) =  $self->$method($where, $logic);
 444
 445   # DBIx::Class directly calls _recurse_where in scalar context, so
 446   # we must implement it, even if not in the official API
 447   return wantarray ? ($sql, @bind) : $sql;
 448 }
 449
 450
 451
 452 #======================================================================
 453 # WHERE: top-level ARRAYREF
 454 #======================================================================
 455
 456
 457 sub _where_ARRAYREF {
 458   my ($self, $where, $logic) = @_;
 459
 460   $logic = uc($logic || $self->{logic});
 461   $logic eq 'AND' or $logic eq 'OR' or puke "unknown logic: $logic";
 462
 463   my @clauses = @$where;
 464
 465   my (@sql_clauses, @all_bind);
 466   # need to use while() so can shift() for pairs
 467   while (my $el = shift @clauses) {
 468
 469     # switch according to kind of $el and get corresponding ($sql, @bind)
 470     my ($sql, @bind) = $self->_SWITCH_refkind($el, {
 471
 472       # skip empty elements, otherwise get invalid trailing AND stuff
 473       ARRAYREF  => sub {$self->_recurse_where($el)        if @$el},
 474
 475       ARRAYREFREF => sub {
 476         my ($s, @b) = @$$el;
 477         $self->_assert_bindval_matches_bindtype(@b);
 478         ($s, @b);
 479       },
 480
 481       HASHREF   => sub {$self->_recurse_where($el, 'and') if %$el},
 482            # LDNOTE : previous SQLA code for hashrefs was creating a dirty
 483            # side-effect: the first hashref within an array would change
 484            # the global logic to 'AND'. So [ {cond1, cond2}, [cond3, cond4] ]
 485            # was interpreted as "(cond1 AND cond2) OR (cond3 AND cond4)",
 486            # whereas it should be "(cond1 AND cond2) OR (cond3 OR cond4)".
 487
 488       SCALARREF => sub { ($$el);                                 },
 489
 490       SCALAR    => sub {# top-level arrayref with scalars, recurse in pairs
 491                         $self->_recurse_where({$el => shift(@clauses)})},
 492
 493       UNDEF     => sub {puke "not supported : UNDEF in arrayref" },
 494     });
 495
 496     if ($sql) {
 497       push @sql_clauses, $sql;
 498       push @all_bind, @bind;
 499     }
 500   }
 501
 502   return $self->_join_sql_clauses($logic, \@sql_clauses, \@all_bind);
 503 }
 504
 505 #======================================================================
 506 # WHERE: top-level ARRAYREFREF
 507 #======================================================================
 508
 509 sub _where_ARRAYREFREF {
 510     my ($self, $where) = @_;
 511     my ($sql, @bind) = @$$where;
 512     $self->_assert_bindval_matches_bindtype(@bind);
 513     return ($sql, @bind);
 514 }
 515
 516 #======================================================================
 517 # WHERE: top-level HASHREF
 518 #======================================================================
 519
 520 sub _where_HASHREF {
 521   my ($self, $where) = @_;
 522   my (@sql_clauses, @all_bind);
 523
 524   for my $k (sort keys %$where) {
 525     my $v = $where->{$k};
 526
 527     # ($k => $v) is either a special unary op or a regular hashpair
 528     my ($sql, @bind) = do {
 529       if ($k =~ /^-./) {
 530         # put the operator in canonical form
 531         my $op = $k;
 532         $op = substr $op, 1;  # remove initial dash
 533         $op =~ s/^\s+|\s+$//g;# remove leading/trailing space
 534         $op =~ s/\s+/ /g;     # compress whitespace
 535
 536         # so that -not_foo works correctly
 537         $op =~ s/^not_/NOT /i;
 538
 539         $self->_debug("Unary OP(-$op) within hashref, recursing...");
 540         my ($s, @b) = $self->_where_unary_op ($op, $v);
 541
 542         # top level vs nested
 543         # we assume that handled unary ops will take care of their ()s
 544         $s = "($s)" unless (
 545           List::Util::first {$op =~ $_->{regex}} @{$self->{unary_ops}}
 546             or
 547           defined($self->{_nested_func_lhs}) && ($self->{_nested_func_lhs} eq $k)
 548         );
 549         ($s, @b);
 550       }
 551       else {
 552         my $method = $self->_METHOD_FOR_refkind("_where_hashpair", $v);
 553         $self->$method($k, $v);
 554       }
 555     };
 556
 557     push @sql_clauses, $sql;
 558     push @all_bind, @bind;
 559   }
 560
 561   return $self->_join_sql_clauses('and', \@sql_clauses, \@all_bind);
 562 }
 563
 564 sub _where_unary_op {
 565   my ($self, $op, $rhs) = @_;
 566
 567   if (my $op_entry = List::Util::first {$op =~ $_->{regex}} @{$self->{unary_ops}}) {
 568     my $handler = $op_entry->{handler};
 569
 570     if (not ref $handler) {
 571       if ($op =~ s/ [_\s]? \d+ $//x ) {
 572         belch 'Use of [and|or|nest]_N modifiers is deprecated and will be removed in SQLA v2.0. '
 573             . "You probably wanted ...-and => [ -$op => COND1, -$op => COND2 ... ]";
 574       }
 575       return $self->$handler ($op, $rhs);
 576     }
 577     elsif (ref $handler eq 'CODE') {
 578       return $handler->($self, $op, $rhs);
 579     }
 580     else {
 581       puke "Illegal handler for operator $op - expecting a method name or a coderef";
 582     }
 583   }
 584
 585   $self->_debug("Generic unary OP: $op - recursing as function");
 586
 587   $self->_assert_pass_injection_guard($op);
 588
 589   my ($sql, @bind) = $self->_SWITCH_refkind ($rhs, {
 590     SCALAR =>   sub {
 591       puke "Illegal use of top-level '$op'"
 592         unless $self->{_nested_func_lhs};
 593
 594       return (
 595         $self->_convert('?'),
 596         $self->_bindtype($self->{_nested_func_lhs}, $rhs)
 597       );
 598     },
 599     FALLBACK => sub {
 600       $self->_recurse_where ($rhs)
 601     },
 602   });
 603
 604   $sql = sprintf ('%s %s',
 605     $self->_sqlcase($op),
 606     $sql,
 607   );
 608
 609   return ($sql, @bind);
 610 }
 611
 612 sub _where_op_ANDOR {
 613   my ($self, $op, $v) = @_;
 614
 615   $self->_SWITCH_refkind($v, {
 616     ARRAYREF => sub {
 617       return $self->_where_ARRAYREF($v, $op);
 618     },
 619
 620     HASHREF => sub {
 621       return ( $op =~ /^or/i )
 622         ? $self->_where_ARRAYREF( [ map { $_ => $v->{$_} } ( sort keys %$v ) ], $op )
 623         : $self->_where_HASHREF($v);
 624     },
 625
 626     SCALARREF  => sub {
 627       puke "-$op => \\\$scalar makes little sense, use " .
 628         ($op =~ /^or/i
 629           ? '[ \$scalar, \%rest_of_conditions ] instead'
 630           : '-and => [ \$scalar, \%rest_of_conditions ] instead'
 631         );
 632     },
 633
 634     ARRAYREFREF => sub {
 635       puke "-$op => \\[...] makes little sense, use " .
 636         ($op =~ /^or/i
 637           ? '[ \[...], \%rest_of_conditions ] instead'
 638           : '-and => [ \[...], \%rest_of_conditions ] instead'
 639         );
 640     },
 641
 642     SCALAR => sub { # permissively interpreted as SQL
 643       puke "-$op => \$value makes little sense, use -bool => \$value instead";
 644     },
 645
 646     UNDEF => sub {
 647       puke "-$op => undef not supported";
 648     },
 649    });
 650 }
 651
 652 sub _where_op_NEST {
 653   my ($self, $op, $v) = @_;
 654
 655   $self->_SWITCH_refkind($v, {
 656
 657     SCALAR => sub { # permissively interpreted as SQL
 658       belch "literal SQL should be -nest => \\'scalar' "
 659           . "instead of -nest => 'scalar' ";
 660       return ($v);
 661     },
 662
 663     UNDEF => sub {
 664       puke "-$op => undef not supported";
 665     },
 666
 667     FALLBACK => sub {
 668       $self->_recurse_where ($v);
 669     },
 670
 671    });
 672 }
 673
 674
 675 sub _where_op_BOOL {
 676   my ($self, $op, $v) = @_;
 677
 678   my ($s, @b) = $self->_SWITCH_refkind($v, {
 679     SCALAR => sub { # interpreted as SQL column
 680       $self->_convert($self->_quote($v));
 681     },
 682
 683     UNDEF => sub {
 684       puke "-$op => undef not supported";
 685     },
 686
 687     FALLBACK => sub {
 688       $self->_recurse_where ($v);
 689     },
 690   });
 691
 692   $s = "(NOT $s)" if $op =~ /^not/i;
 693   ($s, @b);
 694 }
 695
 696
 697 sub _where_op_IDENT {
 698   my $self = shift;
 699   my ($op, $rhs) = splice @_, -2;
 700   if (ref $rhs) {
 701     puke "-$op takes a single scalar argument (a quotable identifier)";
 702   }
 703
 704   # in case we are called as a top level special op (no '=')
 705   my $lhs = shift;
 706
 707   $_ = $self->_convert($self->_quote($_)) for ($lhs, $rhs);
 708
 709   return $lhs
 710     ? "$lhs = $rhs"
 711     : $rhs
 712   ;
 713 }
 714
 715 sub _where_op_VALUE {
 716   my $self = shift;
 717   my ($op, $rhs) = splice @_, -2;
 718
 719   # in case we are called as a top level special op (no '=')
 720   my $lhs = shift;
 721
 722   my @bind =
 723     $self->_bindtype (
 724       ($lhs || $self->{_nested_func_lhs}),
 725       $rhs,
 726     )
 727   ;
 728
 729   return $lhs
 730     ? (
 731       $self->_convert($self->_quote($lhs)) . ' = ' . $self->_convert('?'),
 732       @bind
 733     )
 734     : (
 735       $self->_convert('?'),
 736       @bind,
 737     )
 738   ;
 739 }
 740
 741 sub _where_hashpair_ARRAYREF {
 742   my ($self, $k, $v) = @_;
 743
 744   if( @$v ) {
 745     my @v = @$v; # need copy because of shift below
 746     $self->_debug("ARRAY($k) means distribute over elements");
 747
 748     # put apart first element if it is an operator (-and, -or)
 749     my $op = (
 750        (defined $v[0] && $v[0] =~ /^ - (?: AND|OR ) $/ix)
 751          ? shift @v
 752          : ''
 753     );
 754     my @distributed = map { {$k =>  $_} } @v;
 755
 756     if ($op) {
 757       $self->_debug("OP($op) reinjected into the distributed array");
 758       unshift @distributed, $op;
 759     }
 760
 761     my $logic = $op ? substr($op, 1) : '';
 762
 763     return $self->_recurse_where(\@distributed, $logic);
 764   }
 765   else {
 766     # LDNOTE : not sure of this one. What does "distribute over nothing" mean?
 767     $self->_debug("empty ARRAY($k) means 0=1");
 768     return ($self->{sqlfalse});
 769   }
 770 }
 771
 772 sub _where_hashpair_HASHREF {
 773   my ($self, $k, $v, $logic) = @_;
 774   $logic ||= 'and';
 775
 776   local $self->{_nested_func_lhs} = $self->{_nested_func_lhs};
 777
 778   my ($all_sql, @all_bind);
 779
 780   for my $orig_op (sort keys %$v) {
 781     my $val = $v->{$orig_op};
 782
 783     # put the operator in canonical form
 784     my $op = $orig_op;
 785
 786     # FIXME - we need to phase out dash-less ops
 787     $op =~ s/^-//;        # remove possible initial dash
 788     $op =~ s/^\s+|\s+$//g;# remove leading/trailing space
 789     $op =~ s/\s+/ /g;     # compress whitespace
 790
 791     $self->_assert_pass_injection_guard($op);
 792
 793     # so that -not_foo works correctly
 794     $op =~ s/^not_/NOT /i;
 795
 796     my ($sql, @bind);
 797
 798     # CASE: col-value logic modifiers
 799     if ( $orig_op =~ /^ \- (and|or) $/xi ) {
 800       ($sql, @bind) = $self->_where_hashpair_HASHREF($k, $val, $1);
 801     }
 802     # CASE: special operators like -in or -between
 803     elsif ( my $special_op = List::Util::first {$op =~ $_->{regex}} @{$self->{special_ops}} ) {
 804       my $handler = $special_op->{handler};
 805       if (! $handler) {
 806         puke "No handler supplied for special operator $orig_op";
 807       }
 808       elsif (not ref $handler) {
 809         ($sql, @bind) = $self->$handler ($k, $op, $val);
 810       }
 811       elsif (ref $handler eq 'CODE') {
 812         ($sql, @bind) = $handler->($self, $k, $op, $val);
 813       }
 814       else {
 815         puke "Illegal handler for special operator $orig_op - expecting a method name or a coderef";
 816       }
 817     }
 818     else {
 819       $self->_SWITCH_refkind($val, {
 820
 821         ARRAYREF => sub {       # CASE: col => {op => \@vals}
 822           ($sql, @bind) = $self->_where_field_op_ARRAYREF($k, $op, $val);
 823         },
 824
 825         ARRAYREFREF => sub {    # CASE: col => {op => \[$sql, @bind]} (literal SQL with bind)
 826           my ($sub_sql, @sub_bind) = @$$val;
 827           $self->_assert_bindval_matches_bindtype(@sub_bind);
 828           $sql  = join ' ', $self->_convert($self->_quote($k)),
 829                             $self->_sqlcase($op),
 830                             $sub_sql;
 831           @bind = @sub_bind;
 832         },
 833
 834         UNDEF => sub {          # CASE: col => {op => undef} : sql "IS (NOT)? NULL"
 835           my $is = ($op =~ $self->{equality_op})   ? 'is'     :
 836                    ($op =~ $self->{inequality_op}) ? 'is not' :
 837                puke "unexpected operator '$orig_op' with undef operand";
 838           $sql = $self->_quote($k) . $self->_sqlcase(" $is null");
 839         },
 840
 841         FALLBACK => sub {       # CASE: col => {op/func => $stuff}
 842
 843           # retain for proper column type bind
 844           $self->{_nested_func_lhs} ||= $k;
 845
 846           ($sql, @bind) = $self->_where_unary_op ($op, $val);
 847
 848           $sql = join (' ',
 849             $self->_convert($self->_quote($k)),
 850             $self->{_nested_func_lhs} eq $k ? $sql : "($sql)",  # top level vs nested
 851           );
 852         },
 853       });
 854     }
 855
 856     ($all_sql) = (defined $all_sql and $all_sql) ? $self->_join_sql_clauses($logic, [$all_sql, $sql], []) : $sql;
 857     push @all_bind, @bind;
 858   }
 859   return ($all_sql, @all_bind);
 860 }
 861
 862
 863
 864 sub _where_field_op_ARRAYREF {
 865   my ($self, $k, $op, $vals) = @_;
 866
 867   my @vals = @$vals;  #always work on a copy
 868
 869   if(@vals) {
 870     $self->_debug(sprintf '%s means multiple elements: [ %s ]',
 871       $vals,
 872       join (', ', map { defined $_ ? "'$_'" : 'NULL' } @vals ),
 873     );
 874
 875     # see if the first element is an -and/-or op
 876     my $logic;
 877     if (defined $vals[0] && $vals[0] =~ /^ - ( AND|OR ) $/ix) {
 878       $logic = uc $1;
 879       shift @vals;
 880     }
 881
 882     # distribute $op over each remaining member of @vals, append logic if exists
 883     return $self->_recurse_where([map { {$k => {$op, $_}} } @vals], $logic);
 884
 885     # LDNOTE : had planned to change the distribution logic when
 886     # $op =~ $self->{inequality_op}, because of Morgan laws :
 887     # with {field => {'!=' => [22, 33]}}, it would be ridiculous to generate
 888     # WHERE field != 22 OR  field != 33 : the user probably means
 889     # WHERE field != 22 AND field != 33.
 890     # To do this, replace the above to roughly :
 891     # my $logic = ($op =~ $self->{inequality_op}) ? 'AND' : 'OR';
 892     # return $self->_recurse_where([map { {$k => {$op, $_}} } @vals], $logic);
 893
 894   }
 895   else {
 896     # try to DWIM on equality operators
 897     # LDNOTE : not 100% sure this is the correct thing to do ...
 898     return ($self->{sqlfalse}) if $op =~ $self->{equality_op};
 899     return ($self->{sqltrue})  if $op =~ $self->{inequality_op};
 900
 901     # otherwise
 902     puke "operator '$op' applied on an empty array (field '$k')";
 903   }
 904 }
 905
 906
 907 sub _where_hashpair_SCALARREF {
 908   my ($self, $k, $v) = @_;
 909   $self->_debug("SCALAR($k) means literal SQL: $$v");
 910   my $sql = $self->_quote($k) . " " . $$v;
 911   return ($sql);
 912 }
 913
 914 # literal SQL with bind
 915 sub _where_hashpair_ARRAYREFREF {
 916   my ($self, $k, $v) = @_;
 917   $self->_debug("REF($k) means literal SQL: @${$v}");
 918   my ($sql, @bind) = @$$v;
 919   $self->_assert_bindval_matches_bindtype(@bind);
 920   $sql  = $self->_quote($k) . " " . $sql;
 921   return ($sql, @bind );
 922 }
 923
 924 # literal SQL without bind
 925 sub _where_hashpair_SCALAR {
 926   my ($self, $k, $v) = @_;
 927   $self->_debug("NOREF($k) means simple key=val: $k $self->{cmp} $v");
 928   my $sql = join ' ', $self->_convert($self->_quote($k)),
 929                       $self->_sqlcase($self->{cmp}),
 930                       $self->_convert('?');
 931   my @bind =  $self->_bindtype($k, $v);
 932   return ( $sql, @bind);
 933 }
 934
 935
 936 sub _where_hashpair_UNDEF {
 937   my ($self, $k, $v) = @_;
 938   $self->_debug("UNDEF($k) means IS NULL");
 939   my $sql = $self->_quote($k) . $self->_sqlcase(' is null');
 940   return ($sql);
 941 }
 942
 943 #======================================================================
 944 # WHERE: TOP-LEVEL OTHERS (SCALARREF, SCALAR, UNDEF)
 945 #======================================================================
 946
 947
 948 sub _where_SCALARREF {
 949   my ($self, $where) = @_;
 950
 951   # literal sql
 952   $self->_debug("SCALAR(*top) means literal SQL: $$where");
 953   return ($$where);
 954 }
 955
 956
 957 sub _where_SCALAR {
 958   my ($self, $where) = @_;
 959
 960   # literal sql
 961   $self->_debug("NOREF(*top) means literal SQL: $where");
 962   return ($where);
 963 }
 964
 965
 966 sub _where_UNDEF {
 967   my ($self) = @_;
 968   return ();
 969 }
 970
 971
 972 #======================================================================
 973 # WHERE: BUILTIN SPECIAL OPERATORS (-in, -between)
 974 #======================================================================
 975
 976
 977 sub _where_field_BETWEEN {
 978   my ($self, $k, $op, $vals) = @_;
 979
 980   my ($label, $and, $placeholder);
 981   $label       = $self->_convert($self->_quote($k));
 982   $and         = ' ' . $self->_sqlcase('and') . ' ';
 983   $placeholder = $self->_convert('?');
 984   $op               = $self->_sqlcase($op);
 985
 986   my ($clause, @bind) = $self->_SWITCH_refkind($vals, {
 987     ARRAYREFREF => sub {
 988       my ($s, @b) = @$$vals;
 989       $self->_assert_bindval_matches_bindtype(@b);
 990       ($s, @b);
 991     },
 992     SCALARREF => sub {
 993       return $$vals;
 994     },
 995     ARRAYREF => sub {
 996       puke "special op 'between' accepts an arrayref with exactly two values"
 997         if @$vals != 2;
 998
 999       my (@all_sql, @all_bind);
1000       foreach my $val (@$vals) {
1001         my ($sql, @bind) = $self->_SWITCH_refkind($val, {
1002            SCALAR => sub {
1003              return ($placeholder, $self->_bindtype($k, $val) );
1004            },
1005            SCALARREF => sub {
1006              return $$val;
1007            },
1008            ARRAYREFREF => sub {
1009              my ($sql, @bind) = @$$val;
1010              $self->_assert_bindval_matches_bindtype(@bind);
1011              return ($sql, @bind);
1012            },
1013            HASHREF => sub {
1014              my ($func, $arg, @rest) = %$val;
1015              puke ("Only simple { -func => arg } functions accepted as sub-arguments to BETWEEN")
1016                if (@rest or $func !~ /^ \- (.+)/x);
1017              local $self->{_nested_func_lhs} = $k;
1018              $self->_where_unary_op ($1 => $arg);
1019            }
1020         });
1021         push @all_sql, $sql;
1022         push @all_bind, @bind;
1023       }
1024
1025       return (
1026         (join $and, @all_sql),
1027         @all_bind
1028       );
1029     },
1030     FALLBACK => sub {
1031       puke "special op 'between' accepts an arrayref with two values, or a single literal scalarref/arrayref-ref";
1032     },
1033   });
1034
1035   my $sql = "( $label $op $clause )";
1036   return ($sql, @bind)
1037 }
1038
1039
1040 sub _where_field_IN {
1041   my ($self, $k, $op, $vals) = @_;
1042
1043   # backwards compatibility : if scalar, force into an arrayref
1044   $vals = [$vals] if defined $vals && ! ref $vals;
1045
1046   my ($label)       = $self->_convert($self->_quote($k));
1047   my ($placeholder) = $self->_convert('?');
1048   $op               = $self->_sqlcase($op);
1049
1050   my ($sql, @bind) = $self->_SWITCH_refkind($vals, {
1051     ARRAYREF => sub {     # list of choices
1052       if (@$vals) { # nonempty list
1053         my (@all_sql, @all_bind);
1054
1055         for my $val (@$vals) {
1056           my ($sql, @bind) = $self->_SWITCH_refkind($val, {
1057             SCALAR => sub {
1058               return ($placeholder, $val);
1059             },
1060             SCALARREF => sub {
1061               return $$val;
1062             },
1063             ARRAYREFREF => sub {
1064               my ($sql, @bind) = @$$val;
1065               $self->_assert_bindval_matches_bindtype(@bind);
1066               return ($sql, @bind);
1067             },
1068             HASHREF => sub {
1069               my ($func, $arg, @rest) = %$val;
1070               puke ("Only simple { -func => arg } functions accepted as sub-arguments to IN")
1071                 if (@rest or $func !~ /^ \- (.+)/x);
1072               local $self->{_nested_func_lhs} = $k;
1073               $self->_where_unary_op ($1 => $arg);
1074             },
1075             UNDEF => sub {
1076               return $self->_sqlcase('null');
1077             },
1078           });
1079           push @all_sql, $sql;
1080           push @all_bind, @bind;
1081         }
1082
1083         return (
1084           sprintf ('%s %s ( %s )',
1085             $label,
1086             $op,
1087             join (', ', @all_sql)
1088           ),
1089           $self->_bindtype($k, @all_bind),
1090         );
1091       }
1092       else { # empty list : some databases won't understand "IN ()", so DWIM
1093         my $sql = ($op =~ /\bnot\b/i) ? $self->{sqltrue} : $self->{sqlfalse};
1094         return ($sql);
1095       }
1096     },
1097
1098     SCALARREF => sub {  # literal SQL
1099       my $sql = $self->_open_outer_paren ($$vals);
1100       return ("$label $op ( $sql )");
1101     },
1102     ARRAYREFREF => sub {  # literal SQL with bind
1103       my ($sql, @bind) = @$$vals;
1104       $self->_assert_bindval_matches_bindtype(@bind);
1105       $sql = $self->_open_outer_paren ($sql);
1106       return ("$label $op ( $sql )", @bind);
1107     },
1108
1109     FALLBACK => sub {
1110       puke "special op 'in' requires an arrayref (or scalarref/arrayref-ref)";
1111     },
1112   });
1113
1114   return ($sql, @bind);
1115 }
1116
1117 # Some databases (SQLite) treat col IN (1, 2) different from
1118 # col IN ( (1, 2) ). Use this to strip all outer parens while
1119 # adding them back in the corresponding method
1120 sub _open_outer_paren {
1121   my ($self, $sql) = @_;
1122   $sql = $1 while $sql =~ /^ \s* \( (.*) \) \s* $/xs;
1123   return $sql;
1124 }
1125
1126
1127 #======================================================================
1128 # ORDER BY
1129 #======================================================================
1130
1131 sub _order_by {
1132   my ($self, $arg) = @_;
1133
1134   my (@sql, @bind);
1135   for my $c ($self->_order_by_chunks ($arg) ) {
1136     $self->_SWITCH_refkind ($c, {
1137       SCALAR => sub { push @sql, $c },
1138       ARRAYREF => sub { push @sql, shift @$c; push @bind, @$c },
1139     });
1140   }
1141
1142   my $sql = @sql
1143     ? sprintf ('%s %s',
1144         $self->_sqlcase(' order by'),
1145         join (', ', @sql)
1146       )
1147     : ''
1148   ;
1149
1150   return wantarray ? ($sql, @bind) : $sql;
1151 }
1152
1153 sub _order_by_chunks {
1154   my ($self, $arg) = @_;
1155
1156   return $self->_SWITCH_refkind($arg, {
1157
1158     ARRAYREF => sub {
1159       map { $self->_order_by_chunks ($_ ) } @$arg;
1160     },
1161
1162     ARRAYREFREF => sub {
1163       my ($s, @b) = @$$arg;
1164       $self->_assert_bindval_matches_bindtype(@b);
1165       [ $s, @b ];
1166     },
1167
1168     SCALAR    => sub {$self->_quote($arg)},
1169
1170     UNDEF     => sub {return () },
1171
1172     SCALARREF => sub {$$arg}, # literal SQL, no quoting
1173
1174     HASHREF   => sub {
1175       # get first pair in hash
1176       my ($key, $val, @rest) = %$arg;
1177
1178       return () unless $key;
1179
1180       if ( @rest or not $key =~ /^-(desc|asc)/i ) {
1181         puke "hash passed to _order_by must have exactly one key (-desc or -asc)";
1182       }
1183
1184       my $direction = $1;
1185
1186       my @ret;
1187       for my $c ($self->_order_by_chunks ($val)) {
1188         my ($sql, @bind);
1189
1190         $self->_SWITCH_refkind ($c, {
1191           SCALAR => sub {
1192             $sql = $c;
1193           },
1194           ARRAYREF => sub {
1195             ($sql, @bind) = @$c;
1196           },
1197         });
1198
1199         $sql = $sql . ' ' . $self->_sqlcase($direction);
1200
1201         push @ret, [ $sql, @bind];
1202       }
1203
1204       return @ret;
1205     },
1206   });
1207 }
1208
1209
1210 #======================================================================
1211 # DATASOURCE (FOR NOW, JUST PLAIN TABLE OR LIST OF TABLES)
1212 #======================================================================
1213
1214 sub _table  {
1215   my $self = shift;
1216   my $from = shift;
1217   $self->_SWITCH_refkind($from, {
1218     ARRAYREF     => sub {join ', ', map { $self->_quote($_) } @$from;},
1219     SCALAR       => sub {
1220       $self->_render_dq({
1221         type => DQ_IDENTIFIER,
1222         elements => [ split /\Q$self->{name_sep}/, $from ],
1223       })
1224     },
1225     SCALARREF    => sub {
1226       $self->_render_dq({
1227         type => DQ_LITERAL,
1228         subtype => 'SQL',
1229         literal => $$from
1230       })
1231     },
1232   });
1233 }
1234
1235
1236 #======================================================================
1237 # UTILITY FUNCTIONS
1238 #======================================================================
1239
1240 # highly optimized, as it's called way too often
1241 sub _quote {
1242   # my ($self, $label) = @_;
1243
1244   return '' unless defined $_[1];
1245   return ${$_[1]} if ref($_[1]) eq 'SCALAR';
1246
1247   unless ($_[0]->{quote_char}) {
1248     $_[0]->_assert_pass_injection_guard($_[1]);
1249     return $_[1];
1250   }
1251
1252   my $qref = ref $_[0]->{quote_char};
1253   my ($l, $r);
1254   if (!$qref) {
1255     ($l, $r) = ( $_[0]->{quote_char}, $_[0]->{quote_char} );
1256   }
1257   elsif ($qref eq 'ARRAY') {
1258     ($l, $r) = @{$_[0]->{quote_char}};
1259   }
1260   else {
1261     puke "Unsupported quote_char format: $_[0]->{quote_char}";
1262   }
1263
1264   # parts containing * are naturally unquoted
1265   return join( $_[0]->{name_sep}||'', map
1266     { $_ eq '*' ? $_ : $l . $_ . $r }
1267     ( $_[0]->{name_sep} ? split (/\Q$_[0]->{name_sep}\E/, $_[1] ) : $_[1] )
1268   );
1269 }
1270
1271
1272 # Conversion, if applicable
1273 sub _convert ($) {
1274   #my ($self, $arg) = @_;
1275
1276 # LDNOTE : modified the previous implementation below because
1277 # it was not consistent : the first "return" is always an array,
1278 # the second "return" is context-dependent. Anyway, _convert
1279 # seems always used with just a single argument, so make it a
1280 # scalar function.
1281 #     return @_ unless $self->{convert};
1282 #     my $conv = $self->_sqlcase($self->{convert});
1283 #     my @ret = map { $conv.'('.$_.')' } @_;
1284 #     return wantarray ? @ret : $ret[0];
1285   if ($_[0]->{convert}) {
1286     return $_[0]->_sqlcase($_[0]->{convert}) .'(' . $_[1] . ')';
1287   }
1288   return $_[1];
1289 }
1290
1291 # And bindtype
1292 sub _bindtype (@) {
1293   #my ($self, $col, @vals) = @_;
1294
1295   #LDNOTE : changed original implementation below because it did not make
1296   # sense when bindtype eq 'columns' and @vals > 1.
1297 #  return $self->{bindtype} eq 'columns' ? [ $col, @vals ] : @vals;
1298
1299   # called often - tighten code
1300   return $_[0]->{bindtype} eq 'columns'
1301     ? map {[$_[1], $_]} @_[2 .. $#_]
1302     : @_[2 .. $#_]
1303   ;
1304 }
1305
1306 # Dies if any element of @bind is not in [colname => value] format
1307 # if bindtype is 'columns'.
1308 sub _assert_bindval_matches_bindtype {
1309 #  my ($self, @bind) = @_;
1310   my $self = shift;
1311   if ($self->{bindtype} eq 'columns') {
1312     for (@_) {
1313       if (!defined $_ || ref($_) ne 'ARRAY' || @$_ != 2) {
1314         puke "bindtype 'columns' selected, you need to pass: [column_name => bind_value]"
1315       }
1316     }
1317   }
1318 }
1319
1320 sub _join_sql_clauses {
1321   my ($self, $logic, $clauses_aref, $bind_aref) = @_;
1322
1323   if (@$clauses_aref > 1) {
1324     my $join  = " " . $self->_sqlcase($logic) . " ";
1325     my $sql = '( ' . join($join, @$clauses_aref) . ' )';
1326     return ($sql, @$bind_aref);
1327   }
1328   elsif (@$clauses_aref) {
1329     return ($clauses_aref->[0], @$bind_aref); # no parentheses
1330   }
1331   else {
1332     return (); # if no SQL, ignore @$bind_aref
1333   }
1334 }
1335
1336
1337 # Fix SQL case, if so requested
1338 sub _sqlcase {
1339   # LDNOTE: if $self->{case} is true, then it contains 'lower', so we
1340   # don't touch the argument ... crooked logic, but let's not change it!
1341   return $_[0]->{case} ? $_[1] : uc($_[1]);
1342 }
1343
1344
1345 #======================================================================
1346 # DISPATCHING FROM REFKIND
1347 #======================================================================
1348
1349 sub _refkind {
1350   my ($self, $data) = @_;
1351
1352   return 'UNDEF' unless defined $data;
1353
1354   # blessed objects are treated like scalars
1355   my $ref = (Scalar::Util::blessed $data) ? '' : ref $data;
1356
1357   return 'SCALAR' unless $ref;
1358
1359   my $n_steps = 1;
1360   while ($ref eq 'REF') {
1361     $data = $$data;
1362     $ref = (Scalar::Util::blessed $data) ? '' : ref $data;
1363     $n_steps++ if $ref;
1364   }
1365
1366   return ($ref||'SCALAR') . ('REF' x $n_steps);
1367 }
1368
1369 sub _try_refkind {
1370   my ($self, $data) = @_;
1371   my @try = ($self->_refkind($data));
1372   push @try, 'SCALAR_or_UNDEF' if $try[0] eq 'SCALAR' || $try[0] eq 'UNDEF';
1373   push @try, 'FALLBACK';
1374   return \@try;
1375 }
1376
1377 sub _METHOD_FOR_refkind {
1378   my ($self, $meth_prefix, $data) = @_;
1379
1380   my $method;
1381   for (@{$self->_try_refkind($data)}) {
1382     $method = $self->can($meth_prefix."_".$_)
1383       and last;
1384   }
1385
1386   return $method || puke "cannot dispatch on '$meth_prefix' for ".$self->_refkind($data);
1387 }
1388
1389
1390 sub _SWITCH_refkind {
1391   my ($self, $data, $dispatch_table) = @_;
1392
1393   my $coderef;
1394   for (@{$self->_try_refkind($data)}) {
1395     $coderef = $dispatch_table->{$_}
1396       and last;
1397   }
1398
1399   puke "no dispatch entry for ".$self->_refkind($data)
1400     unless $coderef;
1401
1402   $coderef->();
1403 }
1404
1405
1406
1407
1408 #======================================================================
1409 # VALUES, GENERATE, AUTOLOAD
1410 #======================================================================
1411
1412 # LDNOTE: original code from nwiger, didn't touch code in that section
1413 # I feel the AUTOLOAD stuff should not be the default, it should
1414 # only be activated on explicit demand by user.
1415
1416 sub values {
1417     my $self = shift;
1418     my $data = shift || return;
1419     puke "Argument to ", __PACKAGE__, "->values must be a \\%hash"
1420         unless ref $data eq 'HASH';
1421
1422     my @all_bind;
1423     foreach my $k ( sort keys %$data ) {
1424         my $v = $data->{$k};
1425         $self->_SWITCH_refkind($v, {
1426           ARRAYREF => sub {
1427             if ($self->{array_datatypes}) { # array datatype
1428               push @all_bind, $self->_bindtype($k, $v);
1429             }
1430             else {                          # literal SQL with bind
1431               my ($sql, @bind) = @$v;
1432               $self->_assert_bindval_matches_bindtype(@bind);
1433               push @all_bind, @bind;
1434             }
1435           },
1436           ARRAYREFREF => sub { # literal SQL with bind
1437             my ($sql, @bind) = @${$v};
1438             $self->_assert_bindval_matches_bindtype(@bind);
1439             push @all_bind, @bind;
1440           },
1441           SCALARREF => sub {  # literal SQL without bind
1442           },
1443           SCALAR_or_UNDEF => sub {
1444             push @all_bind, $self->_bindtype($k, $v);
1445           },
1446         });
1447     }
1448
1449     return @all_bind;
1450 }
1451
1452 sub generate {
1453     my $self  = shift;
1454
1455     my(@sql, @sqlq, @sqlv);
1456
1457     for (@_) {
1458         my $ref = ref $_;
1459         if ($ref eq 'HASH') {
1460             for my $k (sort keys %$_) {
1461                 my $v = $_->{$k};
1462                 my $r = ref $v;
1463                 my $label = $self->_quote($k);
1464                 if ($r eq 'ARRAY') {
1465                     # literal SQL with bind
1466                     my ($sql, @bind) = @$v;
1467                     $self->_assert_bindval_matches_bindtype(@bind);
1468                     push @sqlq, "$label = $sql";
1469                     push @sqlv, @bind;
1470                 } elsif ($r eq 'SCALAR') {
1471                     # literal SQL without bind
1472                     push @sqlq, "$label = $$v";
1473                 } else {
1474                     push @sqlq, "$label = ?";
1475                     push @sqlv, $self->_bindtype($k, $v);
1476                 }
1477             }
1478             push @sql, $self->_sqlcase('set'), join ', ', @sqlq;
1479         } elsif ($ref eq 'ARRAY') {
1480             # unlike insert(), assume these are ONLY the column names, i.e. for SQL
1481             for my $v (@$_) {
1482                 my $r = ref $v;
1483                 if ($r eq 'ARRAY') {   # literal SQL with bind
1484                     my ($sql, @bind) = @$v;
1485                     $self->_assert_bindval_matches_bindtype(@bind);
1486                     push @sqlq, $sql;
1487                     push @sqlv, @bind;
1488                 } elsif ($r eq 'SCALAR') {  # literal SQL without bind
1489                     # embedded literal SQL
1490                     push @sqlq, $$v;
1491                 } else {
1492                     push @sqlq, '?';
1493                     push @sqlv, $v;
1494                 }
1495             }
1496             push @sql, '(' . join(', ', @sqlq) . ')';
1497         } elsif ($ref eq 'SCALAR') {
1498             # literal SQL
1499             push @sql, $$_;
1500         } else {
1501             # strings get case twiddled
1502             push @sql, $self->_sqlcase($_);
1503         }
1504     }
1505
1506     my $sql = join ' ', @sql;
1507
1508     # this is pretty tricky
1509     # if ask for an array, return ($stmt, @bind)
1510     # otherwise, s/?/shift @sqlv/ to put it inline
1511     if (wantarray) {
1512         return ($sql, @sqlv);
1513     } else {
1514         1 while $sql =~ s/\?/my $d = shift(@sqlv);
1515                              ref $d ? $d->[1] : $d/e;
1516         return $sql;
1517     }
1518 }
1519
1520
1521 sub DESTROY { 1 }
1522
1523 sub AUTOLOAD {
1524     # This allows us to check for a local, then _form, attr
1525     my $self = shift;
1526     my($name) = $AUTOLOAD =~ /.*::(.+)/;
1527     return $self->generate($name, @_);
1528 }
1529
1530 1;
1531
1532
1533
1534 __END__
1535
1536 =head1 NAME
1537
1538 SQL::Abstract - Generate SQL from Perl data structures
1539
1540 =head1 SYNOPSIS
1541
1542     use SQL::Abstract;
1543
1544     my $sql = SQL::Abstract->new;
1545
1546     my($stmt, @bind) = $sql->select($table, \@fields, \%where, \@order);
1547
1548     my($stmt, @bind) = $sql->insert($table, \%fieldvals || \@values);
1549
1550     my($stmt, @bind) = $sql->update($table, \%fieldvals, \%where);
1551
1552     my($stmt, @bind) = $sql->delete($table, \%where);
1553
1554     # Then, use these in your DBI statements
1555     my $sth = $dbh->prepare($stmt);
1556     $sth->execute(@bind);
1557
1558     # Just generate the WHERE clause
1559     my($stmt, @bind) = $sql->where(\%where, \@order);
1560
1561     # Return values in the same order, for hashed queries
1562     # See PERFORMANCE section for more details
1563     my @bind = $sql->values(\%fieldvals);
1564
1565 =head1 DESCRIPTION
1566
1567 This module was inspired by the excellent L<DBIx::Abstract>.
1568 However, in using that module I found that what I really wanted
1569 to do was generate SQL, but still retain complete control over my
1570 statement handles and use the DBI interface. So, I set out to
1571 create an abstract SQL generation module.
1572
1573 While based on the concepts used by L<DBIx::Abstract>, there are
1574 several important differences, especially when it comes to WHERE
1575 clauses. I have modified the concepts used to make the SQL easier
1576 to generate from Perl data structures and, IMO, more intuitive.
1577 The underlying idea is for this module to do what you mean, based
1578 on the data structures you provide it. The big advantage is that
1579 you don't have to modify your code every time your data changes,
1580 as this module figures it out.
1581
1582 To begin with, an SQL INSERT is as easy as just specifying a hash
1583 of C<key=value> pairs:
1584
1585     my %data = (
1586         name => 'Jimbo Bobson',
1587         phone => '123-456-7890',
1588         address => '42 Sister Lane',
1589         city => 'St. Louis',
1590         state => 'Louisiana',
1591     );
1592
1593 The SQL can then be generated with this:
1594
1595     my($stmt, @bind) = $sql->insert('people', \%data);
1596
1597 Which would give you something like this:
1598
1599     $stmt = "INSERT INTO people
1600                     (address, city, name, phone, state)
1601                     VALUES (?, ?, ?, ?, ?)";
1602     @bind = ('42 Sister Lane', 'St. Louis', 'Jimbo Bobson',
1603              '123-456-7890', 'Louisiana');
1604
1605 These are then used directly in your DBI code:
1606
1607     my $sth = $dbh->prepare($stmt);
1608     $sth->execute(@bind);
1609
1610 =head2 Inserting and Updating Arrays
1611
1612 If your database has array types (like for example Postgres),
1613 activate the special option C<< array_datatypes => 1 >>
1614 when creating the C<SQL::Abstract> object.
1615 Then you may use an arrayref to insert and update database array types:
1616
1617     my $sql = SQL::Abstract->new(array_datatypes => 1);
1618     my %data = (
1619         planets => [qw/Mercury Venus Earth Mars/]
1620     );
1621
1622     my($stmt, @bind) = $sql->insert('solar_system', \%data);
1623
1624 This results in:
1625
1626     $stmt = "INSERT INTO solar_system (planets) VALUES (?)"
1627
1628     @bind = (['Mercury', 'Venus', 'Earth', 'Mars']);
1629
1630
1631 =head2 Inserting and Updating SQL
1632
1633 In order to apply SQL functions to elements of your C<%data> you may
1634 specify a reference to an arrayref for the given hash value. For example,
1635 if you need to execute the Oracle C<to_date> function on a value, you can
1636 say something like this:
1637
1638     my %data = (
1639         name => 'Bill',
1640         date_entered => \["to_date(?,'MM/DD/YYYY')", "03/02/2003"],
1641     );
1642
1643 The first value in the array is the actual SQL. Any other values are
1644 optional and would be included in the bind values array. This gives
1645 you:
1646
1647     my($stmt, @bind) = $sql->insert('people', \%data);
1648
1649     $stmt = "INSERT INTO people (name, date_entered)
1650                 VALUES (?, to_date(?,'MM/DD/YYYY'))";
1651     @bind = ('Bill', '03/02/2003');
1652
1653 An UPDATE is just as easy, all you change is the name of the function:
1654
1655     my($stmt, @bind) = $sql->update('people', \%data);
1656
1657 Notice that your C<%data> isn't touched; the module will generate
1658 the appropriately quirky SQL for you automatically. Usually you'll
1659 want to specify a WHERE clause for your UPDATE, though, which is
1660 where handling C<%where> hashes comes in handy...
1661
1662 =head2 Complex where statements
1663
1664 This module can generate pretty complicated WHERE statements
1665 easily. For example, simple C<key=value> pairs are taken to mean
1666 equality, and if you want to see if a field is within a set
1667 of values, you can use an arrayref. Let's say we wanted to
1668 SELECT some data based on this criteria:
1669
1670     my %where = (
1671        requestor => 'inna',
1672        worker => ['nwiger', 'rcwe', 'sfz'],
1673        status => { '!=', 'completed' }
1674     );
1675
1676     my($stmt, @bind) = $sql->select('tickets', '*', \%where);
1677
1678 The above would give you something like this:
1679
1680     $stmt = "SELECT * FROM tickets WHERE
1681                 ( requestor = ? ) AND ( status != ? )
1682                 AND ( worker = ? OR worker = ? OR worker = ? )";
1683     @bind = ('inna', 'completed', 'nwiger', 'rcwe', 'sfz');
1684
1685 Which you could then use in DBI code like so:
1686
1687     my $sth = $dbh->prepare($stmt);
1688     $sth->execute(@bind);
1689
1690 Easy, eh?
1691
1692 =head1 FUNCTIONS
1693
1694 The functions are simple. There's one for each major SQL operation,
1695 and a constructor you use first. The arguments are specified in a
1696 similar order to each function (table, then fields, then a where
1697 clause) to try and simplify things.
1698
1699
1700
1701
1702 =head2 new(option => 'value')
1703
1704 The C<new()> function takes a list of options and values, and returns
1705 a new B<SQL::Abstract> object which can then be used to generate SQL
1706 through the methods below. The options accepted are:
1707
1708 =over
1709
1710 =item case
1711
1712 If set to 'lower', then SQL will be generated in all lowercase. By
1713 default SQL is generated in "textbook" case meaning something like:
1714
1715     SELECT a_field FROM a_table WHERE some_field LIKE '%someval%'
1716
1717 Any setting other than 'lower' is ignored.
1718
1719 =item cmp
1720
1721 This determines what the default comparison operator is. By default
1722 it is C<=>, meaning that a hash like this:
1723
1724     %where = (name => 'nwiger', email => 'nate@wiger.org');
1725
1726 Will generate SQL like this:
1727
1728     WHERE name = 'nwiger' AND email = 'nate@wiger.org'
1729
1730 However, you may want loose comparisons by default, so if you set
1731 C<cmp> to C<like> you would get SQL such as:
1732
1733     WHERE name like 'nwiger' AND email like 'nate@wiger.org'
1734
1735 You can also override the comparsion on an individual basis - see
1736 the huge section on L</"WHERE CLAUSES"> at the bottom.
1737
1738 =item sqltrue, sqlfalse
1739
1740 Expressions for inserting boolean values within SQL statements.
1741 By default these are C<1=1> and C<1=0>. They are used
1742 by the special operators C<-in> and C<-not_in> for generating
1743 correct SQL even when the argument is an empty array (see below).
1744
1745 =item logic
1746
1747 This determines the default logical operator for multiple WHERE
1748 statements in arrays or hashes. If absent, the default logic is "or"
1749 for arrays, and "and" for hashes. This means that a WHERE
1750 array of the form:
1751
1752     @where = (
1753         event_date => {'>=', '2/13/99'},
1754         event_date => {'<=', '4/24/03'},
1755     );
1756
1757 will generate SQL like this:
1758
1759     WHERE event_date >= '2/13/99' OR event_date <= '4/24/03'
1760
1761 This is probably not what you want given this query, though (look
1762 at the dates). To change the "OR" to an "AND", simply specify:
1763
1764     my $sql = SQL::Abstract->new(logic => 'and');
1765
1766 Which will change the above C<WHERE> to:
1767
1768     WHERE event_date >= '2/13/99' AND event_date <= '4/24/03'
1769
1770 The logic can also be changed locally by inserting
1771 a modifier in front of an arrayref :
1772
1773     @where = (-and => [event_date => {'>=', '2/13/99'},
1774                        event_date => {'<=', '4/24/03'} ]);
1775
1776 See the L</"WHERE CLAUSES"> section for explanations.
1777
1778 =item convert
1779
1780 This will automatically convert comparisons using the specified SQL
1781 function for both column and value. This is mostly used with an argument
1782 of C<upper> or C<lower>, so that the SQL will have the effect of
1783 case-insensitive "searches". For example, this:
1784
1785     $sql = SQL::Abstract->new(convert => 'upper');
1786     %where = (keywords => 'MaKe iT CAse inSeNSItive');
1787
1788 Will turn out the following SQL:
1789
1790     WHERE upper(keywords) like upper('MaKe iT CAse inSeNSItive')
1791
1792 The conversion can be C<upper()>, C<lower()>, or any other SQL function
1793 that can be applied symmetrically to fields (actually B<SQL::Abstract> does
1794 not validate this option; it will just pass through what you specify verbatim).
1795
1796 =item bindtype
1797
1798 This is a kludge because many databases suck. For example, you can't
1799 just bind values using DBI's C<execute()> for Oracle C<CLOB> or C<BLOB> fields.
1800 Instead, you have to use C<bind_param()>:
1801
1802     $sth->bind_param(1, 'reg data');
1803     $sth->bind_param(2, $lots, {ora_type => ORA_CLOB});
1804
1805 The problem is, B<SQL::Abstract> will normally just return a C<@bind> array,
1806 which loses track of which field each slot refers to. Fear not.
1807
1808 If you specify C<bindtype> in new, you can determine how C<@bind> is returned.
1809 Currently, you can specify either C<normal> (default) or C<columns>. If you
1810 specify C<columns>, you will get an array that looks like this:
1811
1812     my $sql = SQL::Abstract->new(bindtype => 'columns');
1813     my($stmt, @bind) = $sql->insert(...);
1814
1815     @bind = (
1816         [ 'column1', 'value1' ],
1817         [ 'column2', 'value2' ],
1818         [ 'column3', 'value3' ],
1819     );
1820
1821 You can then iterate through this manually, using DBI's C<bind_param()>.
1822
1823     $sth->prepare($stmt);
1824     my $i = 1;
1825     for (@bind) {
1826         my($col, $data) = @$_;
1827         if ($col eq 'details' || $col eq 'comments') {
1828             $sth->bind_param($i, $data, {ora_type => ORA_CLOB});
1829         } elsif ($col eq 'image') {
1830             $sth->bind_param($i, $data, {ora_type => ORA_BLOB});
1831         } else {
1832             $sth->bind_param($i, $data);
1833         }
1834         $i++;
1835     }
1836     $sth->execute;      # execute without @bind now
1837
1838 Now, why would you still use B<SQL::Abstract> if you have to do this crap?
1839 Basically, the advantage is still that you don't have to care which fields
1840 are or are not included. You could wrap that above C<for> loop in a simple
1841 sub called C<bind_fields()> or something and reuse it repeatedly. You still
1842 get a layer of abstraction over manual SQL specification.
1843
1844 Note that if you set L</bindtype> to C<columns>, the C<\[$sql, @bind]>
1845 construct (see L</Literal SQL with placeholders and bind values (subqueries)>)
1846 will expect the bind values in this format.
1847
1848 =item quote_char
1849
1850 This is the character that a table or column name will be quoted
1851 with.  By default this is an empty string, but you could set it to
1852 the character C<`>, to generate SQL like this:
1853
1854   SELECT `a_field` FROM `a_table` WHERE `some_field` LIKE '%someval%'
1855
1856 Alternatively, you can supply an array ref of two items, the first being the left
1857 hand quote character, and the second the right hand quote character. For
1858 example, you could supply C<['[',']']> for SQL Server 2000 compliant quotes
1859 that generates SQL like this:
1860
1861   SELECT [a_field] FROM [a_table] WHERE [some_field] LIKE '%someval%'
1862
1863 Quoting is useful if you have tables or columns names that are reserved
1864 words in your database's SQL dialect.
1865
1866 =item name_sep
1867
1868 This is the character that separates a table and column name.  It is
1869 necessary to specify this when the C<quote_char> option is selected,
1870 so that tables and column names can be individually quoted like this:
1871
1872   SELECT `table`.`one_field` FROM `table` WHERE `table`.`other_field` = 1
1873
1874 =item injection_guard
1875
1876 A regular expression C<qr/.../> that is applied to any C<-function> and unquoted
1877 column name specified in a query structure. This is a safety mechanism to avoid
1878 injection attacks when mishandling user input e.g.:
1879
1880   my %condition_as_column_value_pairs = get_values_from_user();
1881   $sqla->select( ... , \%condition_as_column_value_pairs );
1882
1883 If the expression matches an exception is thrown. Note that literal SQL
1884 supplied via C<\'...'> or C<\['...']> is B<not> checked in any way.
1885
1886 Defaults to checking for C<;> and the C<GO> keyword (TransactSQL)
1887
1888 =item array_datatypes
1889
1890 When this option is true, arrayrefs in INSERT or UPDATE are
1891 interpreted as array datatypes and are passed directly
1892 to the DBI layer.
1893 When this option is false, arrayrefs are interpreted
1894 as literal SQL, just like refs to arrayrefs
1895 (but this behavior is for backwards compatibility; when writing
1896 new queries, use the "reference to arrayref" syntax
1897 for literal SQL).
1898
1899
1900 =item special_ops
1901
1902 Takes a reference to a list of "special operators"
1903 to extend the syntax understood by L<SQL::Abstract>.
1904 See section L</"SPECIAL OPERATORS"> for details.
1905
1906 =item unary_ops
1907
1908 Takes a reference to a list of "unary operators"
1909 to extend the syntax understood by L<SQL::Abstract>.
1910 See section L</"UNARY OPERATORS"> for details.
1911
1912
1913
1914 =back
1915
1916 =head2 insert($table, \@values || \%fieldvals, \%options)
1917
1918 This is the simplest function. You simply give it a table name
1919 and either an arrayref of values or hashref of field/value pairs.
1920 It returns an SQL INSERT statement and a list of bind values.
1921 See the sections on L</"Inserting and Updating Arrays"> and
1922 L</"Inserting and Updating SQL"> for information on how to insert
1923 with those data types.
1924
1925 The optional C<\%options> hash reference may contain additional
1926 options to generate the insert SQL. Currently supported options
1927 are:
1928
1929 =over 4
1930
1931 =item returning
1932
1933 Takes either a scalar of raw SQL fields, or an array reference of
1934 field names, and adds on an SQL C<RETURNING> statement at the end.
1935 This allows you to return data generated by the insert statement
1936 (such as row IDs) without performing another C<SELECT> statement.
1937 Note, however, this is not part of the SQL standard and may not
1938 be supported by all database engines.
1939
1940 =back
1941
1942 =head2 update($table, \%fieldvals, \%where)
1943
1944 This takes a table, hashref of field/value pairs, and an optional
1945 hashref L<WHERE clause|/WHERE CLAUSES>. It returns an SQL UPDATE function and a list
1946 of bind values.
1947 See the sections on L</"Inserting and Updating Arrays"> and
1948 L</"Inserting and Updating SQL"> for information on how to insert
1949 with those data types.
1950
1951 =head2 select($source, $fields, $where, $order)
1952
1953 This returns a SQL SELECT statement and associated list of bind values, as
1954 specified by the arguments  :
1955
1956 =over
1957
1958 =item $source
1959
1960 Specification of the 'FROM' part of the statement.
1961 The argument can be either a plain scalar (interpreted as a table
1962 name, will be quoted), or an arrayref (interpreted as a list
1963 of table names, joined by commas, quoted), or a scalarref
1964 (literal table name, not quoted), or a ref to an arrayref
1965 (list of literal table names, joined by commas, not quoted).
1966
1967 =item $fields
1968
1969 Specification of the list of fields to retrieve from
1970 the source.
1971 The argument can be either an arrayref (interpreted as a list
1972 of field names, will be joined by commas and quoted), or a
1973 plain scalar (literal SQL, not quoted).
1974 Please observe that this API is not as flexible as for
1975 the first argument C<$table>, for backwards compatibility reasons.
1976
1977 =item $where
1978
1979 Optional argument to specify the WHERE part of the query.
1980 The argument is most often a hashref, but can also be
1981 an arrayref or plain scalar --
1982 see section L<WHERE clause|/"WHERE CLAUSES"> for details.
1983
1984 =item $order
1985
1986 Optional argument to specify the ORDER BY part of the query.
1987 The argument can be a scalar, a hashref or an arrayref
1988 -- see section L<ORDER BY clause|/"ORDER BY CLAUSES">
1989 for details.
1990
1991 =back
1992
1993
1994 =head2 delete($table, \%where)
1995
1996 This takes a table name and optional hashref L<WHERE clause|/WHERE CLAUSES>.
1997 It returns an SQL DELETE statement and list of bind values.
1998
1999 =head2 where(\%where, \@order)
2000
2001 This is used to generate just the WHERE clause. For example,
2002 if you have an arbitrary data structure and know what the
2003 rest of your SQL is going to look like, but want an easy way
2004 to produce a WHERE clause, use this. It returns an SQL WHERE
2005 clause and list of bind values.
2006
2007
2008 =head2 values(\%data)
2009
2010 This just returns the values from the hash C<%data>, in the same
2011 order that would be returned from any of the other above queries.
2012 Using this allows you to markedly speed up your queries if you
2013 are affecting lots of rows. See below under the L</"PERFORMANCE"> section.
2014
2015 =head2 generate($any, 'number', $of, \@data, $struct, \%types)
2016
2017 Warning: This is an experimental method and subject to change.
2018
2019 This returns arbitrarily generated SQL. It's a really basic shortcut.
2020 It will return two different things, depending on return context:
2021
2022     my($stmt, @bind) = $sql->generate('create table', \$table, \@fields);
2023     my $stmt_and_val = $sql->generate('create table', \$table, \@fields);
2024
2025 These would return the following:
2026
2027     # First calling form
2028     $stmt = "CREATE TABLE test (?, ?)";
2029     @bind = (field1, field2);
2030
2031     # Second calling form
2032     $stmt_and_val = "CREATE TABLE test (field1, field2)";
2033
2034 Depending on what you're trying to do, it's up to you to choose the correct
2035 format. In this example, the second form is what you would want.
2036
2037 By the same token:
2038
2039     $sql->generate('alter session', { nls_date_format => 'MM/YY' });
2040
2041 Might give you:
2042
2043     ALTER SESSION SET nls_date_format = 'MM/YY'
2044
2045 You get the idea. Strings get their case twiddled, but everything
2046 else remains verbatim.
2047
2048 =head1 WHERE CLAUSES
2049
2050 =head2 Introduction
2051
2052 This module uses a variation on the idea from L<DBIx::Abstract>. It
2053 is B<NOT>, repeat I<not> 100% compatible. B<The main logic of this
2054 module is that things in arrays are OR'ed, and things in hashes
2055 are AND'ed.>
2056
2057 The easiest way to explain is to show lots of examples. After
2058 each C<%where> hash shown, it is assumed you used:
2059
2060     my($stmt, @bind) = $sql->where(\%where);
2061
2062 However, note that the C<%where> hash can be used directly in any
2063 of the other functions as well, as described above.
2064
2065 =head2 Key-value pairs
2066
2067 So, let's get started. To begin, a simple hash:
2068
2069     my %where  = (
2070         user   => 'nwiger',
2071         status => 'completed'
2072     );
2073
2074 Is converted to SQL C<key = val> statements:
2075
2076     $stmt = "WHERE user = ? AND status = ?";
2077     @bind = ('nwiger', 'completed');
2078
2079 One common thing I end up doing is having a list of values that
2080 a field can be in. To do this, simply specify a list inside of
2081 an arrayref:
2082
2083     my %where  = (
2084         user   => 'nwiger',
2085         status => ['assigned', 'in-progress', 'pending'];
2086     );
2087
2088 This simple code will create the following:
2089
2090     $stmt = "WHERE user = ? AND ( status = ? OR status = ? OR status = ? )";
2091     @bind = ('nwiger', 'assigned', 'in-progress', 'pending');
2092
2093 A field associated to an empty arrayref will be considered a
2094 logical false and will generate 0=1.
2095
2096 =head2 Tests for NULL values
2097
2098 If the value part is C<undef> then this is converted to SQL <IS NULL>
2099
2100     my %where  = (
2101         user   => 'nwiger',
2102         status => undef,
2103     );
2104
2105 becomes:
2106
2107     $stmt = "WHERE user = ? AND status IS NULL";
2108     @bind = ('nwiger');
2109
2110 To test if a column IS NOT NULL:
2111
2112     my %where  = (
2113         user   => 'nwiger',
2114         status => { '!=', undef },
2115     );
2116
2117 =head2 Specific comparison operators
2118
2119 If you want to specify a different type of operator for your comparison,
2120 you can use a hashref for a given column:
2121
2122     my %where  = (
2123         user   => 'nwiger',
2124         status => { '!=', 'completed' }
2125     );
2126
2127 Which would generate:
2128
2129     $stmt = "WHERE user = ? AND status != ?";
2130     @bind = ('nwiger', 'completed');
2131
2132 To test against multiple values, just enclose the values in an arrayref:
2133
2134     status => { '=', ['assigned', 'in-progress', 'pending'] };
2135
2136 Which would give you:
2137
2138     "WHERE status = ? OR status = ? OR status = ?"
2139
2140
2141 The hashref can also contain multiple pairs, in which case it is expanded
2142 into an C<AND> of its elements:
2143
2144     my %where  = (
2145         user   => 'nwiger',
2146         status => { '!=', 'completed', -not_like => 'pending%' }
2147     );
2148
2149     # Or more dynamically, like from a form
2150     $where{user} = 'nwiger';
2151     $where{status}{'!='} = 'completed';
2152     $where{status}{'-not_like'} = 'pending%';
2153
2154     # Both generate this
2155     $stmt = "WHERE user = ? AND status != ? AND status NOT LIKE ?";
2156     @bind = ('nwiger', 'completed', 'pending%');
2157
2158
2159 To get an OR instead, you can combine it with the arrayref idea:
2160
2161     my %where => (
2162          user => 'nwiger',
2163          priority => [ { '=', 2 }, { '>', 5 } ]
2164     );
2165
2166 Which would generate:
2167
2168     $stmt = "WHERE ( priority = ? OR priority > ? ) AND user = ?";
2169     @bind = ('2', '5', 'nwiger');
2170
2171 If you want to include literal SQL (with or without bind values), just use a
2172 scalar reference or array reference as the value:
2173
2174     my %where  = (
2175         date_entered => { '>' => \["to_date(?, 'MM/DD/YYYY')", "11/26/2008"] },
2176         date_expires => { '<' => \"now()" }
2177     );
2178
2179 Which would generate:
2180
2181     $stmt = "WHERE date_entered > "to_date(?, 'MM/DD/YYYY') AND date_expires < now()";
2182     @bind = ('11/26/2008');
2183
2184
2185 =head2 Logic and nesting operators
2186
2187 In the example above,
2188 there is a subtle trap if you want to say something like
2189 this (notice the C<AND>):
2190
2191     WHERE priority != ? AND priority != ?
2192
2193 Because, in Perl you I<can't> do this:
2194
2195     priority => { '!=', 2, '!=', 1 }
2196
2197 As the second C<!=> key will obliterate the first. The solution
2198 is to use the special C<-modifier> form inside an arrayref:
2199
2200     priority => [ -and => {'!=', 2},
2201                           {'!=', 1} ]
2202
2203
2204 Normally, these would be joined by C<OR>, but the modifier tells it
2205 to use C<AND> instead. (Hint: You can use this in conjunction with the
2206 C<logic> option to C<new()> in order to change the way your queries
2207 work by default.) B<Important:> Note that the C<-modifier> goes
2208 B<INSIDE> the arrayref, as an extra first element. This will
2209 B<NOT> do what you think it might:
2210
2211     priority => -and => [{'!=', 2}, {'!=', 1}]   # WRONG!
2212
2213 Here is a quick list of equivalencies, since there is some overlap:
2214
2215     # Same
2216     status => {'!=', 'completed', 'not like', 'pending%' }
2217     status => [ -and => {'!=', 'completed'}, {'not like', 'pending%'}]
2218
2219     # Same
2220     status => {'=', ['assigned', 'in-progress']}
2221     status => [ -or => {'=', 'assigned'}, {'=', 'in-progress'}]
2222     status => [ {'=', 'assigned'}, {'=', 'in-progress'} ]
2223
2224
2225
2226 =head2 Special operators : IN, BETWEEN, etc.
2227
2228 You can also use the hashref format to compare a list of fields using the
2229 C<IN> comparison operator, by specifying the list as an arrayref:
2230
2231     my %where  = (
2232         status   => 'completed',
2233         reportid => { -in => [567, 2335, 2] }
2234     );
2235
2236 Which would generate:
2237
2238     $stmt = "WHERE status = ? AND reportid IN (?,?,?)";
2239     @bind = ('completed', '567', '2335', '2');
2240
2241 The reverse operator C<-not_in> generates SQL C<NOT IN> and is used in
2242 the same way.
2243
2244 If the argument to C<-in> is an empty array, 'sqlfalse' is generated
2245 (by default : C<1=0>). Similarly, C<< -not_in => [] >> generates
2246 'sqltrue' (by default : C<1=1>).
2247
2248 In addition to the array you can supply a chunk of literal sql or
2249 literal sql with bind:
2250
2251     my %where = {
2252       customer => { -in => \[
2253         'SELECT cust_id FROM cust WHERE balance > ?',
2254         2000,
2255       ],
2256       status => { -in => \'SELECT status_codes FROM states' },
2257     };
2258
2259 would generate:
2260
2261     $stmt = "WHERE (
2262           customer IN ( SELECT cust_id FROM cust WHERE balance > ? )
2263       AND status IN ( SELECT status_codes FROM states )
2264     )";
2265     @bind = ('2000');
2266
2267
2268
2269 Another pair of operators is C<-between> and C<-not_between>,
2270 used with an arrayref of two values:
2271
2272     my %where  = (
2273         user   => 'nwiger',
2274         completion_date => {
2275            -not_between => ['2002-10-01', '2003-02-06']
2276         }
2277     );
2278
2279 Would give you:
2280
2281     WHERE user = ? AND completion_date NOT BETWEEN ( ? AND ? )
2282
2283 Just like with C<-in> all plausible combinations of literal SQL
2284 are possible:
2285
2286     my %where = {
2287       start0 => { -between => [ 1, 2 ] },
2288       start1 => { -between => \["? AND ?", 1, 2] },
2289       start2 => { -between => \"lower(x) AND upper(y)" },
2290       start3 => { -between => [
2291         \"lower(x)",
2292         \["upper(?)", 'stuff' ],
2293       ] },
2294     };
2295
2296 Would give you:
2297
2298     $stmt = "WHERE (
2299           ( start0 BETWEEN ? AND ?                )
2300       AND ( start1 BETWEEN ? AND ?                )
2301       AND ( start2 BETWEEN lower(x) AND upper(y)  )
2302       AND ( start3 BETWEEN lower(x) AND upper(?)  )
2303     )";
2304     @bind = (1, 2, 1, 2, 'stuff');
2305
2306
2307 These are the two builtin "special operators"; but the
2308 list can be expanded : see section L</"SPECIAL OPERATORS"> below.
2309
2310 =head2 Unary operators: bool
2311
2312 If you wish to test against boolean columns or functions within your
2313 database you can use the C<-bool> and C<-not_bool> operators. For
2314 example to test the column C<is_user> being true and the column
2315 C<is_enabled> being false you would use:-
2316
2317     my %where  = (
2318         -bool       => 'is_user',
2319         -not_bool   => 'is_enabled',
2320     );
2321
2322 Would give you:
2323
2324     WHERE is_user AND NOT is_enabled
2325
2326 If a more complex combination is required, testing more conditions,
2327 then you should use the and/or operators:-
2328
2329     my %where  = (
2330         -and           => [
2331             -bool      => 'one',
2332             -bool      => 'two',
2333             -bool      => 'three',
2334             -not_bool  => 'four',
2335         ],
2336     );
2337
2338 Would give you:
2339
2340     WHERE one AND two AND three AND NOT four
2341
2342
2343 =head2 Nested conditions, -and/-or prefixes
2344
2345 So far, we've seen how multiple conditions are joined with a top-level
2346 C<AND>.  We can change this by putting the different conditions we want in
2347 hashes and then putting those hashes in an array. For example:
2348
2349     my @where = (
2350         {
2351             user   => 'nwiger',
2352             status => { -like => ['pending%', 'dispatched'] },
2353         },
2354         {
2355             user   => 'robot',
2356             status => 'unassigned',
2357         }
2358     );
2359
2360 This data structure would create the following:
2361
2362     $stmt = "WHERE ( user = ? AND ( status LIKE ? OR status LIKE ? ) )
2363                 OR ( user = ? AND status = ? ) )";
2364     @bind = ('nwiger', 'pending', 'dispatched', 'robot', 'unassigned');
2365
2366
2367 Clauses in hashrefs or arrayrefs can be prefixed with an C<-and> or C<-or>
2368 to change the logic inside :
2369
2370     my @where = (
2371          -and => [
2372             user => 'nwiger',
2373             [
2374                 -and => [ workhrs => {'>', 20}, geo => 'ASIA' ],
2375                 -or => { workhrs => {'<', 50}, geo => 'EURO' },
2376             ],
2377         ],
2378     );
2379
2380 That would yield:
2381
2382     WHERE ( user = ? AND (
2383                ( workhrs > ? AND geo = ? )
2384             OR ( workhrs < ? OR geo = ? )
2385           ) )
2386
2387 =head3 Algebraic inconsistency, for historical reasons
2388
2389 C<Important note>: when connecting several conditions, the C<-and->|C<-or>
2390 operator goes C<outside> of the nested structure; whereas when connecting
2391 several constraints on one column, the C<-and> operator goes
2392 C<inside> the arrayref. Here is an example combining both features :
2393
2394    my @where = (
2395      -and => [a => 1, b => 2],
2396      -or  => [c => 3, d => 4],
2397       e   => [-and => {-like => 'foo%'}, {-like => '%bar'} ]
2398    )
2399
2400 yielding
2401
2402   WHERE ( (    ( a = ? AND b = ? )
2403             OR ( c = ? OR d = ? )
2404             OR ( e LIKE ? AND e LIKE ? ) ) )
2405
2406 This difference in syntax is unfortunate but must be preserved for
2407 historical reasons. So be careful : the two examples below would
2408 seem algebraically equivalent, but they are not
2409
2410   {col => [-and => {-like => 'foo%'}, {-like => '%bar'}]}
2411   # yields : WHERE ( ( col LIKE ? AND col LIKE ? ) )
2412
2413   [-and => {col => {-like => 'foo%'}, {col => {-like => '%bar'}}]]
2414   # yields : WHERE ( ( col LIKE ? OR col LIKE ? ) )
2415
2416
2417 =head2 Literal SQL and value type operators
2418
2419 The basic premise of SQL::Abstract is that in WHERE specifications the "left
2420 side" is a column name and the "right side" is a value (normally rendered as
2421 a placeholder). This holds true for both hashrefs and arrayref pairs as you
2422 see in the L</WHERE CLAUSES> examples above. Sometimes it is necessary to
2423 alter this behavior. There are several ways of doing so.
2424
2425 =head3 -ident
2426
2427 This is a virtual operator that signals the string to its right side is an
2428 identifier (a column name) and not a value. For example to compare two
2429 columns you would write:
2430
2431     my %where = (
2432         priority => { '<', 2 },
2433         requestor => { -ident => 'submitter' },
2434     );
2435
2436 which creates:
2437
2438     $stmt = "WHERE priority < ? AND requestor = submitter";
2439     @bind = ('2');
2440
2441 If you are maintaining legacy code you may see a different construct as
2442 described in L</Deprecated usage of Literal SQL>, please use C<-ident> in new
2443 code.
2444
2445 =head3 -value
2446
2447 This is a virtual operator that signals that the construct to its right side
2448 is a value to be passed to DBI. This is for example necessary when you want
2449 to write a where clause against an array (for RDBMS that support such
2450 datatypes). For example:
2451
2452     my %where = (
2453         array => { -value => [1, 2, 3] }
2454     );
2455
2456 will result in:
2457
2458     $stmt = 'WHERE array = ?';
2459     @bind = ([1, 2, 3]);
2460
2461 Note that if you were to simply say:
2462
2463     my %where = (
2464         array => [1, 2, 3]
2465     );
2466
2467 the result would porbably be not what you wanted:
2468
2469     $stmt = 'WHERE array = ? OR array = ? OR array = ?';
2470     @bind = (1, 2, 3);
2471
2472 =head3 Literal SQL
2473
2474 Finally, sometimes only literal SQL will do. To include a random snippet
2475 of SQL verbatim, you specify it as a scalar reference. Consider this only
2476 as a last resort. Usually there is a better way. For example:
2477
2478     my %where = (
2479         priority => { '<', 2 },
2480         requestor => { -in => \'(SELECT name FROM hitmen)' },
2481     );
2482
2483 Would create:
2484
2485     $stmt = "WHERE priority < ? AND requestor IN (SELECT name FROM hitmen)"
2486     @bind = (2);
2487
2488 Note that in this example, you only get one bind parameter back, since
2489 the verbatim SQL is passed as part of the statement.
2490
2491 =head4 CAVEAT
2492
2493   Never use untrusted input as a literal SQL argument - this is a massive
2494   security risk (there is no way to check literal snippets for SQL
2495   injections and other nastyness). If you need to deal with untrusted input
2496   use literal SQL with placeholders as described next.
2497
2498 =head3 Literal SQL with placeholders and bind values (subqueries)
2499
2500 If the literal SQL to be inserted has placeholders and bind values,
2501 use a reference to an arrayref (yes this is a double reference --
2502 not so common, but perfectly legal Perl). For example, to find a date
2503 in Postgres you can use something like this:
2504
2505     my %where = (
2506        date_column => \[q/= date '2008-09-30' - ?::integer/, 10/]
2507     )
2508
2509 This would create:
2510
2511     $stmt = "WHERE ( date_column = date '2008-09-30' - ?::integer )"
2512     @bind = ('10');
2513
2514 Note that you must pass the bind values in the same format as they are returned
2515 by L</where>. That means that if you set L</bindtype> to C<columns>, you must
2516 provide the bind values in the C<< [ column_meta => value ] >> format, where
2517 C<column_meta> is an opaque scalar value; most commonly the column name, but
2518 you can use any scalar value (including references and blessed references),
2519 L<SQL::Abstract> will simply pass it through intact. So if C<bindtype> is set
2520 to C<columns> the above example will look like:
2521
2522     my %where = (
2523        date_column => \[q/= date '2008-09-30' - ?::integer/, [ dummy => 10 ]/]
2524     )
2525
2526 Literal SQL is especially useful for nesting parenthesized clauses in the
2527 main SQL query. Here is a first example :
2528
2529   my ($sub_stmt, @sub_bind) = ("SELECT c1 FROM t1 WHERE c2 < ? AND c3 LIKE ?",
2530                                100, "foo%");
2531   my %where = (
2532     foo => 1234,
2533     bar => \["IN ($sub_stmt)" => @sub_bind],
2534   );
2535
2536 This yields :
2537
2538   $stmt = "WHERE (foo = ? AND bar IN (SELECT c1 FROM t1
2539                                              WHERE c2 < ? AND c3 LIKE ?))";
2540   @bind = (1234, 100, "foo%");
2541
2542 Other subquery operators, like for example C<"E<gt> ALL"> or C<"NOT IN">,
2543 are expressed in the same way. Of course the C<$sub_stmt> and
2544 its associated bind values can be generated through a former call
2545 to C<select()> :
2546
2547   my ($sub_stmt, @sub_bind)
2548      = $sql->select("t1", "c1", {c2 => {"<" => 100},
2549                                  c3 => {-like => "foo%"}});
2550   my %where = (
2551     foo => 1234,
2552     bar => \["> ALL ($sub_stmt)" => @sub_bind],
2553   );
2554
2555 In the examples above, the subquery was used as an operator on a column;
2556 but the same principle also applies for a clause within the main C<%where>
2557 hash, like an EXISTS subquery :
2558
2559   my ($sub_stmt, @sub_bind)
2560      = $sql->select("t1", "*", {c1 => 1, c2 => \"> t0.c0"});
2561   my %where = ( -and => [
2562     foo   => 1234,
2563     \["EXISTS ($sub_stmt)" => @sub_bind],
2564   ]);
2565
2566 which yields
2567
2568   $stmt = "WHERE (foo = ? AND EXISTS (SELECT * FROM t1
2569                                         WHERE c1 = ? AND c2 > t0.c0))";
2570   @bind = (1234, 1);
2571
2572
2573 Observe that the condition on C<c2> in the subquery refers to
2574 column C<t0.c0> of the main query : this is I<not> a bind
2575 value, so we have to express it through a scalar ref.
2576 Writing C<< c2 => {">" => "t0.c0"} >> would have generated
2577 C<< c2 > ? >> with bind value C<"t0.c0"> ... not exactly
2578 what we wanted here.
2579
2580 Finally, here is an example where a subquery is used
2581 for expressing unary negation:
2582
2583   my ($sub_stmt, @sub_bind)
2584      = $sql->where({age => [{"<" => 10}, {">" => 20}]});
2585   $sub_stmt =~ s/^ where //i; # don't want "WHERE" in the subclause
2586   my %where = (
2587         lname  => {like => '%son%'},
2588         \["NOT ($sub_stmt)" => @sub_bind],
2589     );
2590
2591 This yields
2592
2593   $stmt = "lname LIKE ? AND NOT ( age < ? OR age > ? )"
2594   @bind = ('%son%', 10, 20)
2595
2596 =head3 Deprecated usage of Literal SQL
2597
2598 Below are some examples of archaic use of literal SQL. It is shown only as
2599 reference for those who deal with legacy code. Each example has a much
2600 better, cleaner and safer alternative that users should opt for in new code.
2601
2602 =over
2603
2604 =item *
2605
2606     my %where = ( requestor => \'IS NOT NULL' )
2607
2608     $stmt = "WHERE requestor IS NOT NULL"
2609
2610 This used to be the way of generating NULL comparisons, before the handling
2611 of C<undef> got formalized. For new code please use the superior syntax as
2612 described in L</Tests for NULL values>.
2613
2614 =item *
2615
2616     my %where = ( requestor => \'= submitter' )
2617
2618     $stmt = "WHERE requestor = submitter"
2619
2620 This used to be the only way to compare columns. Use the superior L</-ident>
2621 method for all new code. For example an identifier declared in such a way
2622 will be properly quoted if L</quote_char> is properly set, while the legacy
2623 form will remain as supplied.
2624
2625 =item *
2626
2627     my %where = ( is_ready  => \"", completed => { '>', '2012-12-21' } )
2628
2629     $stmt = "WHERE completed > ? AND is_ready"
2630     @bind = ('2012-12-21')
2631
2632 Using an empty string literal used to be the only way to express a boolean.
2633 For all new code please use the much more readable
2634 L<-bool|/Unary operators: bool> operator.
2635
2636 =back
2637
2638 =head2 Conclusion
2639
2640 These pages could go on for a while, since the nesting of the data
2641 structures this module can handle are pretty much unlimited (the
2642 module implements the C<WHERE> expansion as a recursive function
2643 internally). Your best bet is to "play around" with the module a
2644 little to see how the data structures behave, and choose the best
2645 format for your data based on that.
2646
2647 And of course, all the values above will probably be replaced with
2648 variables gotten from forms or the command line. After all, if you
2649 knew everything ahead of time, you wouldn't have to worry about
2650 dynamically-generating SQL and could just hardwire it into your
2651 script.
2652
2653 =head1 ORDER BY CLAUSES
2654
2655 Some functions take an order by clause. This can either be a scalar (just a
2656 column name,) a hash of C<< { -desc => 'col' } >> or C<< { -asc => 'col' } >>,
2657 or an array of either of the two previous forms. Examples:
2658
2659                Given            |         Will Generate
2660     ----------------------------------------------------------
2661                                 |
2662     \'colA DESC'                | ORDER BY colA DESC
2663                                 |
2664     'colA'                      | ORDER BY colA
2665                                 |
2666     [qw/colA colB/]             | ORDER BY colA, colB
2667                                 |
2668     {-asc  => 'colA'}           | ORDER BY colA ASC
2669                                 |
2670     {-desc => 'colB'}           | ORDER BY colB DESC
2671                                 |
2672     ['colA', {-asc => 'colB'}]  | ORDER BY colA, colB ASC
2673                                 |
2674     { -asc => [qw/colA colB/] } | ORDER BY colA ASC, colB ASC
2675                                 |
2676     [                           |
2677       { -asc => 'colA' },       | ORDER BY colA ASC, colB DESC,
2678       { -desc => [qw/colB/],    |          colC ASC, colD ASC
2679       { -asc => [qw/colC colD/],|
2680     ]                           |
2681     ===========================================================
2682
2683
2684
2685 =head1 SPECIAL OPERATORS
2686
2687   my $sqlmaker = SQL::Abstract->new(special_ops => [
2688      {
2689       regex => qr/.../,
2690       handler => sub {
2691         my ($self, $field, $op, $arg) = @_;
2692         ...
2693       },
2694      },
2695      {
2696       regex => qr/.../,
2697       handler => 'method_name',
2698      },
2699    ]);
2700
2701 A "special operator" is a SQL syntactic clause that can be
2702 applied to a field, instead of a usual binary operator.
2703 For example :
2704
2705    WHERE field IN (?, ?, ?)
2706    WHERE field BETWEEN ? AND ?
2707    WHERE MATCH(field) AGAINST (?, ?)
2708
2709 Special operators IN and BETWEEN are fairly standard and therefore
2710 are builtin within C<SQL::Abstract> (as the overridable methods
2711 C<_where_field_IN> and C<_where_field_BETWEEN>). For other operators,
2712 like the MATCH .. AGAINST example above which is specific to MySQL,
2713 you can write your own operator handlers - supply a C<special_ops>
2714 argument to the C<new> method. That argument takes an arrayref of
2715 operator definitions; each operator definition is a hashref with two
2716 entries:
2717
2718 =over
2719
2720 =item regex
2721
2722 the regular expression to match the operator
2723
2724 =item handler
2725
2726 Either a coderef or a plain scalar method name. In both cases
2727 the expected return is C<< ($sql, @bind) >>.
2728
2729 When supplied with a method name, it is simply called on the
2730 L<SQL::Abstract/> object as:
2731
2732  $self->$method_name ($field, $op, $arg)
2733
2734  Where:
2735
2736   $op is the part that matched the handler regex
2737   $field is the LHS of the operator
2738   $arg is the RHS
2739
2740 When supplied with a coderef, it is called as:
2741
2742  $coderef->($self, $field, $op, $arg)
2743
2744
2745 =back
2746
2747 For example, here is an implementation
2748 of the MATCH .. AGAINST syntax for MySQL
2749
2750   my $sqlmaker = SQL::Abstract->new(special_ops => [
2751
2752     # special op for MySql MATCH (field) AGAINST(word1, word2, ...)
2753     {regex => qr/^match$/i,
2754      handler => sub {
2755        my ($self, $field, $op, $arg) = @_;
2756        $arg = [$arg] if not ref $arg;
2757        my $label         = $self->_quote($field);
2758        my ($placeholder) = $self->_convert('?');
2759        my $placeholders  = join ", ", (($placeholder) x @$arg);
2760        my $sql           = $self->_sqlcase('match') . " ($label) "
2761                          . $self->_sqlcase('against') . " ($placeholders) ";
2762        my @bind = $self->_bindtype($field, @$arg);
2763        return ($sql, @bind);
2764        }
2765      },
2766
2767   ]);
2768
2769
2770 =head1 UNARY OPERATORS
2771
2772   my $sqlmaker = SQL::Abstract->new(unary_ops => [
2773      {
2774       regex => qr/.../,
2775       handler => sub {
2776         my ($self, $op, $arg) = @_;
2777         ...
2778       },
2779      },
2780      {
2781       regex => qr/.../,
2782       handler => 'method_name',
2783      },
2784    ]);
2785
2786 A "unary operator" is a SQL syntactic clause that can be
2787 applied to a field - the operator goes before the field
2788
2789 You can write your own operator handlers - supply a C<unary_ops>
2790 argument to the C<new> method. That argument takes an arrayref of
2791 operator definitions; each operator definition is a hashref with two
2792 entries:
2793
2794 =over
2795
2796 =item regex
2797
2798 the regular expression to match the operator
2799
2800 =item handler
2801
2802 Either a coderef or a plain scalar method name. In both cases
2803 the expected return is C<< $sql >>.
2804
2805 When supplied with a method name, it is simply called on the
2806 L<SQL::Abstract/> object as:
2807
2808  $self->$method_name ($op, $arg)
2809
2810  Where:
2811
2812   $op is the part that matched the handler regex
2813   $arg is the RHS or argument of the operator
2814
2815 When supplied with a coderef, it is called as:
2816
2817  $coderef->($self, $op, $arg)
2818
2819
2820 =back
2821
2822
2823 =head1 PERFORMANCE
2824
2825 Thanks to some benchmarking by Mark Stosberg, it turns out that
2826 this module is many orders of magnitude faster than using C<DBIx::Abstract>.
2827 I must admit this wasn't an intentional design issue, but it's a
2828 byproduct of the fact that you get to control your C<DBI> handles
2829 yourself.
2830
2831 To maximize performance, use a code snippet like the following:
2832
2833     # prepare a statement handle using the first row
2834     # and then reuse it for the rest of the rows
2835     my($sth, $stmt);
2836     for my $href (@array_of_hashrefs) {
2837         $stmt ||= $sql->insert('table', $href);
2838         $sth  ||= $dbh->prepare($stmt);
2839         $sth->execute($sql->values($href));
2840     }
2841
2842 The reason this works is because the keys in your C<$href> are sorted
2843 internally by B<SQL::Abstract>. Thus, as long as your data retains
2844 the same structure, you only have to generate the SQL the first time
2845 around. On subsequent queries, simply use the C<values> function provided
2846 by this module to return your values in the correct order.
2847
2848 However this depends on the values having the same type - if, for
2849 example, the values of a where clause may either have values
2850 (resulting in sql of the form C<column = ?> with a single bind
2851 value), or alternatively the values might be C<undef> (resulting in
2852 sql of the form C<column IS NULL> with no bind value) then the
2853 caching technique suggested will not work.
2854
2855 =head1 FORMBUILDER
2856
2857 If you use my C<CGI::FormBuilder> module at all, you'll hopefully
2858 really like this part (I do, at least). Building up a complex query
2859 can be as simple as the following:
2860
2861     #!/usr/bin/perl
2862
2863     use CGI::FormBuilder;
2864     use SQL::Abstract;
2865
2866     my $form = CGI::FormBuilder->new(...);
2867     my $sql  = SQL::Abstract->new;
2868
2869     if ($form->submitted) {
2870         my $field = $form->field;
2871         my $id = delete $field->{id};
2872         my($stmt, @bind) = $sql->update('table', $field, {id => $id});
2873     }
2874
2875 Of course, you would still have to connect using C<DBI> to run the
2876 query, but the point is that if you make your form look like your
2877 table, the actual query script can be extremely simplistic.
2878
2879 If you're B<REALLY> lazy (I am), check out C<HTML::QuickTable> for
2880 a fast interface to returning and formatting data. I frequently
2881 use these three modules together to write complex database query
2882 apps in under 50 lines.
2883
2884 =head1 REPO
2885
2886 =over
2887
2888 =item * gitweb: L<http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=dbsrgits/SQL-Abstract.git>
2889
2890 =item * git: L<git://git.shadowcat.co.uk/dbsrgits/SQL-Abstract.git>
2891
2892 =back
2893
2894 =head1 CHANGES
2895
2896 Version 1.50 was a major internal refactoring of C<SQL::Abstract>.
2897 Great care has been taken to preserve the I<published> behavior
2898 documented in previous versions in the 1.* family; however,
2899 some features that were previously undocumented, or behaved
2900 differently from the documentation, had to be changed in order
2901 to clarify the semantics. Hence, client code that was relying
2902 on some dark areas of C<SQL::Abstract> v1.*
2903 B<might behave differently> in v1.50.
2904
2905 The main changes are :
2906
2907 =over
2908
2909 =item *
2910
2911 support for literal SQL through the C<< \ [$sql, bind] >> syntax.
2912
2913 =item *
2914
2915 support for the { operator => \"..." } construct (to embed literal SQL)
2916
2917 =item *
2918
2919 support for the { operator => \["...", @bind] } construct (to embed literal SQL with bind values)
2920
2921 =item *
2922
2923 optional support for L<array datatypes|/"Inserting and Updating Arrays">
2924
2925 =item *
2926
2927 defensive programming : check arguments
2928
2929 =item *
2930
2931 fixed bug with global logic, which was previously implemented
2932 through global variables yielding side-effects. Prior versions would
2933 interpret C<< [ {cond1, cond2}, [cond3, cond4] ] >>
2934 as C<< "(cond1 AND cond2) OR (cond3 AND cond4)" >>.
2935 Now this is interpreted
2936 as C<< "(cond1 AND cond2) OR (cond3 OR cond4)" >>.
2937
2938
2939 =item *
2940
2941 fixed semantics of  _bindtype on array args
2942
2943 =item *
2944
2945 dropped the C<_anoncopy> of the %where tree. No longer necessary,
2946 we just avoid shifting arrays within that tree.
2947
2948 =item *
2949
2950 dropped the C<_modlogic> function
2951
2952 =back
2953
2954 =head1 ACKNOWLEDGEMENTS
2955
2956 There are a number of individuals that have really helped out with
2957 this module. Unfortunately, most of them submitted bugs via CPAN
2958 so I have no idea who they are! But the people I do know are:
2959
2960     Ash Berlin (order_by hash term support)
2961     Matt Trout (DBIx::Class support)
2962     Mark Stosberg (benchmarking)
2963     Chas Owens (initial "IN" operator support)
2964     Philip Collins (per-field SQL functions)
2965     Eric Kolve (hashref "AND" support)
2966     Mike Fragassi (enhancements to "BETWEEN" and "LIKE")
2967     Dan Kubb (support for "quote_char" and "name_sep")
2968     Guillermo Roditi (patch to cleanup "IN" and "BETWEEN", fix and tests for _order_by)
2969     Laurent Dami (internal refactoring, extensible list of special operators, literal SQL)
2970     Norbert Buchmuller (support for literal SQL in hashpair, misc. fixes & tests)
2971     Peter Rabbitson (rewrite of SQLA::Test, misc. fixes & tests)
2972     Oliver Charles (support for "RETURNING" after "INSERT")
2973
2974 Thanks!
2975
2976 =head1 SEE ALSO
2977
2978 L<DBIx::Class>, L<DBIx::Abstract>, L<CGI::FormBuilder>, L<HTML::QuickTable>.
2979
2980 =head1 AUTHOR
2981
2982 Copyright (c) 2001-2007 Nathan Wiger <nwiger@cpan.org>. All Rights Reserved.
2983
2984 This module is actively maintained by Matt Trout <mst@shadowcatsystems.co.uk>
2985
2986 For support, your best bet is to try the C<DBIx::Class> users mailing list.
2987 While not an official support venue, C<DBIx::Class> makes heavy use of
2988 C<SQL::Abstract>, and as such list members there are very familiar with
2989 how to create queries.
2990
2991 =head1 LICENSE
2992
2993 This module is free software; you may copy this under the same
2994 terms as perl itself (either the GNU General Public License or
2995 the Artistic License)
2996
2997 =cut
2998