lib/SDL/Surface.pm

   1 #
   2 #       Surface.pm
   3 #
   4 #       A package for manipulating SDL_Surface *
   5 #
   6 #       Copyright (C) 2003 David J. Goehrig
   7
   8 package SDL::Surface;
   9
  10 use strict;
  11 use SDL;
  12 use SDL::SFont;
  13 use SDL::Color;
  14 use SDL::Rect;
  15
  16 sub new {
  17         my $proto = shift;
  18         my $class = ref($proto) || $proto;
  19         my %options = @_;
  20         my $self;
  21
  22         verify (%options, qw/ -name -n -flags -fl -width -w -height -h -depth -d
  23                                 -pitch -p -Rmask -r -Gmask -g -Bmask -b -Amask -a
  24                                 -from -f /) if $SDL::DEBUG;
  25
  26         if ( defined($options{-name}) && $options{-name} ne "" && exists $SDL::{IMGLoad} ) {
  27            $self = \SDL::IMGLoad($options{-name});
  28         } else {
  29                 my $f = $options{-flags}        || $options{-fl}        || SDL::SDL_ANYFORMAT();
  30                 my $w = $options{-width}        || $options{-w}         || 1;
  31                 my $h = $options{-height}       || $options{-h}         || 1;
  32                 my $d = $options{-depth}        || $options{-d}         || 8;
  33                 my $p = $options{-pitch}        || $options{-p}         || $w*$d;
  34                 my $r = $options{-Rmask}        || $options{-r}
  35                         ||  ( SDL::BigEndian() ? 0xff000000 : 0x000000ff );
  36                 my $g = $options{-Gmask}        || $options{-g}
  37                         ||  ( SDL::BigEndian() ? 0x00ff0000 : 0x0000ff00 );
  38                 my $b = $options{-Bmask}        || $options{-b}
  39                         ||  ( SDL::BigEndian() ? 0x0000ff00 : 0x00ff0000 );
  40                 my $a = $options{-Amask}        || $options{-a}
  41                         ||  ( SDL::BigEndian() ? 0x000000ff : 0xff000000 );
  42
  43                 if ( $options{-from}|| $options{-f} ) {
  44                         my $src = $options{-from}|| $options{-f};
  45                         $self = \SDL::CreateRGBSurfaceFrom($src,$w,$h,$d,$p,$r,$g,$b,$a);
  46                 } else {
  47                         $self = \SDL::CreateRGBSurface($f,$w,$h,$d,$r,$g,$b,$a);
  48                 }
  49         }
  50         die "SDL::Surface::new failed. ", SDL::GetError()
  51                 unless ( $$self);
  52         bless $self,$class;
  53         return $self;
  54 }
  55
  56 sub DESTROY {
  57         SDL::FreeSurface(${$_[0]});
  58 }
  59
  60 sub flags {
  61         SDL::SurfaceFlags(${$_[0]});
  62 }
  63
  64 sub palette {
  65         SDL::SurfacePalette(${$_[0]});
  66 }
  67
  68 sub bpp {
  69         SDL::SurfaceBitsPerPixel(${$_[0]});
  70 }
  71
  72 sub bytes_per_pixel {
  73         SDL::SurfaceBytesPerPixel(${$_[0]});
  74 }
  75
  76 sub Rshift {
  77         SDL::SurfaceRshift(${$_[0]});
  78 }
  79
  80 sub Gshift {
  81         SDL::SurfaceGshift(${$_[0]});
  82 }
  83
  84 sub Bshift {
  85         SDL::SurfaceBshift(${$_[0]});
  86 }
  87
  88 sub Ashift {
  89         SDL::SurfaceAshift(${$_[0]});
  90 }
  91
  92 sub Rmask {
  93         SDL::SurfaceRmask(${$_[0]});
  94 }
  95
  96 sub Gmask {
  97         SDL::SurfaceGmask(${$_[0]});
  98 }
  99
 100 sub Bmask {
 101         SDL::SurfaceBmask(${$_[0]});
 102 }
 103
 104 sub Amask {
 105         SDL::SurfaceAmask(${$_[0]});
 106 }
 107
 108 sub color_key {
 109         SDL::SurfaceColorKey(${$_[0]});
 110 }
 111
 112 sub alpha {
 113         SDL::SurfaceAlpha(${$_[0]});
 114 }
 115
 116 sub width {
 117         SDL::SurfaceW(${$_[0]});
 118 }
 119
 120 sub height {
 121         SDL::SurfaceH(${$_[0]});
 122 }
 123
 124 sub pitch {
 125         SDL::SurfacePitch(${$_[0]});
 126 }
 127
 128 sub pixels {
 129         SDL::SurfacePixels(${$_[0]});
 130 }
 131
 132 sub pixel {
 133         die "SDL::Surface::pixel requires a SDL::Color"
 134                 if $_[3] && $SDL::DEBUG && !$_[3]->isa("SDL::Color");
 135         $_[3] ?
 136                 new SDL::Color -color => SDL::SurfacePixel(${$_[0]},$_[1],$_[2],${$_[3]}) :
 137                 new SDL::Color -color => SDL::SurfacePixel(${$_[0]},$_[1],$_[2]);
 138 }
 139
 140 sub fill {
 141         die "SDL::Surface::fill requires a SDL::Rect object"
 142                 unless !$SDL::DEBUG || $_[1] == 0 || $_[1]->isa('SDL::Rect');
 143         die "SDL::Surface::fill requires a SDL::Color object"
 144                 unless !$SDL::DEBUG || $_[2]->isa('SDL::Color');
 145         if ($_[1] == 0 ) {
 146                 SDL::FillRect(${$_[0]},0,${$_[2]});
 147         } else {
 148                 SDL::FillRect(${$_[0]},${$_[1]},${$_[2]});
 149         }
 150 }
 151
 152 sub lockp {
 153         SDL::MUSTLOCK(${$_[0]});
 154 }
 155
 156 sub lock {
 157         SDL::SurfaceLock(${$_[0]});
 158 }
 159
 160 sub unlock {
 161         SDL::SurfaceUnlock(${$_[0]});
 162 }
 163
 164 sub update {
 165         my $self = shift;;
 166         if ($SDL::DEBUG) {
 167                 for (@_) {
 168                         die "SDL::Surface::update requires SDL::Rect objects"
 169                                 unless $_->isa('SDL::Rect');
 170                 }
 171         }
 172         SDL::UpdateRects($$self, map { ${$_} } @_ );
 173 }
 174
 175 sub flip {
 176         SDL::Flip(${$_[0]});
 177 }
 178
 179 sub blit {
 180         if ($SDL::DEBUG) {
 181                 die "SDL::Surface::blit requires SDL::Rect objects"
 182                         unless ($_[1] == 0 || $_[1]->isa('SDL::Rect'))
 183                         && ($_[3] == 0 || $_[3]->isa('SDL::Rect'));
 184                 die "SDL::Surface::blit requires SDL::Surface objects"
 185                         unless $_[2]->isa('SDL::Surface');
 186         }
 187         SDL::BlitSurface(map { $_ != 0 ? ${$_} : $_ } @_);
 188 }
 189
 190 sub set_colors {
 191         my $self = shift;
 192         my $start = shift;
 193         for (@_) {
 194                 die "SDL::Surface::set_colors requires SDL::Color objects"
 195                         unless !$SDL::DEBUG || $_->isa('SDL::Color');
 196         }
 197         return SDL::SetColors($$self, $start, map { ${$_} } @_);
 198 }
 199
 200 sub set_color_key {
 201         die "SDL::Surface::set_color_key requires a SDL::Color object"
 202                 unless !$SDL::DEBUG || (ref($_[2]) && $_[2]->isa('SDL::Color'));
 203         SDL::SetColorKey(${$_[0]},$_[1],${$_[2]});
 204 }
 205
 206 sub set_alpha {
 207         SDL::SetAlpha(${$_[0]},$_[1],$_[2]);
 208 }
 209
 210 sub display_format {
 211         my $self = shift;
 212         my $tmp = SDL::DisplayFormat($$self);
 213         SDL::FreeSurface ($$self);
 214         $$self = $tmp;
 215         $self;
 216 }
 217
 218 sub rgb {
 219         my $self = shift;
 220         my $tmp = SDL::ConvertRGB($$self);
 221         SDL::FreeSurface($$self);
 222         $$self = $tmp;
 223         $self;
 224 }
 225
 226 sub rgba {
 227         my $self = shift;
 228         my $tmp = SDL::ConvertRGBA($$self);
 229         SDL::FreeSurface($$self);
 230         $$self = $tmp;
 231         $self;
 232 }
 233
 234 sub rect {
 235         my $self = shift;
 236         new SDL::Rect -width => $self->width(), -height => $self->height(),
 237                         -x => $_[0] || 0, -y => $_[1] || 0;
 238 }
 239
 240 sub print {
 241         my ($self,$x,$y,@text) = @_;
 242         SDL::SFont::PutString( $$self, $x, $y, join('',@text));
 243 }
 244
 245 sub save_bmp {
 246         SDL::SaveBMP( ${$_[0]},$_[1]);
 247 }
 248
 249 sub video_info {
 250         shift;
 251         SDL::VideoInfo();
 252 }
 253
 254 1;
 255
 256 __END__;
 257
 258 =pod
 259
 260 =head1 NAME
 261
 262 SDL::Surface - a SDL perl extension
 263
 264 =head1 SYNOPSIS
 265
 266   use SDL::Surface;
 267   $image = new SDL::Surface(-name=>"yomama.jpg");
 268
 269 =head1 DESCRIPTION
 270
 271 The C<SDL::Surface> module encapsulates the SDL_Surface* structure, and
 272 many of its ancillatory functions.  Not only is it a workhorse of the
 273 OO Layer, it is the base class for the C<SDL::App> class.
 274
 275 =head1 EXPORTS
 276
 277         SDL_SWSURFACE           SDL_HWSURFACE
 278         SDL_ASYNCBLIT           SDL_ANYFORMAT
 279         SDL_HWPALETTE           SDL_DOUBLEBUF
 280         SDL_FULLSCREEN          SDL_OPENGL
 281         SDL_OPENGLBLIT          SDL_RESIZEABLE
 282         SDL_NOFRAME             SDL_SRCCOLORKEY
 283         SDL_RLEACCEL            SDL_SRCALPHA
 284         SDL_PREALLOC
 285
 286 =head1 METHODS
 287
 288 =head2 new (-name => 'foo.png')
 289
 290 The C<SDL::Surface> class can be instantiated in a number of different ways.
 291 If support for the SDL_image library was included when SDL_perl was compiled,
 292 the easiest way to create a new surface is to use the C<SDL::Surface::new>
 293 method with the C<-name> option.  This will load the image from the file
 294 and return an object encapsulating the SDL_Surface*.
 295
 296 =head2 new (-from => $buffer, ... )
 297
 298 If the contents of the new Surface is already in memory, C<SDL::Surface::new>
 299 may be called with the C<-from> option to create an image from that section
 300 of memory.  This method takes the following additional parameters:
 301
 302 =over 4
 303
 304 =item *
 305
 306 -width          the width of the image in pixels
 307
 308 =item *
 309
 310 -height         the height of the image in pixels
 311
 312 =item *
 313
 314 -depth          the number of bits per pixel
 315
 316 =item *
 317
 318 -pitch          the number of bytes per line
 319
 320 =item *
 321
 322 -Rmask          an optional bitmask for red
 323
 324 =item *
 325
 326 -Gmask          an optional bitmask for green
 327
 328 =item *
 329
 330 -Bmask          an optional bitmask for green
 331
 332 =item *
 333
 334 -Amask          an optional bitmask for alpha
 335
 336 =back
 337
 338 =head2 new ( -flags => SDL_SWSURFACE, ... )
 339
 340 Finally, C<SDL::Suface::new> may be invoked with the C<-flags> option, in a
 341 similar fashion to the C<-from> directive.  This invocation takes the same
 342 additional options as C<-from> with the exception of C<-pitch> which is ignored.
 343 This method returns a new, blank, SDL::Surface option with any of the following
 344 flags turned on:
 345
 346 =over 4
 347
 348 =item *
 349
 350 SWSURFACE()     a non-accelerated surface
 351
 352 =item *
 353
 354 HWSURFACE()     a hardware accelerated surface
 355
 356 =item *
 357
 358 SRCCOLORKEY()   a surface with a transperant color
 359
 360 =item *
 361
 362 SRCALPHA()      an alpha blended, translucent surface
 363
 364 =back
 365
 366 =head2 flags ()
 367
 368 C<SDL::Surface::flags> returns the flags with which the surface was initialized.
 369
 370 =head2 palette ()
 371
 372 C<SDL::Surface::palette> currently returns a SDL_Palette*, this may change in
 373 future revisions.
 374
 375 =head2 bpp ()
 376
 377 C<SDL::Surface::bpp> returns the bits per pixel of the surface
 378
 379 =head2 bytes_per_pixel ()
 380
 381 C<SDL::Surface::bytes_per_pixel> returns the bytes per pixel of the surface
 382
 383 =head2 Rshift ()
 384
 385 C<SDL::Surface::Rshift> returns the bit index of the red field for the surface's pixel format
 386
 387 =head2 Gshift ()
 388
 389 C<SDL::Surface::Gshift> returns the bit index of the green field for the surface's pixel format
 390
 391 =head2 Bshift ()
 392
 393 C<SDL::Surface::Bshift> returns the bit index of the blue field for the surface's pixel format
 394
 395 =head2 Ashift ()
 396
 397 C<SDL::Surface::Ashift> returns the bit index of the alpha field for the surface's pixel format
 398
 399 =head2 Rmask ()
 400
 401 C<SDL::Surface::Rmask> returns the bit mask for the red field for teh surface's pixel format
 402
 403 =head2 Gmask ()
 404
 405 C<SDL::Surface::Gmask> returns the bit mask for the green field for teh surface's pixel format
 406
 407 =head2 Bmask ()
 408
 409 C<SDL::Surface::Bmask> returns the bit mask for the blue field for teh surface's pixel format
 410
 411 =head2 Amask ()
 412
 413 C<SDL::Surface::Amask> returns the bit mask for the alpha field for teh surface's pixel format
 414
 415 =head2 color_key ()
 416
 417 C<SDL::Surface::color_key> returns the current color key for the image, which can be set with
 418 the C<SDL::Surface::set_color_key> method.  Before calling C<SDL::Surface::color_key> on
 419 a image, you should fist call C<SDL::Surface::display_format> to convert it to the same
 420 format as the display.  Failure to do so will result in failure to apply the correct color_key.
 421
 422 =head2 alpha ()
 423
 424 C<SDL::Surface::alpha> returns the current alpha value for the image, which can be set with
 425 the C<SDL::Surface::set_alpha> method.
 426
 427 =head2 width ()
 428
 429 C<SDL::Surface::width> returns the width in pixels of the surface
 430
 431 =head2 height ()
 432
 433 C<SDL::Surface::height> returns the height in pixels of the surface
 434
 435 =head2 pitch ()
 436
 437 C<SDL::Surface::pitch> returns the width of a surface's scanline in bytes
 438
 439 =head2 pixels ()
 440
 441 C<SDL::Surface::pixels> returns a Uint8* to the image's pixel data.  This is not
 442 inherently useful within perl, though may be used to pass image data to user provided
 443 C functions.
 444
 445 =head2 pixel (x,y,[color])
 446
 447 C<SDL::Surface::pixel> will set the color value of the pixel at (x,y) to the given
 448 color if provided.  C<SDL::Surface::pixel> returns a SDL::Color object for the
 449 color value of the pixel at (x,y) after any possible modifications.
 450
 451 =head2 fill (rect,color)
 452
 453 C<SDL::Surface::fill> will fill the given SDL::Rect rectangle with the specified SDL::Color
 454 This function optionally takes a SDL_Rect* and a SDL_Color*
 455
 456 =head2 lockp ()
 457
 458 C<SDL::Surface::lockp> returns true if the surface must be locked
 459
 460 =head2 lock ()
 461
 462 C<SDL::Surface::lock> places a hardware lock if necessary, preventing access to
 463 the surface's memory
 464
 465 =head2 unlock ()
 466
 467 C<SDL::Surface::unlock> removes any hardware locks, enabling blits
 468
 469 =head2 update ( rects...)
 470
 471 C<SDL::Surface::update> takes one or more SDL::Rect's which determine which sections
 472 of the image are to be updated.  This option is only useful on the appliaction surface.
 473
 474 =head2 flip ()
 475
 476 C<SDL::Surface::flip> updates the full surface, using a double buffer if available
 477
 478 =head2 blit (srect,dest,drect)
 479
 480 C<SDL::Surface::blit> blits the current surface onto the destination surface,
 481 according to the provided rectangles.  If a rectangle is 0, then the full surface is used.
 482
 483 =head2 set_colors (start,colors...)
 484
 485 C<SDL::Surface::set_colors> updates the palette starting at index C<start> with the
 486 supplied colors.  The colors may either be SDL::Color objects or SDL_Color* from the
 487 low level C-style API.
 488
 489 =head2 set_color_key (flag,pixel) or (flag,x,y)
 490
 491 C<SDL::Surface::set_color_key> sets the blit flag, usually SDL_SRCCOLORKEY,
 492 to the specified L<SDL::Color> object.  Optional a SDL_Color* may be passed.
 493
 494 =head2 set_alpha (flag,alpha)
 495
 496 C<SDL::Surface::set_alpha> sets the opacity of the image for alpha blits.
 497 C<alpha> takes a value from 0x00 to 0xff.
 498
 499 =head2 display_format ()
 500
 501 C<SDL::Surface::display_format> converts the surface to the same format as the
 502 current screen.
 503
 504 =head2 rgb ()
 505 C<SDL::Surface::rgb> converts the surface to a 24 bit rgb format regardless of the
 506 initial format.
 507
 508 =head2 rgba ()
 509 C<SDL::Surface::rgba> converts the surface to a 32 bit rgba format regarless of the
 510 initial format.
 511
 512 =head2 print (x,y,text...)
 513
 514 C<SDL::Surface::print> renders the text using the current font onto the image.
 515 This option is only supported for with SDL_image and SFont.
 516
 517 =head2 save_bmp (filename)
 518
 519 C<SDL::Surface::save_bmp> saves the surface to filename in Windows BMP format.
 520
 521 =head2 video_info ()
 522
 523 C<SDL::Surface::video_info> returns a hash describing the current state of the
 524 video hardware.
 525
 526 =head1 AUTHOR
 527
 528 David J. Goehrig
 529
 530 =head1 SEE ALSO
 531
 532 L<perl> L<SDL::App> L<SDL::Color> L<SDL::Palette> L<SDL::Rect>
 533
 534 =cut