lib/SDL/Game/Rect.pm

   1 package SDL::Game::Rect;
   2 use strict;
   3 use warnings;
   4 use Carp;
   5 use base 'SDL::Rect';
   6
   7 our $VERSION = '0.01';
   8
   9 sub new {
  10     my $class = shift;
  11     my $x = shift || 0;
  12     my $y = shift || 0;
  13     my $w = shift || 0;
  14     my $h = shift || 0;
  15
  16     my $self = $class->SUPER::new($x, $y, $w, $h);
  17     unless ($$self) {
  18         #require Carp;
  19         croak SDL::GetError();
  20     }
  21     bless $self, $class;
  22     return $self;
  23 }
  24
  25 #############################
  26 ## extra accessors
  27 #############################
  28 sub bottom {
  29     my ($self, $val) = (@_);
  30     if (defined $val) {
  31         $self->top($val - $self->height); # y = val - height
  32     }
  33     return $self->top + $self->height; # y + height
  34 }
  35
  36 sub right {
  37     my ($self, $val) = (@_);
  38     if (defined $val) {
  39         $self->left($val - $self->width); # x = val - width
  40     }
  41     return $self->left + $self->width; # x + width
  42 }
  43
  44 sub centerx {
  45     my ($self, $val) = (@_);
  46     if (defined $val) {
  47         $self->left($val - ($self->width >> 1)); # x = val - (width/2)
  48     }
  49     return $self->left + ($self->width >> 1); # x + (width/2)
  50 }
  51
  52 sub centery {
  53     my ($self, $val) = (@_);
  54     if (defined $val) {
  55         $self->top($val - ($self->height >> 1)); # y = val - (height/2)
  56     }
  57     return $self->top + ($self->height >> 1); # y + (height/2)
  58 }
  59
  60 sub size {
  61     my ($self, $w, $h) = (@_);
  62
  63     return ($self->width, $self->height)  # (width, height)
  64         unless (defined $w or defined $h);
  65
  66     if (defined $w) {
  67         $self->width($w); # width
  68     }
  69     if (defined $h) {
  70         $self->height($h); # height
  71     }
  72 }
  73
  74 sub topleft {
  75     my ($self, $y, $x) = (@_);
  76
  77     return ($self->top, $self->left) # (top, left)
  78         unless (defined $y or defined $x);
  79
  80     if (defined $x) {
  81         $self->left($x); # left
  82     }
  83     if (defined $y) {
  84         $self->top($y); # top
  85     }
  86     return;
  87 }
  88
  89 sub midleft {
  90     my ($self, $centery, $x) = (@_);
  91
  92     return ($self->top + ($self->height >> 1), $self->left) # (centery, left)
  93         unless (defined $centery or defined $x);
  94
  95     if (defined $x) {
  96         $self->left($x); # left
  97     }
  98     if (defined $centery) {
  99         $self->top($centery - ($self->height >> 1)); # y = centery - (height/2)
 100     }
 101     return;
 102 }
 103
 104 sub bottomleft {
 105     my ($self, $bottom, $x) = (@_);
 106
 107     return ($self->top + $self->height, $self->left) # (bottom, left)
 108         unless (defined $bottom or defined $x);
 109
 110     if (defined $x) {
 111         $self->left($x); # left
 112     }
 113     if (defined $bottom) {
 114         $self->top($bottom - $self->height); # y = bottom - height
 115     }
 116     return;
 117 }
 118
 119 sub center {
 120     my ($self, $centerx, $centery) = (@_);
 121
 122     return ($self->left + ($self->width >> 1), $self->top + ($self->height >> 1))
 123         unless (defined $centerx or defined $centery);
 124
 125     if (defined $centerx) {
 126         $self->left($centerx - ($self->width >> 1)); # x = centerx - (width/2)
 127     }
 128     if (defined $centery) {
 129         $self->top($centery - ($self->height >> 1)); # y = centery - (height/2)
 130     }
 131     return;
 132 }
 133
 134 sub topright {
 135     my ($self, $y, $right) = (@_);
 136
 137     return ($self->top, $self->left + $self->width) # (top, right)
 138         unless (defined $y or defined $right);
 139
 140     if (defined $right) {
 141         $self->left($right - $self->width); # x = right - width
 142     }
 143     if (defined $y) {
 144         $self->top($y); # top
 145     }
 146     return;
 147 }
 148
 149 sub midright {
 150     my ($self, $centery, $right) = (@_);
 151
 152     return ($self->top + ($self->height >> 1), $self->left + $self->width) # (centery, right)
 153         unless (defined $centery or defined $right);
 154
 155     if (defined $right) {
 156         $self->left($right - $self->width); # x = right - width
 157     }
 158     if (defined $centery) {
 159         $self->top($centery - ($self->height >> 1)); # y = centery - (height/2)
 160     }
 161     return;
 162 }
 163
 164 sub bottomright {
 165     my ($self, $bottom, $right) = (@_);
 166
 167     return ($self->top + $self->height, $self->left + $self->width) # (bottom, right)
 168         unless (defined $bottom or defined $right);
 169
 170     if (defined $right) {
 171         $self->left($right - $self->width); # x = right - width
 172     }
 173     if (defined $bottom) {
 174         $self->top($bottom - $self->height); # y = bottom - height
 175     }
 176     return;
 177 }
 178
 179 sub midtop {
 180     my ($self, $centerx, $y) = (@_);
 181
 182     return ($self->left + ($self->width >> 1), $self->top) # (centerx, top)
 183         unless (defined $centerx or defined $y);
 184
 185     if (defined $y) {
 186         $self->top($y); # top
 187     }
 188     if (defined $centerx) {
 189         $self->left($centerx - ($self->width >> 1)); # x = centerx - (width/2)
 190     }
 191     return;
 192 }
 193
 194 sub midbottom {
 195     my ($self, $centerx, $bottom) = (@_);
 196
 197     return ($self->left + ($self->width >> 1), $self->top + $self->height) # (centerx, bottom)
 198         unless (defined $centerx or defined $bottom);
 199
 200     if (defined $bottom) {
 201         $self->top($bottom - $self->height); # y = bottom - height
 202     }
 203     if (defined $centerx) {
 204         $self->left($centerx - ($self->width >> 1)); # x = centerx - (width/2)
 205     }
 206     return;
 207 }
 208
 209 ###############################
 210 ## methods                   ##
 211 ###############################
 212
 213 sub duplicate {
 214 }
 215
 216 sub copy {
 217     my $self = shift;
 218     return $self->new(
 219         -top    => $self->top,
 220         -left   => $self->left,
 221         -width  => $self->width,
 222         -height => $self->height,
 223     );
 224 }
 225
 226 sub move {
 227     my ($self, $x, $y) = (@_);
 228     if (not defined $x or not defined $y) {
 229         #require Carp;
 230         croak "must receive x and y positions as argument";
 231     }
 232     return $self->new(
 233         -top    => $self->top + $y,
 234         -left   => $self->left + $x,
 235         -width  => $self->width,
 236         -height => $self->height,
 237     );
 238 }
 239
 240 sub move_ip {
 241     my ($self, $x, $y) = (@_);
 242     if (not defined $x or not defined $y) {
 243         #require Carp;
 244         croak "must receive x and y positions as argument";
 245     }
 246     $self->x($self->x + $x);
 247     $self->y($self->y + $y);
 248
 249     return;
 250 }
 251
 252 sub inflate {
 253     my ($self, $x, $y) = (@_);
 254     if (not defined $x or not defined $y) {
 255         #require Carp;
 256         croak "must receive x and y positions as argument";
 257     }
 258
 259     return $self->new(
 260         -left   => $self->left   - ($x / 2),
 261         -top    => $self->top    - ($y / 2),
 262         -width  => $self->width  + $x,
 263         -height => $self->height + $y,
 264     );
 265 }
 266
 267 sub inflate_ip {
 268     my ($self, $x, $y) = (@_);
 269     if (not defined $x or not defined $y) {
 270         #require Carp;
 271         croak "must receive x and y positions as argument";
 272     }
 273
 274     $self->x( $self->x - ($x / 2) );
 275     $self->y( $self->y - ($y / 2) );
 276
 277     $self->w( $self->w + $x );
 278     $self->h( $self->h + $y );
 279 }
 280
 281 sub _get_clamp_coordinates {
 282     my ($self_pos, $self_len, $rect_pos, $rect_len) = (@_);
 283
 284     if ($self_len >= $rect_len) {
 285         return $rect_pos + ($rect_len / 2) - ($self_len / 2);
 286     }
 287     elsif ($self_pos < $rect_pos) {
 288         return $rect_pos;
 289     }
 290     elsif ( ($self_pos + $self_len) > ($rect_pos + $rect_len) ) {
 291         return $rect_pos + $rect_len - $self_len;
 292     }
 293     else {
 294         return $self_pos;
 295     }
 296 }
 297
 298 sub clamp {
 299     my ($self, $rect) = (@_);
 300
 301     unless ($rect->isa('SDL::Rect')) {
 302         croak "must receive an SDL::Rect-based object";
 303     }
 304
 305     my $x = _get_clamp_coordinates($self->x, $self->w, $rect->x, $rect->w);
 306     my $y = _get_clamp_coordinates($self->y, $self->h, $rect->y, $rect->h);
 307
 308     return $self->new($x, $y, $self->w, $self->h);
 309 }
 310
 311 sub clamp_ip {
 312     my ($self, $rect) = (@_);
 313
 314     unless ($rect->isa('SDL::Rect')) {
 315         croak "must receive an SDL::Rect-based object";
 316     }
 317
 318     my $x = _get_clamp_coordinates($self->x, $self->w, $rect->x, $rect->w);
 319     my $y = _get_clamp_coordinates($self->y, $self->h, $rect->y, $rect->h);
 320
 321     $self->x($x);
 322     $self->y($y);
 323
 324     return;
 325 }
 326
 327 sub _get_intersection_coordinates {
 328     my ($self, $rect) = (@_);
 329     my ($x, $y, $w, $h);
 330
 331 INTERSECTION:
 332     {
 333         ### Left
 334         if (($self->x >= $rect->x) && ($self->x < ($rect->x + $rect->w))) {
 335             $x = $self->x;
 336         }
 337         elsif (($rect->x >= $self->x) && ($rect->x < ($self->x + $self->w))) {
 338             $x = $rect->x;
 339         }
 340         else {
 341             last INTERSECTION;
 342         }
 343
 344         ## Right
 345         if ((($self->x + $self->w) > $rect->x) && (($self->x + $self->w) <= ($rect->x + $rect->w))) {
 346             $w = ($self->x + $self->w) - $x;
 347         }
 348         elsif ((($rect->x + $rect->w) > $self->x) && (($rect->x + $rect->w) <= ($self->x + $self->w))) {
 349             $w = ($rect->x + $rect->w) - $x;
 350         }
 351         else {
 352             last INTERSECTION;
 353         }
 354
 355         ## Top
 356         if (($self->y >= $rect->y) && ($self->y < ($rect->y + $rect->h))) {
 357             $y = $self->y;
 358         }
 359         elsif (($rect->y >= $self->y) && ($rect->y < ($self->y + $self->h))) {
 360             $y = $rect->y;
 361         }
 362         else {
 363             last INTERSECTION;
 364         }
 365
 366         ## Bottom
 367         if ((($self->y + $self->h) > $rect->y) && (($self->y + $self->h) <= ($rect->y + $rect->h))) {
 368             $h = ($self->y + $self->h) - $y;
 369         }
 370         elsif ((($rect->y + $rect->h) > $self->y) && (($rect->y + $rect->h) <= ($self->y + $self->h))) {
 371             $h = ($rect->y + $rect->h) - $y;
 372         }
 373         else {
 374             last INTERSECTION;
 375         }
 376
 377         return ($x, $y, $w, $h);
 378     }
 379
 380     # if we got here, the two rects do not intersect
 381     return ($self->x, $self->y, 0, 0);
 382
 383 }
 384
 385 sub clip {
 386     my ($self, $rect) = (@_);
 387
 388     unless ($rect->isa('SDL::Rect')) {
 389         croak "must receive an SDL::Rect-based object";
 390     }
 391
 392     my ($x, $y, $w, $h) = _get_intersection_coordinates($self, $rect);
 393
 394     return $self->new($x, $y, $w, $h);
 395 }
 396
 397 sub clip_ip {
 398     my ($self, $rect) = (@_);
 399
 400     unless ($rect->isa('SDL::Rect')) {
 401         croak "must receive an SDL::Rect-based object";
 402     }
 403
 404     my ($x, $y, $w, $h) = _get_intersection_coordinates($self, $rect);
 405
 406     $self->x($x);
 407     $self->y($y);
 408     $self->w($w);
 409     $self->h($h);
 410
 411     return;
 412 }
 413
 414
 415 sub _test_union {
 416     my ($self, $rect) = (@_);
 417     my ($x, $y, $w, $h);
 418
 419     $x = $self->x < $rect->x ? $self->x : $rect->x;  # MIN
 420     $y = $self->y < $rect->y ? $self->y : $rect->y;  # MIN
 421
 422     $w = ($self->x + $self->w) > ($rect->x + $rect->w)
 423        ? ($self->x + $self->w) - $x
 424        : ($rect->x + $rect->w) - $x
 425        ;  # MAX
 426
 427     $h = ($self->y + $self->h) > ($rect->y + $rect->h)
 428        ? ($self->y + $self->h) - $y
 429        : ($rect->y + $rect->h) - $y
 430        ;  # MAX
 431
 432     return ($x, $y, $w, $h);
 433 }
 434
 435 sub union {
 436     my ($self, $rect) = (@_);
 437
 438     unless ($rect->isa('SDL::Rect')) {
 439         croak "must receive an SDL::Rect-based object";
 440     }
 441
 442     my ($x, $y, $w, $h) = _test_union($self, $rect);
 443     return $self->new($x, $y, $w, $h);
 444 }
 445
 446 sub union_ip {
 447     my ($self, $rect) = (@_);
 448
 449     unless ($rect->isa('SDL::Rect')) {
 450         croak "must receive an SDL::Rect-based object";
 451     }
 452
 453     my ($x, $y, $w, $h) = _test_union($self, $rect);
 454
 455     $self->x($x);
 456     $self->y($y);
 457     $self->w($w);
 458     $self->y($h);
 459
 460     return;
 461 }
 462
 463 sub _test_unionall {
 464     my ($self, $rects) = (@_);
 465
 466     # initial values for union rect
 467     my $left   = $self->x;
 468     my $top    = $self->y;
 469     my $right  = $self->x + $self->w;
 470     my $bottom = $self->y + $self->h;
 471
 472     foreach my $rect (@{$rects}) {
 473         unless ($rect->isa('SDL::Rect')) {
 474             # TODO: better error message, maybe saying which item
 475             # is the bad one (by list position)
 476             croak "must receive an array reference of SDL::Rect-based objects";
 477         }
 478
 479         $left   = $rect->x if $rect->x < $left; # MIN
 480         $top    = $rect->y if $rect->y < $top; # MIN
 481         $right  = ($rect->x + $rect->w) if ($rect->x + $rect->w) > $right;  # MAX
 482         $bottom = ($rect->y + $rect->h) if ($rect->y + $rect->h) > $bottom; # MAX
 483     }
 484
 485     return ($left, $top, $right - $left, $bottom - $top);
 486 }
 487
 488 sub unionall {
 489     my ($self, $rects) = (@_);
 490
 491     croak "must receive an array reference of SDL::Rect-based objects"
 492         unless defined $rects and ref $rects eq 'ARRAY';
 493
 494     my ($x, $y, $w, $h) = _test_unionall($self, $rects);
 495
 496     return $self->new($x, $y, $w, $h);
 497 }
 498
 499 sub unionall_ip {
 500     my ($self, $rects) = (@_);
 501
 502     croak "must receive an array reference of SDL::Rect-based objects"
 503         unless defined $rects and ref $rects eq 'ARRAY';
 504
 505     my ($x, $y, $w, $h) = _test_unionall($self, $rects);
 506
 507     $self->x($x);
 508     $self->y($y);
 509     $self->w($w);
 510     $self->h($h);
 511
 512     return;
 513 }
 514
 515 sub _check_fit {
 516     my ($self, $rect) = (@_);
 517
 518     my $x_ratio = $self->w / $rect->w;
 519     my $y_ratio = $self->h / $rect->h;
 520     my $max_ratio = ($x_ratio > $y_ratio) ? $x_ratio : $y_ratio;
 521
 522     my $w = int ($self->w / $max_ratio);
 523     my $h = int ($self->h / $max_ratio);
 524
 525     my $x = $rect->x + int (($rect->w - $w) / 2);
 526     my $y = $rect->y + int (($rect->h - $h) / 2);
 527
 528     return ($x, $y, $w, $h);
 529 }
 530
 531 sub fit {
 532     my ($self, $rect) = (@_);
 533
 534     unless ($rect->isa('SDL::Rect')) {
 535         croak "must receive an SDL::Rect-based object";
 536     }
 537
 538     my ($x, $y, $w, $h) = _check_fit($self, $rect);
 539
 540     return $self->new ($x, $y, $w, $h);
 541 }
 542
 543 sub fit_ip {
 544     my ($self, $rect) = (@_);
 545
 546     unless ($rect->isa('SDL::Rect')) {
 547         croak "must receive an SDL::Rect-based object";
 548     }
 549
 550     my ($x, $y, $w, $h) = _check_fit($self, $rect);
 551
 552     $self->x($x);
 553     $self->y($y);
 554     $self->w($w);
 555     $self->h($h);
 556
 557     return;
 558 }
 559
 560 sub normalize {
 561     my $self = shift;
 562
 563     if ($self->w < 0) {
 564         $self->x($self->x + $self->w);
 565         $self->w(-$self->w);
 566     }
 567
 568     if ($self->h < 0) {
 569         $self->y( $self->y + $self->h);
 570         $self->h(-$self->h);
 571     }
 572     return;
 573 }
 574
 575 sub contains {
 576     my ($self, $rect) = (@_);
 577
 578     unless ($rect->isa('SDL::Rect')) {
 579         croak "must receive an SDL::Rect-based object";
 580     }
 581
 582     my $contained = ($self->x <= $rect->x)
 583                  && ($self->y <= $rect->y)
 584                  && ($self->x + $self->w >= $rect->x + $rect->w)
 585                  && ($self->y + $self->h >= $rect->y + $rect->h)
 586                  && ($self->x + $self->w > $rect->x)
 587                  && ($self->y + $self->h > $rect->y)
 588                  ;
 589
 590     return $contained;
 591 }
 592
 593
 594 sub collidepoint {
 595     my ($self, $x, $y) = (@_);
 596
 597     unless (defined $x and defined $y) {
 598         croak "must receive (x,y) as arguments";
 599     }
 600
 601     my $inside = $x >= $self->x
 602               && $x < $self->x + $self->w
 603               && $y >= $self->y
 604               && $y < $self->y + $self->h
 605               ;
 606
 607     return $inside;
 608 }
 609
 610 42;
 611 __END__
 612
 613 =head1 NAME
 614
 615 SDL::Game::Rect - SDL::Game object for storing and manipulating rectangular coordinates
 616
 617 =head1 SYNOPSIS
 618
 619
 620 =head1 DESCRIPTION
 621
 622 C<< SDL::Game::Rect >> object are used to store and manipulate rectangular areas. Rect objects are created from a combination of left (or x), top (or y), width (or w) and height (or h) values, just like raw C<< SDL::Rect objects >>.
 623
 624 All C<< SDL::Game::Rect >> methods that change either position or size of a Rect return B<a new copy> of the Rect with the affected changes. The original Rect is B<not> modified. If you wish to modify the current Rect object, you can use the equivalent "in-place" methods that do not return but instead affects the original Rect. These "in-place" methods are denoted with the "ip" suffix. Note that changing a Rect's attribute is I<always> an in-place operation.
 625
 626
 627 =head2 ATTRIBUTES
 628
 629 All Rect attributes are acessors, meaning you can get them by name, and set them by passing a value:
 630
 631    $rect->left(15);
 632    $rect->left;       # 15
 633
 634 The Rect object has several attributes which can be used to resize, move and align the Rect.
 635
 636
 637 =over 4
 638
 639 =item * width, w - gets/sets object's width
 640
 641 =item * height, h - gets/sets object's height
 642
 643 =item * left, x - moves the object left position to match the given coordinate
 644
 645 =item * top, y  - moves the object top position to match the given coordinate
 646
 647 =item * bottom - moves the object bottom position to match the given coordinate
 648
 649 =item * right - moves the object right position to match the given coordinate
 650
 651 =item * centerx - moves the object's horizontal center to match the given coordinate
 652
 653 =item * centery - moves the object's vertical center to match the given coordinate
 654
 655 =back
 656
 657 Some of the attributes above can be fetched or set in pairs:
 658
 659   $rect->topleft(10, 15);   # top is now 10, left is now 15
 660
 661   my ($width, $height) = $rect->size;
 662
 663
 664 =over 4
 665
 666 =item * size - gets/sets object's size (width, height)
 667
 668 =item * topleft - gets/sets object's top and left positions
 669
 670 =item * midleft - gets/sets object's vertical center and left positions
 671
 672 =item * bottomleft - gets/sets object's bottom and left positions
 673
 674 =item * center - gets/sets object's center (horizontal(x), vertical(y))
 675
 676 =item * topright - gets/sets object's top and right positions
 677
 678 =item * midright - gets/sets object's vertical center and right positions
 679
 680 =item * bottomright - gets/sets object's bottom and right positions
 681
 682 =item * midtop - gets/sets object's horizontal center and top positions
 683
 684 =item * midbottom - gets/sets object's horizontal center and bottom positions
 685
 686 =back
 687
 688
 689 =head2 METHODS
 690
 691 Methods denoted as receiving Rect objects can receive either C<<SDL::Game::Rect>> or raw C<<SDL::Rect>> objects.
 692
 693 =head3 new ($left, $top, $width, $height)
 694
 695 Returns a new Rect object with the given coordinates. If any value is omitted (by passing undef), 0 is used instead.
 696
 697 =head3 copy
 698
 699 =head3 duplicate
 700
 701 Returns a new Rect object having the same position and size as the original
 702
 703 =head3 move(x, y)
 704
 705 Returns a new Rect that is moved by the given offset. The x and y arguments can be any integer value, positive or negative.
 706
 707 =head3 move_ip(x, y)
 708
 709 Same as C<<move>> above, but moves the current Rect in place and returns nothing.
 710
 711 =head3 inflate(x, y)
 712
 713 Grows or shrinks the rectangle. Returns a new Rect with the size changed by the given offset. The rectangle remains centered around its current center. Negative values will return a shrinked rectangle instead.
 714
 715 =head3 inflate_ip(x, y)
 716
 717 Same as C<<inflate>> above, but grows/shrinks the current Rect in place and returns nothing.
 718
 719 =head3 clamp($rect)
 720
 721 Returns a new Rect moved to be completely inside the Rect object passed as an argument. If the current Rect is too large to fit inside the passed Rect, it is centered inside it, but its size is not changed.
 722
 723 =head3 clamp_ip($rect)
 724
 725 Same as C<<clamp>> above, but moves the current Rect in place and returns nothing.
 726
 727 =head3 clip($rect)
 728
 729 Returns a new Rect with the intersection between the two Rect objects, that is, returns a new Rect cropped to be completely inside the Rect object passed as an argument. If the two rectangles do not overlap to begin with, a Rect with 0 size is returned, in the original Rect's (x,y) coordinates.
 730
 731 =head3 clip_ip($rect)
 732
 733 Same as C<<clip>> above, but crops the current Rect in place and returns nothing. As the original method, the Rect becomes zero-sized if the two rectangles do not overlap to begin with, retaining its (x, y) coordinates.
 734
 735 =head3 union($rect)
 736
 737 Returns a new rectangle that completely covers the area of the current Rect and the one passed as an argument. There may be area inside the new Rect that is not covered by the originals.
 738
 739 =head3 union_ip($rect)
 740
 741 Same as C<<union>> above, but resizes the current Rect in place and returns nothing.
 742
 743 =head3 unionall( [$rect1, $rect2, ...] )
 744
 745 Returns the union of one rectangle with a sequence of many rectangles, passed as an ARRAY REF.
 746
 747 =head3 unionall_ip( [$rect1, $rect2, ...] )
 748
 749 Same as C<<unionall>> above, but resizes the current Rect in place and returns nothing.
 750
 751 =head3 fit($rect)
 752
 753 Returns a new Rect moved and resized to fit the Rect object passed as an argument. The aspect ratio of the original Rect is preserved, so the new rectangle may be smaller than the target in either width or height.
 754
 755 =head3 fit_ip($rect)
 756
 757 Same as C<<fit>> above, but moves/resizes the current Rect in place and returns nothing.
 758
 759 =head3 normalize
 760
 761 Corrects negative sizes, flipping width/height of the Rect if they have a negative size. No repositioning is made so the rectangle will remain in the same place, but the negative sides will be swapped. This method returns nothing.
 762
 763 =head3 contains($rect)
 764
 765 Returns true (non-zero) when the argument is completely inside the Rect. Otherwise returns undef.
 766
 767 =head3 collidepoint(x, y)
 768
 769 Returns true (non-zero) if the given point is inside the Rect, otherwise returns undef. A point along the right or bottom edge is not considered to be inside the rectangle.
 770
 771 =head3 colliderect($rect)
 772
 773 Returns true (non-zero) if any portion of either rectangles overlap (except for the top+bottom or left+right edges).
 774
 775 =head3 collidelist( [$rect1, $rect2, ...] )
 776
 777 Test whether the rectangle collides with any in a sequence of rectangles, passed as an ARRAY REF. The index of the first collision found is returned. Returns undef if no collisions are found.
 778
 779 =head3 collidelistall( [$rect1, $rect2, ...] )
 780
 781 Returns an ARRAY REF of all the indices that contain rectangles that collide with the Rect. If no intersecting rectangles are found, an empty list ref is returned.
 782
 783 =head3 collidehash( {key1 => $rect1, key2 => $rect2, ...} )
 784
 785 Receives a HASH REF and returns the a (key, value) list with the key and value of the first hash item that collides with the Rect. If no collisions are found, returns (undef, undef).
 786
 787 =head3 collidehashall( {key1 => $rect1, key2 => $rect2, ...} )
 788
 789 Returns a HASH REF of all the key and value pairs that intersect with the Rect. If no collisions are found an empty hash ref is returned.
 790
 791
 792 =head1 AUTHOR
 793
 794 Breno G. de Oliveira, C<< <garu at cpan.org> >>
 795
 796 =head1 BUGS
 797
 798 Please report any bugs or feature requests to the bug tracker. I will be notified, and then you'll automatically be notified of progress on your bug as we make changes.
 799
 800
 801 =head1 SUPPORT
 802
 803 You can find documentation for this module with the perldoc command.
 804
 805     perldoc SDL::Game::Rect
 806
 807
 808 =head1 ACKNOWLEDGEMENTS
 809
 810 Many thanks to all SDL_Perl contributors, and to the authors of pygame.rect, in which this particular module is heavily based.
 811
 812 =head1 COPYRIGHT & LICENSE
 813
 814 Copyright 2009 Breno G. de Oliveira, all rights reserved.
 815
 816 This program is free software; you can redistribute it and/or modify it
 817 under the same terms as Perl itself.
 818
 819
 820 =head1 SEE ALSO
 821
 822 perl, L<SDL>, L<SDL::Rect>, L<SDL::Game>