lib/Role/Tiny.pm

   1 package Role::Tiny;
   2
   3 sub _getglob { \*{$_[0]} }
   4 sub _getstash { \%{"$_[0]::"} }
   5
   6 use strict;
   7 use warnings FATAL => 'all';
   8
   9 our $VERSION = '1.000_900'; # 1.0.900
  10 $VERSION = eval $VERSION;
  11
  12 our %INFO;
  13 our %APPLIED_TO;
  14 our %COMPOSED;
  15 our %UNION_INFO;
  16
  17 # Module state workaround totally stolen from Zefram's Module::Runtime.
  18
  19 BEGIN {
  20   *_WORK_AROUND_BROKEN_MODULE_STATE = "$]" < 5.009 ? sub(){1} : sub(){0};
  21 }
  22
  23 sub Role::Tiny::__GUARD__::DESTROY {
  24   delete $INC{$_[0]->[0]} if @{$_[0]};
  25 }
  26
  27 sub _load_module {
  28   (my $proto = $_[0]) =~ s/::/\//g;
  29   $proto .= '.pm';
  30   return 1 if $INC{$proto};
  31   # can't just ->can('can') because a sub-package Foo::Bar::Baz
  32   # creates a 'Baz::' key in Foo::Bar's symbol table
  33   return 1 if grep !/::$/, keys %{_getstash($_[0])||{}};
  34   my $guard = _WORK_AROUND_BROKEN_MODULE_STATE
  35     && bless([ $proto ], 'Role::Tiny::__GUARD__');
  36   require $proto;
  37   pop @$guard if _WORK_AROUND_BROKEN_MODULE_STATE;
  38   return 1;
  39 }
  40
  41 sub import {
  42   my $target = caller;
  43   my $me = shift;
  44   strict->import;
  45   warnings->import(FATAL => 'all');
  46   return if $INFO{$target}; # already exported into this package
  47   # get symbol table reference
  48   my $stash = do { no strict 'refs'; \%{"${target}::"} };
  49   # install before/after/around subs
  50   foreach my $type (qw(before after around)) {
  51     *{_getglob "${target}::${type}"} = sub {
  52       require Class::Method::Modifiers;
  53       push @{$INFO{$target}{modifiers}||=[]}, [ $type => @_ ];
  54     };
  55   }
  56   *{_getglob "${target}::requires"} = sub {
  57     push @{$INFO{$target}{requires}||=[]}, @_;
  58   };
  59   *{_getglob "${target}::with"} = sub {
  60     $me->apply_union_of_roles_to_package($target, @_);
  61   };
  62   # grab all *non-constant* (stash slot is not a scalarref) subs present
  63   # in the symbol table and store their refaddrs (no need to forcibly
  64   # inflate constant subs into real subs) - also add '' to here (this
  65   # is used later)
  66   @{$INFO{$target}{not_methods}={}}{
  67     '', map { *$_{CODE}||() } grep !ref($_), values %$stash
  68   } = ();
  69   # a role does itself
  70   $APPLIED_TO{$target} = { $target => undef };
  71 }
  72
  73 sub apply_role_to_package {
  74   my ($me, $to, $role) = @_;
  75
  76   _load_module($role);
  77
  78   die "This is apply_role_to_package" if ref($to);
  79   die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
  80
  81   $me->_check_requires($to, $role, @{$info->{requires}||[]});
  82
  83   $me->_install_methods($to, $role);
  84
  85   $me->_install_modifiers($to, $info->{modifiers});
  86
  87   # only add does() method to classes and only if they don't have one
  88   if (not $INFO{$to} and not $to->can('does')) {
  89     *{_getglob "${to}::does"} = \&does_role;
  90   }
  91
  92   # copy our role list into the target's
  93   @{$APPLIED_TO{$to}||={}}{keys %{$APPLIED_TO{$role}}} = ();
  94 }
  95
  96 sub apply_roles_to_object {
  97   my ($me, $object, @roles) = @_;
  98   die "No roles supplied!" unless @roles;
  99   my $class = ref($object);
 100   bless($object, $me->create_class_with_roles($class, @roles));
 101   $object;
 102 }
 103
 104 sub create_class_with_roles {
 105   my ($me, $superclass, @roles) = @_;
 106
 107   die "No roles supplied!" unless @roles;
 108
 109   {
 110     my %seen;
 111     $seen{$_}++ for @roles;
 112     if (my @dupes = grep $seen{$_} > 1, @roles) {
 113       die "Duplicated roles: ".join(', ', @dupes);
 114     }
 115   }
 116
 117   my $new_name = join(
 118     '__WITH__', $superclass, my $compose_name = join '__AND__', @roles
 119   );
 120
 121   return $new_name if $COMPOSED{class}{$new_name};
 122
 123   foreach my $role (@roles) {
 124     _load_module($role);
 125     die "${role} is not a Role::Tiny" unless $INFO{$role};
 126   }
 127
 128   if ($] >= 5.010) {
 129     require mro;
 130   } else {
 131     require MRO::Compat;
 132   }
 133
 134   my @composable = map $me->_composable_package_for($_), reverse @roles;
 135
 136   *{_getglob("${new_name}::ISA")} = [ @composable, $superclass ];
 137
 138   my @info = map $INFO{$_}, @roles;
 139
 140   $me->_check_requires(
 141     $new_name, $compose_name,
 142     do { my %h; @h{map @{$_->{requires}||[]}, @info} = (); keys %h }
 143   );
 144
 145   *{_getglob "${new_name}::does"} = \&does_role unless $new_name->can('does');
 146
 147   @{$APPLIED_TO{$new_name}||={}}{
 148     map keys %{$APPLIED_TO{$_}}, @roles
 149   } = ();
 150
 151   $COMPOSED{class}{$new_name} = 1;
 152   return $new_name;
 153 }
 154
 155 sub apply_union_of_roles_to_package {
 156   my ($me, $to, @roles) = @_;
 157
 158   return $me->apply_role_to_package($to, $roles[0]) if @roles == 1;
 159
 160   my %conflicts = %{$me->_union_info_for(@roles)->{conflicts}};
 161   delete $conflicts{$_} for $me->_concrete_methods_of($to);
 162   if (keys %conflicts) {
 163     my $fail =
 164       join "\n",
 165         map {
 166           "Due to a method name conflict between roles "
 167           ."'".join(' and ', sort values %{$conflicts{$_}})."'"
 168           .", the method '$_' must be implemented by '${to}'"
 169         } keys %conflicts;
 170     die $fail;
 171   }
 172   $me->apply_role_to_package($to, $_) for @roles;
 173   $APPLIED_TO{$to}{join('|',@roles)} = 1;
 174 }
 175
 176 sub _union_info_for {
 177   my ($me, @roles) = @_;
 178   $UNION_INFO{join('|', sort @roles)} ||= do {
 179     _load_module($_) for @roles;
 180     my %methods;
 181     foreach my $role (@roles) {
 182       my $this_methods = $me->_concrete_methods_of($role);
 183       $methods{$_}{$this_methods->{$_}} = $role for keys %$this_methods;
 184     }
 185     delete $methods{$_} for grep keys(%{$methods{$_}}) == 1, keys %methods;
 186     +{ conflicts => \%methods }
 187   };
 188 }
 189
 190 sub _composable_package_for {
 191   my ($me, $role) = @_;
 192   my $composed_name = 'Role::Tiny::_COMPOSABLE::'.$role;
 193   return $composed_name if $COMPOSED{role}{$composed_name};
 194   $me->_install_methods($composed_name, $role);
 195   my $base_name = $composed_name.'::_BASE';
 196   *{_getglob("${composed_name}::ISA")} = [ $base_name ];
 197   my $modifiers = $INFO{$role}{modifiers}||[];
 198   my @mod_base;
 199   foreach my $modified (
 200     do { my %h; @h{map $_->[1], @$modifiers} = (); keys %h }
 201   ) {
 202     push @mod_base, "sub ${modified} { shift->next::method(\@_) }";
 203   }
 204   my $e;
 205   {
 206     local $@;
 207     eval(my $code = join "\n", "package ${base_name};", @mod_base);
 208     $e = "Evaling failed: $@\nTrying to eval:\n${code}" if $@;
 209   }
 210   die $e if $e;
 211   $me->_install_modifiers($composed_name, $modifiers);
 212   $COMPOSED{role}{$composed_name} = 1;
 213   return $composed_name;
 214 }
 215
 216 sub _check_requires {
 217   my ($me, $to, $name, @requires) = @_;
 218   if (my @requires_fail = grep !$to->can($_), @requires) {
 219     # role -> role, add to requires, role -> class, error out
 220     if (my $to_info = $INFO{$to}) {
 221       push @{$to_info->{requires}||=[]}, @requires_fail;
 222     } else {
 223       die "Can't apply ${name} to ${to} - missing ".join(', ', @requires_fail);
 224     }
 225   }
 226 }
 227
 228 sub _concrete_methods_of {
 229   my ($me, $role) = @_;
 230   my $info = $INFO{$role};
 231   # grab role symbol table
 232   my $stash = do { no strict 'refs'; \%{"${role}::"}};
 233   my $not_methods = $info->{not_methods};
 234   +{
 235     # grab all code entries that aren't in the not_methods list
 236     map {
 237       my $code = *{$stash->{$_}}{CODE};
 238       # rely on the '' key we added in import for "no code here"
 239       exists $not_methods->{$code||''} ? () : ($_ => $code)
 240     } grep !ref($stash->{$_}), keys %$stash
 241   };
 242 }
 243
 244 sub methods_provided_by {
 245   my ($me, $role) = @_;
 246   die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
 247   (keys %{$me->_concrete_methods_of($role)}, @{$info->{requires}||[]});
 248 }
 249
 250 sub _install_methods {
 251   my ($me, $to, $role) = @_;
 252
 253   my $info = $INFO{$role};
 254
 255   my $methods = $me->_concrete_methods_of($role);
 256
 257   # grab target symbol table
 258   my $stash = do { no strict 'refs'; \%{"${to}::"}};
 259
 260   # determine already extant methods of target
 261   my %has_methods;
 262   @has_methods{grep
 263     +(ref($stash->{$_}) || *{$stash->{$_}}{CODE}),
 264     keys %$stash
 265   } = ();
 266
 267   foreach my $i (grep !exists $has_methods{$_}, keys %$methods) {
 268     no warnings 'once';
 269     *{_getglob "${to}::${i}"} = $methods->{$i};
 270   }
 271 }
 272
 273 sub _install_modifiers {
 274   my ($me, $to, $modifiers) = @_;
 275   if (my $info = $INFO{$to}) {
 276     push @{$info->{modifiers}}, @{$modifiers||[]};
 277   } else {
 278     foreach my $modifier (@{$modifiers||[]}) {
 279       $me->_install_single_modifier($to, @$modifier);
 280     }
 281   }
 282 }
 283
 284 sub _install_single_modifier {
 285   my ($me, @args) = @_;
 286   Class::Method::Modifiers::install_modifier(@args);
 287 }
 288
 289 sub does_role {
 290   my ($proto, $role) = @_;
 291   return exists $APPLIED_TO{ref($proto)||$proto}{$role};
 292 }
 293
 294 1;
 295
 296 =head1 NAME
 297
 298 Role::Tiny - Roles. Like a nouvelle cuisine portion size slice of Moose.
 299
 300 =head1 SYNOPSIS
 301
 302  package Some::Role;
 303
 304  use Role::Tiny;
 305
 306  sub foo { ... }
 307
 308  sub bar { ... }
 309
 310  around baz => sub { ... }
 311
 312  1;
 313
 314 else where
 315
 316  package Some::Class;
 317
 318  use Role::Tiny::With;
 319
 320  # bar gets imported, but not foo
 321  with 'Some::Role';
 322
 323  sub foo { ... }
 324
 325  # baz is wrapped in the around modifier by Class::Method::Modifiers
 326  sub baz { ... }
 327
 328  1;
 329
 330 If you wanted attributes as well, look at L<Moo::Role>.
 331
 332 =head1 DESCRIPTION
 333
 334 C<Role::Tiny> is a minimalist role composition tool.
 335
 336 =head1 ROLE COMPOSITION
 337
 338 Role composition can be thought of as much more clever and meaningful multiple
 339 inheritance.  The basics of this implementation of roles is:
 340
 341 =over 2
 342
 343 =item *
 344
 345 If a method is already defined on a class, that method will not be composed in
 346 from the role.
 347
 348 =item *
 349
 350 If a method that the role L</requires> to be implemented is not implemented,
 351 role application will fail loudly.
 352
 353 =back
 354
 355 Unlike L<Class::C3>, where the B<last> class inherited from "wins," role
 356 composition is the other way around, where first wins.  In a more complete
 357 system (see L<Moose>) roles are checked to see if they clash.  The goal of this
 358 is to be much simpler, hence disallowing composition of multiple roles at once.
 359
 360 =head1 METHODS
 361
 362 =head2 apply_role_to_package
 363
 364  Role::Tiny->apply_role_to_package('Some::Package', 'Some::Role');
 365
 366 Composes role with package.  See also L<Role::Tiny::With>.
 367
 368 =head2 apply_roles_to_object
 369
 370  Role::Tiny->apply_roles_to_object($foo, qw(Some::Role1 Some::Role2));
 371
 372 Composes roles in order into object directly.  Object is reblessed into the
 373 resulting class.
 374
 375 =head2 create_class_with_roles
 376
 377  Role::Tiny->create_class_with_roles('Some::Base', qw(Some::Role1 Some::Role2));
 378
 379 Creates a new class based on base, with the roles composed into it in order.
 380 New class is returned.
 381
 382 =head1 SUBROUTINES
 383
 384 =head2 does_role
 385
 386  if (Role::Tiny::does_role($foo, 'Some::Role')) {
 387    ...
 388  }
 389
 390 Returns true if class has been composed with role.
 391
 392 This subroutine is also installed as ->does on any class a Role::Tiny is
 393 composed into unless that class already has an ->does method, so
 394
 395   if ($foo->does('Some::Role')) {
 396     ...
 397   }
 398
 399 will work for classes but to test a role, one must use ::does_role directly
 400
 401 =head1 IMPORTED SUBROUTINES
 402
 403 =head2 requires
 404
 405  requires qw(foo bar);
 406
 407 Declares a list of methods that must be defined to compose role.
 408
 409 =head2 with
 410
 411  with 'Some::Role1';
 412  with 'Some::Role2';
 413
 414 Composes another role into the current role.  Only one role may be composed in
 415 at a time to allow the code to remain as simple as possible.
 416
 417 =head2 before
 418
 419  before foo => sub { ... };
 420
 421 See L<< Class::Method::Modifiers/before method(s) => sub { ... } >> for full
 422 documentation.
 423
 424 Note that since you are not required to use method modifiers,
 425 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 426 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 427 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 428
 429 =head2 around
 430
 431  around foo => sub { ... };
 432
 433 See L<< Class::Method::Modifiers/around method(s) => sub { ... } >> for full
 434 documentation.
 435
 436 Note that since you are not required to use method modifiers,
 437 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 438 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 439 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 440
 441 =head2 after
 442
 443  after foo => sub { ... };
 444
 445 See L<< Class::Method::Modifiers/after method(s) => sub { ... } >> for full
 446 documentation.
 447
 448 Note that since you are not required to use method modifiers,
 449 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 450 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 451 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 452
 453 =head1 SEE ALSO
 454
 455 L<Role::Tiny> is the attribute-less subset of L<Moo::Role>; L<Moo::Role> is
 456 a meta-protocol-less subset of the king of role systems, L<Moose::Role>.
 457
 458 If you don't want method modifiers and do want to be forcibly restricted
 459 to a single role application per class, Ovid's L<Role::Basic> exists. But
 460 Stevan Little (the L<Moose> author) and I are both still convinced that
 461 he's Doing It Wrong.
 462
 463 =head1 AUTHOR
 464
 465 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 466
 467 =head1 CONTRIBUTORS
 468
 469 dg - David Leadbeater (cpan:DGL) <dgl@dgl.cx>
 470
 471 frew - Arthur Axel "fREW" Schmidt (cpan:FREW) <frioux@gmail.com>
 472
 473 hobbs - Andrew Rodland (cpan:ARODLAND) <arodland@cpan.org>
 474
 475 jnap - John Napiorkowski (cpan:JJNAPIORK) <jjn1056@yahoo.com>
 476
 477 ribasushi - Peter Rabbitson (cpan:RIBASUSHI) <ribasushi@cpan.org>
 478
 479 chip - Chip Salzenberg (cpan:CHIPS) <chip@pobox.com>
 480
 481 ajgb - Alex J. G. Burzyński (cpan:AJGB) <ajgb@cpan.org>
 482
 483 doy - Jesse Luehrs (cpan:DOY) <doy at tozt dot net>
 484
 485 perigrin - Chris Prather (cpan:PERIGRIN) <chris@prather.org>
 486
 487 =head1 COPYRIGHT
 488
 489 Copyright (c) 2010-2012 the Role::Tiny L</AUTHOR> and L</CONTRIBUTORS>
 490 as listed above.
 491
 492 =head1 LICENSE
 493
 494 This library is free software and may be distributed under the same terms
 495 as perl itself.
 496
 497 =cut