lib/Role/Tiny.pm

   1 package Role::Tiny;
   2
   3 sub _getglob { \*{$_[0]} }
   4 sub _getstash { \%{"$_[0]::"} }
   5
   6 use strict;
   7 use warnings FATAL => 'all';
   8
   9 our $VERSION = '1.000_900'; # 1.0.900
  10 $VERSION = eval $VERSION;
  11
  12 our %INFO;
  13 our %APPLIED_TO;
  14 our %COMPOSED;
  15 our %COMPOSITE_INFO;
  16
  17 # Module state workaround totally stolen from Zefram's Module::Runtime.
  18
  19 BEGIN {
  20   *_WORK_AROUND_BROKEN_MODULE_STATE = "$]" < 5.009 ? sub(){1} : sub(){0};
  21 }
  22
  23 sub Role::Tiny::__GUARD__::DESTROY {
  24   delete $INC{$_[0]->[0]} if @{$_[0]};
  25 }
  26
  27 sub _load_module {
  28   (my $proto = $_[0]) =~ s/::/\//g;
  29   $proto .= '.pm';
  30   return 1 if $INC{$proto};
  31   # can't just ->can('can') because a sub-package Foo::Bar::Baz
  32   # creates a 'Baz::' key in Foo::Bar's symbol table
  33   return 1 if grep !/::$/, keys %{_getstash($_[0])||{}};
  34   my $guard = _WORK_AROUND_BROKEN_MODULE_STATE
  35     && bless([ $proto ], 'Role::Tiny::__GUARD__');
  36   require $proto;
  37   pop @$guard if _WORK_AROUND_BROKEN_MODULE_STATE;
  38   return 1;
  39 }
  40
  41 sub import {
  42   my $target = caller;
  43   my $me = shift;
  44   strict->import;
  45   warnings->import(FATAL => 'all');
  46   return if $INFO{$target}; # already exported into this package
  47   # get symbol table reference
  48   my $stash = do { no strict 'refs'; \%{"${target}::"} };
  49   # install before/after/around subs
  50   foreach my $type (qw(before after around)) {
  51     *{_getglob "${target}::${type}"} = sub {
  52       require Class::Method::Modifiers;
  53       push @{$INFO{$target}{modifiers}||=[]}, [ $type => @_ ];
  54     };
  55   }
  56   *{_getglob "${target}::requires"} = sub {
  57     push @{$INFO{$target}{requires}||=[]}, @_;
  58   };
  59   *{_getglob "${target}::with"} = sub {
  60     $me->apply_roles_to_package($target, @_);
  61   };
  62   # grab all *non-constant* (stash slot is not a scalarref) subs present
  63   # in the symbol table and store their refaddrs (no need to forcibly
  64   # inflate constant subs into real subs) - also add '' to here (this
  65   # is used later)
  66   @{$INFO{$target}{not_methods}={}}{
  67     '', map { *$_{CODE}||() } grep !ref($_), values %$stash
  68   } = ();
  69   # a role does itself
  70   $APPLIED_TO{$target} = { $target => undef };
  71 }
  72
  73 sub apply_single_role_to_package {
  74   my ($me, $to, $role) = @_;
  75
  76   _load_module($role);
  77
  78   die "This is apply_role_to_package" if ref($to);
  79   die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
  80
  81   $me->_check_requires($to, $role, @{$info->{requires}||[]});
  82
  83   $me->_install_methods($to, $role);
  84
  85   $me->_install_modifiers($to, $info->{modifiers});
  86
  87   # only add does() method to classes and only if they don't have one
  88   if (not $INFO{$to} and not $to->can('does')) {
  89     *{_getglob "${to}::does"} = \&does_role;
  90   }
  91
  92   # copy our role list into the target's
  93   @{$APPLIED_TO{$to}||={}}{keys %{$APPLIED_TO{$role}}} = ();
  94 }
  95
  96 sub apply_roles_to_object {
  97   my ($me, $object, @roles) = @_;
  98   die "No roles supplied!" unless @roles;
  99   my $class = ref($object);
 100   bless($object, $me->create_class_with_roles($class, @roles));
 101   $object;
 102 }
 103
 104 sub create_class_with_roles {
 105   my ($me, $superclass, @roles) = @_;
 106
 107   die "No roles supplied!" unless @roles;
 108
 109   {
 110     my %seen;
 111     $seen{$_}++ for @roles;
 112     if (my @dupes = grep $seen{$_} > 1, @roles) {
 113       die "Duplicated roles: ".join(', ', @dupes);
 114     }
 115   }
 116
 117   my $new_name = join(
 118     '__WITH__', $superclass, my $compose_name = join '__AND__', @roles
 119   );
 120
 121   return $new_name if $COMPOSED{class}{$new_name};
 122
 123   foreach my $role (@roles) {
 124     _load_module($role);
 125     die "${role} is not a Role::Tiny" unless $INFO{$role};
 126   }
 127
 128   if ($] >= 5.010) {
 129     require mro;
 130   } else {
 131     require MRO::Compat;
 132   }
 133
 134   my @composable = map $me->_composable_package_for($_), reverse @roles;
 135
 136   *{_getglob("${new_name}::ISA")} = [ @composable, $superclass ];
 137
 138   my @info = map $INFO{$_}, @roles;
 139
 140   $me->_check_requires(
 141     $new_name, $compose_name,
 142     do { my %h; @h{map @{$_->{requires}||[]}, @info} = (); keys %h }
 143   );
 144
 145   *{_getglob "${new_name}::does"} = \&does_role unless $new_name->can('does');
 146
 147   @{$APPLIED_TO{$new_name}||={}}{
 148     map keys %{$APPLIED_TO{$_}}, @roles
 149   } = ();
 150
 151   $COMPOSED{class}{$new_name} = 1;
 152   return $new_name;
 153 }
 154
 155 sub apply_role_to_package { shift->apply_single_role_to_package(@_) }
 156
 157 sub apply_roles_to_package {
 158   my ($me, $to, @roles) = @_;
 159
 160   return $me->apply_single_role_to_package($to, $roles[0]) if @roles == 1;
 161
 162   my %conflicts = %{$me->_composite_info_for(@roles)->{conflicts}};
 163   delete $conflicts{$_} for $me->_concrete_methods_of($to);
 164   if (keys %conflicts) {
 165     my $fail =
 166       join "\n",
 167         map {
 168           "Due to a method name conflict between roles "
 169           ."'".join(' and ', sort values %{$conflicts{$_}})."'"
 170           .", the method '$_' must be implemented by '${to}'"
 171         } keys %conflicts;
 172     die $fail;
 173   }
 174   $me->apply_single_role_to_package($to, $_) for @roles;
 175   $APPLIED_TO{$to}{join('|',@roles)} = 1;
 176 }
 177
 178 sub _composite_info_for {
 179   my ($me, @roles) = @_;
 180   $COMPOSITE_INFO{join('|', sort @roles)} ||= do {
 181     _load_module($_) for @roles;
 182     my %methods;
 183     foreach my $role (@roles) {
 184       my $this_methods = $me->_concrete_methods_of($role);
 185       $methods{$_}{$this_methods->{$_}} = $role for keys %$this_methods;
 186     }
 187     delete $methods{$_} for grep keys(%{$methods{$_}}) == 1, keys %methods;
 188     +{ conflicts => \%methods }
 189   };
 190 }
 191
 192 sub _composable_package_for {
 193   my ($me, $role) = @_;
 194   my $composed_name = 'Role::Tiny::_COMPOSABLE::'.$role;
 195   return $composed_name if $COMPOSED{role}{$composed_name};
 196   $me->_install_methods($composed_name, $role);
 197   my $base_name = $composed_name.'::_BASE';
 198   *{_getglob("${composed_name}::ISA")} = [ $base_name ];
 199   my $modifiers = $INFO{$role}{modifiers}||[];
 200   my @mod_base;
 201   foreach my $modified (
 202     do { my %h; @h{map $_->[1], @$modifiers} = (); keys %h }
 203   ) {
 204     push @mod_base, "sub ${modified} { shift->next::method(\@_) }";
 205   }
 206   my $e;
 207   {
 208     local $@;
 209     eval(my $code = join "\n", "package ${base_name};", @mod_base);
 210     $e = "Evaling failed: $@\nTrying to eval:\n${code}" if $@;
 211   }
 212   die $e if $e;
 213   $me->_install_modifiers($composed_name, $modifiers);
 214   $COMPOSED{role}{$composed_name} = 1;
 215   return $composed_name;
 216 }
 217
 218 sub _check_requires {
 219   my ($me, $to, $name, @requires) = @_;
 220   if (my @requires_fail = grep !$to->can($_), @requires) {
 221     # role -> role, add to requires, role -> class, error out
 222     if (my $to_info = $INFO{$to}) {
 223       push @{$to_info->{requires}||=[]}, @requires_fail;
 224     } else {
 225       die "Can't apply ${name} to ${to} - missing ".join(', ', @requires_fail);
 226     }
 227   }
 228 }
 229
 230 sub _concrete_methods_of {
 231   my ($me, $role) = @_;
 232   my $info = $INFO{$role};
 233   # grab role symbol table
 234   my $stash = do { no strict 'refs'; \%{"${role}::"}};
 235   my $not_methods = $info->{not_methods};
 236   +{
 237     # grab all code entries that aren't in the not_methods list
 238     map {
 239       my $code = *{$stash->{$_}}{CODE};
 240       # rely on the '' key we added in import for "no code here"
 241       exists $not_methods->{$code||''} ? () : ($_ => $code)
 242     } grep !ref($stash->{$_}), keys %$stash
 243   };
 244 }
 245
 246 sub methods_provided_by {
 247   my ($me, $role) = @_;
 248   die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
 249   (keys %{$me->_concrete_methods_of($role)}, @{$info->{requires}||[]});
 250 }
 251
 252 sub _install_methods {
 253   my ($me, $to, $role) = @_;
 254
 255   my $info = $INFO{$role};
 256
 257   my $methods = $me->_concrete_methods_of($role);
 258
 259   # grab target symbol table
 260   my $stash = do { no strict 'refs'; \%{"${to}::"}};
 261
 262   # determine already extant methods of target
 263   my %has_methods;
 264   @has_methods{grep
 265     +(ref($stash->{$_}) || *{$stash->{$_}}{CODE}),
 266     keys %$stash
 267   } = ();
 268
 269   foreach my $i (grep !exists $has_methods{$_}, keys %$methods) {
 270     no warnings 'once';
 271     *{_getglob "${to}::${i}"} = $methods->{$i};
 272   }
 273 }
 274
 275 sub _install_modifiers {
 276   my ($me, $to, $modifiers) = @_;
 277   if (my $info = $INFO{$to}) {
 278     push @{$info->{modifiers}}, @{$modifiers||[]};
 279   } else {
 280     foreach my $modifier (@{$modifiers||[]}) {
 281       $me->_install_single_modifier($to, @$modifier);
 282     }
 283   }
 284 }
 285
 286 sub _install_single_modifier {
 287   my ($me, @args) = @_;
 288   Class::Method::Modifiers::install_modifier(@args);
 289 }
 290
 291 sub does_role {
 292   my ($proto, $role) = @_;
 293   return exists $APPLIED_TO{ref($proto)||$proto}{$role};
 294 }
 295
 296 1;
 297
 298 =head1 NAME
 299
 300 Role::Tiny - Roles. Like a nouvelle cuisine portion size slice of Moose.
 301
 302 =head1 SYNOPSIS
 303
 304  package Some::Role;
 305
 306  use Role::Tiny;
 307
 308  sub foo { ... }
 309
 310  sub bar { ... }
 311
 312  around baz => sub { ... }
 313
 314  1;
 315
 316 else where
 317
 318  package Some::Class;
 319
 320  use Role::Tiny::With;
 321
 322  # bar gets imported, but not foo
 323  with 'Some::Role';
 324
 325  sub foo { ... }
 326
 327  # baz is wrapped in the around modifier by Class::Method::Modifiers
 328  sub baz { ... }
 329
 330  1;
 331
 332 If you wanted attributes as well, look at L<Moo::Role>.
 333
 334 =head1 DESCRIPTION
 335
 336 C<Role::Tiny> is a minimalist role composition tool.
 337
 338 =head1 ROLE COMPOSITION
 339
 340 Role composition can be thought of as much more clever and meaningful multiple
 341 inheritance.  The basics of this implementation of roles is:
 342
 343 =over 2
 344
 345 =item *
 346
 347 If a method is already defined on a class, that method will not be composed in
 348 from the role.
 349
 350 =item *
 351
 352 If a method that the role L</requires> to be implemented is not implemented,
 353 role application will fail loudly.
 354
 355 =back
 356
 357 Unlike L<Class::C3>, where the B<last> class inherited from "wins," role
 358 composition is the other way around, where the class wins. If multiple roles
 359 are applied in a single call (single with statement), then if any of their
 360 provided methods clash, an exception is raised unless the class provides
 361 a method since this conflict indicates a potential problem.
 362
 363 =head1 METHODS
 364
 365 =head2 apply_roles_to_package
 366
 367  Role::Tiny->apply_roles_to_package(
 368    'Some::Package', 'Some::Role', 'Some::Other::Role'
 369  );
 370
 371 Composes role with package.  See also L<Role::Tiny::With>.
 372
 373 =head2 apply_roles_to_object
 374
 375  Role::Tiny->apply_roles_to_object($foo, qw(Some::Role1 Some::Role2));
 376
 377 Composes roles in order into object directly.  Object is reblessed into the
 378 resulting class.
 379
 380 =head2 create_class_with_roles
 381
 382  Role::Tiny->create_class_with_roles('Some::Base', qw(Some::Role1 Some::Role2));
 383
 384 Creates a new class based on base, with the roles composed into it in order.
 385 New class is returned.
 386
 387 =head1 SUBROUTINES
 388
 389 =head2 does_role
 390
 391  if (Role::Tiny::does_role($foo, 'Some::Role')) {
 392    ...
 393  }
 394
 395 Returns true if class has been composed with role.
 396
 397 This subroutine is also installed as ->does on any class a Role::Tiny is
 398 composed into unless that class already has an ->does method, so
 399
 400   if ($foo->does('Some::Role')) {
 401     ...
 402   }
 403
 404 will work for classes but to test a role, one must use ::does_role directly
 405
 406 =head1 IMPORTED SUBROUTINES
 407
 408 =head2 requires
 409
 410  requires qw(foo bar);
 411
 412 Declares a list of methods that must be defined to compose role.
 413
 414 =head2 with
 415
 416  with 'Some::Role1';
 417
 418  with 'Some::Role1', 'Some::Role2';
 419
 420 Composes another role into the current role (or class via L<Role::Tiny::With>).
 421
 422 If you have conflicts and want to resolve them in favour of Some::Role1 you
 423 can instead write:
 424
 425  with 'Some::Role1';
 426  with 'Some::Role2';
 427
 428 If you have conflicts and want to resolve different conflicts in favour of
 429 different roles, please refactor your codebase.
 430
 431 =head2 before
 432
 433  before foo => sub { ... };
 434
 435 See L<< Class::Method::Modifiers/before method(s) => sub { ... } >> for full
 436 documentation.
 437
 438 Note that since you are not required to use method modifiers,
 439 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 440 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 441 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 442
 443 =head2 around
 444
 445  around foo => sub { ... };
 446
 447 See L<< Class::Method::Modifiers/around method(s) => sub { ... } >> for full
 448 documentation.
 449
 450 Note that since you are not required to use method modifiers,
 451 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 452 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 453 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 454
 455 =head2 after
 456
 457  after foo => sub { ... };
 458
 459 See L<< Class::Method::Modifiers/after method(s) => sub { ... } >> for full
 460 documentation.
 461
 462 Note that since you are not required to use method modifiers,
 463 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 464 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 465 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 466
 467 =head1 SEE ALSO
 468
 469 L<Role::Tiny> is the attribute-less subset of L<Moo::Role>; L<Moo::Role> is
 470 a meta-protocol-less subset of the king of role systems, L<Moose::Role>.
 471
 472 If you don't want method modifiers and do want to be forcibly restricted
 473 to a single role application per class, Ovid's L<Role::Basic> exists. But
 474 Stevan Little (the L<Moose> author) don't find the additional restrictions
 475 to be amazingly helpful in most cases; L<Role::Basic>'s choices are more
 476 a guide to what you should prefer doing, to our mind, rather than something
 477 that needs to be enforced.
 478
 479 =head1 AUTHOR
 480
 481 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 482
 483 =head1 CONTRIBUTORS
 484
 485 dg - David Leadbeater (cpan:DGL) <dgl@dgl.cx>
 486
 487 frew - Arthur Axel "fREW" Schmidt (cpan:FREW) <frioux@gmail.com>
 488
 489 hobbs - Andrew Rodland (cpan:ARODLAND) <arodland@cpan.org>
 490
 491 jnap - John Napiorkowski (cpan:JJNAPIORK) <jjn1056@yahoo.com>
 492
 493 ribasushi - Peter Rabbitson (cpan:RIBASUSHI) <ribasushi@cpan.org>
 494
 495 chip - Chip Salzenberg (cpan:CHIPS) <chip@pobox.com>
 496
 497 ajgb - Alex J. G. Burzyński (cpan:AJGB) <ajgb@cpan.org>
 498
 499 doy - Jesse Luehrs (cpan:DOY) <doy at tozt dot net>
 500
 501 perigrin - Chris Prather (cpan:PERIGRIN) <chris@prather.org>
 502
 503 =head1 COPYRIGHT
 504
 505 Copyright (c) 2010-2012 the Role::Tiny L</AUTHOR> and L</CONTRIBUTORS>
 506 as listed above.
 507
 508 =head1 LICENSE
 509
 510 This library is free software and may be distributed under the same terms
 511 as perl itself.
 512
 513 =cut