lib/Role/Tiny.pm

   1 package Role::Tiny;
   2
   3 sub _getglob { \*{$_[0]} }
   4 sub _getstash { \%{"$_[0]::"} }
   5
   6 use strict;
   7 use warnings FATAL => 'all';
   8
   9 our $VERSION = '1.002005'; # 1.2.5
  10 $VERSION = eval $VERSION;
  11
  12 our %INFO;
  13 our %APPLIED_TO;
  14 our %COMPOSED;
  15 our %COMPOSITE_INFO;
  16
  17 # Module state workaround totally stolen from Zefram's Module::Runtime.
  18
  19 BEGIN {
  20   *_WORK_AROUND_BROKEN_MODULE_STATE = "$]" < 5.009 ? sub(){1} : sub(){0};
  21 }
  22
  23 sub Role::Tiny::__GUARD__::DESTROY {
  24   delete $INC{$_[0]->[0]} if @{$_[0]};
  25 }
  26
  27 sub _load_module {
  28   (my $proto = $_[0]) =~ s/::/\//g;
  29   $proto .= '.pm';
  30   return 1 if $INC{$proto};
  31   # can't just ->can('can') because a sub-package Foo::Bar::Baz
  32   # creates a 'Baz::' key in Foo::Bar's symbol table
  33   return 1 if grep !/::$/, keys %{_getstash($_[0])||{}};
  34   my $guard = _WORK_AROUND_BROKEN_MODULE_STATE
  35     && bless([ $proto ], 'Role::Tiny::__GUARD__');
  36   require $proto;
  37   pop @$guard if _WORK_AROUND_BROKEN_MODULE_STATE;
  38   return 1;
  39 }
  40
  41 sub import {
  42   my $target = caller;
  43   my $me = shift;
  44   strict->import;
  45   warnings->import(FATAL => 'all');
  46   return if $INFO{$target}; # already exported into this package
  47   $INFO{$target}{is_role} = 1;
  48   # get symbol table reference
  49   my $stash = _getstash($target);
  50   # install before/after/around subs
  51   foreach my $type (qw(before after around)) {
  52     *{_getglob "${target}::${type}"} = sub {
  53       require Class::Method::Modifiers;
  54       push @{$INFO{$target}{modifiers}||=[]}, [ $type => @_ ];
  55       return;
  56     };
  57   }
  58   *{_getglob "${target}::requires"} = sub {
  59     push @{$INFO{$target}{requires}||=[]}, @_;
  60     return;
  61   };
  62   *{_getglob "${target}::with"} = sub {
  63     $me->apply_roles_to_package($target, @_);
  64     return;
  65   };
  66   # grab all *non-constant* (stash slot is not a scalarref) subs present
  67   # in the symbol table and store their refaddrs (no need to forcibly
  68   # inflate constant subs into real subs) with a map to the coderefs in
  69   # case of copying or re-use
  70   my @not_methods = (map { *$_{CODE}||() } grep !ref($_), values %$stash);
  71   @{$INFO{$target}{not_methods}={}}{@not_methods} = @not_methods;
  72   # a role does itself
  73   $APPLIED_TO{$target} = { $target => undef };
  74 }
  75
  76 sub role_application_steps {
  77   qw(_install_methods _check_requires _install_modifiers _copy_applied_list);
  78 }
  79
  80 sub apply_single_role_to_package {
  81   my ($me, $to, $role) = @_;
  82
  83   _load_module($role);
  84
  85   die "This is apply_role_to_package" if ref($to);
  86   die "${role} is not a Role::Tiny" unless $INFO{$role};
  87
  88   foreach my $step ($me->role_application_steps) {
  89     $me->$step($to, $role);
  90   }
  91 }
  92
  93 sub _copy_applied_list {
  94   my ($me, $to, $role) = @_;
  95   # copy our role list into the target's
  96   @{$APPLIED_TO{$to}||={}}{keys %{$APPLIED_TO{$role}}} = ();
  97 }
  98
  99 sub apply_roles_to_object {
 100   my ($me, $object, @roles) = @_;
 101   die "No roles supplied!" unless @roles;
 102   my $class = ref($object);
 103   bless($object, $me->create_class_with_roles($class, @roles));
 104   $object;
 105 }
 106
 107 sub create_class_with_roles {
 108   my ($me, $superclass, @roles) = @_;
 109
 110   die "No roles supplied!" unless @roles;
 111
 112   _load_module($superclass);
 113   {
 114     my %seen;
 115     $seen{$_}++ for @roles;
 116     if (my @dupes = grep $seen{$_} > 1, @roles) {
 117       die "Duplicated roles: ".join(', ', @dupes);
 118     }
 119   }
 120
 121   my $new_name = join(
 122     '__WITH__', $superclass, my $compose_name = join '__AND__', @roles
 123   );
 124
 125   return $new_name if $COMPOSED{class}{$new_name};
 126
 127   foreach my $role (@roles) {
 128     _load_module($role);
 129     die "${role} is not a Role::Tiny" unless $INFO{$role};
 130   }
 131
 132   if ($] >= 5.010) {
 133     require mro;
 134   } else {
 135     require MRO::Compat;
 136   }
 137
 138   my $composite_info = $me->_composite_info_for(@roles);
 139   my %conflicts = %{$composite_info->{conflicts}};
 140   if (keys %conflicts) {
 141     my $fail =
 142       join "\n",
 143         map {
 144           "Method name conflict for '$_' between roles "
 145           ."'".join(' and ', sort values %{$conflicts{$_}})."'"
 146           .", cannot apply these simultaneously to an object."
 147         } keys %conflicts;
 148     die $fail;
 149   }
 150
 151   my @composable = map $me->_composable_package_for($_), reverse @roles;
 152
 153   # some methods may not exist in the role, but get generated by
 154   # _composable_package_for (Moose accessors via Moo).  filter out anything
 155   # provided by the composable packages, excluding the subs we generated to
 156   # make modifiers work.
 157   my @requires = grep {
 158     my $method = $_;
 159     !grep $_->can($method) && !$COMPOSED{role}{$_}{modifiers_only}{$method},
 160       @composable
 161   } @{$composite_info->{requires}};
 162
 163   $me->_check_requires(
 164     $superclass, $compose_name, \@requires
 165   );
 166
 167   *{_getglob("${new_name}::ISA")} = [ @composable, $superclass ];
 168
 169   @{$APPLIED_TO{$new_name}||={}}{
 170     map keys %{$APPLIED_TO{$_}}, @roles
 171   } = ();
 172
 173   $COMPOSED{class}{$new_name} = 1;
 174   return $new_name;
 175 }
 176
 177 # preserved for compat, and apply_roles_to_package calls it to allow an
 178 # updated Role::Tiny to use a non-updated Moo::Role
 179
 180 sub apply_role_to_package { shift->apply_single_role_to_package(@_) }
 181
 182 sub apply_roles_to_package {
 183   my ($me, $to, @roles) = @_;
 184
 185   return $me->apply_role_to_package($to, $roles[0]) if @roles == 1;
 186
 187   my %conflicts = %{$me->_composite_info_for(@roles)->{conflicts}};
 188   delete $conflicts{$_} for keys %{ $me->_concrete_methods_of($to) };
 189   if (keys %conflicts) {
 190     my $fail =
 191       join "\n",
 192         map {
 193           "Due to a method name conflict between roles "
 194           ."'".join(' and ', sort values %{$conflicts{$_}})."'"
 195           .", the method '$_' must be implemented by '${to}'"
 196         } keys %conflicts;
 197     die $fail;
 198   }
 199
 200   # the if guard here is essential since otherwise we accidentally create
 201   # a $INFO for something that isn't a Role::Tiny (or Moo::Role) because
 202   # autovivification hates us and wants us to die()
 203   if ($INFO{$to}) {
 204     delete $INFO{$to}{methods}; # reset since we're about to add methods
 205   }
 206
 207   # backcompat: allow subclasses to use apply_single_role_to_package
 208   # to apply changes.  set a local var so ours does nothing.
 209   our %BACKCOMPAT_HACK;
 210   if($me ne __PACKAGE__
 211       and exists $BACKCOMPAT_HACK{$me} ? $BACKCOMPAT_HACK{$me} :
 212       $BACKCOMPAT_HACK{$me} =
 213         $me->can('role_application_steps')
 214           == \&role_application_steps
 215         && $me->can('apply_single_role_to_package')
 216           != \&apply_single_role_to_package
 217   ) {
 218     foreach my $role (@roles) {
 219       $me->apply_single_role_to_package($to, $role);
 220     }
 221   }
 222   else {
 223     foreach my $step ($me->role_application_steps) {
 224       foreach my $role (@roles) {
 225         $me->$step($to, $role);
 226       }
 227     }
 228   }
 229   $APPLIED_TO{$to}{join('|',@roles)} = 1;
 230 }
 231
 232 sub _composite_info_for {
 233   my ($me, @roles) = @_;
 234   $COMPOSITE_INFO{join('|', sort @roles)} ||= do {
 235     foreach my $role (@roles) {
 236       _load_module($role);
 237     }
 238     my %methods;
 239     foreach my $role (@roles) {
 240       my $this_methods = $me->_concrete_methods_of($role);
 241       $methods{$_}{$this_methods->{$_}} = $role for keys %$this_methods;
 242     }
 243     my %requires;
 244     @requires{map @{$INFO{$_}{requires}||[]}, @roles} = ();
 245     delete $requires{$_} for keys %methods;
 246     delete $methods{$_} for grep keys(%{$methods{$_}}) == 1, keys %methods;
 247     +{ conflicts => \%methods, requires => [keys %requires] }
 248   };
 249 }
 250
 251 sub _composable_package_for {
 252   my ($me, $role) = @_;
 253   my $composed_name = 'Role::Tiny::_COMPOSABLE::'.$role;
 254   return $composed_name if $COMPOSED{role}{$composed_name};
 255   $me->_install_methods($composed_name, $role);
 256   my $base_name = $composed_name.'::_BASE';
 257   # force stash to exist so ->can doesn't complain
 258   _getstash($base_name);
 259   # Not using _getglob, since setting @ISA via the typeglob breaks
 260   # inheritance on 5.10.0 if the stash has previously been accessed an
 261   # then a method called on the class (in that order!), which
 262   # ->_install_methods (with the help of ->_install_does) ends up doing.
 263   { no strict 'refs'; @{"${composed_name}::ISA"} = ( $base_name ); }
 264   my $modifiers = $INFO{$role}{modifiers}||[];
 265   my @mod_base;
 266   my @modifiers = grep !$composed_name->can($_),
 267     do { my %h; @h{map @{$_}[1..$#$_-1], @$modifiers} = (); keys %h };
 268   foreach my $modified (@modifiers) {
 269     push @mod_base, "sub ${modified} { shift->next::method(\@_) }";
 270   }
 271   my $e;
 272   {
 273     local $@;
 274     eval(my $code = join "\n", "package ${base_name};", @mod_base);
 275     $e = "Evaling failed: $@\nTrying to eval:\n${code}" if $@;
 276   }
 277   die $e if $e;
 278   $me->_install_modifiers($composed_name, $role);
 279   $COMPOSED{role}{$composed_name} = {
 280     modifiers_only => { map { $_ => 1 } @modifiers },
 281   };
 282   return $composed_name;
 283 }
 284
 285 sub _check_requires {
 286   my ($me, $to, $name, $requires) = @_;
 287   return unless my @requires = @{$requires||$INFO{$name}{requires}||[]};
 288   if (my @requires_fail = grep !$to->can($_), @requires) {
 289     # role -> role, add to requires, role -> class, error out
 290     if (my $to_info = $INFO{$to}) {
 291       push @{$to_info->{requires}||=[]}, @requires_fail;
 292     } else {
 293       die "Can't apply ${name} to ${to} - missing ".join(', ', @requires_fail);
 294     }
 295   }
 296 }
 297
 298 sub _concrete_methods_of {
 299   my ($me, $role) = @_;
 300   my $info = $INFO{$role};
 301   # grab role symbol table
 302   my $stash = _getstash($role);
 303   # reverse so our keys become the values (captured coderefs) in case
 304   # they got copied or re-used since
 305   my $not_methods = { reverse %{$info->{not_methods}||{}} };
 306   $info->{methods} ||= +{
 307     # grab all code entries that aren't in the not_methods list
 308     map {
 309       my $code = *{$stash->{$_}}{CODE};
 310       ( ! $code or exists $not_methods->{$code} ) ? () : ($_ => $code)
 311     } grep !ref($stash->{$_}), keys %$stash
 312   };
 313 }
 314
 315 sub methods_provided_by {
 316   my ($me, $role) = @_;
 317   die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
 318   (keys %{$me->_concrete_methods_of($role)}, @{$info->{requires}||[]});
 319 }
 320
 321 sub _install_methods {
 322   my ($me, $to, $role) = @_;
 323
 324   my $info = $INFO{$role};
 325
 326   my $methods = $me->_concrete_methods_of($role);
 327
 328   # grab target symbol table
 329   my $stash = _getstash($to);
 330
 331   # determine already extant methods of target
 332   my %has_methods;
 333   @has_methods{grep
 334     +(ref($stash->{$_}) || *{$stash->{$_}}{CODE}),
 335     keys %$stash
 336   } = ();
 337
 338   foreach my $i (grep !exists $has_methods{$_}, keys %$methods) {
 339     no warnings 'once';
 340     *{_getglob "${to}::${i}"} = $methods->{$i};
 341   }
 342
 343   $me->_install_does($to);
 344 }
 345
 346 sub _install_modifiers {
 347   my ($me, $to, $name) = @_;
 348   return unless my $modifiers = $INFO{$name}{modifiers};
 349   if (my $info = $INFO{$to}) {
 350     push @{$info->{modifiers}}, @{$modifiers||[]};
 351   } else {
 352     foreach my $modifier (@{$modifiers||[]}) {
 353       $me->_install_single_modifier($to, @$modifier);
 354     }
 355   }
 356 }
 357
 358 my $vcheck_error;
 359
 360 sub _install_single_modifier {
 361   my ($me, @args) = @_;
 362   defined($vcheck_error) or $vcheck_error = do {
 363     local $@;
 364     eval { Class::Method::Modifiers->VERSION(1.05); 1 }
 365       ? 0
 366       : $@
 367   };
 368   $vcheck_error and die $vcheck_error;
 369   Class::Method::Modifiers::install_modifier(@args);
 370 }
 371
 372 my $FALLBACK = sub { 0 };
 373 sub _install_does {
 374   my ($me, $to) = @_;
 375
 376   # only add does() method to classes
 377   return if $INFO{$to};
 378
 379   # add does() only if they don't have one
 380   *{_getglob "${to}::does"} = \&does_role unless $to->can('does');
 381
 382   return if ($to->can('DOES') and $to->can('DOES') != (UNIVERSAL->can('DOES') || 0));
 383
 384   my $existing = $to->can('DOES') || $to->can('isa') || $FALLBACK;
 385   my $new_sub = sub {
 386     my ($proto, $role) = @_;
 387     Role::Tiny::does_role($proto, $role) or $proto->$existing($role);
 388   };
 389   no warnings 'redefine';
 390   *{_getglob "${to}::DOES"} = $new_sub;
 391 }
 392
 393 sub does_role {
 394   my ($proto, $role) = @_;
 395   if ($] >= 5.010) {
 396     require mro;
 397   } else {
 398     require MRO::Compat;
 399   }
 400   foreach my $class (@{mro::get_linear_isa(ref($proto)||$proto)}) {
 401     return 1 if exists $APPLIED_TO{$class}{$role};
 402   }
 403   return 0;
 404 }
 405
 406 sub is_role {
 407   my ($me, $role) = @_;
 408   return !!$INFO{$role};
 409 }
 410
 411 1;
 412
 413 =encoding utf-8
 414
 415 =head1 NAME
 416
 417 Role::Tiny - Roles. Like a nouvelle cuisine portion size slice of Moose.
 418
 419 =head1 SYNOPSIS
 420
 421  package Some::Role;
 422
 423  use Role::Tiny;
 424
 425  sub foo { ... }
 426
 427  sub bar { ... }
 428
 429  around baz => sub { ... }
 430
 431  1;
 432
 433 else where
 434
 435  package Some::Class;
 436
 437  use Role::Tiny::With;
 438
 439  # bar gets imported, but not foo
 440  with 'Some::Role';
 441
 442  sub foo { ... }
 443
 444  # baz is wrapped in the around modifier by Class::Method::Modifiers
 445  sub baz { ... }
 446
 447  1;
 448
 449 If you wanted attributes as well, look at L<Moo::Role>.
 450
 451 =head1 DESCRIPTION
 452
 453 C<Role::Tiny> is a minimalist role composition tool.
 454
 455 =head1 ROLE COMPOSITION
 456
 457 Role composition can be thought of as much more clever and meaningful multiple
 458 inheritance.  The basics of this implementation of roles is:
 459
 460 =over 2
 461
 462 =item *
 463
 464 If a method is already defined on a class, that method will not be composed in
 465 from the role.
 466
 467 =item *
 468
 469 If a method that the role L</requires> to be implemented is not implemented,
 470 role application will fail loudly.
 471
 472 =back
 473
 474 Unlike L<Class::C3>, where the B<last> class inherited from "wins," role
 475 composition is the other way around, where the class wins. If multiple roles
 476 are applied in a single call (single with statement), then if any of their
 477 provided methods clash, an exception is raised unless the class provides
 478 a method since this conflict indicates a potential problem.
 479
 480 =head1 IMPORTED SUBROUTINES
 481
 482 =head2 requires
 483
 484  requires qw(foo bar);
 485
 486 Declares a list of methods that must be defined to compose role.
 487
 488 =head2 with
 489
 490  with 'Some::Role1';
 491
 492  with 'Some::Role1', 'Some::Role2';
 493
 494 Composes another role into the current role (or class via L<Role::Tiny::With>).
 495
 496 If you have conflicts and want to resolve them in favour of Some::Role1 you
 497 can instead write:
 498
 499  with 'Some::Role1';
 500  with 'Some::Role2';
 501
 502 If you have conflicts and want to resolve different conflicts in favour of
 503 different roles, please refactor your codebase.
 504
 505 =head2 before
 506
 507  before foo => sub { ... };
 508
 509 See L<< Class::Method::Modifiers/before method(s) => sub { ... } >> for full
 510 documentation.
 511
 512 Note that since you are not required to use method modifiers,
 513 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 514 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 515 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 516
 517 =head2 around
 518
 519  around foo => sub { ... };
 520
 521 See L<< Class::Method::Modifiers/around method(s) => sub { ... } >> for full
 522 documentation.
 523
 524 Note that since you are not required to use method modifiers,
 525 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 526 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 527 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 528
 529 =head2 after
 530
 531  after foo => sub { ... };
 532
 533 See L<< Class::Method::Modifiers/after method(s) => sub { ... } >> for full
 534 documentation.
 535
 536 Note that since you are not required to use method modifiers,
 537 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 538 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 539 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 540
 541 =head1 SUBROUTINES
 542
 543 =head2 does_role
 544
 545  if (Role::Tiny::does_role($foo, 'Some::Role')) {
 546    ...
 547  }
 548
 549 Returns true if class has been composed with role.
 550
 551 This subroutine is also installed as ->does on any class a Role::Tiny is
 552 composed into unless that class already has an ->does method, so
 553
 554   if ($foo->does('Some::Role')) {
 555     ...
 556   }
 557
 558 will work for classes but to test a role, one must use ::does_role directly.
 559
 560 Additionally, Role::Tiny will override the standard Perl C<DOES> method
 561 for your class. However, if C<any> class in your class' inheritance
 562 hierarchy provides C<DOES>, then Role::Tiny will not override it.
 563
 564 =head1 METHODS
 565
 566 =head2 apply_roles_to_package
 567
 568  Role::Tiny->apply_roles_to_package(
 569    'Some::Package', 'Some::Role', 'Some::Other::Role'
 570  );
 571
 572 Composes role with package.  See also L<Role::Tiny::With>.
 573
 574 =head2 apply_roles_to_object
 575
 576  Role::Tiny->apply_roles_to_object($foo, qw(Some::Role1 Some::Role2));
 577
 578 Composes roles in order into object directly.  Object is reblessed into the
 579 resulting class.
 580
 581 =head2 create_class_with_roles
 582
 583  Role::Tiny->create_class_with_roles('Some::Base', qw(Some::Role1 Some::Role2));
 584
 585 Creates a new class based on base, with the roles composed into it in order.
 586 New class is returned.
 587
 588 =head2 is_role
 589
 590  Role::Tiny->is_role('Some::Role1')
 591
 592 Returns true if the given package is a role.
 593
 594 =head1 SEE ALSO
 595
 596 L<Role::Tiny> is the attribute-less subset of L<Moo::Role>; L<Moo::Role> is
 597 a meta-protocol-less subset of the king of role systems, L<Moose::Role>.
 598
 599 If you don't want method modifiers and do want to be forcibly restricted
 600 to a single role application per class, Ovid's L<Role::Basic> exists. But
 601 Stevan Little (the L<Moose> author) and I don't find the additional
 602 restrictions to be amazingly helpful in most cases; L<Role::Basic>'s choices
 603 are more a guide to what you should prefer doing, to our mind, rather than
 604 something that needs to be enforced.
 605
 606 =head1 AUTHOR
 607
 608 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 609
 610 =head1 CONTRIBUTORS
 611
 612 dg - David Leadbeater (cpan:DGL) <dgl@dgl.cx>
 613
 614 frew - Arthur Axel "fREW" Schmidt (cpan:FREW) <frioux@gmail.com>
 615
 616 hobbs - Andrew Rodland (cpan:ARODLAND) <arodland@cpan.org>
 617
 618 jnap - John Napiorkowski (cpan:JJNAPIORK) <jjn1056@yahoo.com>
 619
 620 ribasushi - Peter Rabbitson (cpan:RIBASUSHI) <ribasushi@cpan.org>
 621
 622 chip - Chip Salzenberg (cpan:CHIPS) <chip@pobox.com>
 623
 624 ajgb - Alex J. G. Burzyński (cpan:AJGB) <ajgb@cpan.org>
 625
 626 doy - Jesse Luehrs (cpan:DOY) <doy at tozt dot net>
 627
 628 perigrin - Chris Prather (cpan:PERIGRIN) <chris@prather.org>
 629
 630 Mithaldu - Christian Walde (cpan:MITHALDU) <walde.christian@googlemail.com>
 631
 632 ilmari - Dagfinn Ilmari Mannsåker (cpan:ILMARI) <ilmari@ilmari.org>
 633
 634 tobyink - Toby Inkster (cpan:TOBYINK) <tobyink@cpan.org>
 635
 636 =head1 COPYRIGHT
 637
 638 Copyright (c) 2010-2012 the Role::Tiny L</AUTHOR> and L</CONTRIBUTORS>
 639 as listed above.
 640
 641 =head1 LICENSE
 642
 643 This library is free software and may be distributed under the same terms
 644 as perl itself.
 645
 646 =cut