lib/Reaction/UI/ViewPort/Role/Actions.pm

   1 package Reaction::UI::ViewPort::Role::Actions;
   2
   3 use Reaction::Role;
   4 use Reaction::UI::ViewPort::URI;
   5
   6 use namespace::clean -except => [ qw(meta) ];
   7
   8 has actions => (
   9   is => 'ro',
  10   isa => 'ArrayRef',
  11   lazy_build => 1
  12 );
  13
  14 has action_order => (
  15   is => 'ro',
  16   isa => 'ArrayRef'
  17 );
  18
  19 has action_filter => (
  20   isa => 'CodeRef', is => 'ro',
  21   required => '1', lazy => '1',
  22   default => sub {
  23       my $self = shift;
  24       sub { return [keys %{ $self->action_prototypes }] }
  25   }
  26 );
  27
  28 has action_prototypes => (
  29   is => 'ro',
  30   isa => 'HashRef',
  31   required => 1,
  32   default => sub{ {} }
  33 );
  34
  35 has computed_action_order => (
  36   is => 'ro',
  37   isa => 'ArrayRef',
  38   lazy_build => 1
  39 );
  40
  41 sub _build_computed_action_order {
  42   my $self = shift;
  43   my $ordered = $self->sort_by_spec(
  44     ($self->has_action_order ? $self->action_order : []),
  45     [ keys %{ $self->action_prototypes } ]
  46   );
  47   return $self->action_filter->($ordered, $self->model);
  48 }
  49
  50 sub _build_actions {
  51   my ($self) = @_;
  52   my (@act, $i);
  53   my $ctx = $self->ctx;
  54   my $loc = $self->location;
  55   my $target = $self->model;
  56
  57   foreach my $proto_name ( @{ $self->computed_action_order } ) {
  58     my $proto = $self->action_prototypes->{$proto_name};
  59     my $uri = $proto->{uri} or confess('uri is required in prototype action');
  60     my $label = exists $proto->{label} ? $proto->{label} : $proto_name;
  61     my $layout = exists $proto->{layout} ? $proto->{layout} : 'uri';
  62
  63     my $action = Reaction::UI::ViewPort::URI->new(
  64       location => join ('-', $loc, 'action', $i++),
  65       uri => ( ref($uri) eq 'CODE' ? $uri->($target, $ctx) : $uri ),
  66       display => ( ref($label) eq 'CODE' ? $label->($target, $ctx) : $label ),
  67       layout => ( ref($layout) eq 'CODE' ? $layout->($target, $ctx) : $layout ),
  68     );
  69     push(@act, $action);
  70   }
  71   return \@act;
  72 }
  73
  74 1;
  75
  76 __END__;
  77
  78 =head1 NAME
  79
  80 Reaction::UI::ViewPort::Role::Actions
  81
  82 =head1 DESCRIPTION
  83
  84 A role to ease attaching actions to L<Reaction::InterfaceModel::Object>s
  85
  86 =head1 ATTRIBUTES
  87
  88 =head2 actions
  89
  90 Read-only, lazy-building ArrayRef of URI objects pointing to actions.
  91
  92 =head2 action_prototypes
  93
  94 A HashRef of prototypes for building the Action links. The prototypes should be
  95 composed like these:
  96
  97     my %action_prototypes = (
  98       example_action => { label => 'Example Action', uri => $uri_obj },
  99     );
 100
 101     #or you can get fancy and do something like what is below:
 102     sub make_label{
 103       my($im, $ctx) =  @_; #InterfaceModel::Object/Collection, Catalyst Context
 104       return 'label_text';
 105     }
 106     sub make_uri{
 107       my($im, $ctx) =  @_; #InterfaceModel::Object/Collection, Catalyst Context
 108       return return $ctx->uri_for('some_action');
 109     }
 110     my %action_prototypes = (
 111       example_action => { label => \&make_label, uri => \&make_uri },
 112     );
 113
 114 =head2 action_order
 115
 116 User-provided ArrayRef with how the actions should be ordered eg
 117
 118      action_order => [qw/view edit delete/]
 119
 120 =head2 computed_action_order
 121
 122 Read-only lazy-building ARRAY ref. The final computed action order. This may
 123 differ from the C<action_order> provided if you any actions were not included
 124 in that list.
 125
 126 =head1 METHODS
 127
 128 =head2 _build_actions
 129
 130 Cycle through the C<computed_action_order> and create a new
 131 L<ViewPort::URI|Reaction::UI::ViewPort::URI> object for each action using the
 132 provided prototypes.
 133
 134 =head2 _build_computed_action_order
 135
 136 Compute the final action ordering by using the provided C<action_order> as a
 137 spec to order all the present actions (the keys of C<action_prototypes>)
 138
 139 =head1 ACTION PROTOTYPES
 140
 141 Action prototypes are simply hashrefs that must contain a C<uri> key and may
 142 contain a C<label> key. The label can be anything that the display attribute of
 143 L<ViewPort::URI|Reaction::UI::ViewPort::URI> will accept, usually a scalar or a
 144 ViewPort. The value for C<uri> may be either a scalar, a L<URI> object (or
 145 anything that C<ISA URI>).
 146
 147 Additionally, both C<label> and C<uri> can be CODE refs. In this case, the code
 148 will be executed at C<_build_actions> time and will recieve two arguments, the
 149 value returned by C<model> and the value returned by C<ctx> in that order. Both
 150 of these methods should be implemented in the consuming class. By convention,
 151 model refers to the target of the action, an C<InterfaceModel::Object> in the
 152 case of a member action and an C<InterfaceModel::Collection> in the case of a
 153 Collection action. C<ctx> should be the current Catalyst context.
 154
 155 =head1 AUTHORS
 156
 157 See L<Reaction::Class> for authors.
 158
 159 =head1 LICENSE
 160
 161 See L<Reaction::Class> for the license.
 162
 163 =cut