lib/Reaction/UI/ViewPort/Field.pm

   1 package Reaction::UI::ViewPort::Field;
   2
   3 use Reaction::Class;
   4 use aliased 'Reaction::InterfaceModel::Object';
   5 use aliased 'Reaction::Meta::InterfaceModel::Object::ParameterAttribute';
   6
   7 use namespace::clean -except => [ qw(meta) ];
   8 extends 'Reaction::UI::ViewPort';
   9
  10 has value        => (is => 'rw', lazy_build => 1);
  11 has name         => (is => 'rw', isa => 'Str', lazy_build => 1);
  12 has label        => (is => 'rw', isa => 'Str', lazy_build => 1);
  13 has value_string => (is => 'rw', isa => 'Str', lazy_build => 1);
  14
  15 has model     => (is => 'ro', isa => Object,             required => 1);
  16 has attribute => (is => 'ro', isa => ParameterAttribute, required => 1);
  17
  18 sub _build_name { shift->attribute->name };
  19
  20 sub _build_label {
  21   join(' ', map { ucfirst } split('_', shift->name));
  22 }
  23
  24 sub _build_value {
  25   my ($self) = @_;
  26   my $reader = $self->attribute->get_read_method;
  27   return $self->model->$reader;
  28 }
  29
  30 sub _model_has_value {
  31   my ($self) = @_;
  32   my $predicate = $self->attribute->get_predicate_method;
  33
  34   if (!$predicate || $self->model->$predicate
  35       # || ($self->attribute->is_lazy
  36       #    && !$self->attribute->is_lazy_fail)
  37     ) {
  38     # edenc -- uncommented the lazy checks above
  39     # model->$predicate returns false if the value isn't set
  40     # but has a lazy builder
  41
  42     # either model attribute has a value now or can build it
  43     return 1;
  44   }
  45   return 0;
  46 }
  47
  48 sub _build_value_string {
  49   my ($self) = @_;
  50   # XXX need the defined test because the IM lazy builds from
  51   # the model and DBIC can have nullable fields and DBIC doesn't
  52   # have a way to tell us that doesn't force value inflation (extra
  53   # SELECTs for belongs_to) so basically we're screwed.
  54   return ($self->_model_has_value && defined($self->_build_value)
  55             ? $self->_value_string_from_value
  56             : $self->_empty_string_value);
  57 }
  58
  59 sub _value_string_from_value {
  60   shift->value;
  61 }
  62
  63 sub _empty_string_value { '' }
  64
  65 sub value_is_required {
  66   my $self = shift;
  67   $self->model->attribute_is_required($self->attribute);
  68 }
  69
  70 __PACKAGE__->meta->make_immutable;
  71
  72
  73 1;
  74 __END__;
  75
  76 =head1 NAME
  77
  78 Reaction::UI::ViewPort::Field
  79
  80 =head1 DESCRIPTION
  81
  82 =head1 ATTRIBUTES
  83
  84 =head2 model
  85
  86 =head2 attribute
  87
  88 =head2 value
  89
  90 =head2 name
  91
  92 =head2 label
  93
  94 =head2 value_string
  95
  96 =head1 AUTHORS
  97
  98 See L<Reaction::Class> for authors.
  99
 100 =head1 LICENSE
 101
 102 See L<Reaction::Class> for the license.
 103
 104 =cut