lib/Reaction/UI/ViewPort/Field/Role/Mutable.pm

   1 package Reaction::UI::ViewPort::Field::Role::Mutable;
   2
   3 use Reaction::Role;
   4
   5 use aliased 'Reaction::InterfaceModel::Action';
   6 use aliased 'Reaction::Meta::InterfaceModel::Action::ParameterAttribute';
   7
   8 use namespace::clean -except => [ qw(meta) ];
   9
  10 has model     => (is => 'ro', isa => Action, required => 1);
  11 has attribute => (is => 'ro', isa => ParameterAttribute, required => 1);
  12
  13 has value      => (
  14   is => 'rw', lazy_build => 1, trigger_adopt('value'),
  15   clearer => 'clear_value',
  16 );
  17 has needs_sync => (is => 'rw', isa => 'Int', default => 0);
  18 #predicates are autmagically generated for lazy and non-required attrs
  19 has message => (is => 'rw', isa => 'Str', clearer => 'clear_message');
  20
  21 after clear_value => sub {
  22   my $self = shift;
  23   $self->clear_message if $self->has_message;
  24   $self->needs_sync(1);
  25 };
  26 sub adopt_value {
  27   my ($self) = @_;
  28   $self->clear_message if $self->has_message;
  29   $self->needs_sync(1); # if $self->has_attribute;
  30 };
  31 sub can_sync_to_action {
  32   my $self = shift;
  33   return 1 unless $self->needs_sync;
  34   my $attr = $self->attribute;
  35
  36   if ($self->has_value) {
  37     my $value = $self->value;
  38     if (my $tc = $attr->type_constraint) {
  39       $value = $tc->coercion->coerce($value) if ($tc->has_coercion);
  40       if (defined (my $error = $tc->validate($value))) {
  41         $self->message($error);
  42         return;
  43       }
  44     }
  45   } else {
  46     return if $attr->is_required;
  47   }
  48   return 1;
  49 };
  50 sub sync_to_action {
  51   my ($self) = @_;
  52   return unless $self->can_sync_to_action;
  53
  54   my $attr = $self->attribute;
  55
  56   if ($self->has_value) {
  57     my $value = $self->value;
  58     if (my $tc = $attr->type_constraint) {
  59       #this will go away when we have moose dbic. until then though...
  60       $value = $tc->coercion->coerce($value) if ($tc->has_coercion);
  61     }
  62     my $writer = $attr->get_write_method;
  63     confess "No writer for attribute" unless defined($writer);
  64     $self->model->$writer($value);
  65   } else {
  66     my $predicate = $attr->get_predicate_method;
  67     confess "No predicate for attribute" unless defined($predicate);
  68     if ($self->model->$predicate) {
  69       my $clearer = $attr->get_clearer_method;
  70       confess "${predicate} returned true but no clearer for attribute"
  71         unless defined($clearer);
  72       $self->model->$clearer;
  73     }
  74   }
  75   $self->needs_sync(0);
  76 };
  77 sub sync_from_action {
  78   my ($self) = @_;
  79   return unless !$self->needs_sync; # && $self->has_attribute;
  80   if( !$self->has_message ){
  81     if(my $error = $self->model->error_for($self->attribute) ){
  82       $self->message( $error );
  83     }
  84   }
  85 };
  86
  87 around accept_events => sub { ('value', shift->(@_)) };
  88
  89
  90
  91 1;
  92
  93 =head1 NAME
  94
  95 Reaction::UI::ViewPort::Role::Actions
  96
  97 =head1 DESCRIPTION
  98
  99 A role to ease attaching actions to L<Reaction::InterfaceModel::Object>s
 100
 101 =head1 ATTRIBUTES
 102
 103 =head2 needs_sync
 104
 105 =head2 message
 106
 107 =head2 model
 108
 109 =head2 attribute
 110
 111 =head2 value
 112
 113 =head1 METHODS
 114
 115 =head2 accept_events
 116
 117 =head2 sync_from_action
 118
 119 =head2 sync_to_action
 120
 121 =head2 adopt_value
 122
 123 =head1 AUTHORS
 124
 125 See L<Reaction::Class> for authors.
 126
 127 =head1 LICENSE
 128
 129 See L<Reaction::Class> for the license.
 130
 131 =cut