lib/Reaction/UI/ViewPort/Action.pm

   1 package Reaction::UI::ViewPort::Action;
   2
   3 use Reaction::Class;
   4
   5 use MooseX::Types::URI qw/Uri/;
   6 use MooseX::Types::Moose qw/Int Str/;
   7 use MooseX::Types::Common::String qw/NonEmptySimpleStr/;
   8
   9 use namespace::clean -except => [ qw(meta) ];
  10
  11 extends 'Reaction::UI::ViewPort::Object::Mutable';
  12 with 'Reaction::UI::ViewPort::Action::Role::OK';
  13
  14 has message => (is => 'rw', isa => Str);
  15 has '+model' => (handles => [qw/error_message has_error_message/]);
  16
  17 #this has to fucking go. it BLOWS.
  18 has method => (
  19   is => 'rw',
  20   isa => NonEmptySimpleStr,
  21   default => sub { 'post' }
  22 );
  23
  24 has action => ( is => 'rw', isa => Uri );
  25
  26 has changed => (
  27   is => 'rw',
  28   isa => Int,
  29   reader => 'is_changed',
  30   default => sub{0}
  31 );
  32
  33 sub can_apply {
  34   my ($self) = @_;
  35   foreach my $field ( @{ $self->fields } ) {
  36     return 0 if $field->needs_sync;
  37     # if e.g. a datetime field has an invalid value that can't be re-assembled
  38     # into a datetime object, the action may be in a consistent state but
  39     # not synchronized from the fields; in this case, we must not apply
  40   }
  41   return $self->model->can_apply;
  42 }
  43
  44 sub do_apply {
  45   shift->model->do_apply;
  46 }
  47
  48 after apply_child_events => sub {
  49   # interrupt here because fields will have been updated
  50   my ($self) = @_;
  51   $self->sync_action_from_fields;
  52 };
  53
  54 sub sync_action_from_fields {
  55   my ($self) = @_;
  56   foreach my $field (@{$self->fields}) {
  57     $field->sync_to_action; # get the field to populate the $action if possible
  58   }
  59   $self->model->sync_all;
  60   foreach my $field (@{$self->fields}) {
  61     $field->sync_from_action; # get errors from $action if applicable
  62   }
  63 }
  64
  65 after handle_events => sub {
  66   my ($self, $events) = @_;
  67   foreach my $event ($self->accept_events) {
  68     unless (exists $events->{$event} ) {
  69       # for <input type="image"... buttons
  70       if ( exists $events->{"${event}.x"} && exists $events->{"${event}.y"} ) {
  71         $self->_dump_event($event, $events->{$event}) if DEBUG_EVENTS;
  72         $self->$event($events->{$event});
  73       }
  74     }
  75   }
  76 };
  77
  78 __PACKAGE__->meta->make_immutable;
  79
  80 1;
  81
  82 __END__;
  83
  84 =head1 NAME
  85
  86 Reaction::UI::ViewPort::Action - Provide user with a form with OK, Apply and Close.
  87
  88 =head1 SYNOPSIS
  89
  90   $controller->push_viewport('Reaction::UI::ViewPort::Action',
  91     model           => $interface_model_action,
  92     field_order     => [qw( firstname lastname )],
  93     excluded_fields => [qw( password )],
  94   );
  95
  96 =head1 DESCRIPTION
  97
  98 This subclass of L<Reaction::UI::ViewPort::Object::Mutable> is used for
  99 rendering a complete form supporting Apply, Close and OK.
 100
 101 =head1 ATTRIBUTES
 102
 103 =head2 message
 104
 105 =head2 model
 106
 107 Inherited from L<Reaction::UI::ViewPort::Object::Mutable>. Must be a
 108 L<Reaction::InterfaceModel::Action>.
 109
 110 Also handles C<error_message> and C<has_error_message> methods.
 111
 112 =head2 method
 113
 114 post / get
 115
 116 =head2 changed
 117
 118 Returns true if a field has been edited.
 119
 120 =head1 METHODS
 121
 122 =head2 can_apply
 123
 124 Returns true if no field C<needs_sync> and the L</model> C<can_apply>.
 125
 126 =head2 do_apply
 127
 128 Delegates to C<do_apply> on the L</model>, which is a
 129 L<Reaction::InterfaceModel::Action>.
 130
 131 =head2 sync_action_from_fields
 132
 133 Firstly calls C<sync_to_action> on every L<Reaction::UI::ViewPort::Field::Mutable>
 134 in L<fields|Reaction::UI::ViewPort::Object/fields>. Then it calls C<sync_all> on
 135 the L<Reaction::InterfaceModel::Action> in L</model>. Next it will call
 136 C<sync_from_action> on every field to repopulate them from the L</model>.
 137
 138 =head1 SUBCLASSING
 139
 140   package MyApp::UI::ViewPort::Action;
 141   use Reaction::Class;
 142   use MooseX::Types::Moose qw( Int );
 143
 144   use namespace::clean -except => 'meta';
 145
 146   extends 'Reaction::UI::ViewPort::Action';
 147
 148   has render_timestamp => (
 149     is       => 'ro',
 150     isa      => Int,
 151     default  => sub { time },
 152     required => 1,
 153   );
 154
 155   has '+field_order' => (default => sub {[qw( firstname lastname )]});
 156
 157   1;
 158
 159 =head1 SEE ALSO
 160
 161 L<Reaction::UI::ViewPort>
 162
 163 L<Reaction::UI::ViewPort::Object>
 164
 165 L<Reaction::UI::ViewPort::Object::Mutable>
 166
 167 L<Reaction::InterfaceModel::Action::Role::Apply>
 168
 169 L<Reaction::InterfaceModel::Action::Role::Close>
 170
 171 L<Reaction::InterfaceModel::Action::Role::OK>
 172
 173 =head1 AUTHORS
 174
 175 See L<Reaction::Class> for authors.
 176
 177 =head1 LICENSE
 178
 179 See L<Reaction::Class> for the license.
 180
 181 =cut
 182