lib/Pod/Text.pm

   1 # Pod::Text -- Convert POD data to formatted ASCII text.
   2 # $Id: Text.pm,v 2.6 2000/10/10 02:13:17 eagle Exp $
   3 #
   4 # Copyright 1999, 2000 by Russ Allbery <rra@stanford.edu>
   5 #
   6 # This program is free software; you can redistribute it and/or modify it
   7 # under the same terms as Perl itself.
   8 #
   9 # This module is intended to be a replacement for Pod::Text, and attempts to
  10 # match its output except for some specific circumstances where other
  11 # decisions seemed to produce better output.  It uses Pod::Parser and is
  12 # designed to be very easy to subclass.
  13
  14 ############################################################################
  15 # Modules and declarations
  16 ############################################################################
  17
  18 package Pod::Text;
  19
  20 require 5.004;
  21
  22 use Carp qw(carp croak);
  23 use Exporter ();
  24 use Pod::Select ();
  25
  26 use strict;
  27 use vars qw(@ISA @EXPORT %ESCAPES $VERSION);
  28
  29 # We inherit from Pod::Select instead of Pod::Parser so that we can be used
  30 # by Pod::Usage.
  31 @ISA = qw(Pod::Select Exporter);
  32
  33 # We have to export pod2text for backward compatibility.
  34 @EXPORT = qw(pod2text);
  35
  36 # Don't use the CVS revision as the version, since this module is also in
  37 # Perl core and too many things could munge CVS magic revision strings.
  38 # This number should ideally be the same as the CVS revision in podlators,
  39 # however.
  40 $VERSION = 2.06;
  41
  42
  43 ############################################################################
  44 # Table of supported E<> escapes
  45 ############################################################################
  46
  47 # This table is taken near verbatim from Pod::PlainText in Pod::Parser,
  48 # which got it near verbatim from the original Pod::Text.  It is therefore
  49 # credited to Tom Christiansen, and I'm glad I didn't have to write it.  :)
  50 # "iexcl" to "divide" added by Tim Jenness.
  51 %ESCAPES = (
  52     'amp'       =>    '&',      # ampersand
  53     'lt'        =>    '<',      # left chevron, less-than
  54     'gt'        =>    '>',      # right chevron, greater-than
  55     'quot'      =>    '"',      # double quote
  56     'sol'       =>    '/',      # solidus (forward slash)
  57     'verbar'    =>    '|',      # vertical bar
  58
  59     "Aacute"    =>    "\xC1",   # capital A, acute accent
  60     "aacute"    =>    "\xE1",   # small a, acute accent
  61     "Acirc"     =>    "\xC2",   # capital A, circumflex accent
  62     "acirc"     =>    "\xE2",   # small a, circumflex accent
  63     "AElig"     =>    "\xC6",   # capital AE diphthong (ligature)
  64     "aelig"     =>    "\xE6",   # small ae diphthong (ligature)
  65     "Agrave"    =>    "\xC0",   # capital A, grave accent
  66     "agrave"    =>    "\xE0",   # small a, grave accent
  67     "Aring"     =>    "\xC5",   # capital A, ring
  68     "aring"     =>    "\xE5",   # small a, ring
  69     "Atilde"    =>    "\xC3",   # capital A, tilde
  70     "atilde"    =>    "\xE3",   # small a, tilde
  71     "Auml"      =>    "\xC4",   # capital A, dieresis or umlaut mark
  72     "auml"      =>    "\xE4",   # small a, dieresis or umlaut mark
  73     "Ccedil"    =>    "\xC7",   # capital C, cedilla
  74     "ccedil"    =>    "\xE7",   # small c, cedilla
  75     "Eacute"    =>    "\xC9",   # capital E, acute accent
  76     "eacute"    =>    "\xE9",   # small e, acute accent
  77     "Ecirc"     =>    "\xCA",   # capital E, circumflex accent
  78     "ecirc"     =>    "\xEA",   # small e, circumflex accent
  79     "Egrave"    =>    "\xC8",   # capital E, grave accent
  80     "egrave"    =>    "\xE8",   # small e, grave accent
  81     "ETH"       =>    "\xD0",   # capital Eth, Icelandic
  82     "eth"       =>    "\xF0",   # small eth, Icelandic
  83     "Euml"      =>    "\xCB",   # capital E, dieresis or umlaut mark
  84     "euml"      =>    "\xEB",   # small e, dieresis or umlaut mark
  85     "Iacute"    =>    "\xCC",   # capital I, acute accent
  86     "iacute"    =>    "\xEC",   # small i, acute accent
  87     "Icirc"     =>    "\xCE",   # capital I, circumflex accent
  88     "icirc"     =>    "\xEE",   # small i, circumflex accent
  89     "Igrave"    =>    "\xCD",   # capital I, grave accent
  90     "igrave"    =>    "\xED",   # small i, grave accent
  91     "Iuml"      =>    "\xCF",   # capital I, dieresis or umlaut mark
  92     "iuml"      =>    "\xEF",   # small i, dieresis or umlaut mark
  93     "Ntilde"    =>    "\xD1",   # capital N, tilde
  94     "ntilde"    =>    "\xF1",   # small n, tilde
  95     "Oacute"    =>    "\xD3",   # capital O, acute accent
  96     "oacute"    =>    "\xF3",   # small o, acute accent
  97     "Ocirc"     =>    "\xD4",   # capital O, circumflex accent
  98     "ocirc"     =>    "\xF4",   # small o, circumflex accent
  99     "Ograve"    =>    "\xD2",   # capital O, grave accent
 100     "ograve"    =>    "\xF2",   # small o, grave accent
 101     "Oslash"    =>    "\xD8",   # capital O, slash
 102     "oslash"    =>    "\xF8",   # small o, slash
 103     "Otilde"    =>    "\xD5",   # capital O, tilde
 104     "otilde"    =>    "\xF5",   # small o, tilde
 105     "Ouml"      =>    "\xD6",   # capital O, dieresis or umlaut mark
 106     "ouml"      =>    "\xF6",   # small o, dieresis or umlaut mark
 107     "szlig"     =>    "\xDF",   # small sharp s, German (sz ligature)
 108     "THORN"     =>    "\xDE",   # capital THORN, Icelandic
 109     "thorn"     =>    "\xFE",   # small thorn, Icelandic
 110     "Uacute"    =>    "\xDA",   # capital U, acute accent
 111     "uacute"    =>    "\xFA",   # small u, acute accent
 112     "Ucirc"     =>    "\xDB",   # capital U, circumflex accent
 113     "ucirc"     =>    "\xFB",   # small u, circumflex accent
 114     "Ugrave"    =>    "\xD9",   # capital U, grave accent
 115     "ugrave"    =>    "\xF9",   # small u, grave accent
 116     "Uuml"      =>    "\xDC",   # capital U, dieresis or umlaut mark
 117     "uuml"      =>    "\xFC",   # small u, dieresis or umlaut mark
 118     "Yacute"    =>    "\xDD",   # capital Y, acute accent
 119     "yacute"    =>    "\xFD",   # small y, acute accent
 120     "yuml"      =>    "\xFF",   # small y, dieresis or umlaut mark
 121
 122     "laquo"     =>    "\xAB",   # left pointing double angle quotation mark
 123     "lchevron"  =>    "\xAB",   #  synonym (backwards compatibility)
 124     "raquo"     =>    "\xBB",   # right pointing double angle quotation mark
 125     "rchevron"  =>    "\xBB",   #  synonym (backwards compatibility)
 126
 127     "iexcl"     =>    "\xA1",   # inverted exclamation mark
 128     "cent"      =>    "\xA2",   # cent sign
 129     "pound"     =>    "\xA3",   # (UK) pound sign
 130     "curren"    =>    "\xA4",   # currency sign
 131     "yen"       =>    "\xA5",   # yen sign
 132     "brvbar"    =>    "\xA6",   # broken vertical bar
 133     "sect"      =>    "\xA7",   # section sign
 134     "uml"       =>    "\xA8",   # diaresis
 135     "copy"      =>    "\xA9",   # Copyright symbol
 136     "ordf"      =>    "\xAA",   # feminine ordinal indicator
 137     "not"       =>    "\xAC",   # not sign
 138     "shy"       =>    "\xAD",   # soft hyphen
 139     "reg"       =>    "\xAE",   # registered trademark
 140     "macr"      =>    "\xAF",   # macron, overline
 141     "deg"       =>    "\xB0",   # degree sign
 142     "plusmn"    =>    "\xB1",   # plus-minus sign
 143     "sup2"      =>    "\xB2",   # superscript 2
 144     "sup3"      =>    "\xB3",   # superscript 3
 145     "acute"     =>    "\xB4",   # acute accent
 146     "micro"     =>    "\xB5",   # micro sign
 147     "para"      =>    "\xB6",   # pilcrow sign = paragraph sign
 148     "middot"    =>    "\xB7",   # middle dot = Georgian comma
 149     "cedil"     =>    "\xB8",   # cedilla
 150     "sup1"      =>    "\xB9",   # superscript 1
 151     "ordm"      =>    "\xBA",   # masculine ordinal indicator
 152     "frac14"    =>    "\xBC",   # vulgar fraction one quarter
 153     "frac12"    =>    "\xBD",   # vulgar fraction one half
 154     "frac34"    =>    "\xBE",   # vulgar fraction three quarters
 155     "iquest"    =>    "\xBF",   # inverted question mark
 156     "times"     =>    "\xD7",   # multiplication sign
 157     "divide"    =>    "\xF7",   # division sign
 158 );
 159
 160
 161 ############################################################################
 162 # Initialization
 163 ############################################################################
 164
 165 # Initialize the object.  Must be sure to call our parent initializer.
 166 sub initialize {
 167     my $self = shift;
 168
 169     $$self{alt}      = 0  unless defined $$self{alt};
 170     $$self{indent}   = 4  unless defined $$self{indent};
 171     $$self{loose}    = 0  unless defined $$self{loose};
 172     $$self{sentence} = 0  unless defined $$self{sentence};
 173     $$self{width}    = 76 unless defined $$self{width};
 174
 175     # Figure out what quotes we'll be using for C<> text.
 176     $$self{quotes} ||= "'";
 177     if ($$self{quotes} eq 'none') {
 178         $$self{LQUOTE} = $$self{RQUOTE} = '';
 179     } elsif (length ($$self{quotes}) == 1) {
 180         $$self{LQUOTE} = $$self{RQUOTE} = $$self{quotes};
 181     } elsif ($$self{quotes} =~ /^(.)(.)$/
 182              || $$self{quotes} =~ /^(..)(..)$/) {
 183         $$self{LQUOTE} = $1;
 184         $$self{RQUOTE} = $2;
 185     } else {
 186         croak qq(Invalid quote specification "$$self{quotes}");
 187     }
 188
 189     $$self{INDENTS}  = [];              # Stack of indentations.
 190     $$self{MARGIN}   = $$self{indent};  # Current left margin in spaces.
 191
 192     $self->SUPER::initialize;
 193 }
 194
 195
 196 ############################################################################
 197 # Core overrides
 198 ############################################################################
 199
 200 # Called for each command paragraph.  Gets the command, the associated
 201 # paragraph, the line number, and a Pod::Paragraph object.  Just dispatches
 202 # the command to a method named the same as the command.  =cut is handled
 203 # internally by Pod::Parser.
 204 sub command {
 205     my $self = shift;
 206     my $command = shift;
 207     return if $command eq 'pod';
 208     return if ($$self{EXCLUDE} && $command ne 'end');
 209     $self->item ("\n") if defined $$self{ITEM};
 210     if ($self->can ('cmd_' . $command)) {
 211         $command = 'cmd_' . $command;
 212         $self->$command (@_);
 213     } else {
 214         my ($text, $line, $paragraph) = @_;
 215         my $file;
 216         ($file, $line) = $paragraph->file_line;
 217         $text =~ s/\n+\z//;
 218         $text = " $text" if ($text =~ /^\S/);
 219         warn qq($file:$line: Unknown command paragraph "=$command$text"\n);
 220         return;
 221     }
 222 }
 223
 224 # Called for a verbatim paragraph.  Gets the paragraph, the line number, and
 225 # a Pod::Paragraph object.  Just output it verbatim, but with tabs converted
 226 # to spaces.
 227 sub verbatim {
 228     my $self = shift;
 229     return if $$self{EXCLUDE};
 230     $self->item if defined $$self{ITEM};
 231     local $_ = shift;
 232     return if /^\s*$/;
 233     s/^(\s*\S+)/(' ' x $$self{MARGIN}) . $1/gme;
 234     $self->output ($_);
 235 }
 236
 237 # Called for a regular text block.  Gets the paragraph, the line number, and
 238 # a Pod::Paragraph object.  Perform interpolation and output the results.
 239 sub textblock {
 240     my $self = shift;
 241     return if $$self{EXCLUDE};
 242     $self->output ($_[0]), return if $$self{VERBATIM};
 243     local $_ = shift;
 244     my $line = shift;
 245
 246     # Perform a little magic to collapse multiple L<> references.  This is
 247     # here mostly for backwards-compatibility.  We'll just rewrite the whole
 248     # thing into actual text at this part, bypassing the whole internal
 249     # sequence parsing thing.
 250     s{
 251         (
 252           L<                    # A link of the form L</something>.
 253               /
 254               (
 255                   [:\w]+        # The item has to be a simple word...
 256                   (\(\))?       # ...or simple function.
 257               )
 258           >
 259           (
 260               ,?\s+(and\s+)?    # Allow lots of them, conjuncted.
 261               L<
 262                   /
 263                   (
 264                       [:\w]+
 265                       (\(\))?
 266                   )
 267               >
 268           )+
 269         )
 270     } {
 271         local $_ = $1;
 272         s%L</([^>]+)>%$1%g;
 273         my @items = split /(?:,?\s+(?:and\s+)?)/;
 274         my $string = "the ";
 275         my $i;
 276         for ($i = 0; $i < @items; $i++) {
 277             $string .= $items[$i];
 278             $string .= ", " if @items > 2 && $i != $#items;
 279             $string .= " and " if ($i == $#items - 1);
 280         }
 281         $string .= " entries elsewhere in this document";
 282         $string;
 283     }gex;
 284
 285     # Now actually interpolate and output the paragraph.
 286     $_ = $self->interpolate ($_, $line);
 287     s/\s+$/\n/;
 288     if (defined $$self{ITEM}) {
 289         $self->item ($_ . "\n");
 290     } else {
 291         $self->output ($self->reformat ($_ . "\n"));
 292     }
 293 }
 294
 295 # Called for an interior sequence.  Gets the command, argument, and a
 296 # Pod::InteriorSequence object and is expected to return the resulting text.
 297 # Calls code, bold, italic, file, and link to handle those types of
 298 # sequences, and handles S<>, E<>, X<>, and Z<> directly.
 299 sub interior_sequence {
 300     my $self = shift;
 301     my $command = shift;
 302     local $_ = shift;
 303     return '' if ($command eq 'X' || $command eq 'Z');
 304
 305     # Expand escapes into the actual character now, carping if invalid.
 306     if ($command eq 'E') {
 307         if (/^\d+$/) {
 308             return chr;
 309         } else {
 310             return $ESCAPES{$_} if defined $ESCAPES{$_};
 311             carp "Unknown escape: E<$_>";
 312             return "E<$_>";
 313         }
 314     }
 315
 316     # For all the other sequences, empty content produces no output.
 317     return if $_ eq '';
 318
 319     # For S<>, compress all internal whitespace and then map spaces to \01.
 320     # When we output the text, we'll map this back.
 321     if ($command eq 'S') {
 322         s/\s{2,}/ /g;
 323         tr/ /\01/;
 324         return $_;
 325     }
 326
 327     # Anything else needs to get dispatched to another method.
 328     if    ($command eq 'B') { return $self->seq_b ($_) }
 329     elsif ($command eq 'C') { return $self->seq_c ($_) }
 330     elsif ($command eq 'F') { return $self->seq_f ($_) }
 331     elsif ($command eq 'I') { return $self->seq_i ($_) }
 332     elsif ($command eq 'L') { return $self->seq_l ($_) }
 333     else { carp "Unknown sequence $command<$_>" }
 334 }
 335
 336 # Called for each paragraph that's actually part of the POD.  We take
 337 # advantage of this opportunity to untabify the input.
 338 sub preprocess_paragraph {
 339     my $self = shift;
 340     local $_ = shift;
 341     1 while s/^(.*?)(\t+)/$1 . ' ' x (length ($2) * 8 - length ($1) % 8)/me;
 342     $_;
 343 }
 344
 345
 346 ############################################################################
 347 # Command paragraphs
 348 ############################################################################
 349
 350 # All command paragraphs take the paragraph and the line number.
 351
 352 # First level heading.
 353 sub cmd_head1 {
 354     my $self = shift;
 355     local $_ = shift;
 356     s/\s+$//;
 357     $_ = $self->interpolate ($_, shift);
 358     if ($$self{alt}) {
 359         $self->output ("\n==== $_ ====\n\n");
 360     } else {
 361         $_ .= "\n" if $$self{loose};
 362         $self->output ($_ . "\n");
 363     }
 364 }
 365
 366 # Second level heading.
 367 sub cmd_head2 {
 368     my $self = shift;
 369     local $_ = shift;
 370     s/\s+$//;
 371     $_ = $self->interpolate ($_, shift);
 372     if ($$self{alt}) {
 373         $self->output ("\n==   $_   ==\n\n");
 374     } else {
 375         $self->output (' ' x ($$self{indent} / 2) . $_ . "\n\n");
 376     }
 377 }
 378
 379 # Start a list.
 380 sub cmd_over {
 381     my $self = shift;
 382     local $_ = shift;
 383     unless (/^[-+]?\d+\s+$/) { $_ = $$self{indent} }
 384     push (@{ $$self{INDENTS} }, $$self{MARGIN});
 385     $$self{MARGIN} += ($_ + 0);
 386 }
 387
 388 # End a list.
 389 sub cmd_back {
 390     my $self = shift;
 391     $$self{MARGIN} = pop @{ $$self{INDENTS} };
 392     unless (defined $$self{MARGIN}) {
 393         carp "Unmatched =back";
 394         $$self{MARGIN} = $$self{indent};
 395     }
 396 }
 397
 398 # An individual list item.
 399 sub cmd_item {
 400     my $self = shift;
 401     if (defined $$self{ITEM}) { $self->item }
 402     local $_ = shift;
 403     s/\s+$//;
 404     $$self{ITEM} = $self->interpolate ($_);
 405 }
 406
 407 # Begin a block for a particular translator.  Setting VERBATIM triggers
 408 # special handling in textblock().
 409 sub cmd_begin {
 410     my $self = shift;
 411     local $_ = shift;
 412     my ($kind) = /^(\S+)/ or return;
 413     if ($kind eq 'text') {
 414         $$self{VERBATIM} = 1;
 415     } else {
 416         $$self{EXCLUDE} = 1;
 417     }
 418 }
 419
 420 # End a block for a particular translator.  We assume that all =begin/=end
 421 # pairs are properly closed.
 422 sub cmd_end {
 423     my $self = shift;
 424     $$self{EXCLUDE} = 0;
 425     $$self{VERBATIM} = 0;
 426 }
 427
 428 # One paragraph for a particular translator.  Ignore it unless it's intended
 429 # for text, in which case we treat it as a verbatim text block.
 430 sub cmd_for {
 431     my $self = shift;
 432     local $_ = shift;
 433     my $line = shift;
 434     return unless s/^text\b[ \t]*\n?//;
 435     $self->verbatim ($_, $line);
 436 }
 437
 438
 439 ############################################################################
 440 # Interior sequences
 441 ############################################################################
 442
 443 # The simple formatting ones.  These are here mostly so that subclasses can
 444 # override them and do more complicated things.
 445 sub seq_b { return $_[0]{alt} ? "``$_[1]''" : $_[1] }
 446 sub seq_f { return $_[0]{alt} ? "\"$_[1]\"" : $_[1] }
 447 sub seq_i { return '*' . $_[1] . '*' }
 448 sub seq_c {
 449     return $_[0]{alt} ? "``$_[1]''" : "$_[0]{LQUOTE}$_[1]$_[0]{RQUOTE}"
 450 }
 451
 452 # The complicated one.  Handle links.  Since this is plain text, we can't
 453 # actually make any real links, so this is all to figure out what text we
 454 # print out.
 455 sub seq_l {
 456     my $self = shift;
 457     local $_ = shift;
 458
 459     # Smash whitespace in case we were split across multiple lines.
 460     s/\s+/ /g;
 461
 462     # If we were given any explicit text, just output it.
 463     if (/^([^|]+)\|/) { return $1 }
 464
 465     # Okay, leading and trailing whitespace isn't important; get rid of it.
 466     s/^\s+//;
 467     s/\s+$//;
 468
 469     # Default to using the whole content of the link entry as a section
 470     # name.  Note that L<manpage/> forces a manpage interpretation, as does
 471     # something looking like L<manpage(section)>.  The latter is an
 472     # enhancement over the original Pod::Text.
 473     my ($manpage, $section) = ('', $_);
 474     if (/^"\s*(.*?)\s*"$/) {
 475         $section = '"' . $1 . '"';
 476     } elsif (m/^[-:.\w]+(?:\(\S+\))?$/) {
 477         ($manpage, $section) = ($_, '');
 478     } elsif (m%/%) {
 479         ($manpage, $section) = split (/\s*\/\s*/, $_, 2);
 480     }
 481
 482     # Now build the actual output text.
 483     my $text = '';
 484     if (!length $section) {
 485         $text = "the $manpage manpage" if length $manpage;
 486     } elsif ($section =~ /^[:\w]+(?:\(\))?/) {
 487         $text .= 'the ' . $section . ' entry';
 488         $text .= (length $manpage) ? " in the $manpage manpage"
 489                                    : " elsewhere in this document";
 490     } else {
 491         $section =~ s/^\"\s*//;
 492         $section =~ s/\s*\"$//;
 493         $text .= 'the section on "' . $section . '"';
 494         $text .= " in the $manpage manpage" if length $manpage;
 495     }
 496     $text;
 497 }
 498
 499
 500 ############################################################################
 501 # List handling
 502 ############################################################################
 503
 504 # This method is called whenever an =item command is complete (in other
 505 # words, we've seen its associated paragraph or know for certain that it
 506 # doesn't have one).  It gets the paragraph associated with the item as an
 507 # argument.  If that argument is empty, just output the item tag; if it
 508 # contains a newline, output the item tag followed by the newline.
 509 # Otherwise, see if there's enough room for us to output the item tag in the
 510 # margin of the text or if we have to put it on a separate line.
 511 sub item {
 512     my $self = shift;
 513     local $_ = shift;
 514     my $tag = $$self{ITEM};
 515     unless (defined $tag) {
 516         carp "item called without tag";
 517         return;
 518     }
 519     undef $$self{ITEM};
 520     my $indent = $$self{INDENTS}[-1];
 521     unless (defined $indent) { $indent = $$self{indent} }
 522     my $space = ' ' x $indent;
 523     $space =~ s/^ /:/ if $$self{alt};
 524     if (!$_ || /^\s+$/ || ($$self{MARGIN} - $indent < length ($tag) + 1)) {
 525         my $margin = $$self{MARGIN};
 526         $$self{MARGIN} = $indent;
 527         my $output = $self->reformat ($tag);
 528         $output =~ s/\n*$/\n/;
 529         $self->output ($output);
 530         $$self{MARGIN} = $margin;
 531         $self->output ($self->reformat ($_)) if /\S/;
 532     } else {
 533         $_ = $self->reformat ($_);
 534         s/^ /:/ if ($$self{alt} && $indent > 0);
 535         my $tagspace = ' ' x length $tag;
 536         s/^($space)$tagspace/$1$tag/ or warn "Bizarre space in item";
 537         $self->output ($_);
 538     }
 539 }
 540
 541
 542 ############################################################################
 543 # Output formatting
 544 ############################################################################
 545
 546 # Wrap a line, indenting by the current left margin.  We can't use
 547 # Text::Wrap because it plays games with tabs.  We can't use formline, even
 548 # though we'd really like to, because it screws up non-printing characters.
 549 # So we have to do the wrapping ourselves.
 550 sub wrap {
 551     my $self = shift;
 552     local $_ = shift;
 553     my $output = '';
 554     my $spaces = ' ' x $$self{MARGIN};
 555     my $width = $$self{width} - $$self{MARGIN};
 556     while (length > $width) {
 557         if (s/^([^\n]{0,$width})\s+// || s/^([^\n]{$width})//) {
 558             $output .= $spaces . $1 . "\n";
 559         } else {
 560             last;
 561         }
 562     }
 563     $output .= $spaces . $_;
 564     $output =~ s/\s+$/\n\n/;
 565     $output;
 566 }
 567
 568 # Reformat a paragraph of text for the current margin.  Takes the text to
 569 # reformat and returns the formatted text.
 570 sub reformat {
 571     my $self = shift;
 572     local $_ = shift;
 573
 574     # If we're trying to preserve two spaces after sentences, do some
 575     # munging to support that.  Otherwise, smash all repeated whitespace.
 576     if ($$self{sentence}) {
 577         s/ +$//mg;
 578         s/\.\n/. \n/g;
 579         s/\n/ /g;
 580         s/   +/  /g;
 581     } else {
 582         s/\s+/ /g;
 583     }
 584     $self->wrap ($_);
 585 }
 586
 587 # Output text to the output device.
 588 sub output { $_[1] =~ tr/\01/ /; print { $_[0]->output_handle } $_[1] }
 589
 590
 591 ############################################################################
 592 # Backwards compatibility
 593 ############################################################################
 594
 595 # The old Pod::Text module did everything in a pod2text() function.  This
 596 # tries to provide the same interface for legacy applications.
 597 sub pod2text {
 598     my @args;
 599
 600     # This is really ugly; I hate doing option parsing in the middle of a
 601     # module.  But the old Pod::Text module supported passing flags to its
 602     # entry function, so handle -a and -<number>.
 603     while ($_[0] =~ /^-/) {
 604         my $flag = shift;
 605         if    ($flag eq '-a')       { push (@args, alt => 1)    }
 606         elsif ($flag =~ /^-(\d+)$/) { push (@args, width => $1) }
 607         else {
 608             unshift (@_, $flag);
 609             last;
 610         }
 611     }
 612
 613     # Now that we know what arguments we're using, create the parser.
 614     my $parser = Pod::Text->new (@args);
 615
 616     # If two arguments were given, the second argument is going to be a file
 617     # handle.  That means we want to call parse_from_filehandle(), which
 618     # means we need to turn the first argument into a file handle.  Magic
 619     # open will handle the <&STDIN case automagically.
 620     if (defined $_[1]) {
 621         my @fhs = @_;
 622         local *IN;
 623         unless (open (IN, $fhs[0])) {
 624             croak ("Can't open $fhs[0] for reading: $!\n");
 625             return;
 626         }
 627         $fhs[0] = \*IN;
 628         return $parser->parse_from_filehandle (@fhs);
 629     } else {
 630         return $parser->parse_from_file (@_);
 631     }
 632 }
 633
 634
 635 ############################################################################
 636 # Module return value and documentation
 637 ############################################################################
 638
 639 1;
 640 __END__
 641
 642 =head1 NAME
 643
 644 Pod::Text - Convert POD data to formatted ASCII text
 645
 646 =head1 SYNOPSIS
 647
 648     use Pod::Text;
 649     my $parser = Pod::Text->new (sentence => 0, width => 78);
 650
 651     # Read POD from STDIN and write to STDOUT.
 652     $parser->parse_from_filehandle;
 653
 654     # Read POD from file.pod and write to file.txt.
 655     $parser->parse_from_file ('file.pod', 'file.txt');
 656
 657 =head1 DESCRIPTION
 658
 659 Pod::Text is a module that can convert documentation in the POD format (the
 660 preferred language for documenting Perl) into formatted ASCII.  It uses no
 661 special formatting controls or codes whatsoever, and its output is therefore
 662 suitable for nearly any device.
 663
 664 As a derived class from Pod::Parser, Pod::Text supports the same methods and
 665 interfaces.  See L<Pod::Parser> for all the details; briefly, one creates a
 666 new parser with C<Pod::Text-E<gt>new()> and then calls either
 667 parse_from_filehandle() or parse_from_file().
 668
 669 new() can take options, in the form of key/value pairs, that control the
 670 behavior of the parser.  The currently recognized options are:
 671
 672 =over 4
 673
 674 =item alt
 675
 676 If set to a true value, selects an alternate output format that, among other
 677 things, uses a different heading style and marks C<=item> entries with a
 678 colon in the left margin.  Defaults to false.
 679
 680 =item indent
 681
 682 The number of spaces to indent regular text, and the default indentation for
 683 C<=over> blocks.  Defaults to 4.
 684
 685 =item loose
 686
 687 If set to a true value, a blank line is printed after a C<=head1> heading.
 688 If set to false (the default), no blank line is printed after C<=head1>,
 689 although one is still printed after C<=head2>.  This is the default because
 690 it's the expected formatting for manual pages; if you're formatting
 691 arbitrary text documents, setting this to true may result in more pleasing
 692 output.
 693
 694 =item quotes
 695
 696 Sets the quote marks used to surround CE<lt>> text.  If the value is a
 697 single character, it is used as both the left and right quote; if it is two
 698 characters, the first character is used as the left quote and the second as
 699 the right quoted; and if it is four characters, the first two are used as
 700 the left quote and the second two as the right quote.
 701
 702 This may also be set to the special value C<none>, in which case no quote
 703 marks are added around CE<lt>> text.
 704
 705 =item sentence
 706
 707 If set to a true value, Pod::Text will assume that each sentence ends in two
 708 spaces, and will try to preserve that spacing.  If set to false, all
 709 consecutive whitespace in non-verbatim paragraphs is compressed into a
 710 single space.  Defaults to true.
 711
 712 =item width
 713
 714 The column at which to wrap text on the right-hand side.  Defaults to 76.
 715
 716 =back
 717
 718 The standard Pod::Parser method parse_from_filehandle() takes up to two
 719 arguments, the first being the file handle to read POD from and the second
 720 being the file handle to write the formatted output to.  The first defaults
 721 to STDIN if not given, and the second defaults to STDOUT.  The method
 722 parse_from_file() is almost identical, except that its two arguments are the
 723 input and output disk files instead.  See L<Pod::Parser> for the specific
 724 details.
 725
 726 =head1 DIAGNOSTICS
 727
 728 =over 4
 729
 730 =item Bizarre space in item
 731
 732 (W) Something has gone wrong in internal C<=item> processing.  This message
 733 indicates a bug in Pod::Text; you should never see it.
 734
 735 =item Can't open %s for reading: %s
 736
 737 (F) Pod::Text was invoked via the compatibility mode pod2text() interface
 738 and the input file it was given could not be opened.
 739
 740 =item Invalid quote specification "%s"
 741
 742 (F) The quote specification given (the quotes option to the constructor) was
 743 invalid.  A quote specification must be one, two, or four characters long.
 744
 745 =item %s:%d: Unknown command paragraph "%s".
 746
 747 (W) The POD source contained a non-standard command paragraph (something of
 748 the form C<=command args>) that Pod::Man didn't know about.  It was ignored.
 749
 750 =item Unknown escape: %s
 751
 752 (W) The POD source contained an C<EE<lt>E<gt>> escape that Pod::Text didn't
 753 know about.
 754
 755 =item Unknown sequence: %s
 756
 757 (W) The POD source contained a non-standard internal sequence (something of
 758 the form C<XE<lt>E<gt>>) that Pod::Text didn't know about.
 759
 760 =item Unmatched =back
 761
 762 (W) Pod::Text encountered a C<=back> command that didn't correspond to an
 763 C<=over> command.
 764
 765 =back
 766
 767 =head1 RESTRICTIONS
 768
 769 Embedded Ctrl-As (octal 001) in the input will be mapped to spaces on
 770 output, due to an internal implementation detail.
 771
 772 =head1 NOTES
 773
 774 This is a replacement for an earlier Pod::Text module written by Tom
 775 Christiansen.  It has a revamped interface, since it now uses Pod::Parser,
 776 but an interface roughly compatible with the old Pod::Text::pod2text()
 777 function is still available.  Please change to the new calling convention,
 778 though.
 779
 780 The original Pod::Text contained code to do formatting via termcap
 781 sequences, although it wasn't turned on by default and it was problematic to
 782 get it to work at all.  This rewrite doesn't even try to do that, but a
 783 subclass of it does.  Look for L<Pod::Text::Termcap|Pod::Text::Termcap>.
 784
 785 =head1 SEE ALSO
 786
 787 L<Pod::Parser|Pod::Parser>, L<Pod::Text::Termcap|Pod::Text::Termcap>,
 788 pod2text(1)
 789
 790 =head1 AUTHOR
 791
 792 Russ Allbery E<lt>rra@stanford.eduE<gt>, based I<very> heavily on the
 793 original Pod::Text by Tom Christiansen E<lt>tchrist@mox.perl.comE<gt> and
 794 its conversion to Pod::Parser by Brad Appleton
 795 E<lt>bradapp@enteract.comE<gt>.
 796
 797 =cut