lib/Pod/Text/Termcap.pm

   1 # Pod::Text::Termcap -- Convert POD data to ASCII text with format escapes.
   2 # $Id: Termcap.pm,v 2.3 2006-01-25 23:56:54 eagle Exp $
   3 #
   4 # Copyright 1999, 2001, 2002, 2004, 2006 by Russ Allbery <rra@stanford.edu>
   5 #
   6 # This program is free software; you may redistribute it and/or modify it
   7 # under the same terms as Perl itself.
   8 #
   9 # This is a simple subclass of Pod::Text that overrides a few key methods to
  10 # output the right termcap escape sequences for formatted text on the current
  11 # terminal type.
  12
  13 ##############################################################################
  14 # Modules and declarations
  15 ##############################################################################
  16
  17 package Pod::Text::Termcap;
  18
  19 require 5.004;
  20
  21 use Pod::Text ();
  22 use POSIX ();
  23 use Term::Cap;
  24
  25 use strict;
  26 use vars qw(@ISA $VERSION);
  27
  28 @ISA = qw(Pod::Text);
  29
  30 # Don't use the CVS revision as the version, since this module is also in Perl
  31 # core and too many things could munge CVS magic revision strings.  This
  32 # number should ideally be the same as the CVS revision in podlators, however.
  33 $VERSION = 2.03;
  34
  35 ##############################################################################
  36 # Overrides
  37 ##############################################################################
  38
  39 # In the initialization method, grab our terminal characteristics as well as
  40 # do all the stuff we normally do.
  41 sub new {
  42     my ($self, @args) = @_;
  43     my ($ospeed, $term, $termios);
  44     $self = $self->SUPER::new (@args);
  45
  46     # $ENV{HOME} is usually not set on Windows.  The default Term::Cap path
  47     # may not work on Solaris.
  48     my $home = exists $ENV{HOME} ? "$ENV{HOME}/.termcap:" : '';
  49     $ENV{TERMPATH} = $home . '/etc/termcap:/usr/share/misc/termcap'
  50                            . ':/usr/share/lib/termcap';
  51
  52     # Fall back on a hard-coded terminal speed if POSIX::Termios isn't
  53     # available (such as on VMS).
  54     eval { $termios = POSIX::Termios->new };
  55     if ($@) {
  56         $ospeed = 9600;
  57     } else {
  58         $termios->getattr;
  59         $ospeed = $termios->getospeed || 9600;
  60     }
  61
  62     # Fall back on the ANSI escape sequences if Term::Cap doesn't work.
  63     eval { $term = Tgetent Term::Cap { TERM => undef, OSPEED => $ospeed } };
  64     $$self{BOLD} = $$term{_md} || "\e[1m";
  65     $$self{UNDL} = $$term{_us} || "\e[4m";
  66     $$self{NORM} = $$term{_me} || "\e[m";
  67
  68     unless (defined $$self{width}) {
  69         $$self{opt_width} = $ENV{COLUMNS} || $$term{_co} || 80;
  70         $$self{opt_width} -= 2;
  71     }
  72
  73     return $self;
  74 }
  75
  76 # Make level one headings bold.
  77 sub cmd_head1 {
  78     my ($self, $attrs, $text) = @_;
  79     $text =~ s/\s+$//;
  80     $self->SUPER::cmd_head1 ($attrs, "$$self{BOLD}$text$$self{NORM}");
  81 }
  82
  83 # Make level two headings bold.
  84 sub cmd_head2 {
  85     my ($self, $attrs, $text) = @_;
  86     $text =~ s/\s+$//;
  87     $self->SUPER::cmd_head2 ($attrs, "$$self{BOLD}$text$$self{NORM}");
  88 }
  89
  90 # Fix up B<> and I<>.  Note that we intentionally don't do F<>.
  91 sub cmd_b { my $self = shift; return "$$self{BOLD}$_[1]$$self{NORM}" }
  92 sub cmd_i { my $self = shift; return "$$self{UNDL}$_[1]$$self{NORM}" }
  93
  94 # Output any included code in bold.
  95 sub output_code {
  96     my ($self, $code) = @_;
  97     $self->output ($$self{BOLD} . $code . $$self{NORM});
  98 }
  99
 100 # Override the wrapping code to igore the special sequences.
 101 sub wrap {
 102     my $self = shift;
 103     local $_ = shift;
 104     my $output = '';
 105     my $spaces = ' ' x $$self{MARGIN};
 106     my $width = $$self{opt_width} - $$self{MARGIN};
 107
 108     # $codes matches a single special sequence.  $char matches any number of
 109     # special sequences preceeding a single character other than a newline.
 110     # We have to do $shortchar and $longchar in variables because the
 111     # construct ${char}{0,$width} didn't do the right thing until Perl 5.8.x.
 112     my $codes = "(?:\Q$$self{BOLD}\E|\Q$$self{UNDL}\E|\Q$$self{NORM}\E)";
 113     my $char = "(?:$codes*[^\\n])";
 114     my $shortchar = $char . "{0,$width}";
 115     my $longchar = $char . "{$width}";
 116     while (length > $width) {
 117         if (s/^($shortchar)\s+// || s/^($longchar)//) {
 118             $output .= $spaces . $1 . "\n";
 119         } else {
 120             last;
 121         }
 122     }
 123     $output .= $spaces . $_;
 124     $output =~ s/\s+$/\n\n/;
 125     return $output;
 126 }
 127
 128 ##############################################################################
 129 # Module return value and documentation
 130 ##############################################################################
 131
 132 1;
 133 __END__
 134
 135 =head1 NAME
 136
 137 Pod::Text::Termcap - Convert POD data to ASCII text with format escapes
 138
 139 =head1 SYNOPSIS
 140
 141     use Pod::Text::Termcap;
 142     my $parser = Pod::Text::Termcap->new (sentence => 0, width => 78);
 143
 144     # Read POD from STDIN and write to STDOUT.
 145     $parser->parse_from_filehandle;
 146
 147     # Read POD from file.pod and write to file.txt.
 148     $parser->parse_from_file ('file.pod', 'file.txt');
 149
 150 =head1 DESCRIPTION
 151
 152 Pod::Text::Termcap is a simple subclass of Pod::Text that highlights output
 153 text using the correct termcap escape sequences for the current terminal.
 154 Apart from the format codes, it in all ways functions like Pod::Text.  See
 155 L<Pod::Text> for details and available options.
 156
 157 =head1 NOTES
 158
 159 This module uses Term::Cap to retrieve the formatting escape sequences for
 160 the current terminal, and falls back on the ECMA-48 (the same in this
 161 regard as ANSI X3.64 and ISO 6429, the escape codes also used by DEC VT100
 162 terminals) if the bold, underline, and reset codes aren't set in the
 163 termcap information.
 164
 165 =head1 SEE ALSO
 166
 167 L<Pod::Text>, L<Pod::Simple>, L<Term::Cap>
 168
 169 The current version of this module is always available from its web site at
 170 L<http://www.eyrie.org/~eagle/software/podlators/>.  It is also part of the
 171 Perl core distribution as of 5.6.0.
 172
 173 =head1 AUTHOR
 174
 175 Russ Allbery <rra@stanford.edu>.
 176
 177 =head1 COPYRIGHT AND LICENSE
 178
 179 Copyright 1999, 2001, 2002, 2004, 2006 by Russ Allbery <rra@stanford.edu>.
 180
 181 This program is free software; you may redistribute it and/or modify it
 182 under the same terms as Perl itself.
 183
 184 =cut