lib/Pod/Text/Color.pm

   1 # Pod::Text::Color -- Convert POD data to formatted color ASCII text
   2 #
   3 # Copyright 1999, 2001, 2004, 2006 by Russ Allbery <rra@stanford.edu>
   4 #
   5 # This program is free software; you may redistribute it and/or modify it
   6 # under the same terms as Perl itself.
   7 #
   8 # This is just a basic proof of concept.  It should later be modified to make
   9 # better use of color, take options changing what colors are used for what
  10 # text, and the like.
  11
  12 ##############################################################################
  13 # Modules and declarations
  14 ##############################################################################
  15
  16 package Pod::Text::Color;
  17
  18 require 5.004;
  19
  20 use Pod::Text ();
  21 use Term::ANSIColor qw(colored);
  22
  23 use strict;
  24 use vars qw(@ISA $VERSION);
  25
  26 @ISA = qw(Pod::Text);
  27
  28 # Don't use the CVS revision as the version, since this module is also in Perl
  29 # core and too many things could munge CVS magic revision strings.  This
  30 # number should ideally be the same as the CVS revision in podlators, however.
  31 $VERSION = 2.03;
  32
  33 ##############################################################################
  34 # Overrides
  35 ##############################################################################
  36
  37 # Make level one headings bold.
  38 sub cmd_head1 {
  39     my ($self, $attrs, $text) = @_;
  40     $text =~ s/\s+$//;
  41     $self->SUPER::cmd_head1 ($attrs, colored ($text, 'bold'));
  42 }
  43
  44 # Make level two headings bold.
  45 sub cmd_head2 {
  46     my ($self, $attrs, $text) = @_;
  47     $text =~ s/\s+$//;
  48     $self->SUPER::cmd_head2 ($attrs, colored ($text, 'bold'));
  49 }
  50
  51 # Fix the various formatting codes.
  52 sub cmd_b { return colored ($_[2], 'bold')   }
  53 sub cmd_f { return colored ($_[2], 'cyan')   }
  54 sub cmd_i { return colored ($_[2], 'yellow') }
  55
  56 # Output any included code in green.
  57 sub output_code {
  58     my ($self, $code) = @_;
  59     $code = colored ($code, 'green');
  60     $self->output ($code);
  61 }
  62
  63 # We unfortunately have to override the wrapping code here, since the normal
  64 # wrapping code gets really confused by all the escape sequences.
  65 sub wrap {
  66     my $self = shift;
  67     local $_ = shift;
  68     my $output = '';
  69     my $spaces = ' ' x $$self{MARGIN};
  70     my $width = $$self{opt_width} - $$self{MARGIN};
  71
  72     # We have to do $shortchar and $longchar in variables because the
  73     # construct ${char}{0,$width} didn't do the right thing until Perl 5.8.x.
  74     my $char = '(?:(?:\e\[[\d;]+m)*[^\n])';
  75     my $shortchar = $char . "{0,$width}";
  76     my $longchar = $char . "{$width}";
  77     while (length > $width) {
  78         if (s/^($shortchar)\s+// || s/^($longchar)//) {
  79             $output .= $spaces . $1 . "\n";
  80         } else {
  81             last;
  82         }
  83     }
  84     $output .= $spaces . $_;
  85     $output =~ s/\s+$/\n\n/;
  86     $output;
  87 }
  88
  89 ##############################################################################
  90 # Module return value and documentation
  91 ##############################################################################
  92
  93 1;
  94 __END__
  95
  96 =head1 NAME
  97
  98 Pod::Text::Color - Convert POD data to formatted color ASCII text
  99
 100 =head1 SYNOPSIS
 101
 102     use Pod::Text::Color;
 103     my $parser = Pod::Text::Color->new (sentence => 0, width => 78);
 104
 105     # Read POD from STDIN and write to STDOUT.
 106     $parser->parse_from_filehandle;
 107
 108     # Read POD from file.pod and write to file.txt.
 109     $parser->parse_from_file ('file.pod', 'file.txt');
 110
 111 =head1 DESCRIPTION
 112
 113 Pod::Text::Color is a simple subclass of Pod::Text that highlights output
 114 text using ANSI color escape sequences.  Apart from the color, it in all
 115 ways functions like Pod::Text.  See L<Pod::Text> for details and available
 116 options.
 117
 118 Term::ANSIColor is used to get colors and therefore must be installed to use
 119 this module.
 120
 121 =head1 BUGS
 122
 123 This is just a basic proof of concept.  It should be seriously expanded to
 124 support configurable coloration via options passed to the constructor, and
 125 B<pod2text> should be taught about those.
 126
 127 =head1 SEE ALSO
 128
 129 L<Pod::Text>, L<Pod::Simple>
 130
 131 The current version of this module is always available from its web site at
 132 L<http://www.eyrie.org/~eagle/software/podlators/>.  It is also part of the
 133 Perl core distribution as of 5.6.0.
 134
 135 =head1 AUTHOR
 136
 137 Russ Allbery <rra@stanford.edu>.
 138
 139 =head1 COPYRIGHT AND LICENSE
 140
 141 Copyright 1999, 2001, 2004, 2006 by Russ Allbery <rra@stanford.edu>.
 142
 143 This program is free software; you may redistribute it and/or modify it
 144 under the same terms as Perl itself.
 145
 146 =cut