lib/Pod/Text/Color.pm

   1 # Pod::Text::Color -- Convert POD data to formatted color ASCII text
   2 # $Id: Color.pm,v 2.1 2004/12/31 21:50:00 eagle Exp $
   3 #
   4 # Copyright 1999, 2001, 2004 by Russ Allbery <rra@stanford.edu>
   5 #
   6 # This program is free software; you may redistribute it and/or modify it
   7 # under the same terms as Perl itself.
   8 #
   9 # This is just a basic proof of concept.  It should later be modified to make
  10 # better use of color, take options changing what colors are used for what
  11 # text, and the like.
  12
  13 ##############################################################################
  14 # Modules and declarations
  15 ##############################################################################
  16
  17 package Pod::Text::Color;
  18
  19 require 5.004;
  20
  21 use Pod::Text ();
  22 use Term::ANSIColor qw(colored);
  23
  24 use strict;
  25 use vars qw(@ISA $VERSION);
  26
  27 @ISA = qw(Pod::Text);
  28
  29 # Don't use the CVS revision as the version, since this module is also in Perl
  30 # core and too many things could munge CVS magic revision strings.  This
  31 # number should ideally be the same as the CVS revision in podlators, however.
  32 $VERSION = 2.01;
  33
  34 ##############################################################################
  35 # Overrides
  36 ##############################################################################
  37
  38 # Make level one headings bold.
  39 sub cmd_head1 {
  40     my ($self, $attrs, $text) = @_;
  41     $text =~ s/\s+$//;
  42     $self->SUPER::cmd_head1 ($attrs, colored ($text, 'bold'));
  43 }
  44
  45 # Make level two headings bold.
  46 sub cmd_head2 {
  47     my ($self, $attrs, $text) = @_;
  48     $text =~ s/\s+$//;
  49     $self->SUPER::cmd_head2 ($attrs, colored ($text, 'bold'));
  50 }
  51
  52 # Fix the various formatting codes.
  53 sub cmd_b { return colored ($_[2], 'bold')   }
  54 sub cmd_f { return colored ($_[2], 'cyan')   }
  55 sub cmd_i { return colored ($_[2], 'yellow') }
  56
  57 # Output any included code in green.
  58 sub output_code {
  59     my ($self, $code) = @_;
  60     $code = colored ($code, 'green');
  61     $self->output ($code);
  62 }
  63
  64 # We unfortunately have to override the wrapping code here, since the normal
  65 # wrapping code gets really confused by all the escape sequences.
  66 sub wrap {
  67     my $self = shift;
  68     local $_ = shift;
  69     my $output = '';
  70     my $spaces = ' ' x $$self{MARGIN};
  71     my $width = $$self{opt_width} - $$self{MARGIN};
  72     my $char = '(?:(?:\e\[[\d;]+m)*[^\n])';
  73     while (length > $width) {
  74         if (s/^(${char}{0,$width})\s+// || s/^(${char}{$width})//) {
  75             $output .= $spaces . $1 . "\n";
  76         } else {
  77             last;
  78         }
  79     }
  80     $output .= $spaces . $_;
  81     $output =~ s/\s+$/\n\n/;
  82     $output;
  83 }
  84
  85 ##############################################################################
  86 # Module return value and documentation
  87 ##############################################################################
  88
  89 1;
  90 __END__
  91
  92 =head1 NAME
  93
  94 Pod::Text::Color - Convert POD data to formatted color ASCII text
  95
  96 =head1 SYNOPSIS
  97
  98     use Pod::Text::Color;
  99     my $parser = Pod::Text::Color->new (sentence => 0, width => 78);
 100
 101     # Read POD from STDIN and write to STDOUT.
 102     $parser->parse_from_filehandle;
 103
 104     # Read POD from file.pod and write to file.txt.
 105     $parser->parse_from_file ('file.pod', 'file.txt');
 106
 107 =head1 DESCRIPTION
 108
 109 Pod::Text::Color is a simple subclass of Pod::Text that highlights output
 110 text using ANSI color escape sequences.  Apart from the color, it in all
 111 ways functions like Pod::Text.  See L<Pod::Text> for details and available
 112 options.
 113
 114 Term::ANSIColor is used to get colors and therefore must be installed to use
 115 this module.
 116
 117 =head1 BUGS
 118
 119 This is just a basic proof of concept.  It should be seriously expanded to
 120 support configurable coloration via options passed to the constructor, and
 121 B<pod2text> should be taught about those.
 122
 123 =head1 SEE ALSO
 124
 125 L<Pod::Text>, L<Pod::Simple>
 126
 127 The current version of this module is always available from its web site at
 128 L<http://www.eyrie.org/~eagle/software/podlators/>.  It is also part of the
 129 Perl core distribution as of 5.6.0.
 130
 131 =head1 AUTHOR
 132
 133 Russ Allbery <rra@stanford.edu>.
 134
 135 =head1 COPYRIGHT AND LICENSE
 136
 137 Copyright 1999, 2001, 2004 by Russ Allbery <rra@stanford.edu>.
 138
 139 This program is free software; you may redistribute it and/or modify it
 140 under the same terms as Perl itself.
 141
 142 =cut