lib/Pod/Man.pm

   1 # Pod::Man -- Convert POD data to formatted *roff input.
   2 # $Id: Man.pm,v 1.4 2000/04/26 04:03:41 eagle Exp $
   3 #
   4 # Copyright 1999, 2000 by Russ Allbery <rra@stanford.edu>
   5 #
   6 # This program is free software; you can redistribute it and/or modify it
   7 # under the same terms as Perl itself.
   8 #
   9 # This module is intended to be a replacement for the pod2man script
  10 # distributed with versions of Perl prior to 5.6, and attempts to match its
  11 # output except for some specific circumstances where other decisions seemed
  12 # to produce better output.  It uses Pod::Parser and is designed to be easy
  13 # to subclass.
  14 #
  15 # Perl core hackers, please note that this module is also separately
  16 # maintained outside of the Perl core as part of the podlators.  Please send
  17 # me any patches at the address above in addition to sending them to the
  18 # standard Perl mailing lists.
  19
  20 ############################################################################
  21 # Modules and declarations
  22 ############################################################################
  23
  24 package Pod::Man;
  25
  26 require 5.004;
  27
  28 use Carp qw(carp croak);
  29 use Pod::Parser ();
  30
  31 use strict;
  32 use subs qw(makespace);
  33 use vars qw(@ISA %ESCAPES $PREAMBLE $VERSION);
  34
  35 @ISA = qw(Pod::Parser);
  36
  37 # Don't use the CVS revision as the version, since this module is also in
  38 # Perl core and too many things could munge CVS magic revision strings.
  39 # This number should ideally be the same as the CVS revision in podlators,
  40 # however.
  41 $VERSION = 1.04;
  42
  43
  44 ############################################################################
  45 # Preamble and *roff output tables
  46 ############################################################################
  47
  48 # The following is the static preamble which starts all *roff output we
  49 # generate.  It's completely static except for the font to use as a
  50 # fixed-width font, which is designed by @CFONT@.  $PREAMBLE should
  51 # therefore be run through s/\@CFONT\@/<font>/g before output.
  52 $PREAMBLE = <<'----END OF PREAMBLE----';
  53 .de Sh \" Subsection heading
  54 .br
  55 .if t .Sp
  56 .ne 5
  57 .PP
  58 \fB\\$1\fR
  59 .PP
  60 ..
  61 .de Sp \" Vertical space (when we can't use .PP)
  62 .if t .sp .5v
  63 .if n .sp
  64 ..
  65 .de Ip \" List item
  66 .br
  67 .ie \\n(.$>=3 .ne \\$3
  68 .el .ne 3
  69 .IP "\\$1" \\$2
  70 ..
  71 .de Vb \" Begin verbatim text
  72 .ft @CFONT@
  73 .nf
  74 .ne \\$1
  75 ..
  76 .de Ve \" End verbatim text
  77 .ft R
  78
  79 .fi
  80 ..
  81 .\" Set up some character translations and predefined strings.  \*(-- will
  82 .\" give an unbreakable dash, \*(PI will give pi, \*(L" will give a left
  83 .\" double quote, and \*(R" will give a right double quote.  | will give a
  84 .\" real vertical bar.  \*(C+ will give a nicer C++.  Capital omega is used
  85 .\" to do unbreakable dashes and therefore won't be available.  \*(C` and
  86 .\" \*(C' expand to `' in nroff, nothing in troff, for use with C<>
  87 .tr \(*W-|\(bv\*(Tr
  88 .ds C+ C\v'-.1v'\h'-1p'\s-2+\h'-1p'+\s0\v'.1v'\h'-1p'
  89 .ie n \{\
  90 .    ds -- \(*W-
  91 .    ds PI pi
  92 .    if (\n(.H=4u)&(1m=24u) .ds -- \(*W\h'-12u'\(*W\h'-12u'-\" diablo 10 pitch
  93 .    if (\n(.H=4u)&(1m=20u) .ds -- \(*W\h'-12u'\(*W\h'-8u'-\"  diablo 12 pitch
  94 .    ds L" ""
  95 .    ds R" ""
  96 .    ds C` `
  97 .    ds C' '
  98 'br\}
  99 .el\{\
 100 .    ds -- \|\(em\|
 101 .    ds PI \(*p
 102 .    ds L" ``
 103 .    ds R" ''
 104 'br\}
 105 .\"
 106 .\" If the F register is turned on, we'll generate index entries on stderr
 107 .\" for titles (.TH), headers (.SH), subsections (.Sh), items (.Ip), and
 108 .\" index entries marked with X<> in POD.  Of course, you'll have to process
 109 .\" the output yourself in some meaningful fashion.
 110 .if \nF \{\
 111 .    de IX
 112 .    tm Index:\\$1\t\\n%\t"\\$2"
 113 ..
 114 .    nr % 0
 115 .    rr F
 116 .\}
 117 .\"
 118 .\" For nroff, turn off justification.  Always turn off hyphenation; it
 119 .\" makes way too many mistakes in technical documents.
 120 .hy 0
 121 .if n .na
 122 .\"
 123 .\" Accent mark definitions (@(#)ms.acc 1.5 88/02/08 SMI; from UCB 4.2).
 124 .\" Fear.  Run.  Save yourself.  No user-serviceable parts.
 125 .bd B 3
 126 .    \" fudge factors for nroff and troff
 127 .if n \{\
 128 .    ds #H 0
 129 .    ds #V .8m
 130 .    ds #F .3m
 131 .    ds #[ \f1
 132 .    ds #] \fP
 133 .\}
 134 .if t \{\
 135 .    ds #H ((1u-(\\\\n(.fu%2u))*.13m)
 136 .    ds #V .6m
 137 .    ds #F 0
 138 .    ds #[ \&
 139 .    ds #] \&
 140 .\}
 141 .    \" simple accents for nroff and troff
 142 .if n \{\
 143 .    ds ' \&
 144 .    ds ` \&
 145 .    ds ^ \&
 146 .    ds , \&
 147 .    ds ~ ~
 148 .    ds /
 149 .\}
 150 .if t \{\
 151 .    ds ' \\k:\h'-(\\n(.wu*8/10-\*(#H)'\'\h"|\\n:u"
 152 .    ds ` \\k:\h'-(\\n(.wu*8/10-\*(#H)'\`\h'|\\n:u'
 153 .    ds ^ \\k:\h'-(\\n(.wu*10/11-\*(#H)'^\h'|\\n:u'
 154 .    ds , \\k:\h'-(\\n(.wu*8/10)',\h'|\\n:u'
 155 .    ds ~ \\k:\h'-(\\n(.wu-\*(#H-.1m)'~\h'|\\n:u'
 156 .    ds / \\k:\h'-(\\n(.wu*8/10-\*(#H)'\z\(sl\h'|\\n:u'
 157 .\}
 158 .    \" troff and (daisy-wheel) nroff accents
 159 .ds : \\k:\h'-(\\n(.wu*8/10-\*(#H+.1m+\*(#F)'\v'-\*(#V'\z.\h'.2m+\*(#F'.\h'|\\n:u'\v'\*(#V'
 160 .ds 8 \h'\*(#H'\(*b\h'-\*(#H'
 161 .ds o \\k:\h'-(\\n(.wu+\w'\(de'u-\*(#H)/2u'\v'-.3n'\*(#[\z\(de\v'.3n'\h'|\\n:u'\*(#]
 162 .ds d- \h'\*(#H'\(pd\h'-\w'~'u'\v'-.25m'\f2\(hy\fP\v'.25m'\h'-\*(#H'
 163 .ds D- D\\k:\h'-\w'D'u'\v'-.11m'\z\(hy\v'.11m'\h'|\\n:u'
 164 .ds th \*(#[\v'.3m'\s+1I\s-1\v'-.3m'\h'-(\w'I'u*2/3)'\s-1o\s+1\*(#]
 165 .ds Th \*(#[\s+2I\s-2\h'-\w'I'u*3/5'\v'-.3m'o\v'.3m'\*(#]
 166 .ds ae a\h'-(\w'a'u*4/10)'e
 167 .ds Ae A\h'-(\w'A'u*4/10)'E
 168 .    \" corrections for vroff
 169 .if v .ds ~ \\k:\h'-(\\n(.wu*9/10-\*(#H)'\s-2\u~\d\s+2\h'|\\n:u'
 170 .if v .ds ^ \\k:\h'-(\\n(.wu*10/11-\*(#H)'\v'-.4m'^\v'.4m'\h'|\\n:u'
 171 .    \" for low resolution devices (crt and lpr)
 172 .if \n(.H>23 .if \n(.V>19 \
 173 \{\
 174 .    ds : e
 175 .    ds 8 ss
 176 .    ds o a
 177 .    ds d- d\h'-1'\(ga
 178 .    ds D- D\h'-1'\(hy
 179 .    ds th \o'bp'
 180 .    ds Th \o'LP'
 181 .    ds ae ae
 182 .    ds Ae AE
 183 .\}
 184 .rm #[ #] #H #V #F C
 185 ----END OF PREAMBLE----
 186
 187 # This table is taken nearly verbatim from Tom Christiansen's pod2man.  It
 188 # assumes that the standard preamble has already been printed, since that's
 189 # what defines all of the accent marks.  Note that some of these are quoted
 190 # with double quotes since they contain embedded single quotes, so use \\
 191 # uniformly for backslash for readability.
 192 %ESCAPES = (
 193     'amp'       =>    '&',      # ampersand
 194     'lt'        =>    '<',      # left chevron, less-than
 195     'gt'        =>    '>',      # right chevron, greater-than
 196     'quot'      =>    '"',      # double quote
 197     'sol'       =>    '/',      # solidus
 198     'verbar'    =>    '|',      # vertical bar
 199
 200     'Aacute'    =>    "A\\*'",  # capital A, acute accent
 201     'aacute'    =>    "a\\*'",  # small a, acute accent
 202     'Acirc'     =>    'A\\*^',  # capital A, circumflex accent
 203     'acirc'     =>    'a\\*^',  # small a, circumflex accent
 204     'AElig'     =>    '\*(AE',  # capital AE diphthong (ligature)
 205     'aelig'     =>    '\*(ae',  # small ae diphthong (ligature)
 206     'Agrave'    =>    "A\\*`",  # capital A, grave accent
 207     'agrave'    =>    "A\\*`",  # small a, grave accent
 208     'Aring'     =>    'A\\*o',  # capital A, ring
 209     'aring'     =>    'a\\*o',  # small a, ring
 210     'Atilde'    =>    'A\\*~',  # capital A, tilde
 211     'atilde'    =>    'a\\*~',  # small a, tilde
 212     'Auml'      =>    'A\\*:',  # capital A, dieresis or umlaut mark
 213     'auml'      =>    'a\\*:',  # small a, dieresis or umlaut mark
 214     'Ccedil'    =>    'C\\*,',  # capital C, cedilla
 215     'ccedil'    =>    'c\\*,',  # small c, cedilla
 216     'Eacute'    =>    "E\\*'",  # capital E, acute accent
 217     'eacute'    =>    "e\\*'",  # small e, acute accent
 218     'Ecirc'     =>    'E\\*^',  # capital E, circumflex accent
 219     'ecirc'     =>    'e\\*^',  # small e, circumflex accent
 220     'Egrave'    =>    'E\\*`',  # capital E, grave accent
 221     'egrave'    =>    'e\\*`',  # small e, grave accent
 222     'ETH'       =>    '\\*(D-', # capital Eth, Icelandic
 223     'eth'       =>    '\\*(d-', # small eth, Icelandic
 224     'Euml'      =>    'E\\*:',  # capital E, dieresis or umlaut mark
 225     'euml'      =>    'e\\*:',  # small e, dieresis or umlaut mark
 226     'Iacute'    =>    "I\\*'",  # capital I, acute accent
 227     'iacute'    =>    "i\\*'",  # small i, acute accent
 228     'Icirc'     =>    'I\\*^',  # capital I, circumflex accent
 229     'icirc'     =>    'i\\*^',  # small i, circumflex accent
 230     'Igrave'    =>    'I\\*`',  # capital I, grave accent
 231     'igrave'    =>    'i\\*`',  # small i, grave accent
 232     'Iuml'      =>    'I\\*:',  # capital I, dieresis or umlaut mark
 233     'iuml'      =>    'i\\*:',  # small i, dieresis or umlaut mark
 234     'Ntilde'    =>    'N\*~',   # capital N, tilde
 235     'ntilde'    =>    'n\*~',   # small n, tilde
 236     'Oacute'    =>    "O\\*'",  # capital O, acute accent
 237     'oacute'    =>    "o\\*'",  # small o, acute accent
 238     'Ocirc'     =>    'O\\*^',  # capital O, circumflex accent
 239     'ocirc'     =>    'o\\*^',  # small o, circumflex accent
 240     'Ograve'    =>    'O\\*`',  # capital O, grave accent
 241     'ograve'    =>    'o\\*`',  # small o, grave accent
 242     'Oslash'    =>    'O\\*/',  # capital O, slash
 243     'oslash'    =>    'o\\*/',  # small o, slash
 244     'Otilde'    =>    'O\\*~',  # capital O, tilde
 245     'otilde'    =>    'o\\*~',  # small o, tilde
 246     'Ouml'      =>    'O\\*:',  # capital O, dieresis or umlaut mark
 247     'ouml'      =>    'o\\*:',  # small o, dieresis or umlaut mark
 248     'szlig'     =>    '\*8',    # small sharp s, German (sz ligature)
 249     'THORN'     =>    '\\*(Th', # capital THORN, Icelandic
 250     'thorn'     =>    '\\*(th', # small thorn, Icelandic
 251     'Uacute'    =>    "U\\*'",  # capital U, acute accent
 252     'uacute'    =>    "u\\*'",  # small u, acute accent
 253     'Ucirc'     =>    'U\\*^',  # capital U, circumflex accent
 254     'ucirc'     =>    'u\\*^',  # small u, circumflex accent
 255     'Ugrave'    =>    'U\\*`',  # capital U, grave accent
 256     'ugrave'    =>    'u\\*`',  # small u, grave accent
 257     'Uuml'      =>    'U\\*:',  # capital U, dieresis or umlaut mark
 258     'uuml'      =>    'u\\*:',  # small u, dieresis or umlaut mark
 259     'Yacute'    =>    "Y\\*'",  # capital Y, acute accent
 260     'yacute'    =>    "y\\*'",  # small y, acute accent
 261     'yuml'      =>    'y\\*:',  # small y, dieresis or umlaut mark
 262 );
 263
 264
 265 ############################################################################
 266 # Static helper functions
 267 ############################################################################
 268
 269 # Protect leading quotes and periods against interpretation as commands.
 270 # Also protect anything starting with a backslash, since it could expand
 271 # or hide something that *roff would interpret as a command.  This is
 272 # overkill, but it's much simpler than trying to parse *roff here.
 273 sub protect {
 274     local $_ = shift;
 275     s/^([.\'\\])/\\&$1/mg;
 276     $_;
 277 }
 278
 279 # Given a command and a single argument that may or may not contain double
 280 # quotes, handle double-quote formatting for it.  If there are no double
 281 # quotes, just return the command followed by the argument in double quotes.
 282 # If there are double quotes, use an if statement to test for nroff, and for
 283 # nroff output the command followed by the argument in double quotes with
 284 # embedded double quotes doubled.  For other formatters, remap paired double
 285 # quotes to `` and ''.
 286 sub switchquotes {
 287     my $command = shift;
 288     local $_ = shift;
 289     my $extra = shift;
 290     s/\\\*\([LR]\"/\"/g;
 291     if (/\"/) {
 292         s/\"/\"\"/g;
 293         my $troff = $_;
 294         $troff =~ s/\"\"([^\"]*)\"\"/\`\`$1\'\'/g;
 295         s/\"/\"\"/g if $extra;
 296         $troff =~ s/\"/\"\"/g if $extra;
 297         $_ = qq("$_") . ($extra ? " $extra" : '');
 298         $troff = qq("$troff") . ($extra ? " $extra" : '');
 299         return ".if n $command $_\n.el $command $troff\n";
 300     } else {
 301         $_ = qq("$_") . ($extra ? " $extra" : '');
 302         return "$command $_\n";
 303     }
 304 }
 305
 306 # Translate a font string into an escape.
 307 sub toescape { (length ($_[0]) > 1 ? '\f(' : '\f') . $_[0] }
 308
 309
 310 ############################################################################
 311 # Initialization
 312 ############################################################################
 313
 314 # Initialize the object.  Here, we also process any additional options
 315 # passed to the constructor or set up defaults if none were given.  center
 316 # is the centered title, release is the version number, and date is the date
 317 # for the documentation.  Note that we can't know what file name we're
 318 # processing due to the architecture of Pod::Parser, so that *has* to either
 319 # be passed to the constructor or set separately with Pod::Man::name().
 320 sub initialize {
 321     my $self = shift;
 322
 323     # Figure out the fixed-width font.  If user-supplied, make sure that
 324     # they are the right length.
 325     for (qw/fixed fixedbold fixeditalic fixedbolditalic/) {
 326         if (defined $$self{$_}) {
 327             if (length ($$self{$_}) < 1 || length ($$self{$_}) > 2) {
 328                 croak "roff font should be 1 or 2 chars, not `$$self{$_}'";
 329             }
 330         } else {
 331             $$self{$_} = '';
 332         }
 333     }
 334
 335     # Set the default fonts.  We can't be sure what fixed bold-italic is
 336     # going to be called, so default to just bold.
 337     $$self{fixed}           ||= 'CW';
 338     $$self{fixedbold}       ||= 'CB';
 339     $$self{fixeditalic}     ||= 'CI';
 340     $$self{fixedbolditalic} ||= 'CB';
 341
 342     # Set up a table of font escapes.  First number is fixed-width, second
 343     # is bold, third is italic.
 344     $$self{FONTS} = { '000' => '\fR', '001' => '\fI',
 345                       '010' => '\fB', '011' => '\f(BI',
 346                       '100' => toescape ($$self{fixed}),
 347                       '101' => toescape ($$self{fixeditalic}),
 348                       '110' => toescape ($$self{fixedbold}),
 349                       '111' => toescape ($$self{fixedbolditalic})};
 350
 351     # Extra stuff for page titles.
 352     $$self{center} = 'User Contributed Perl Documentation'
 353         unless defined $$self{center};
 354     $$self{indent}  = 4 unless defined $$self{indent};
 355
 356     # We used to try first to get the version number from a local binary,
 357     # but we shouldn't need that any more.  Get the version from the running
 358     # Perl.  Work a little magic to handle subversions correctly under both
 359     # the pre-5.6 and the post-5.6 version numbering schemes.
 360     if (!defined $$self{release}) {
 361         my @version = ($] =~ /^(\d+)\.(\d{3})(\d{0,3})$/);
 362         $version[2] ||= 0;
 363         $version[2] *= 10 ** (3 - length $version[2]);
 364         for (@version) { $_ += 0 }
 365         $$self{release} = 'perl v' . join ('.', @version);
 366     }
 367
 368     # Double quotes in things that will be quoted.
 369     for (qw/center date release/) {
 370         $$self{$_} =~ s/\"/\"\"/g if $$self{$_};
 371     }
 372
 373     $$self{INDENT}  = 0;        # Current indentation level.
 374     $$self{INDENTS} = [];       # Stack of indentations.
 375     $$self{INDEX}   = [];       # Index keys waiting to be printed.
 376
 377     $self->SUPER::initialize;
 378 }
 379
 380 # For each document we process, output the preamble first.  Note that the
 381 # fixed width font is a global default; once we interpolate it into the
 382 # PREAMBLE, it ain't ever changing.  Maybe fix this later.
 383 sub begin_pod {
 384     my $self = shift;
 385
 386     # Try to figure out the name and section from the file name.
 387     my $section = $$self{section} || 1;
 388     my $name = $$self{name};
 389     if (!defined $name) {
 390         $name = $self->input_file;
 391         $section = 3 if (!$$self{section} && $name =~ /\.pm\z/i);
 392         $name =~ s/\.p(od|[lm])\z//i;
 393         if ($section =~ /^1/) {
 394             require File::Basename;
 395             $name = uc File::Basename::basename ($name);
 396         } else {
 397             # Lose everything up to the first of
 398             #     */lib/*perl*      standard or site_perl module
 399             #     */*perl*/lib      from -D prefix=/opt/perl
 400             #     */*perl*/         random module hierarchy
 401             # which works.  Should be fixed to use File::Spec.  Also handle
 402             # a leading lib/ since that's what ExtUtils::MakeMaker creates.
 403             for ($name) {
 404                 s%//+%/%g;
 405                 if (     s%^.*?/lib/[^/]*perl[^/]*/%%si
 406                       or s%^.*?/[^/]*perl[^/]*/(?:lib/)?%%si) {
 407                     s%^site(_perl)?/%%s;      # site and site_perl
 408                     s%^(.*-$^O|$^O-.*)/%%so;  # arch
 409                     s%^\d+\.\d+%%s;           # version
 410                 }
 411                 s%^lib/%%;
 412                 s%/%::%g;
 413             }
 414         }
 415     }
 416
 417     # Modification date header.  Try to use the modification time of our
 418     # input.
 419     if (!defined $$self{date}) {
 420         my $time = (stat $self->input_file)[9] || time;
 421         my ($day, $month, $year) = (localtime $time)[3,4,5];
 422         $month++;
 423         $year += 1900;
 424         $$self{date} = sprintf ('%4d-%02d-%02d', $year, $month, $day);
 425     }
 426
 427     # Now, print out the preamble and the title.
 428     $PREAMBLE =~ s/\@CFONT\@/$$self{fixed}/;
 429     chomp $PREAMBLE;
 430     print { $self->output_handle } <<"----END OF HEADER----";
 431 .\\" Automatically generated by Pod::Man version $VERSION
 432 .\\" @{[ scalar localtime ]}
 433 .\\"
 434 .\\" Standard preamble:
 435 .\\" ======================================================================
 436 $PREAMBLE
 437 .\\" ======================================================================
 438 .\\"
 439 .IX Title "$name $section"
 440 .TH $name $section "$$self{release}" "$$self{date}" "$$self{center}"
 441 .UC
 442 ----END OF HEADER----
 443 #"# for cperl-mode
 444
 445     # Initialize a few per-file variables.
 446     $$self{INDENT} = 0;
 447     $$self{NEEDSPACE} = 0;
 448 }
 449
 450
 451 ############################################################################
 452 # Core overrides
 453 ############################################################################
 454
 455 # Called for each command paragraph.  Gets the command, the associated
 456 # paragraph, the line number, and a Pod::Paragraph object.  Just dispatches
 457 # the command to a method named the same as the command.  =cut is handled
 458 # internally by Pod::Parser.
 459 sub command {
 460     my $self = shift;
 461     my $command = shift;
 462     return if $command eq 'pod';
 463     return if ($$self{EXCLUDE} && $command ne 'end');
 464     $command = 'cmd_' . $command;
 465     $self->$command (@_);
 466 }
 467
 468 # Called for a verbatim paragraph.  Gets the paragraph, the line number, and
 469 # a Pod::Paragraph object.  Rofficate backslashes, untabify, put a
 470 # zero-width character at the beginning of each line to protect against
 471 # commands, and wrap in .Vb/.Ve.
 472 sub verbatim {
 473     my $self = shift;
 474     return if $$self{EXCLUDE};
 475     local $_ = shift;
 476     return if /^\s+$/;
 477     s/\s+$/\n/;
 478     my $lines = tr/\n/\n/;
 479     1 while s/^(.*?)(\t+)/$1 . ' ' x (length ($2) * 8 - length ($1) % 8)/me;
 480     s/\\/\\e/g;
 481     s/^(\s*\S)/'\&' . $1/gme;
 482     $self->makespace if $$self{NEEDSPACE};
 483     $self->output (".Vb $lines\n$_.Ve\n");
 484     $$self{NEEDSPACE} = 0;
 485 }
 486
 487 # Called for a regular text block.  Gets the paragraph, the line number, and
 488 # a Pod::Paragraph object.  Perform interpolation and output the results.
 489 sub textblock {
 490     my $self = shift;
 491     return if $$self{EXCLUDE};
 492     $self->output ($_[0]), return if $$self{VERBATIM};
 493
 494     # Perform a little magic to collapse multiple L<> references.  We'll
 495     # just rewrite the whole thing into actual text at this part, bypassing
 496     # the whole internal sequence parsing thing.
 497     my $text = shift;
 498     $text =~ s{
 499         (L<                     # A link of the form L</something>.
 500               /
 501               (
 502                   [:\w]+        # The item has to be a simple word...
 503                   (\(\))?       # ...or simple function.
 504               )
 505           >
 506           (
 507               ,?\s+(and\s+)?    # Allow lots of them, conjuncted.
 508               L<
 509                   /
 510                   ( [:\w]+ ( \(\) )? )
 511               >
 512           )+
 513         )
 514     } {
 515         local $_ = $1;
 516         s{ L< / ( [^>]+ ) > } {$1}xg;
 517         my @items = split /(?:,?\s+(?:and\s+)?)/;
 518         my $string = 'the ';
 519         my $i;
 520         for ($i = 0; $i < @items; $i++) {
 521             $string .= $items[$i];
 522             $string .= ', ' if @items > 2 && $i != $#items;
 523             $string .= ' ' if @items == 2 && $i == 2;
 524             $string .= 'and ' if ($i == $#items - 1);
 525         }
 526         $string .= ' entries elsewhere in this document';
 527         $string;
 528     }gex;
 529
 530     # Parse the tree and output it.  collapse knows about references to
 531     # scalars as well as scalars and does the right thing with them.
 532     $text = $self->parse ($text, @_);
 533     $text =~ s/\n\s*$/\n/;
 534     $self->makespace if $$self{NEEDSPACE};
 535     $self->output (protect $self->mapfonts ($text));
 536     $self->outindex;
 537     $$self{NEEDSPACE} = 1;
 538 }
 539
 540 # Called for an interior sequence.  Takes a Pod::InteriorSequence object and
 541 # returns a reference to a scalar.  This scalar is the final formatted text.
 542 # It's returned as a reference so that other interior sequences above us
 543 # know that the text has already been processed.
 544 sub sequence {
 545     my ($self, $seq) = @_;
 546     my $command = $seq->cmd_name;
 547
 548     # Zero-width characters.
 549     if ($command eq 'Z') {
 550         # Workaround to generate a blessable reference, needed by 5.005.
 551         my $tmp = '\&';
 552         return bless \ "$tmp", 'Pod::Man::String';
 553     }
 554
 555     # C<>, L<>, X<>, and E<> don't apply guesswork to their contents.  C<>
 556     # needs some additional special handling.
 557     my $literal = ($command =~ /^[CELX]$/);
 558     $literal++ if $command eq 'C';
 559     local $_ = $self->collapse ($seq->parse_tree, $literal);
 560
 561     # Handle E<> escapes.
 562     if ($command eq 'E') {
 563         if (/^\d+$/) {
 564             return bless \ chr ($_), 'Pod::Man::String';
 565         } elsif (exists $ESCAPES{$_}) {
 566             return bless \ "$ESCAPES{$_}", 'Pod::Man::String';
 567         } else {
 568             carp "Unknown escape E<$1>";
 569             return bless \ "E<$_>", 'Pod::Man::String';
 570         }
 571     }
 572
 573     # For all the other sequences, empty content produces no output.
 574     return '' if $_ eq '';
 575
 576     # Handle formatting sequences.
 577     if ($command eq 'B') {
 578         return bless \ ('\f(BS' . $_ . '\f(BE'), 'Pod::Man::String';
 579     } elsif ($command eq 'F') {
 580         return bless \ ('\f(IS' . $_ . '\f(IE'), 'Pod::Man::String';
 581     } elsif ($command eq 'I') {
 582         return bless \ ('\f(IS' . $_ . '\f(IE'), 'Pod::Man::String';
 583     } elsif ($command eq 'C') {
 584         return bless \ ('\f(FS\*(C`' . $_ . "\\*(C'\\f(FE"),
 585             'Pod::Man::String';
 586     }
 587
 588     # Handle links.
 589     if ($command eq 'L') {
 590         # A bug in lvalue subs in 5.6 requires the temporary variable.
 591         my $tmp = $self->buildlink ($_);
 592         return bless \ "$tmp", 'Pod::Man::String';
 593     }
 594
 595     # Whitespace protection replaces whitespace with "\ ".
 596     if ($command eq 'S') {
 597         s/\s+/\\ /g;
 598         return bless \ "$_", 'Pod::Man::String';
 599     }
 600
 601     # Add an index entry to the list of ones waiting to be output.
 602     if ($command eq 'X') { push (@{ $$self{INDEX} }, $_); return '' }
 603
 604     # Anything else is unknown.
 605     carp "Unknown sequence $command<$_>";
 606 }
 607
 608
 609 ############################################################################
 610 # Command paragraphs
 611 ############################################################################
 612
 613 # All command paragraphs take the paragraph and the line number.
 614
 615 # First level heading.  We can't output .IX in the NAME section due to a bug
 616 # in some versions of catman, so don't output a .IX for that section.  .SH
 617 # already uses small caps, so remove any E<> sequences that would cause
 618 # them.
 619 sub cmd_head1 {
 620     my $self = shift;
 621     local $_ = $self->parse (@_);
 622     s/\s+$//;
 623     s/\\s-?\d//g;
 624     $self->output (switchquotes ('.SH', $self->mapfonts ($_)));
 625     $self->outindex (($_ eq 'NAME') ? () : ('Header', $_));
 626     $$self{NEEDSPACE} = 0;
 627 }
 628
 629 # Second level heading.
 630 sub cmd_head2 {
 631     my $self = shift;
 632     local $_ = $self->parse (@_);
 633     s/\s+$//;
 634     $self->output (switchquotes ('.Sh', $self->mapfonts ($_)));
 635     $self->outindex ('Subsection', $_);
 636     $$self{NEEDSPACE} = 0;
 637 }
 638
 639 # Start a list.  For indents after the first, wrap the outside indent in .RS
 640 # so that hanging paragraph tags will be correct.
 641 sub cmd_over {
 642     my $self = shift;
 643     local $_ = shift;
 644     unless (/^[-+]?\d+\s+$/) { $_ = $$self{indent} }
 645     if (@{ $$self{INDENTS} } > 0) {
 646         $self->output (".RS $$self{INDENT}\n");
 647     }
 648     push (@{ $$self{INDENTS} }, $$self{INDENT});
 649     $$self{INDENT} = ($_ + 0);
 650 }
 651
 652 # End a list.  If we've closed an embedded indent, we've mangled the hanging
 653 # paragraph indent, so temporarily replace it with .RS and set WEIRDINDENT.
 654 # We'll close that .RS at the next =back or =item.
 655 sub cmd_back {
 656     my $self = shift;
 657     $$self{INDENT} = pop @{ $$self{INDENTS} };
 658     unless (defined $$self{INDENT}) {
 659         carp "Unmatched =back";
 660         $$self{INDENT} = 0;
 661     }
 662     if ($$self{WEIRDINDENT}) {
 663         $self->output (".RE\n");
 664         $$self{WEIRDINDENT} = 0;
 665     }
 666     if (@{ $$self{INDENTS} } > 0) {
 667         $self->output (".RE\n");
 668         $self->output (".RS $$self{INDENT}\n");
 669         $$self{WEIRDINDENT} = 1;
 670     }
 671     $$self{NEEDSPACE} = 1;
 672 }
 673
 674 # An individual list item.  Emit an index entry for anything that's
 675 # interesting, but don't emit index entries for things like bullets and
 676 # numbers.  rofficate bullets too while we're at it (so for nice output, use
 677 # * for your lists rather than o or . or - or some other thing).  Newlines
 678 # in an item title are turned into spaces since *roff can't handle them
 679 # embedded.
 680 sub cmd_item {
 681     my $self = shift;
 682     local $_ = $self->parse (@_);
 683     s/\s+$//;
 684     s/\s*\n\s*/ /g;
 685     my $index;
 686     if (/\w/ && !/^\w[.\)]\s*$/) {
 687         $index = $_;
 688         $index =~ s/^\s*[-*+o.]?\s*//;
 689     }
 690     s/^\*(\s|\Z)/\\\(bu$1/;
 691     if ($$self{WEIRDINDENT}) {
 692         $self->output (".RE\n");
 693         $$self{WEIRDINDENT} = 0;
 694     }
 695     $_ = $self->mapfonts ($_);
 696     $self->output (switchquotes ('.Ip', $_, $$self{INDENT}));
 697     $self->outindex ($index ? ('Item', $index) : ());
 698     $$self{NEEDSPACE} = 0;
 699 }
 700
 701 # Begin a block for a particular translator.  Setting VERBATIM triggers
 702 # special handling in textblock().
 703 sub cmd_begin {
 704     my $self = shift;
 705     local $_ = shift;
 706     my ($kind) = /^(\S+)/ or return;
 707     if ($kind eq 'man' || $kind eq 'roff') {
 708         $$self{VERBATIM} = 1;
 709     } else {
 710         $$self{EXCLUDE} = 1;
 711     }
 712 }
 713
 714 # End a block for a particular translator.  We assume that all =begin/=end
 715 # pairs are properly closed.
 716 sub cmd_end {
 717     my $self = shift;
 718     $$self{EXCLUDE} = 0;
 719     $$self{VERBATIM} = 0;
 720 }
 721
 722 # One paragraph for a particular translator.  Ignore it unless it's intended
 723 # for man or roff, in which case we output it verbatim.
 724 sub cmd_for {
 725     my $self = shift;
 726     local $_ = shift;
 727     return unless s/^(?:man|roff)\b[ \t]*\n?//;
 728     $self->output ($_);
 729 }
 730
 731
 732 ############################################################################
 733 # Link handling
 734 ############################################################################
 735
 736 # Handle links.  We can't actually make real hyperlinks, so this is all to
 737 # figure out what text and formatting we print out.
 738 sub buildlink {
 739     my $self = shift;
 740     local $_ = shift;
 741
 742     # Smash whitespace in case we were split across multiple lines.
 743     s/\s+/ /g;
 744
 745     # If we were given any explicit text, just output it.
 746     if (m{ ^ ([^|]+) \| }x) { return $1 }
 747
 748     # Okay, leading and trailing whitespace isn't important.
 749     s/^\s+//;
 750     s/\s+$//;
 751
 752     # Default to using the whole content of the link entry as a section
 753     # name.  Note that L<manpage/> forces a manpage interpretation, as does
 754     # something looking like L<manpage(section)>.  Do the same thing to
 755     # L<manpage(section)> as we would to manpage(section) without the L<>;
 756     # see guesswork().  If we've added italics, don't add the "manpage"
 757     # text; markup is sufficient.
 758     my ($manpage, $section) = ('', $_);
 759     if (/^"\s*(.*?)\s*"$/) {
 760         $section = '"' . $1 . '"';
 761     } elsif (m{ ^ [-:.\w]+ (?: \( \S+ \) )? $ }x) {
 762         ($manpage, $section) = ($_, '');
 763         $manpage =~ s/^([^\(]+)\(/'\f(IS' . $1 . '\f(IE\|('/e;
 764     } elsif (m%/%) {
 765         ($manpage, $section) = split (/\s*\/\s*/, $_, 2);
 766         if ($manpage =~ /^[-:.\w]+(?:\(\S+\))?$/) {
 767             $manpage =~ s/^([^\(]+)\(/'\f(IS' . $1 . '\f(IE\|'/e;
 768         }
 769         $section =~ s/^\"\s*//;
 770         $section =~ s/\s*\"$//;
 771     }
 772     if ($manpage && $manpage !~ /\\f\(IS/) {
 773         $manpage = "the $manpage manpage";
 774     }
 775
 776     # Now build the actual output text.
 777     my $text = '';
 778     if (!length ($section) && !length ($manpage)) {
 779         carp "Invalid link $_";
 780     } elsif (!length ($section)) {
 781         $text = $manpage;
 782     } elsif ($section =~ /^[:\w]+(?:\(\))?/) {
 783         $text .= 'the ' . $section . ' entry';
 784         $text .= (length $manpage) ? " in $manpage"
 785                                    : " elsewhere in this document";
 786     } else {
 787         if ($section !~ /^".*"$/) { $section = '"' . $section . '"' }
 788         $text .= 'the section on ' . $section;
 789         $text .= " in $manpage" if length $manpage;
 790     }
 791     $text;
 792 }
 793
 794
 795 ############################################################################
 796 # Escaping and fontification
 797 ############################################################################
 798
 799 # At this point, we'll have embedded font codes of the form \f(<font>[SE]
 800 # where <font> is one of B, I, or F.  Turn those into the right font start
 801 # or end codes.  B<someI<thing> else> should map to \fBsome\f(BIthing\fB
 802 # else\fR.  The old pod2man didn't get this right; the second \fB was \fR,
 803 # so nested sequences didn't work right.  We take care of this by using
 804 # variables as a combined pointer to our current font sequence, and set each
 805 # to the number of current nestings of start tags for that font.  Use them
 806 # as a vector to look up what font sequence to use.
 807 sub mapfonts {
 808     my $self = shift;
 809     local $_ = shift;
 810
 811     my ($fixed, $bold, $italic) = (0, 0, 0);
 812     my %magic = (F => \$fixed, B => \$bold, I => \$italic);
 813     s { \\f\((.)(.) } {
 814         ${ $magic{$1} } += ($2 eq 'S') ? 1 : -1;
 815         $$self{FONTS}{($fixed && 1) . ($bold && 1) . ($italic && 1)};
 816     }gxe;
 817     $_;
 818 }
 819
 820
 821 ############################################################################
 822 # *roff-specific parsing
 823 ############################################################################
 824
 825 # Called instead of parse_text, calls parse_text with the right flags.
 826 sub parse {
 827     my $self = shift;
 828     $self->parse_text ({ -expand_seq   => 'sequence',
 829                          -expand_ptree => 'collapse' }, @_);
 830 }
 831
 832 # Takes a parse tree and a flag saying whether or not to treat it as literal
 833 # text (not call guesswork on it), and returns the concatenation of all of
 834 # the text strings in that parse tree.  If the literal flag isn't true,
 835 # guesswork() will be called on all plain scalars in the parse tree.
 836 # Otherwise, just escape backslashes in the normal case.  If collapse is
 837 # being called on a C<> sequence, literal is set to 2, and we do some
 838 # additional cleanup.  Assumes that everything in the parse tree is either a
 839 # scalar or a reference to a scalar.
 840 sub collapse {
 841     my ($self, $ptree, $literal) = @_;
 842     if ($literal) {
 843         return join ('', map {
 844             if (ref $_) {
 845                 $$_;
 846             } else {
 847                 s/\\/\\e/g;
 848                 s/-/\\-/g    if $literal > 1;
 849                 s/__/_\\|_/g if $literal > 1;
 850                 $_;
 851             }
 852         } $ptree->children);
 853     } else {
 854         return join ('', map {
 855             ref ($_) ? $$_ : $self->guesswork ($_)
 856         } $ptree->children);
 857     }
 858 }
 859
 860 # Takes a text block to perform guesswork on; this is guaranteed not to
 861 # contain any interior sequences.  Returns the text block with remapping
 862 # done.
 863 sub guesswork {
 864     my $self = shift;
 865     local $_ = shift;
 866
 867     # rofficate backslashes.
 868     s/\\/\\e/g;
 869
 870     # Ensure double underbars have a tiny space between them.
 871     s/__/_\\|_/g;
 872
 873     # Make all caps a little smaller.  Be careful here, since we don't want
 874     # to make @ARGV into small caps, nor do we want to fix the MIME in
 875     # MIME-Version, since it looks weird with the full-height V.
 876     s{
 877         ( ^ | [\s\(\"\'\`\[\{<>] )
 878         ( [A-Z] [A-Z] [/A-Z+:\d_\$&-]* )
 879         (?: (?= [\s>\}\]\)\'\".?!,;:] | -- ) | $ )
 880     } { $1 . '\s-1' . $2 . '\s0' }egx;
 881
 882     # Turn PI into a pretty pi.
 883     s{ (?: \\s-1 | \b ) PI (?: \\s0 | \b ) } {\\*\(PI}gx;
 884
 885     # Italize functions in the form func().
 886     s{
 887         \b
 888         (
 889             [:\w]+ (?:\\s-1)? \(\)
 890         )
 891     } { '\f(IS' . $1 . '\f(IE' }egx;
 892
 893     # func(n) is a reference to a manual page.  Make it \fIfunc\fR\|(n).
 894     s{
 895         \b
 896         (\w[-:.\w]+ (?:\\s-1)?)
 897         (
 898             \( [^\)] \)
 899         )
 900     } { '\f(IS' . $1 . '\f(IE\|' . $2 }egx;
 901
 902     # Convert simple Perl variable references to a fixed-width font.
 903     s{
 904         ( \s+ )
 905         ( [\$\@%] [\w:]+ )
 906         (?! \( )
 907     } { $1 . '\f(FS' . $2 . '\f(FE'}egx;
 908
 909     # Translate -- into a real em dash if it's used like one and fix up
 910     # dashes, but keep hyphens hyphens.
 911     s{ (\G|^|.) (-+) (\b|.) } {
 912         my ($pre, $dash, $post) = ($1, $2, $3);
 913         if (length ($dash) == 1) {
 914             ($pre =~ /[a-zA-Z]/) ? "$pre-$post" : "$pre\\-$post";
 915         } elsif (length ($dash) == 2
 916                  && ((!$pre && !$post)
 917                      || ($pre =~ /\w/ && !$post)
 918                      || ($pre eq ' ' && $post eq ' ')
 919                      || ($pre eq '=' && $post ne '=')
 920                      || ($pre ne '=' && $post eq '='))) {
 921             "$pre\\*(--$post";
 922         } else {
 923             $pre . ('\-' x length $dash) . $post;
 924         }
 925     }egxs;
 926
 927     # Fix up double quotes.
 928     s{ \" ([^\"]+) \" } { '\*(L"' . $1 . '\*(R"' }egx;
 929
 930     # Make C++ into \*(C+, which is a squinched version.
 931     s{ \b C\+\+ } {\\*\(C+}gx;
 932
 933     # All done.
 934     $_;
 935 }
 936
 937
 938 ############################################################################
 939 # Output formatting
 940 ############################################################################
 941
 942 # Make vertical whitespace.
 943 sub makespace {
 944     my $self = shift;
 945     $self->output ($$self{INDENT} > 0 ? ".Sp\n" : ".PP\n");
 946 }
 947
 948 # Output any pending index entries, and optionally an index entry given as
 949 # an argument.  Support multiple index entries in X<> separated by slashes,
 950 # and strip special escapes from index entries.
 951 sub outindex {
 952     my ($self, $section, $index) = @_;
 953     my @entries = map { split m%\s*/\s*% } @{ $$self{INDEX} };
 954     return unless ($section || @entries);
 955     $$self{INDEX} = [];
 956     my $output;
 957     if (@entries) {
 958         my $output = '.IX Xref "'
 959             . join (' ', map { s/\"/\"\"/; $_ } @entries)
 960             . '"' . "\n";
 961     }
 962     if ($section) {
 963         $index =~ s/\"/\"\"/;
 964         $index =~ s/\\-/-/g;
 965         $index =~ s/\\(?:s-?\d|.\(..|.)//g;
 966         $output .= ".IX $section " . '"' . $index . '"' . "\n";
 967     }
 968     $self->output ($output);
 969 }
 970
 971 # Output text to the output device.
 972 sub output { print { $_[0]->output_handle } $_[1] }
 973
 974 __END__
 975
 976 .\" These are some extra bits of roff that I don't want to lose track of
 977 .\" but that have been removed from the preamble to make it a bit shorter
 978 .\" since they're not currently being used.  They're accents and special
 979 .\" characters we don't currently have escapes for.
 980 .if n \{\
 981 .    ds ? ?
 982 .    ds ! !
 983 .    ds q
 984 .\}
 985 .if t \{\
 986 .    ds ? \s-2c\h'-\w'c'u*7/10'\u\h'\*(#H'\zi\d\s+2\h'\w'c'u*8/10'
 987 .    ds ! \s-2\(or\s+2\h'-\w'\(or'u'\v'-.8m'.\v'.8m'
 988 .    ds q o\h'-\w'o'u*8/10'\s-4\v'.4m'\z\(*i\v'-.4m'\s+4\h'\w'o'u*8/10'
 989 .\}
 990 .ds v \\k:\h'-(\\n(.wu*9/10-\*(#H)'\v'-\*(#V'\*(#[\s-4v\s0\v'\*(#V'\h'|\\n:u'\*(#]
 991 .ds _ \\k:\h'-(\\n(.wu*9/10-\*(#H+(\*(#F*2/3))'\v'-.4m'\z\(hy\v'.4m'\h'|\\n:u'
 992 .ds . \\k:\h'-(\\n(.wu*8/10)'\v'\*(#V*4/10'\z.\v'-\*(#V*4/10'\h'|\\n:u'
 993 .ds 3 \*(#[\v'.2m'\s-2\&3\s0\v'-.2m'\*(#]
 994 .ds oe o\h'-(\w'o'u*4/10)'e
 995 .ds Oe O\h'-(\w'O'u*4/10)'E
 996 .if \n(.H>23 .if \n(.V>19 \
 997 \{\
 998 .    ds v \h'-1'\o'\(aa\(ga'
 999 .    ds _ \h'-1'^
1000 .    ds . \h'-1'.
1001 .    ds 3 3
1002 .    ds oe oe
1003 .    ds Oe OE
1004 .\}
1005
1006 ############################################################################
1007 # Documentation
1008 ############################################################################
1009
1010 =head1 NAME
1011
1012 Pod::Man - Convert POD data to formatted *roff input
1013
1014 =head1 SYNOPSIS
1015
1016     use Pod::Man;
1017     my $parser = Pod::Man->new (release => $VERSION, section => 8);
1018
1019     # Read POD from STDIN and write to STDOUT.
1020     $parser->parse_from_filehandle;
1021
1022     # Read POD from file.pod and write to file.1.
1023     $parser->parse_from_file ('file.pod', 'file.1');
1024
1025 =head1 DESCRIPTION
1026
1027 Pod::Man is a module to convert documentation in the POD format (the
1028 preferred language for documenting Perl) into *roff input using the man
1029 macro set.  The resulting *roff code is suitable for display on a terminal
1030 using nroff(1), normally via man(1), or printing using troff(1).  It is
1031 conventionally invoked using the driver script B<pod2man>, but it can also
1032 be used directly.
1033
1034 As a derived class from Pod::Parser, Pod::Man supports the same methods and
1035 interfaces.  See L<Pod::Parser> for all the details; briefly, one creates a
1036 new parser with C<Pod::Man-E<gt>new()> and then calls either
1037 parse_from_filehandle() or parse_from_file().
1038
1039 new() can take options, in the form of key/value pairs that control the
1040 behavior of the parser.  See below for details.
1041
1042 If no options are given, Pod::Man uses the name of the input file with any
1043 trailing C<.pod>, C<.pm>, or C<.pl> stripped as the man page title, to
1044 section 1 unless the file ended in C<.pm> in which case it defaults to
1045 section 3, to a centered title of "User Contributed Perl Documentation", to
1046 a centered footer of the Perl version it is run with, and to a left-hand
1047 footer of the modification date of its input (or the current date if given
1048 STDIN for input).
1049
1050 Pod::Man assumes that your *roff formatters have a fixed-width font named
1051 CW.  If yours is called something else (like CR), use the C<fixed> option to
1052 specify it.  This generally only matters for troff output for printing.
1053 Similarly, you can set the fonts used for bold, italic, and bold italic
1054 fixed-width output.
1055
1056 Besides the obvious pod conversions, Pod::Man also takes care of formatting
1057 func(), func(n), and simple variable references like $foo or @bar so you
1058 don't have to use code escapes for them; complex expressions like
1059 C<$fred{'stuff'}> will still need to be escaped, though.  It also translates
1060 dashes that aren't used as hyphens into en dashes, makes long dashes--like
1061 this--into proper em dashes, fixes "paired quotes," makes C++ and PI look
1062 right, puts a little space between double underbars, makes ALLCAPS a teeny
1063 bit smaller in troff(1), and escapes stuff that *roff treats as special so
1064 that you don't have to.
1065
1066 The recognized options to new() are as follows.  All options take a single
1067 argument.
1068
1069 =over 4
1070
1071 =item center
1072
1073 Sets the centered page header to use instead of "User Contributed Perl
1074 Documentation".
1075
1076 =item date
1077
1078 Sets the left-hand footer.  By default, the modification date of the input
1079 file will be used, or the current date if stat() can't find that file (the
1080 case if the input is from STDIN), and the date will be formatted as
1081 YYYY-MM-DD.
1082
1083 =item fixed
1084
1085 The fixed-width font to use for vertabim text and code.  Defaults to CW.
1086 Some systems may want CR instead.  Only matters for troff(1) output.
1087
1088 =item fixedbold
1089
1090 Bold version of the fixed-width font.  Defaults to CB.  Only matters for
1091 troff(1) output.
1092
1093 =item fixeditalic
1094
1095 Italic version of the fixed-width font (actually, something of a misnomer,
1096 since most fixed-width fonts only have an oblique version, not an italic
1097 version).  Defaults to CI.  Only matters for troff(1) output.
1098
1099 =item fixedbolditalic
1100
1101 Bold italic (probably actually oblique) version of the fixed-width font.
1102 Pod::Man doesn't assume you have this, and defaults to CB.  Some systems
1103 (such as Solaris) have this font available as CX.  Only matters for troff(1)
1104 output.
1105
1106 =item release
1107
1108 Set the centered footer.  By default, this is the version of Perl you run
1109 Pod::Man under.  Note that some system an macro sets assume that the
1110 centered footer will be a modification date and will prepend something like
1111 "Last modified: "; if this is the case, you may want to set C<release> to
1112 the last modified date and C<date> to the version number.
1113
1114 =item section
1115
1116 Set the section for the C<.TH> macro.  The standard section numbering
1117 convention is to use 1 for user commands, 2 for system calls, 3 for
1118 functions, 4 for devices, 5 for file formats, 6 for games, 7 for
1119 miscellaneous information, and 8 for administrator commands.  There is a lot
1120 of variation here, however; some systems (like Solaris) use 4 for file
1121 formats, 5 for miscellaneous information, and 7 for devices.  Still others
1122 use 1m instead of 8, or some mix of both.  About the only section numbers
1123 that are reliably consistent are 1, 2, and 3.
1124
1125 By default, section 1 will be used unless the file ends in .pm in which case
1126 section 3 will be selected.
1127
1128 =back
1129
1130 The standard Pod::Parser method parse_from_filehandle() takes up to two
1131 arguments, the first being the file handle to read POD from and the second
1132 being the file handle to write the formatted output to.  The first defaults
1133 to STDIN if not given, and the second defaults to STDOUT.  The method
1134 parse_from_file() is almost identical, except that its two arguments are the
1135 input and output disk files instead.  See L<Pod::Parser> for the specific
1136 details.
1137
1138 =head1 DIAGNOSTICS
1139
1140 =over 4
1141
1142 =item roff font should be 1 or 2 chars, not `%s'
1143
1144 (F) You specified a *roff font (using C<fixed>, C<fixedbold>, etc.) that
1145 wasn't either one or two characters.  Pod::Man doesn't support *roff fonts
1146 longer than two characters, although some *roff extensions do (the canonical
1147 versions of nroff(1) and troff(1) don't either).
1148
1149 =item Invalid link %s
1150
1151 (W) The POD source contained a C<LE<lt>E<gt>> sequence that Pod::Man was
1152 unable to parse.  You should never see this error message; it probably
1153 indicates a bug in Pod::Man.
1154
1155 =item Unknown escape EE<lt>%sE<gt>
1156
1157 (W) The POD source contained an C<EE<lt>E<gt>> escape that Pod::Man didn't
1158 know about.  C<EE<lt>%sE<gt>> was printed verbatim in the output.
1159
1160 =item Unknown sequence %s
1161
1162 (W) The POD source contained a non-standard interior sequence (something of
1163 the form C<XE<lt>E<gt>>) that Pod::Man didn't know about.  It was ignored.
1164
1165 =item Unmatched =back
1166
1167 (W) Pod::Man encountered a C<=back> command that didn't correspond to an
1168 C<=over> command.
1169
1170 =back
1171
1172 =head1 BUGS
1173
1174 The lint-like features and strict POD format checking done by B<pod2man> are
1175 not yet implemented and should be, along with the corresponding C<lax>
1176 option.
1177
1178 The NAME section should be recognized specially and index entries emitted
1179 for everything in that section.  This would have to be deferred until the
1180 next section, since extraneous things in NAME tends to confuse various man
1181 page processors.
1182
1183 The handling of hyphens, en dashes, and em dashes is somewhat fragile, and
1184 one may get the wrong one under some circumstances.  This should only matter
1185 for troff(1) output.
1186
1187 When and whether to use small caps is somewhat tricky, and Pod::Man doesn't
1188 necessarily get it right.
1189
1190 Pod::Man doesn't handle font names longer than two characters.  Neither do
1191 most troff(1) implementations, but GNU troff does as an extension.  It would
1192 be nice to support as an option for those who want to use it.
1193
1194 The preamble added to each output file is rather verbose, and most of it is
1195 only necessary in the presence of EE<lt>E<gt> escapes for non-ASCII
1196 characters.  It would ideally be nice if all of those definitions were only
1197 output if needed, perhaps on the fly as the characters are used.
1198
1199 Some of the automagic applied to file names assumes Unix directory
1200 separators.
1201
1202 Pod::Man is excessively slow.
1203
1204 =head1 SEE ALSO
1205
1206 L<Pod::Parser|Pod::Parser>, perlpod(1), pod2man(1), nroff(1), troff(1),
1207 man(1), man(7)
1208
1209 Ossanna, Joseph F., and Brian W. Kernighan.  "Troff User's Manual,"
1210 Computing Science Technical Report No. 54, AT&T Bell Laboratories.  This is
1211 the best documentation of standard nroff(1) and troff(1).  At the time of
1212 this writing, it's available at http://www.cs.bell-labs.com/cm/cs/cstr.html.
1213
1214 The man page documenting the man macro set may be man(5) instead of man(7)
1215 on your system.  Also, please see pod2man(1) for extensive documentation on
1216 writing manual pages if you've not done it before and aren't familiar with
1217 the conventions.
1218
1219 =head1 AUTHOR
1220
1221 Russ Allbery E<lt>rra@stanford.eduE<gt>, based I<very> heavily on the
1222 original B<pod2man> by Tom Christiansen E<lt>tchrist@mox.perl.comE<gt>.
1223
1224 =cut