lib/Pod/Man.pm

   1 # Pod::Man -- Convert POD data to formatted *roff input.
   2 # $Id: Man.pm,v 0.8 1999/10/07 09:39:37 eagle Exp $
   3 #
   4 # Copyright 1999 by Russ Allbery <rra@stanford.edu>
   5 #
   6 # This program is free software; you can redistribute it and/or modify it
   7 # under the same terms as Perl itself.
   8 #
   9 # This module is intended to be a replacement for pod2man, and attempts to
  10 # match its output except for some specific circumstances where other
  11 # decisions seemed to produce better output.  It uses Pod::Parser and is
  12 # designed to be very easy to subclass.
  13
  14 ############################################################################
  15 # Modules and declarations
  16 ############################################################################
  17
  18 package Pod::Man;
  19
  20 require 5.004;
  21
  22 use Carp qw(carp croak);
  23 use Pod::Parser ();
  24
  25 use strict;
  26 use subs qw(makespace);
  27 use vars qw(@ISA %ESCAPES $PREAMBLE $VERSION);
  28
  29 @ISA = qw(Pod::Parser);
  30
  31 ($VERSION = (split (' ', q$Revision: 0.8 $ ))[1]) =~ s/\.(\d)$/.0$1/;
  32
  33
  34 ############################################################################
  35 # Preamble and *roff output tables
  36 ############################################################################
  37
  38 # The following is the static preamble which starts all *roff output we
  39 # generate.  It's completely static except for the font to use as a
  40 # fixed-width font, which is designed by @CFONT@.  $PREAMBLE should
  41 # therefore be run through s/\@CFONT\@/<font>/g before output.
  42 $PREAMBLE = <<'----END OF PREAMBLE----';
  43 .de Sh \" Subsection heading
  44 .br
  45 .if t .Sp
  46 .ne 5
  47 .PP
  48 \fB\\$1\fR
  49 .PP
  50 ..
  51 .de Sp \" Vertical space (when we can't use .PP)
  52 .if t .sp .5v
  53 .if n .sp
  54 ..
  55 .de Ip \" List item
  56 .br
  57 .ie \\n(.$>=3 .ne \\$3
  58 .el .ne 3
  59 .IP "\\$1" \\$2
  60 ..
  61 .de Vb \" Begin verbatim text
  62 .ft @CFONT@
  63 .nf
  64 .ne \\$1
  65 ..
  66 .de Ve \" End verbatim text
  67 .ft R
  68
  69 .fi
  70 ..
  71 .\" Set up some character translations and predefined strings.  \*(-- will
  72 .\" give an unbreakable dash, \*(PI will give pi, \*(L" will give a left
  73 .\" double quote, and \*(R" will give a right double quote.  | will give a
  74 .\" real vertical bar.  \*(C+ will give a nicer C++.  Capital omega is used
  75 .\" to do unbreakable dashes and therefore won't be available.  \*(C` and
  76 .\" \*(C' expand to `' in nroff, nothing in troff, for use with C<>
  77 .tr \(*W-|\(bv\*(Tr
  78 .ds C+ C\v'-.1v'\h'-1p'\s-2+\h'-1p'+\s0\v'.1v'\h'-1p'
  79 .ie n \{\
  80 .    ds -- \(*W-
  81 .    ds PI pi
  82 .    if (\n(.H=4u)&(1m=24u) .ds -- \(*W\h'-12u'\(*W\h'-12u'-\" diablo 10 pitch
  83 .    if (\n(.H=4u)&(1m=20u) .ds -- \(*W\h'-12u'\(*W\h'-8u'-\"  diablo 12 pitch
  84 .    ds L" ""
  85 .    ds R" ""
  86 .    ds C` `
  87 .    ds C' '
  88 'br\}
  89 .el\{\
  90 .    ds -- \|\(em\|
  91 .    ds PI \(*p
  92 .    ds L" ``
  93 .    ds R" ''
  94 'br\}
  95 .\"
  96 .\" If the F register is turned on, we'll generate index entries on stderr
  97 .\" for titles (.TH), headers (.SH), subsections (.Sh), items (.Ip), and
  98 .\" index entries marked with X<> in POD.  Of course, you'll have to process
  99 .\" the output yourself in some meaningful fashion.
 100 .if \nF \{\
 101 .    de IX
 102 .    tm Index:\\$1\t\\n%\t"\\$2"
 103 .    .
 104 .    nr % 0
 105 .    rr F
 106 .\}
 107 .\"
 108 .\" For nroff, turn off justification.  Always turn off hyphenation; it
 109 .\" makes way too many mistakes in technical documents.
 110 .hy 0
 111 .if n .na
 112 .\"
 113 .\" Accent mark definitions (@(#)ms.acc 1.5 88/02/08 SMI; from UCB 4.2).
 114 .\" Fear.  Run.  Save yourself.  No user-serviceable parts.
 115 .bd B 3
 116 .    \" fudge factors for nroff and troff
 117 .if n \{\
 118 .    ds #H 0
 119 .    ds #V .8m
 120 .    ds #F .3m
 121 .    ds #[ \f1
 122 .    ds #] \fP
 123 .\}
 124 .if t \{\
 125 .    ds #H ((1u-(\\\\n(.fu%2u))*.13m)
 126 .    ds #V .6m
 127 .    ds #F 0
 128 .    ds #[ \&
 129 .    ds #] \&
 130 .\}
 131 .    \" simple accents for nroff and troff
 132 .if n \{\
 133 .    ds ' \&
 134 .    ds ` \&
 135 .    ds ^ \&
 136 .    ds , \&
 137 .    ds ~ ~
 138 .    ds /
 139 .\}
 140 .if t \{\
 141 .    ds ' \\k:\h'-(\\n(.wu*8/10-\*(#H)'\'\h"|\\n:u"
 142 .    ds ` \\k:\h'-(\\n(.wu*8/10-\*(#H)'\`\h'|\\n:u'
 143 .    ds ^ \\k:\h'-(\\n(.wu*10/11-\*(#H)'^\h'|\\n:u'
 144 .    ds , \\k:\h'-(\\n(.wu*8/10)',\h'|\\n:u'
 145 .    ds ~ \\k:\h'-(\\n(.wu-\*(#H-.1m)'~\h'|\\n:u'
 146 .    ds / \\k:\h'-(\\n(.wu*8/10-\*(#H)'\z\(sl\h'|\\n:u'
 147 .\}
 148 .    \" troff and (daisy-wheel) nroff accents
 149 .ds : \\k:\h'-(\\n(.wu*8/10-\*(#H+.1m+\*(#F)'\v'-\*(#V'\z.\h'.2m+\*(#F'.\h'|\\n:u'\v'\*(#V'
 150 .ds 8 \h'\*(#H'\(*b\h'-\*(#H'
 151 .ds o \\k:\h'-(\\n(.wu+\w'\(de'u-\*(#H)/2u'\v'-.3n'\*(#[\z\(de\v'.3n'\h'|\\n:u'\*(#]
 152 .ds d- \h'\*(#H'\(pd\h'-\w'~'u'\v'-.25m'\f2\(hy\fP\v'.25m'\h'-\*(#H'
 153 .ds D- D\\k:\h'-\w'D'u'\v'-.11m'\z\(hy\v'.11m'\h'|\\n:u'
 154 .ds th \*(#[\v'.3m'\s+1I\s-1\v'-.3m'\h'-(\w'I'u*2/3)'\s-1o\s+1\*(#]
 155 .ds Th \*(#[\s+2I\s-2\h'-\w'I'u*3/5'\v'-.3m'o\v'.3m'\*(#]
 156 .ds ae a\h'-(\w'a'u*4/10)'e
 157 .ds Ae A\h'-(\w'A'u*4/10)'E
 158 .    \" corrections for vroff
 159 .if v .ds ~ \\k:\h'-(\\n(.wu*9/10-\*(#H)'\s-2\u~\d\s+2\h'|\\n:u'
 160 .if v .ds ^ \\k:\h'-(\\n(.wu*10/11-\*(#H)'\v'-.4m'^\v'.4m'\h'|\\n:u'
 161 .    \" for low resolution devices (crt and lpr)
 162 .if \n(.H>23 .if \n(.V>19 \
 163 \{\
 164 .    ds : e
 165 .    ds 8 ss
 166 .    ds o a
 167 .    ds d- d\h'-1'\(ga
 168 .    ds D- D\h'-1'\(hy
 169 .    ds th \o'bp'
 170 .    ds Th \o'LP'
 171 .    ds ae ae
 172 .    ds Ae AE
 173 .\}
 174 .rm #[ #] #H #V #F C
 175 ----END OF PREAMBLE----
 176
 177 # This table is taken nearly verbatim from Tom Christiansen's pod2man.  It
 178 # assumes that the standard preamble has already been printed, since that's
 179 # what defines all of the accent marks.  Note that some of these are quoted
 180 # with double quotes since they contain embedded single quotes, so use \\
 181 # uniformly for backslash for readability.
 182 %ESCAPES = (
 183     'amp'       =>    '&',      # ampersand
 184     'lt'        =>    '<',      # left chevron, less-than
 185     'gt'        =>    '>',      # right chevron, greater-than
 186     'quot'      =>    '"',      # double quote
 187
 188     'Aacute'    =>    "A\\*'",  # capital A, acute accent
 189     'aacute'    =>    "a\\*'",  # small a, acute accent
 190     'Acirc'     =>    'A\\*^',  # capital A, circumflex accent
 191     'acirc'     =>    'a\\*^',  # small a, circumflex accent
 192     'AElig'     =>    '\*(AE',  # capital AE diphthong (ligature)
 193     'aelig'     =>    '\*(ae',  # small ae diphthong (ligature)
 194     'Agrave'    =>    "A\\*`",  # capital A, grave accent
 195     'agrave'    =>    "A\\*`",  # small a, grave accent
 196     'Aring'     =>    'A\\*o',  # capital A, ring
 197     'aring'     =>    'a\\*o',  # small a, ring
 198     'Atilde'    =>    'A\\*~',  # capital A, tilde
 199     'atilde'    =>    'a\\*~',  # small a, tilde
 200     'Auml'      =>    'A\\*:',  # capital A, dieresis or umlaut mark
 201     'auml'      =>    'a\\*:',  # small a, dieresis or umlaut mark
 202     'Ccedil'    =>    'C\\*,',  # capital C, cedilla
 203     'ccedil'    =>    'c\\*,',  # small c, cedilla
 204     'Eacute'    =>    "E\\*'",  # capital E, acute accent
 205     'eacute'    =>    "e\\*'",  # small e, acute accent
 206     'Ecirc'     =>    'E\\*^',  # capital E, circumflex accent
 207     'ecirc'     =>    'e\\*^',  # small e, circumflex accent
 208     'Egrave'    =>    'E\\*`',  # capital E, grave accent
 209     'egrave'    =>    'e\\*`',  # small e, grave accent
 210     'ETH'       =>    '\\*(D-', # capital Eth, Icelandic
 211     'eth'       =>    '\\*(d-', # small eth, Icelandic
 212     'Euml'      =>    'E\\*:',  # capital E, dieresis or umlaut mark
 213     'euml'      =>    'e\\*:',  # small e, dieresis or umlaut mark
 214     'Iacute'    =>    "I\\*'",  # capital I, acute accent
 215     'iacute'    =>    "i\\*'",  # small i, acute accent
 216     'Icirc'     =>    'I\\*^',  # capital I, circumflex accent
 217     'icirc'     =>    'i\\*^',  # small i, circumflex accent
 218     'Igrave'    =>    'I\\*`',  # capital I, grave accent
 219     'igrave'    =>    'i\\*`',  # small i, grave accent
 220     'Iuml'      =>    'I\\*:',  # capital I, dieresis or umlaut mark
 221     'iuml'      =>    'i\\*:',  # small i, dieresis or umlaut mark
 222     'Ntilde'    =>    'N\*~',   # capital N, tilde
 223     'ntilde'    =>    'n\*~',   # small n, tilde
 224     'Oacute'    =>    "O\\*'",  # capital O, acute accent
 225     'oacute'    =>    "o\\*'",  # small o, acute accent
 226     'Ocirc'     =>    'O\\*^',  # capital O, circumflex accent
 227     'ocirc'     =>    'o\\*^',  # small o, circumflex accent
 228     'Ograve'    =>    'O\\*`',  # capital O, grave accent
 229     'ograve'    =>    'o\\*`',  # small o, grave accent
 230     'Oslash'    =>    'O\\*/',  # capital O, slash
 231     'oslash'    =>    'o\\*/',  # small o, slash
 232     'Otilde'    =>    'O\\*~',  # capital O, tilde
 233     'otilde'    =>    'o\\*~',  # small o, tilde
 234     'Ouml'      =>    'O\\*:',  # capital O, dieresis or umlaut mark
 235     'ouml'      =>    'o\\*:',  # small o, dieresis or umlaut mark
 236     'szlig'     =>    '\*8',    # small sharp s, German (sz ligature)
 237     'THORN'     =>    '\\*(Th', # capital THORN, Icelandic
 238     'thorn'     =>    '\\*(th', # small thorn, Icelandic
 239     'Uacute'    =>    "U\\*'",  # capital U, acute accent
 240     'uacute'    =>    "u\\*'",  # small u, acute accent
 241     'Ucirc'     =>    'U\\*^',  # capital U, circumflex accent
 242     'ucirc'     =>    'u\\*^',  # small u, circumflex accent
 243     'Ugrave'    =>    'U\\*`',  # capital U, grave accent
 244     'ugrave'    =>    'u\\*`',  # small u, grave accent
 245     'Uuml'      =>    'U\\*:',  # capital U, dieresis or umlaut mark
 246     'uuml'      =>    'u\\*:',  # small u, dieresis or umlaut mark
 247     'Yacute'    =>    "Y\\*'",  # capital Y, acute accent
 248     'yacute'    =>    "y\\*'",  # small y, acute accent
 249     'yuml'      =>    'y\\*:',  # small y, dieresis or umlaut mark
 250 );
 251
 252
 253 ############################################################################
 254 # Static helper functions
 255 ############################################################################
 256
 257 # Protect leading quotes and periods against interpretation as commands.
 258 sub protect { local $_ = shift; s/^([.\'])/\\&$1/mg; $_ }
 259
 260 # Given a command and a single argument that may or may not contain double
 261 # quotes, handle double-quote formatting for it.  If there are no double
 262 # quotes, just return the command followed by the argument in double quotes.
 263 # If there are double quotes, use an if statement to test for nroff, and for
 264 # nroff output the command followed by the argument in double quotes with
 265 # embedded double quotes doubled.  For other formatters, remap paired double
 266 # quotes to `` and ''.
 267 sub switchquotes {
 268     my $command = shift;
 269     local $_ = shift;
 270     my $extra = shift;
 271     s/\\\*\([LR]\"/\"/g;
 272     if (/\"/) {
 273         s/\"/\"\"/g;
 274         my $troff = $_;
 275         $troff =~ s/\"\"([^\"]*)\"\"/\`\`$1\'\'/g;
 276         s/\"/\"\"/g if $extra;
 277         $troff =~ s/\"/\"\"/g if $extra;
 278         $_ = qq("$_") . ($extra ? " $extra" : '');
 279         $troff = qq("$troff") . ($extra ? " $extra" : '');
 280         return ".if n $command $_\n.el $command $troff\n";
 281     } else {
 282         $_ = qq("$_") . ($extra ? " $extra" : '');
 283         return "$command $_\n";
 284     }
 285 }
 286
 287 # Translate a font string into an escape.
 288 sub toescape { (length ($_[0]) > 1 ? '\f(' : '\f') . $_[0] }
 289
 290
 291 ############################################################################
 292 # Initialization
 293 ############################################################################
 294
 295 # Initialize the object.  Here, we also process any additional options
 296 # passed to the constructor or set up defaults if none were given.  center
 297 # is the centered title, release is the version number, and date is the date
 298 # for the documentation.  Note that we can't know what file name we're
 299 # processing due to the architecture of Pod::Parser, so that *has* to either
 300 # be passed to the constructor or set separately with Pod::Man::name().
 301 sub initialize {
 302     my $self = shift;
 303
 304     # Figure out the fixed-width font.  If user-supplied, make sure that
 305     # they are the right length.
 306     for (qw/fixed fixedbold fixeditalic fixedbolditalic/) {
 307         if (defined $$self{$_}) {
 308             if (length ($$self{$_}) < 1 || length ($$self{$_}) > 2) {
 309                 croak "roff font should be 1 or 2 chars, not `$$self{$_}'";
 310             }
 311         } else {
 312             $$self{$_} = '';
 313         }
 314     }
 315
 316     # Set the default fonts.  We can't be sure what fixed bold-italic is
 317     # going to be called, so default to just bold.
 318     $$self{fixed}           ||= 'CW';
 319     $$self{fixedbold}       ||= 'CB';
 320     $$self{fixeditalic}     ||= 'CI';
 321     $$self{fixedbolditalic} ||= 'CB';
 322
 323     # Set up a table of font escapes.  First number is fixed-width, second
 324     # is bold, third is italic.
 325     $$self{FONTS} = { '000' => '\fR', '001' => '\fI',
 326                       '010' => '\fB', '011' => '\f(BI',
 327                       '100' => toescape ($$self{fixed}),
 328                       '101' => toescape ($$self{fixeditalic}),
 329                       '110' => toescape ($$self{fixedbold}),
 330                       '111' => toescape ($$self{fixedbolditalic})};
 331
 332     # Extra stuff for page titles.
 333     $$self{center} = 'User Contributed Perl Documentation'
 334         unless defined $$self{center};
 335     $$self{indent}  = 4 unless defined $$self{indent};
 336
 337     # We used to try first to get the version number from a local binary,
 338     # but we shouldn't need that any more.  Get the version from the running
 339     # Perl.
 340     if (!defined $$self{release}) {
 341         my ($version, $patch) = ($] =~ /^(.{5})(\d{2})?/);
 342         $$self{release}  = "perl $version";
 343         $$self{release} .= ", patch $patch" if $patch;
 344     }
 345
 346     # Double quotes in things that will be quoted.
 347     for (qw/center date release/) { $$self{$_} =~ s/\"/\"\"/g }
 348
 349     $$self{INDENT}  = 0;        # Current indentation level.
 350     $$self{INDENTS} = [];       # Stack of indentations.
 351     $$self{INDEX}   = [];       # Index keys waiting to be printed.
 352
 353     $self->SUPER::initialize;
 354 }
 355
 356 # For each document we process, output the preamble first.  Note that the
 357 # fixed width font is a global default; once we interpolate it into the
 358 # PREAMBLE, it ain't ever changing.  Maybe fix this later.
 359 sub begin_pod {
 360     my $self = shift;
 361
 362     # Try to figure out the name and section from the file name.
 363     my $section = $$self{section} || 1;
 364     my $name = $$self{name};
 365     if (!defined $name) {
 366         $name = $self->input_file;
 367         $section = 3 if (!$$self{section} && $name =~ /\.pm$/i);
 368         $name =~ s/\.p(od|[lm])$//i;
 369         if ($section =~ /^1/) {
 370             require File::Basename;
 371             $name = uc File::Basename::basename ($name);
 372         } else {
 373             # Lose everything up to the first of
 374             #     */lib/*perl*      standard or site_perl module
 375             #     */*perl*/lib      from -D prefix=/opt/perl
 376             #     */*perl*/         random module hierarchy
 377             # which works.  Should be fixed to use File::Spec.
 378             for ($name) {
 379                 s%//+%/%g;
 380                 if (     s%^.*?/lib/[^/]*perl[^/]*/%%i
 381                       or s%^.*?/[^/]*perl[^/]*/(?:lib/)?%%i) {
 382                     s%^site(_perl)?/%%;       # site and site_perl
 383                     s%^(.*-$^O|$^O-.*)/%%o;   # arch
 384                     s%^\d+\.\d+%%;            # version
 385                 }
 386                 s%/%::%g;
 387             }
 388         }
 389     }
 390
 391     # Modification date header.  Try to use the modification time of our
 392     # input.
 393     if (!defined $$self{date}) {
 394         my $time = (stat $self->input_file)[9] || time;
 395         my ($day, $month, $year) = (localtime $time)[3,4,5];
 396         $month++;
 397         $year += 1900;
 398         $$self{date} = join ('-', $year, $month, $day);
 399     }
 400
 401     # Now, print out the preamble and the title.
 402     $PREAMBLE =~ s/\@CFONT\@/$$self{fixed}/;
 403     chomp $PREAMBLE;
 404     print { $self->output_handle } <<"----END OF HEADER----";
 405 .\\" Automatically generated by Pod::Man version $VERSION
 406 .\\" @{[ scalar localtime ]}
 407 .\\"
 408 .\\" Standard preamble:
 409 .\\" ======================================================================
 410 $PREAMBLE
 411 .\\" ======================================================================
 412 .\\"
 413 .IX Title "$name $section"
 414 .TH $name $section "$$self{release}" "$$self{date}" "$$self{center}"
 415 .UC
 416 ----END OF HEADER----
 417 #"# for cperl-mode
 418
 419     # Initialize a few per-file variables.
 420     $$self{INDENT} = 0;
 421     $$self{NEEDSPACE} = 0;
 422 }
 423
 424
 425 ############################################################################
 426 # Core overrides
 427 ############################################################################
 428
 429 # Called for each command paragraph.  Gets the command, the associated
 430 # paragraph, the line number, and a Pod::Paragraph object.  Just dispatches
 431 # the command to a method named the same as the command.  =cut is handled
 432 # internally by Pod::Parser.
 433 sub command {
 434     my $self = shift;
 435     my $command = shift;
 436     return if $command eq 'pod';
 437     return if ($$self{EXCLUDE} && $command ne 'end');
 438     $command = 'cmd_' . $command;
 439     $self->$command (@_);
 440 }
 441
 442 # Called for a verbatim paragraph.  Gets the paragraph, the line number, and
 443 # a Pod::Paragraph object.  Rofficate backslashes, untabify, put a
 444 # zero-width character at the beginning of each line to protect against
 445 # commands, and wrap in .Vb/.Ve.
 446 sub verbatim {
 447     my $self = shift;
 448     return if $$self{EXCLUDE};
 449     local $_ = shift;
 450     return if /^\s+$/;
 451     s/\s+$/\n/;
 452     my $lines = tr/\n/\n/;
 453     1 while s/^(.*?)(\t+)/$1 . ' ' x (length ($2) * 8 - length ($1) % 8)/me;
 454     s/\\/\\e/g;
 455     s/^(\s*\S)/'\&' . $1/gme;
 456     $self->makespace if $$self{NEEDSPACE};
 457     $self->output (".Vb $lines\n$_.Ve\n");
 458     $$self{NEEDSPACE} = 0;
 459 }
 460
 461 # Called for a regular text block.  Gets the paragraph, the line number, and
 462 # a Pod::Paragraph object.  Perform interpolation and output the results.
 463 sub textblock {
 464     my $self = shift;
 465     return if $$self{EXCLUDE};
 466     $self->output ($_[0]), return if $$self{VERBATIM};
 467
 468     # Perform a little magic to collapse multiple L<> references.  We'll
 469     # just rewrite the whole thing into actual text at this part, bypassing
 470     # the whole internal sequence parsing thing.
 471     s{
 472         (L<                     # A link of the form L</something>.
 473               /
 474               (
 475                   [:\w]+        # The item has to be a simple word...
 476                   (\(\))?       # ...or simple function.
 477               )
 478           >
 479           (
 480               ,?\s+(and\s+)?    # Allow lots of them, conjuncted.
 481               L<
 482                   /
 483                   ( [:\w]+ ( \(\) )? )
 484               >
 485           )+
 486         )
 487     } {
 488         local $_ = $1;
 489         s{ L< / ([^>]+ ) } {$1}g;
 490         my @items = split /(?:,?\s+(?:and\s+)?)/;
 491         my $string = "the ";
 492         my $i;
 493         for ($i = 0; $i < @items; $i++) {
 494             $string .= $items[$i];
 495             $string .= ", " if @items > 2 && $i != $#items;
 496             $string .= " and " if ($i == $#items - 1);
 497         }
 498         $string .= " entries elsewhere in this document";
 499         $string;
 500     }gex;
 501
 502     # Parse the tree and output it.  collapse knows about references to
 503     # scalars as well as scalars and does the right thing with them.
 504     local $_ = $self->parse (@_);
 505     s/\n\s*$/\n/;
 506     $self->makespace if $$self{NEEDSPACE};
 507     $self->output (protect $self->mapfonts ($_));
 508     $self->outindex;
 509     $$self{NEEDSPACE} = 1;
 510 }
 511
 512 # Called for an interior sequence.  Takes a Pod::InteriorSequence object and
 513 # returns a reference to a scalar.  This scalar is the final formatted text.
 514 # It's returned as a reference so that other interior sequences above us
 515 # know that the text has already been processed.
 516 sub sequence {
 517     my ($self, $seq) = @_;
 518     my $command = $seq->cmd_name;
 519
 520     # Zero-width characters.
 521     if ($command eq 'Z') { return bless \ '\&', 'Pod::Man::String' }
 522
 523     # C<>, L<>, X<>, and E<> don't apply guesswork to their contents.
 524     local $_ = $self->collapse ($seq->parse_tree, $command =~ /^[CELX]$/);
 525
 526     # Handle E<> escapes.
 527     if ($command eq 'E') {
 528         if (/^\d+$/) {
 529             return bless \ chr ($_), 'Pod::Man::String';
 530         } elsif (exists $ESCAPES{$_}) {
 531             return bless \ "$ESCAPES{$_}", 'Pod::Man::String';
 532         } else {
 533             carp "Unknown escape E<$1>";
 534             return bless \ "E<$_>", 'Pod::Man::String';
 535         }
 536     }
 537
 538     # For all the other sequences, empty content produces no output.
 539     return '' if $_ eq '';
 540
 541     # Handle formatting sequences.
 542     if ($command eq 'B') {
 543         return bless \ ('\f(BS' . $_ . '\f(BE'), 'Pod::Man::String';
 544     } elsif ($command eq 'F') {
 545         return bless \ ('\f(IS' . $_ . '\f(IE'), 'Pod::Man::String';
 546     } elsif ($command eq 'I') {
 547         return bless \ ('\f(IS' . $_ . '\f(IE'), 'Pod::Man::String';
 548     } elsif ($command eq 'C') {
 549         s/-/\\-/g;
 550         s/__/_\\|_/g;
 551         return bless \ ('\f(FS\*(C`' . $_ . "\\*(C'\\f(FE"),
 552             'Pod::Man::String';
 553     }
 554
 555     # Handle links.
 556     if ($command eq 'L') {
 557         return bless \ ($self->buildlink ($_)), 'Pod::Man::String';
 558     }
 559
 560     # Whitespace protection replaces whitespace with "\ ".
 561     if ($command eq 'S') {
 562         s/\s+/\\ /g;
 563         return bless \ "$_", 'Pod::Man::String';
 564     }
 565
 566     # Add an index entry to the list of ones waiting to be output.
 567     if ($command eq 'X') { push (@{ $$self{INDEX} }, $_); return '' }
 568
 569     # Anything else is unknown.
 570     carp "Unknown sequence $command<$_>";
 571 }
 572
 573
 574 ############################################################################
 575 # Command paragraphs
 576 ############################################################################
 577
 578 # All command paragraphs take the paragraph and the line number.
 579
 580 # First level heading.  We can't output .IX in the NAME section due to a bug
 581 # in some versions of catman, so don't output a .IX for that section.  .SH
 582 # already uses small caps, so remove any E<> sequences that would cause
 583 # them.
 584 sub cmd_head1 {
 585     my $self = shift;
 586     local $_ = $self->parse (@_);
 587     s/\s+$//;
 588     s/\\s-?\d//g;
 589     $self->output (switchquotes ('.SH', $self->mapfonts ($_)));
 590     $self->outindex (($_ eq 'NAME') ? () : ('Header', $_));
 591     $$self{NEEDSPACE} = 0;
 592 }
 593
 594 # Second level heading.
 595 sub cmd_head2 {
 596     my $self = shift;
 597     local $_ = $self->parse (@_);
 598     s/\s+$//;
 599     $self->output (switchquotes ('.Sh', $self->mapfonts ($_)));
 600     $self->outindex ('Subsection', $_);
 601     $$self{NEEDSPACE} = 0;
 602 }
 603
 604 # Start a list.  For indents after the first, wrap the outside indent in .RS
 605 # so that hanging paragraph tags will be correct.
 606 sub cmd_over {
 607     my $self = shift;
 608     local $_ = shift;
 609     unless (/^[-+]?\d+\s+$/) { $_ = $$self{indent} }
 610     if (@{ $$self{INDENTS} } > 0) {
 611         $self->output (".RS $$self{INDENT}\n");
 612     }
 613     push (@{ $$self{INDENTS} }, $$self{INDENT});
 614     $$self{INDENT} = ($_ + 0);
 615 }
 616
 617 # End a list.  If we've closed an embedded indent, we've mangled the hanging
 618 # paragraph indent, so temporarily replace it with .RS and set WEIRDINDENT.
 619 # We'll close that .RS at the next =back or =item.
 620 sub cmd_back {
 621     my $self = shift;
 622     $$self{INDENT} = pop @{ $$self{INDENTS} };
 623     unless (defined $$self{INDENT}) {
 624         carp "Unmatched =back";
 625         $$self{INDENT} = 0;
 626     }
 627     if ($$self{WEIRDINDENT}) {
 628         $self->output (".RE\n");
 629         $$self{WEIRDINDENT} = 0;
 630     }
 631     if (@{ $$self{INDENTS} } > 0) {
 632         $self->output (".RE\n");
 633         $self->output (".RS $$self{INDENT}\n");
 634         $$self{WEIRDINDENT} = 1;
 635     }
 636     $$self{NEEDSPACE} = 1;
 637 }
 638
 639 # An individual list item.  Emit an index entry for anything that's
 640 # interesting, but don't emit index entries for things like bullets and
 641 # numbers.  rofficate bullets too while we're at it (so for nice output, use
 642 # * for your lists rather than o or . or - or some other thing).
 643 sub cmd_item {
 644     my $self = shift;
 645     local $_ = $self->parse (@_);
 646     s/\s+$//;
 647     my $index;
 648     if (/\w/ && !/^\w[.\)]\s*$/) {
 649         $index = $_;
 650         $index =~ s/^\s*[-*+o.]?\s*//;
 651     }
 652     s/^\*(\s|\Z)/\\\(bu$1/;
 653     if ($$self{WEIRDINDENT}) {
 654         $self->output (".RE\n");
 655         $$self{WEIRDINDENT} = 0;
 656     }
 657     $_ = $self->mapfonts ($_);
 658     $self->output (switchquotes ('.Ip', $_, $$self{INDENT}));
 659     $self->outindex ($index ? ('Item', $index) : ());
 660     $$self{NEEDSPACE} = 0;
 661 }
 662
 663 # Begin a block for a particular translator.  Setting VERBATIM triggers
 664 # special handling in textblock().
 665 sub cmd_begin {
 666     my $self = shift;
 667     local $_ = shift;
 668     my ($kind) = /^(\S+)/ or return;
 669     if ($kind eq 'man' || $kind eq 'roff') {
 670         $$self{VERBATIM} = 1;
 671     } else {
 672         $$self{EXCLUDE} = 1;
 673     }
 674 }
 675
 676 # End a block for a particular translator.  We assume that all =begin/=end
 677 # pairs are properly closed.
 678 sub cmd_end {
 679     my $self = shift;
 680     $$self{EXCLUDE} = 0;
 681     $$self{VERBATIM} = 0;
 682 }
 683
 684 # One paragraph for a particular translator.  Ignore it unless it's intended
 685 # for man or roff, in which case we output it verbatim.
 686 sub cmd_for {
 687     my $self = shift;
 688     local $_ = shift;
 689     my $line = shift;
 690     return unless s/^(?:man|roff)\b[ \t]*\n?//;
 691     $self->output ($_);
 692 }
 693
 694
 695 ############################################################################
 696 # Link handling
 697 ############################################################################
 698
 699 # Handle links.  We can't actually make real hyperlinks, so this is all to
 700 # figure out what text and formatting we print out.
 701 sub buildlink {
 702     my $self = shift;
 703     local $_ = shift;
 704
 705     # Smash whitespace in case we were split across multiple lines.
 706     s/\s+/ /g;
 707
 708     # If we were given any explicit text, just output it.
 709     if (m{ ^ ([^|]+) \| }x) { return $1 }
 710
 711     # Okay, leading and trailing whitespace isn't important.
 712     s/^\s+//;
 713     s/\s+$//;
 714
 715     # Default to using the whole content of the link entry as a section
 716     # name.  Note that L<manpage/> forces a manpage interpretation, as does
 717     # something looking like L<manpage(section)>.  Do the same thing to
 718     # L<manpage(section)> as we would to manpage(section) without the L<>;
 719     # see guesswork().  If we've added italics, don't add the "manpage"
 720     # text; markup is sufficient.
 721     my ($manpage, $section) = ('', $_);
 722     if (/^"\s*(.*?)\s*"$/) {
 723         $section = '"' . $1 . '"';
 724     } elsif (m{ ^ [-:.\w]+ (?: \( \S+ \) )? $ }x) {
 725         ($manpage, $section) = ($_, '');
 726         $manpage =~ s/^([^\(]+)\(/'\f(IS' . $1 . '\f(IE\|('/e;
 727     } elsif (m%/%) {
 728         ($manpage, $section) = split (/\s*\/\s*/, $_, 2);
 729         if ($manpage =~ /^[-:.\w]+(?:\(\S+\))?$/) {
 730             $manpage =~ s/^([^\(]+)\(/'\f(IS' . $1 . '\f(IE\|'/e;
 731         }
 732         $section =~ s/^\"\s*//;
 733         $section =~ s/\s*\"$//;
 734     }
 735     if ($manpage && $manpage !~ /\\f\(IS/) {
 736         $manpage = "the $manpage manpage";
 737     }
 738
 739     # Now build the actual output text.
 740     my $text = '';
 741     if (!length ($section) && !length ($manpage)) {
 742         carp "Invalid link $_";
 743     } elsif (!length ($section)) {
 744         $text = $manpage;
 745     } elsif ($section =~ /^[:\w]+(?:\(\))?/) {
 746         $text .= 'the ' . $section . ' entry';
 747         $text .= (length $manpage) ? " in $manpage"
 748                                    : " elsewhere in this document";
 749     } else {
 750         if ($section !~ /^".*"$/) { $section = '"' . $section . '"' }
 751         $text .= 'the section on ' . $section;
 752         $text .= " in $manpage" if length $manpage;
 753     }
 754     $text;
 755 }
 756
 757
 758 ############################################################################
 759 # Escaping and fontification
 760 ############################################################################
 761
 762 # At this point, we'll have embedded font codes of the form \f(<font>[SE]
 763 # where <font> is one of B, I, or F.  Turn those into the right font start
 764 # or end codes.  B<someI<thing> else> should map to \fBsome\f(BIthing\fB
 765 # else\fR.  The old pod2man didn't get this right; the second \fB was \fR,
 766 # so nested sequences didn't work right.  We take care of this by using
 767 # variables as a combined pointer to our current font sequence, and set each
 768 # to the number of current nestings of start tags for that font.  Use them
 769 # as a vector to look up what font sequence to use.
 770 sub mapfonts {
 771     my $self = shift;
 772     local $_ = shift;
 773
 774     my ($fixed, $bold, $italic) = (0, 0, 0);
 775     my %magic = (F => \$fixed, B => \$bold, I => \$italic);
 776     s { \\f\((.)(.) } {
 777         ${ $magic{$1} } += ($2 eq 'S') ? 1 : -1;
 778         $$self{FONTS}{($fixed && 1) . ($bold && 1) . ($italic && 1)};
 779     }gxe;
 780     $_;
 781 }
 782
 783
 784 ############################################################################
 785 # *roff-specific parsing
 786 ############################################################################
 787
 788 # Called instead of parse_text, calls parse_text with the right flags.
 789 sub parse {
 790     my $self = shift;
 791     $self->parse_text ({ -expand_seq   => 'sequence',
 792                          -expand_ptree => 'collapse' }, @_);
 793 }
 794
 795 # Takes a parse tree and a flag saying whether or not to treat it as literal
 796 # text (not call guesswork on it), and returns the concatenation of all of
 797 # the text strings in that parse tree.  If the literal flag isn't true,
 798 # guesswork() will be called on all plain scalars in the parse tree.
 799 # Assumes that everything in the parse tree is either a scalar or a
 800 # reference to a scalar.
 801 sub collapse {
 802     my ($self, $ptree, $literal) = @_;
 803     if ($literal) {
 804         return join ('', map {
 805             if (ref $_) {
 806                 $$_;
 807             } else {
 808                 s/\\/\\e/g;
 809                 $_;
 810             }
 811         } $ptree->children);
 812     } else {
 813         return join ('', map {
 814             ref ($_) ? $$_ : $self->guesswork ($_)
 815         } $ptree->children);
 816     }
 817 }
 818
 819 # Takes a text block to perform guesswork on; this is guaranteed not to
 820 # contain any interior sequences.  Returns the text block with remapping
 821 # done.
 822 sub guesswork {
 823     my $self = shift;
 824     local $_ = shift;
 825
 826     # rofficate backslashes.
 827     s/\\/\\e/g;
 828
 829     # Ensure double underbars have a tiny space between them.
 830     s/__/_\\|_/g;
 831
 832     # Make all caps a little smaller.  Be careful here, since we don't want
 833     # to make @ARGV into small caps, nor do we want to fix the MIME in
 834     # MIME-Version, since it looks weird with the full-height V.
 835     s{
 836         ( ^ | [\s\(\"\'\`\[\{<>] )
 837         ( [A-Z] [A-Z] [/A-Z+:\d_\$&-]* )
 838         (?: (?= [\s>\}\]\)\'\".?!,;:] | -- ) | $ )
 839     } { $1 . '\s-1' . $2 . '\s0' . $3 }egx;
 840
 841     # Turn PI into a pretty pi.
 842     s{ (?: \\s-1 | \b ) PI (?: \\s0 | \b ) } {\\*\(PI}gx;
 843
 844     # Italize functions in the form func().
 845     s{
 846         \b
 847         (
 848             [:\w]+ (?:\\s-1)? \(\)
 849         )
 850     } { '\f(IS' . $1 . '\f(IE' }egx;
 851
 852     # func(n) is a reference to a manual page.  Make it \fIfunc\fR\|(n).
 853     s{
 854         \b
 855         (\w[-:.\w]+ (?:\\s-1)?)
 856         (
 857             \( [^\)] \)
 858         )
 859     } { '\f(IS' . $1 . '\f(IE\|' . $2 }egx;
 860
 861     # Convert simple Perl variable references to a fixed-width font.
 862     s{
 863         ( \s+ )
 864         ( [\$\@%] [\w:]+ )
 865         (?! \( )
 866     } { $1 . '\f(FS' . $2 . '\f(FE'}egx;
 867
 868     # Translate -- into a real em dash if it's used like one and fix up
 869     # dashes, but keep hyphens hyphens.
 870     s{ (\G|^|.) (-+) (\b|.) } {
 871         my ($pre, $dash, $post) = ($1, $2, $3);
 872         if (length ($dash) == 1) {
 873             ($pre =~ /[a-zA-Z]/) ? "$pre-$post" : "$pre\\-$post";
 874         } elsif (length ($dash) == 2
 875                  && ((!$pre && !$post)
 876                      || ($pre =~ /\w/ && !$post)
 877                      || ($pre eq ' ' && $post eq ' ')
 878                      || ($pre eq '=' && $post ne '=')
 879                      || ($pre ne '=' && $post eq '='))) {
 880             "$pre\\*(--$post";
 881         } else {
 882             $pre . ('\-' x length $dash) . $post;
 883         }
 884     }egxs;
 885
 886     # Fix up double quotes.
 887     s{ \" ([^\"]+) \" } { '\*(L"' . $1 . '\*(R"' }egx;
 888
 889     # Make C++ into \*(C+, which is a squinched version.
 890     s{ \b C\+\+ } {\\*\(C+}gx;
 891
 892     # All done.
 893     $_;
 894 }
 895
 896
 897 ############################################################################
 898 # Output formatting
 899 ############################################################################
 900
 901 # Make vertical whitespace.
 902 sub makespace {
 903     my $self = shift;
 904     $self->output ($$self{INDENT} > 0 ? ".Sp\n" : ".PP\n");
 905 }
 906
 907 # Output any pending index entries, and optionally an index entry given as
 908 # an argument.  Support multiple index entries in X<> separated by slashes,
 909 # and strip special escapes from index entries.
 910 sub outindex {
 911     my ($self, $section, $index) = @_;
 912     my @entries = map { split m%\s*/\s*% } @{ $$self{INDEX} };
 913     return unless ($section || @entries);
 914     $$self{INDEX} = [];
 915     my $output;
 916     if (@entries) {
 917         my $output = '.IX Xref "'
 918             . join (' ', map { s/\"/\"\"/; $_ } @entries)
 919             . '"' . "\n";
 920     }
 921     if ($section) {
 922         $index =~ s/\"/\"\"/;
 923         $index =~ s/\\-/-/g;
 924         $index =~ s/\\(?:s-?\d|.\(..|.)//g;
 925         $output .= ".IX $section " . '"' . $index . '"' . "\n";
 926     }
 927     $self->output ($output);
 928 }
 929
 930 # Output text to the output device.
 931 sub output { print { $_[0]->output_handle } $_[1] }
 932
 933 __END__
 934
 935 .\" These are some extra bits of roff that I don't want to lose track of
 936 .\" but that have been removed from the preamble to make it a bit shorter
 937 .\" since they're not currently being used.  They're accents and special
 938 .\" characters we don't currently have escapes for.
 939 .if n \{\
 940 .    ds ? ?
 941 .    ds ! !
 942 .    ds q
 943 .\}
 944 .if t \{\
 945 .    ds ? \s-2c\h'-\w'c'u*7/10'\u\h'\*(#H'\zi\d\s+2\h'\w'c'u*8/10'
 946 .    ds ! \s-2\(or\s+2\h'-\w'\(or'u'\v'-.8m'.\v'.8m'
 947 .    ds q o\h'-\w'o'u*8/10'\s-4\v'.4m'\z\(*i\v'-.4m'\s+4\h'\w'o'u*8/10'
 948 .\}
 949 .ds v \\k:\h'-(\\n(.wu*9/10-\*(#H)'\v'-\*(#V'\*(#[\s-4v\s0\v'\*(#V'\h'|\\n:u'\*(#]
 950 .ds _ \\k:\h'-(\\n(.wu*9/10-\*(#H+(\*(#F*2/3))'\v'-.4m'\z\(hy\v'.4m'\h'|\\n:u'
 951 .ds . \\k:\h'-(\\n(.wu*8/10)'\v'\*(#V*4/10'\z.\v'-\*(#V*4/10'\h'|\\n:u'
 952 .ds 3 \*(#[\v'.2m'\s-2\&3\s0\v'-.2m'\*(#]
 953 .ds oe o\h'-(\w'o'u*4/10)'e
 954 .ds Oe O\h'-(\w'O'u*4/10)'E
 955 .if \n(.H>23 .if \n(.V>19 \
 956 \{\
 957 .    ds v \h'-1'\o'\(aa\(ga'
 958 .    ds _ \h'-1'^
 959 .    ds . \h'-1'.
 960 .    ds 3 3
 961 .    ds oe oe
 962 .    ds Oe OE
 963 .\}
 964
 965 ############################################################################
 966 # Documentation
 967 ############################################################################
 968
 969 =head1 NAME
 970
 971 Pod::Man - Convert POD data to formatted *roff input
 972
 973 =head1 SYNOPSIS
 974
 975     use Pod::Man;
 976     my $parser = Pod::Man->new (release => $VERSION, section => 8);
 977
 978     # Read POD from STDIN and write to STDOUT.
 979     $parser->parse_from_filehandle;
 980
 981     # Read POD from file.pod and write to file.1.
 982     $parser->parse_from_file ('file.pod', 'file.1');
 983
 984 =head1 DESCRIPTION
 985
 986 Pod::Man is a module to convert documentation in the POD format (the
 987 preferred language for documenting Perl) into *roff input using the man
 988 macro set.  The resulting *roff code is suitable for display on a terminal
 989 using nroff(1), normally via man(1), or printing using troff(1).  It is
 990 conventionally invoked using the driver script B<pod2roff>, but it can also
 991 be used directly.
 992
 993 As a derived class from Pod::Parser, Pod::Man supports the same methods and
 994 interfaces.  See L<Pod::Parser> for all the details; briefly, one creates a
 995 new parser with C<Pod::Man-E<gt>new()> and then calls either
 996 parse_from_filehandle() or parse_from_file().
 997
 998 new() can take options, in the form of key/value pairs that control the
 999 behavior of the parser.  See below for details.
1000
1001 If no options are given, Pod::Man uses the name of the input file with any
1002 trailing C<.pod>, C<.pm>, or C<.pl> stripped as the man page title, to
1003 section 1 unless the file ended in C<.pm> in which case it defaults to
1004 section 3, to a centered title of "User Contributed Perl Documentation", to
1005 a centered footer of the Perl version it is run with, and to a left-hand
1006 footer of the modification date of its input (or the current date if given
1007 STDIN for input).
1008
1009 Pod::Man assumes that your *roff formatters have a fixed-width font named
1010 CW.  If yours is called something else (like CR), use the C<fixed> option to
1011 specify it.  This generally only matters for troff output for printing.
1012 Similarly, you can set the fonts used for bold, italic, and bold italic
1013 fixed-width output.
1014
1015 Besides the obvious pod conversions, Pod::Man also takes care of formatting
1016 func(), func(n), and simple variable references like $foo or @bar so you
1017 don't have to use code escapes for them; complex expressions like
1018 C<$fred{'stuff'}> will still need to be escaped, though.  It also translates
1019 dashes that aren't used as hyphens into en dashes, makes long dashes--like
1020 this--into proper em dashes, fixes "paired quotes," makes C++ and PI look
1021 right, puts a little space between double underbars, makes ALLCAPS a teeny
1022 bit smaller in troff(1), and escapes stuff that *roff treats as special so
1023 that you don't have to.
1024
1025 The recognized options to new() are as follows.  All options take a single
1026 argument.
1027
1028 =over 4
1029
1030 =item center
1031
1032 Sets the centered page header to use instead of "User Contributed Perl
1033 Documentation".
1034
1035 =item date
1036
1037 Sets the left-hand footer.  By default, the modification date of the input
1038 file will be used, or the current date if stat() can't find that file (the
1039 case if the input is from STDIN), and the date will be formatted as
1040 YYYY-MM-DD.
1041
1042 =item fixed
1043
1044 The fixed-width font to use for vertabim text and code.  Defaults to CW.
1045 Some systems may want CR instead.  Only matters for troff(1) output.
1046
1047 =item fixedbold
1048
1049 Bold version of the fixed-width font.  Defaults to CB.  Only matters for
1050 troff(1) output.
1051
1052 =item fixeditalic
1053
1054 Italic version of the fixed-width font (actually, something of a misnomer,
1055 since most fixed-width fonts only have an oblique version, not an italic
1056 version).  Defaults to CI.  Only matters for troff(1) output.
1057
1058 =item fixedbolditalic
1059
1060 Bold italic (probably actually oblique) version of the fixed-width font.
1061 Pod::Man doesn't assume you have this, and defaults to CB.  Some systems
1062 (such as Solaris) have this font available as CX.  Only matters for troff(1)
1063 output.
1064
1065 =item release
1066
1067 Set the centered footer.  By default, this is the version of Perl you run
1068 Pod::Man under.  Note that some system an macro sets assume that the
1069 centered footer will be a modification date and will prepend something like
1070 "Last modified: "; if this is the case, you may want to set C<release> to
1071 the last modified date and C<date> to the version number.
1072
1073 =item section
1074
1075 Set the section for the C<.TH> macro.  The standard section numbering
1076 convention is to use 1 for user commands, 2 for system calls, 3 for
1077 functions, 4 for devices, 5 for file formats, 6 for games, 7 for
1078 miscellaneous information, and 8 for administrator commands.  There is a lot
1079 of variation here, however; some systems (like Solaris) use 4 for file
1080 formats, 5 for miscellaneous information, and 7 for devices.  Still others
1081 use 1m instead of 8, or some mix of both.  About the only section numbers
1082 that are reliably consistent are 1, 2, and 3.
1083
1084 By default, section 1 will be used unless the file ends in .pm in which case
1085 section 3 will be selected.
1086
1087 =back
1088
1089 The standard Pod::Parser method parse_from_filehandle() takes up to two
1090 arguments, the first being the file handle to read POD from and the second
1091 being the file handle to write the formatted output to.  The first defaults
1092 to STDIN if not given, and the second defaults to STDOUT.  The method
1093 parse_from_file() is almost identical, except that its two arguments are the
1094 input and output disk files instead.  See L<Pod::Parser> for the specific
1095 details.
1096
1097 =head1 DIAGNOSTICS
1098
1099 =over 4
1100
1101 =item roff font should be 1 or 2 chars, not `%s'
1102
1103 (F) You specified a *roff font (using C<fixed>, C<fixedbold>, etc.) that
1104 wasn't either one or two characters.  Pod::Man doesn't support *roff fonts
1105 longer than two characters, although some *roff extensions do (the canonical
1106 versions of nroff(1) and troff(1) don't either).
1107
1108 =item Invalid link %s
1109
1110 (W) The POD source contained a C<LE<lt>E<gt>> sequence that Pod::Man was
1111 unable to parse.  You should never see this error message; it probably
1112 indicates a bug in Pod::Man.
1113
1114 =item Unknown escape EE<lt>%sE<gt>
1115
1116 (W) The POD source contained an C<EE<lt>E<gt>> escape that Pod::Man didn't
1117 know about.  C<EE<lt>%sE<gt>> was printed verbatim in the output.
1118
1119 =item Unknown sequence %s
1120
1121 (W) The POD source contained a non-standard interior sequence (something of
1122 the form C<XE<lt>E<gt>>) that Pod::Man didn't know about.  It was ignored.
1123
1124 =item Unmatched =back
1125
1126 (W) Pod::Man encountered a C<=back> command that didn't correspond to an
1127 C<=over> command.
1128
1129 =back
1130
1131 =head1 BUGS
1132
1133 The lint-like features and strict POD format checking done by B<pod2man> are
1134 not yet implemented and should be, along with the corresponding C<lax>
1135 option.
1136
1137 The NAME section should be recognized specially and index entries emitted
1138 for everything in that section.  This would have to be deferred until the
1139 next section, since extraneous things in NAME tends to confuse various man
1140 page processors.
1141
1142 The handling of hyphens, en dashes, and em dashes is somewhat fragile, and
1143 one may get the wrong one under some circumstances.  This should only matter
1144 for troff(1) output.
1145
1146 When and whether to use small caps is somewhat tricky, and Pod::Man doesn't
1147 necessarily get it right.
1148
1149 Pod::Man doesn't handle font names longer than two characters.  Neither do
1150 most troff(1) implementations, but GNU troff does as an extension.  It would
1151 be nice to support as an option for those who want to use it.
1152
1153 The preamble added to each output file is rather verbose, and most of it is
1154 only necessary in the presence of EE<lt>E<gt> escapes for non-ASCII
1155 characters.  It would ideally be nice if all of those definitions were only
1156 output if needed, perhaps on the fly as the characters are used.
1157
1158 Some of the automagic applied to file names assumes Unix directory
1159 separators.
1160
1161 Pod::Man is excessively slow.
1162
1163 =head1 NOTES
1164
1165 The intention is for this module and its driver script to eventually replace
1166 B<pod2man> in Perl core.
1167
1168 =head1 SEE ALSO
1169
1170 L<Pod::Parser|Pod::Parser>, perlpod(1), pod2roff(1), nroff(1), troff(1),
1171 man(1), man(7)
1172
1173 Ossanna, Joseph F., and Brian W. Kernighan.  "Troff User's Manual,"
1174 Computing Science Technical Report No. 54, AT&T Bell Laboratories.  This is
1175 the best documentation of standard nroff(1) and troff(1).  At the time of
1176 this writing, it's available at http://www.cs.bell-labs.com/cm/cs/cstr.html.
1177
1178 The man page documenting the man macro set may be man(5) instead of man(7)
1179 on your system.  Also, please see pod2roff(1) for extensive documentation on
1180 writing manual pages if you've not done it before and aren't familiar with
1181 the conventions.
1182
1183 =head1 AUTHOR
1184
1185 Russ Allbery E<lt>rra@stanford.eduE<gt>, based I<very> heavily on the
1186 original B<pod2man> by Tom Christiansen E<lt>tchrist@mox.perl.comE<gt>.
1187
1188 =cut