lib/Package/Stash.pm

   1 package Package::Stash;
   2 use strict;
   3 use warnings;
   4
   5 use Carp qw(confess);
   6 use Scalar::Util qw(reftype);
   7
   8 =head1 NAME
   9
  10 Package::Stash - routines for manipulating stashes
  11
  12 =head1 SYNOPSIS
  13
  14   my $stash = Package::Stash->new('Foo');
  15   $stash->add_package_symbol('%foo', {bar => 1});
  16   # $Foo::foo{bar} == 1
  17   $stash->has_package_symbol('$foo') # false
  18   my $namespace = $stash->namespace;
  19   *{ $namespace->{foo} }{HASH} # {bar => 1}
  20
  21 =head1 DESCRIPTION
  22
  23 Manipulating stashes (Perl's symbol tables) is occasionally necessary, but
  24 incredibly messy, and easy to get wrong. This module hides all of that behind a
  25 simple API.
  26
  27 NOTE: Most methods in this class require a variable specification that includes
  28 a sigil. If this sigil is absent, it is assumed to represent the IO slot.
  29
  30 =head1 METHODS
  31
  32 =cut
  33
  34 =head2 new $package_name
  35
  36 Creates a new C<Package::Stash> object, for the package given as the only
  37 argument.
  38
  39 =cut
  40
  41 sub new {
  42     my $class = shift;
  43     my ($namespace) = @_;
  44     return bless { 'package' => $namespace }, $class;
  45 }
  46
  47 =head2 name
  48
  49 Returns the name of the package that this object represents.
  50
  51 =cut
  52
  53 sub name {
  54     return $_[0]->{package};
  55 }
  56
  57 =head2 namespace
  58
  59 Returns the raw stash itself.
  60
  61 =cut
  62
  63 sub namespace {
  64     # NOTE:
  65     # because of issues with the Perl API
  66     # to the typeglob in some versions, we
  67     # need to just always grab a new
  68     # reference to the hash here. Ideally
  69     # we could just store a ref and it would
  70     # Just Work, but oh well :\
  71     no strict 'refs';
  72     return \%{$_[0]->name . '::'};
  73 }
  74
  75 {
  76     my %SIGIL_MAP = (
  77         '$' => 'SCALAR',
  78         '@' => 'ARRAY',
  79         '%' => 'HASH',
  80         '&' => 'CODE',
  81         ''  => 'IO',
  82     );
  83
  84     sub _deconstruct_variable_name {
  85         my ($self, $variable) = @_;
  86
  87         (defined $variable && length $variable)
  88             || confess "You must pass a variable name";
  89
  90         my $sigil = substr($variable, 0, 1, '');
  91
  92         if (exists $SIGIL_MAP{$sigil}) {
  93             return ($variable, $sigil, $SIGIL_MAP{$sigil});
  94         }
  95         else {
  96             return ("${sigil}${variable}", '', $SIGIL_MAP{''});
  97         }
  98     }
  99 }
 100
 101 =head2 add_package_symbol $variable $value %opts
 102
 103 Adds a new package symbol, for the symbol given as C<$variable>, and optionally
 104 gives it an initial value of C<$value>. C<$variable> should be the name of
 105 variable including the sigil, so
 106
 107   Package::Stash->new('Foo')->add_package_symbol('%foo')
 108
 109 will create C<%Foo::foo>.
 110
 111 Valid options (all optional) are C<filename>, C<first_line_num>, and
 112 C<last_line_num>.
 113
 114 C<$opts{filename}>, C<$opts{first_line_num}>, and C<$opts{last_line_num}> can
 115 be used to indicate where the symbol should be regarded as having been defined.
 116 Currently these values are only used if the symbol is a subroutine ('C<&>'
 117 sigil) and only if C<$^P & 0x10> is true, in which case the special C<%DB::sub>
 118 hash is updated to record the values of C<filename>, C<first_line_num>, and
 119 C<last_line_num> for the subroutine. If these are not passed, their values are
 120 inferred (as much as possible) from C<caller> information.
 121
 122 This is especially useful for debuggers and profilers, which use C<%DB::sub> to
 123 determine where the source code for a subroutine can be found.  See
 124 L<http://perldoc.perl.org/perldebguts.html#Debugger-Internals> for more
 125 information about C<%DB::sub>.
 126
 127 =cut
 128
 129 sub _valid_for_type {
 130     my $self = shift;
 131     my ($value, $type) = @_;
 132     if ($type eq 'HASH' || $type eq 'ARRAY'
 133      || $type eq 'IO'   || $type eq 'CODE') {
 134         return reftype($value) eq $type;
 135     }
 136     else {
 137         my $ref = reftype($value);
 138         return !defined($ref) || $ref eq 'SCALAR' || $ref eq 'REF' || $ref eq 'LVALUE';
 139     }
 140 }
 141
 142 sub add_package_symbol {
 143     my ($self, $variable, $initial_value, %opts) = @_;
 144
 145     my ($name, $sigil, $type) = ref $variable eq 'HASH'
 146         ? @{$variable}{qw[name sigil type]}
 147         : $self->_deconstruct_variable_name($variable);
 148
 149     my $pkg = $self->name;
 150
 151     if (@_ > 2) {
 152         $self->_valid_for_type($initial_value, $type)
 153             || confess "$initial_value is not of type $type";
 154
 155         # cheap fail-fast check for PERLDBf_SUBLINE and '&'
 156         if ($^P and $^P & 0x10 && $sigil eq '&') {
 157             my $filename = $opts{filename};
 158             my $first_line_num = $opts{first_line_num};
 159
 160             (undef, $filename, $first_line_num) = caller
 161                 if not defined $filename;
 162
 163             my $last_line_num = $opts{last_line_num} || ($first_line_num ||= 0);
 164
 165             # http://perldoc.perl.org/perldebguts.html#Debugger-Internals
 166             $DB::sub{$pkg . '::' . $name} = "$filename:$first_line_num-$last_line_num";
 167         }
 168     }
 169
 170     no strict 'refs';
 171     no warnings 'redefine', 'misc', 'prototype';
 172     *{$pkg . '::' . $name} = ref $initial_value ? $initial_value : \$initial_value;
 173 }
 174
 175 =head2 remove_package_glob $name
 176
 177 Removes all package variables with the given name, regardless of sigil.
 178
 179 =cut
 180
 181 sub remove_package_glob {
 182     my ($self, $name) = @_;
 183     no strict 'refs';
 184     delete ${$self->name . '::'}{$name};
 185 }
 186
 187 # ... these functions deal with stuff on the namespace level
 188
 189 =head2 has_package_symbol $variable
 190
 191 Returns whether or not the given package variable (including sigil) exists.
 192
 193 =cut
 194
 195 sub has_package_symbol {
 196     my ($self, $variable) = @_;
 197
 198     my ($name, $sigil, $type) = ref $variable eq 'HASH'
 199         ? @{$variable}{qw[name sigil type]}
 200         : $self->_deconstruct_variable_name($variable);
 201
 202     my $namespace = $self->namespace;
 203
 204     return unless exists $namespace->{$name};
 205
 206     my $entry_ref = \$namespace->{$name};
 207     if (reftype($entry_ref) eq 'GLOB') {
 208         if ( $type eq 'SCALAR' ) {
 209             return defined ${ *{$entry_ref}{SCALAR} };
 210         }
 211         else {
 212             return defined *{$entry_ref}{$type};
 213         }
 214     }
 215     else {
 216         # a symbol table entry can be -1 (stub), string (stub with prototype),
 217         # or reference (constant)
 218         return $type eq 'CODE';
 219     }
 220 }
 221
 222 =head2 get_package_symbol $variable
 223
 224 Returns the value of the given package variable (including sigil).
 225
 226 =cut
 227
 228 sub get_package_symbol {
 229     my ($self, $variable) = @_;
 230
 231     my ($name, $sigil, $type) = ref $variable eq 'HASH'
 232         ? @{$variable}{qw[name sigil type]}
 233         : $self->_deconstruct_variable_name($variable);
 234
 235     my $namespace = $self->namespace;
 236
 237     if (!exists $namespace->{$name}) {
 238         # assigning to the result of this function like
 239         #   @{$stash->get_package_symbol('@ISA')} = @new_ISA
 240         # makes the result not visible until the variable is explicitly
 241         # accessed... in the case of @ISA, this might never happen
 242         # for instance, assigning like that and then calling $obj->isa
 243         # will fail. see t/005-isa.t
 244         if ($type eq 'ARRAY' && $name ne 'ISA') {
 245             $self->add_package_symbol($variable, []);
 246         }
 247         elsif ($type eq 'HASH') {
 248             $self->add_package_symbol($variable, {});
 249         }
 250         else {
 251             # FIXME
 252             $self->add_package_symbol($variable)
 253         }
 254     }
 255
 256     my $entry_ref = \$namespace->{$name};
 257
 258     if (ref($entry_ref) eq 'GLOB') {
 259         return *{$entry_ref}{$type};
 260     }
 261     else {
 262         if ($type eq 'CODE') {
 263             no strict 'refs';
 264             return \&{ $self->name . '::' . $name };
 265         }
 266         else {
 267             return undef;
 268         }
 269     }
 270 }
 271
 272 =head2 remove_package_symbol $variable
 273
 274 Removes the package variable described by C<$variable> (which includes the
 275 sigil); other variables with the same name but different sigils will be
 276 untouched.
 277
 278 =cut
 279
 280 sub remove_package_symbol {
 281     my ($self, $variable) = @_;
 282
 283     my ($name, $sigil, $type) = ref $variable eq 'HASH'
 284         ? @{$variable}{qw[name sigil type]}
 285         : $self->_deconstruct_variable_name($variable);
 286
 287     # FIXME:
 288     # no doubt this is grossly inefficient and
 289     # could be done much easier and faster in XS
 290
 291     my ($scalar_desc, $array_desc, $hash_desc, $code_desc, $io_desc) = (
 292         { sigil => '$', type => 'SCALAR', name => $name },
 293         { sigil => '@', type => 'ARRAY',  name => $name },
 294         { sigil => '%', type => 'HASH',   name => $name },
 295         { sigil => '&', type => 'CODE',   name => $name },
 296         { sigil => '',  type => 'IO',     name => $name },
 297     );
 298
 299     my ($scalar, $array, $hash, $code, $io);
 300     if ($type eq 'SCALAR') {
 301         $array  = $self->get_package_symbol($array_desc)  if $self->has_package_symbol($array_desc);
 302         $hash   = $self->get_package_symbol($hash_desc)   if $self->has_package_symbol($hash_desc);
 303         $code   = $self->get_package_symbol($code_desc)   if $self->has_package_symbol($code_desc);
 304         $io     = $self->get_package_symbol($io_desc)     if $self->has_package_symbol($io_desc);
 305     }
 306     elsif ($type eq 'ARRAY') {
 307         $scalar = $self->get_package_symbol($scalar_desc);
 308         $hash   = $self->get_package_symbol($hash_desc)   if $self->has_package_symbol($hash_desc);
 309         $code   = $self->get_package_symbol($code_desc)   if $self->has_package_symbol($code_desc);
 310         $io     = $self->get_package_symbol($io_desc)     if $self->has_package_symbol($io_desc);
 311     }
 312     elsif ($type eq 'HASH') {
 313         $scalar = $self->get_package_symbol($scalar_desc);
 314         $array  = $self->get_package_symbol($array_desc)  if $self->has_package_symbol($array_desc);
 315         $code   = $self->get_package_symbol($code_desc)   if $self->has_package_symbol($code_desc);
 316         $io     = $self->get_package_symbol($io_desc)     if $self->has_package_symbol($io_desc);
 317     }
 318     elsif ($type eq 'CODE') {
 319         $scalar = $self->get_package_symbol($scalar_desc);
 320         $array  = $self->get_package_symbol($array_desc)  if $self->has_package_symbol($array_desc);
 321         $hash   = $self->get_package_symbol($hash_desc)   if $self->has_package_symbol($hash_desc);
 322         $io     = $self->get_package_symbol($io_desc)     if $self->has_package_symbol($io_desc);
 323     }
 324     elsif ($type eq 'IO') {
 325         $scalar = $self->get_package_symbol($scalar_desc);
 326         $array  = $self->get_package_symbol($array_desc)  if $self->has_package_symbol($array_desc);
 327         $hash   = $self->get_package_symbol($hash_desc)   if $self->has_package_symbol($hash_desc);
 328         $code   = $self->get_package_symbol($code_desc)   if $self->has_package_symbol($code_desc);
 329     }
 330     else {
 331         confess "This should never ever ever happen";
 332     }
 333
 334     $self->remove_package_glob($name);
 335
 336     $self->add_package_symbol($scalar_desc => $scalar);
 337     $self->add_package_symbol($array_desc  => $array)  if defined $array;
 338     $self->add_package_symbol($hash_desc   => $hash)   if defined $hash;
 339     $self->add_package_symbol($code_desc   => $code)   if defined $code;
 340     $self->add_package_symbol($io_desc     => $io)     if defined $io;
 341 }
 342
 343 =head2 list_all_package_symbols $type_filter
 344
 345 Returns a list of package variable names in the package, without sigils. If a
 346 C<type_filter> is passed, it is used to select package variables of a given
 347 type, where valid types are the slots of a typeglob ('SCALAR', 'CODE', 'HASH',
 348 etc).
 349
 350 =cut
 351
 352 sub list_all_package_symbols {
 353     my ($self, $type_filter) = @_;
 354
 355     my $namespace = $self->namespace;
 356     return keys %{$namespace} unless defined $type_filter;
 357
 358     # NOTE:
 359     # or we can filter based on
 360     # type (SCALAR|ARRAY|HASH|CODE)
 361     if ($type_filter eq 'CODE') {
 362         return grep {
 363             (ref($namespace->{$_})
 364                 ? (ref($namespace->{$_}) eq 'SCALAR')
 365                 : (ref(\$namespace->{$_}) eq 'GLOB'
 366                    && defined(*{$namespace->{$_}}{CODE})));
 367         } keys %{$namespace};
 368     } else {
 369         return grep { *{$namespace->{$_}}{$type_filter} } keys %{$namespace};
 370     }
 371 }
 372
 373 =head1 BUGS
 374
 375 No known bugs.
 376
 377 Please report any bugs through RT: email
 378 C<bug-package-stash at rt.cpan.org>, or browse to
 379 L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Package-Stash>.
 380
 381 =head1 SEE ALSO
 382
 383 L<Class::MOP::Package> - this module is a factoring out of code that used to
 384 live here
 385
 386 =head1 SUPPORT
 387
 388 You can find this documentation for this module with the perldoc command.
 389
 390     perldoc Package::Stash
 391
 392 You can also look for information at:
 393
 394 =over 4
 395
 396 =item * AnnoCPAN: Annotated CPAN documentation
 397
 398 L<http://annocpan.org/dist/Package-Stash>
 399
 400 =item * CPAN Ratings
 401
 402 L<http://cpanratings.perl.org/d/Package-Stash>
 403
 404 =item * RT: CPAN's request tracker
 405
 406 L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Package-Stash>
 407
 408 =item * Search CPAN
 409
 410 L<http://search.cpan.org/dist/Package-Stash>
 411
 412 =back
 413
 414 =head1 AUTHOR
 415
 416   Jesse Luehrs <doy at tozt dot net>
 417
 418 Mostly copied from code from L<Class::MOP::Package>, by Stevan Little and the
 419 Moose Cabal.
 420
 421 =head1 COPYRIGHT AND LICENSE
 422
 423 This software is copyright (c) 2010 by Jesse Luehrs.
 424
 425 This is free software; you can redistribute it and/or modify it under
 426 the same terms as perl itself.
 427
 428 =cut
 429
 430 1;