lib/Package/Stash.pm

   1 package Package::Stash;
   2 use strict;
   3 use warnings;
   4
   5 use Carp qw(confess);
   6 use Scalar::Util qw(reftype);
   7
   8 =head1 NAME
   9
  10 Package::Stash - routines for manipulating stashes
  11
  12 =head1 SYNOPSIS
  13
  14   my $stash = Package::Stash->new('Foo');
  15   $stash->add_package_symbol('%foo', {bar => 1});
  16   # $Foo::foo{bar} == 1
  17   $stash->has_package_symbol('$foo') # false
  18   my $namespace = $stash->namespace;
  19   *{ $namespace->{foo} }{HASH} # {bar => 1}
  20
  21 =head1 DESCRIPTION
  22
  23 Manipulating stashes (Perl's symbol tables) is occasionally necessary, but
  24 incredibly messy, and easy to get wrong. This module hides all of that behind a
  25 simple API.
  26
  27 NOTE: Most methods in this class require a variable specification that includes
  28 a sigil. If this sigil is absent, it is assumed to represent the IO slot.
  29
  30 =head1 METHODS
  31
  32 =cut
  33
  34 =head2 new $package_name
  35
  36 Creates a new C<Package::Stash> object, for the package given as the only
  37 argument.
  38
  39 =cut
  40
  41 sub new {
  42     my $class = shift;
  43     my ($namespace) = @_;
  44     return bless { 'package' => $namespace }, $class;
  45 }
  46
  47 =head2 name
  48
  49 Returns the name of the package that this object represents.
  50
  51 =cut
  52
  53 sub name {
  54     return $_[0]->{package};
  55 }
  56
  57 =head2 namespace
  58
  59 Returns the raw stash itself.
  60
  61 =cut
  62
  63 sub namespace {
  64     # NOTE:
  65     # because of issues with the Perl API
  66     # to the typeglob in some versions, we
  67     # need to just always grab a new
  68     # reference to the hash here. Ideally
  69     # we could just store a ref and it would
  70     # Just Work, but oh well :\
  71     no strict 'refs';
  72     return \%{$_[0]->name . '::'};
  73 }
  74
  75 {
  76     my %SIGIL_MAP = (
  77         '$' => 'SCALAR',
  78         '@' => 'ARRAY',
  79         '%' => 'HASH',
  80         '&' => 'CODE',
  81         ''  => 'IO',
  82     );
  83
  84     sub _deconstruct_variable_name {
  85         my ($self, $variable) = @_;
  86
  87         (defined $variable && length $variable)
  88             || confess "You must pass a variable name";
  89
  90         my $sigil = substr($variable, 0, 1, '');
  91
  92         if (exists $SIGIL_MAP{$sigil}) {
  93             return ($variable, $sigil, $SIGIL_MAP{$sigil});
  94         }
  95         else {
  96             return ("${sigil}${variable}", '', $SIGIL_MAP{''});
  97         }
  98     }
  99 }
 100
 101 =head2 add_package_symbol $variable $value $filename $firstlinenum $lastlinenum
 102
 103 Adds a new package symbol, for the symbol given as C<$variable>, and optionally
 104 gives it an initial value of C<$value>. C<$variable> should be the name of
 105 variable including the sigil, so
 106
 107   Package::Stash->new('Foo')->add_package_symbol('%foo')
 108
 109 will create C<%Foo::foo>.
 110
 111 The optional $filename, $firstlinenum, and $lastlinenum arguments can be used
 112 to indicate where the symbol should be regarded as having been defined.
 113 Currently these values are only used if the symbol is a subroutine ('C<&>'
 114 sigil) and only if C<$^P & 0x10> is true.  In which case the special
 115 C<%DB::sub> hash is updated to record the values of $filename, $firstlinenum,
 116 and $lastlinenum for the subroutine.
 117
 118 This is especially useful for debuggers and profilers, which use C<%DB::sub> to
 119 determine where the source code for a subroutine can be found.  See
 120 L<http://perldoc.perl.org/perldebguts.html#Debugger-Internals> for more
 121 information about C<%DB::sub>.
 122
 123 =cut
 124
 125 sub _valid_for_type {
 126     my $self = shift;
 127     my ($value, $type) = @_;
 128     if ($type eq 'HASH' || $type eq 'ARRAY'
 129      || $type eq 'IO'   || $type eq 'CODE') {
 130         return reftype($value) eq $type;
 131     }
 132     else {
 133         my $ref = reftype($value);
 134         return !defined($ref) || $ref eq 'SCALAR' || $ref eq 'REF' || $ref eq 'LVALUE';
 135     }
 136 }
 137
 138 sub add_package_symbol {
 139     my ($self, $variable, $initial_value) = @_; # extra args unpacked below
 140
 141     my ($name, $sigil, $type) = ref $variable eq 'HASH'
 142         ? @{$variable}{qw[name sigil type]}
 143         : $self->_deconstruct_variable_name($variable);
 144
 145     my $pkg = $self->name;
 146
 147     if (@_ > 2) {
 148         $self->_valid_for_type($initial_value, $type)
 149             || confess "$initial_value is not of type $type";
 150
 151         # cheap fail-fast check for PERLDBf_SUBLINE and '&'
 152         if ($^P and $^P & 0x10 && $sigil eq '&') {
 153             my (undef, undef, undef, $filename, $firstlinenum, $lastlinenum) = @_;
 154
 155             (undef, $filename, $firstlinenum) = caller
 156                 if not defined $filename;
 157             $lastlinenum = $firstlinenum ||= 0
 158                 if not defined $lastlinenum;
 159
 160             # http://perldoc.perl.org/perldebguts.html#Debugger-Internals
 161             $DB::sub{$pkg . '::' . $name} = "$filename:$firstlinenum-$lastlinenum";
 162         }
 163     }
 164
 165     no strict 'refs';
 166     no warnings 'redefine', 'misc', 'prototype';
 167     *{$pkg . '::' . $name} = ref $initial_value ? $initial_value : \$initial_value;
 168 }
 169
 170 =head2 remove_package_glob $name
 171
 172 Removes all package variables with the given name, regardless of sigil.
 173
 174 =cut
 175
 176 sub remove_package_glob {
 177     my ($self, $name) = @_;
 178     no strict 'refs';
 179     delete ${$self->name . '::'}{$name};
 180 }
 181
 182 # ... these functions deal with stuff on the namespace level
 183
 184 =head2 has_package_symbol $variable
 185
 186 Returns whether or not the given package variable (including sigil) exists.
 187
 188 =cut
 189
 190 sub has_package_symbol {
 191     my ($self, $variable) = @_;
 192
 193     my ($name, $sigil, $type) = ref $variable eq 'HASH'
 194         ? @{$variable}{qw[name sigil type]}
 195         : $self->_deconstruct_variable_name($variable);
 196
 197     my $namespace = $self->namespace;
 198
 199     return unless exists $namespace->{$name};
 200
 201     my $entry_ref = \$namespace->{$name};
 202     if (reftype($entry_ref) eq 'GLOB') {
 203         if ( $type eq 'SCALAR' ) {
 204             return defined ${ *{$entry_ref}{SCALAR} };
 205         }
 206         else {
 207             return defined *{$entry_ref}{$type};
 208         }
 209     }
 210     else {
 211         # a symbol table entry can be -1 (stub), string (stub with prototype),
 212         # or reference (constant)
 213         return $type eq 'CODE';
 214     }
 215 }
 216
 217 =head2 get_package_symbol $variable
 218
 219 Returns the value of the given package variable (including sigil).
 220
 221 =cut
 222
 223 sub get_package_symbol {
 224     my ($self, $variable) = @_;
 225
 226     my ($name, $sigil, $type) = ref $variable eq 'HASH'
 227         ? @{$variable}{qw[name sigil type]}
 228         : $self->_deconstruct_variable_name($variable);
 229
 230     my $namespace = $self->namespace;
 231
 232     if (!exists $namespace->{$name}) {
 233         # assigning to the result of this function like
 234         #   @{$stash->get_package_symbol('@ISA')} = @new_ISA
 235         # makes the result not visible until the variable is explicitly
 236         # accessed... in the case of @ISA, this might never happen
 237         # for instance, assigning like that and then calling $obj->isa
 238         # will fail. see t/005-isa.t
 239         if ($type eq 'ARRAY' && $name ne 'ISA') {
 240             $self->add_package_symbol($variable, []);
 241         }
 242         elsif ($type eq 'HASH') {
 243             $self->add_package_symbol($variable, {});
 244         }
 245         else {
 246             # FIXME
 247             $self->add_package_symbol($variable)
 248         }
 249     }
 250
 251     my $entry_ref = \$namespace->{$name};
 252
 253     if (ref($entry_ref) eq 'GLOB') {
 254         return *{$entry_ref}{$type};
 255     }
 256     else {
 257         if ($type eq 'CODE') {
 258             no strict 'refs';
 259             return \&{ $self->name . '::' . $name };
 260         }
 261         else {
 262             return undef;
 263         }
 264     }
 265 }
 266
 267 =head2 remove_package_symbol $variable
 268
 269 Removes the package variable described by C<$variable> (which includes the
 270 sigil); other variables with the same name but different sigils will be
 271 untouched.
 272
 273 =cut
 274
 275 sub remove_package_symbol {
 276     my ($self, $variable) = @_;
 277
 278     my ($name, $sigil, $type) = ref $variable eq 'HASH'
 279         ? @{$variable}{qw[name sigil type]}
 280         : $self->_deconstruct_variable_name($variable);
 281
 282     # FIXME:
 283     # no doubt this is grossly inefficient and
 284     # could be done much easier and faster in XS
 285
 286     my ($scalar_desc, $array_desc, $hash_desc, $code_desc, $io_desc) = (
 287         { sigil => '$', type => 'SCALAR', name => $name },
 288         { sigil => '@', type => 'ARRAY',  name => $name },
 289         { sigil => '%', type => 'HASH',   name => $name },
 290         { sigil => '&', type => 'CODE',   name => $name },
 291         { sigil => '',  type => 'IO',     name => $name },
 292     );
 293
 294     my ($scalar, $array, $hash, $code, $io);
 295     if ($type eq 'SCALAR') {
 296         $array  = $self->get_package_symbol($array_desc)  if $self->has_package_symbol($array_desc);
 297         $hash   = $self->get_package_symbol($hash_desc)   if $self->has_package_symbol($hash_desc);
 298         $code   = $self->get_package_symbol($code_desc)   if $self->has_package_symbol($code_desc);
 299         $io     = $self->get_package_symbol($io_desc)     if $self->has_package_symbol($io_desc);
 300     }
 301     elsif ($type eq 'ARRAY') {
 302         $scalar = $self->get_package_symbol($scalar_desc);
 303         $hash   = $self->get_package_symbol($hash_desc)   if $self->has_package_symbol($hash_desc);
 304         $code   = $self->get_package_symbol($code_desc)   if $self->has_package_symbol($code_desc);
 305         $io     = $self->get_package_symbol($io_desc)     if $self->has_package_symbol($io_desc);
 306     }
 307     elsif ($type eq 'HASH') {
 308         $scalar = $self->get_package_symbol($scalar_desc);
 309         $array  = $self->get_package_symbol($array_desc)  if $self->has_package_symbol($array_desc);
 310         $code   = $self->get_package_symbol($code_desc)   if $self->has_package_symbol($code_desc);
 311         $io     = $self->get_package_symbol($io_desc)     if $self->has_package_symbol($io_desc);
 312     }
 313     elsif ($type eq 'CODE') {
 314         $scalar = $self->get_package_symbol($scalar_desc);
 315         $array  = $self->get_package_symbol($array_desc)  if $self->has_package_symbol($array_desc);
 316         $hash   = $self->get_package_symbol($hash_desc)   if $self->has_package_symbol($hash_desc);
 317         $io     = $self->get_package_symbol($io_desc)     if $self->has_package_symbol($io_desc);
 318     }
 319     elsif ($type eq 'IO') {
 320         $scalar = $self->get_package_symbol($scalar_desc);
 321         $array  = $self->get_package_symbol($array_desc)  if $self->has_package_symbol($array_desc);
 322         $hash   = $self->get_package_symbol($hash_desc)   if $self->has_package_symbol($hash_desc);
 323         $code   = $self->get_package_symbol($code_desc)   if $self->has_package_symbol($code_desc);
 324     }
 325     else {
 326         confess "This should never ever ever happen";
 327     }
 328
 329     $self->remove_package_glob($name);
 330
 331     $self->add_package_symbol($scalar_desc => $scalar);
 332     $self->add_package_symbol($array_desc  => $array)  if defined $array;
 333     $self->add_package_symbol($hash_desc   => $hash)   if defined $hash;
 334     $self->add_package_symbol($code_desc   => $code)   if defined $code;
 335     $self->add_package_symbol($io_desc     => $io)     if defined $io;
 336 }
 337
 338 =head2 list_all_package_symbols $type_filter
 339
 340 Returns a list of package variable names in the package, without sigils. If a
 341 C<type_filter> is passed, it is used to select package variables of a given
 342 type, where valid types are the slots of a typeglob ('SCALAR', 'CODE', 'HASH',
 343 etc).
 344
 345 =cut
 346
 347 sub list_all_package_symbols {
 348     my ($self, $type_filter) = @_;
 349
 350     my $namespace = $self->namespace;
 351     return keys %{$namespace} unless defined $type_filter;
 352
 353     # NOTE:
 354     # or we can filter based on
 355     # type (SCALAR|ARRAY|HASH|CODE)
 356     if ($type_filter eq 'CODE') {
 357         return grep {
 358             (ref($namespace->{$_})
 359                 ? (ref($namespace->{$_}) eq 'SCALAR')
 360                 : (ref(\$namespace->{$_}) eq 'GLOB'
 361                    && defined(*{$namespace->{$_}}{CODE})));
 362         } keys %{$namespace};
 363     } else {
 364         return grep { *{$namespace->{$_}}{$type_filter} } keys %{$namespace};
 365     }
 366 }
 367
 368 =head1 BUGS
 369
 370 No known bugs.
 371
 372 Please report any bugs through RT: email
 373 C<bug-package-stash at rt.cpan.org>, or browse to
 374 L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Package-Stash>.
 375
 376 =head1 SEE ALSO
 377
 378 L<Class::MOP::Package> - this module is a factoring out of code that used to
 379 live here
 380
 381 =head1 SUPPORT
 382
 383 You can find this documentation for this module with the perldoc command.
 384
 385     perldoc Package::Stash
 386
 387 You can also look for information at:
 388
 389 =over 4
 390
 391 =item * AnnoCPAN: Annotated CPAN documentation
 392
 393 L<http://annocpan.org/dist/Package-Stash>
 394
 395 =item * CPAN Ratings
 396
 397 L<http://cpanratings.perl.org/d/Package-Stash>
 398
 399 =item * RT: CPAN's request tracker
 400
 401 L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Package-Stash>
 402
 403 =item * Search CPAN
 404
 405 L<http://search.cpan.org/dist/Package-Stash>
 406
 407 =back
 408
 409 =head1 AUTHOR
 410
 411   Jesse Luehrs <doy at tozt dot net>
 412
 413 Mostly copied from code from L<Class::MOP::Package>, by Stevan Little and the
 414 Moose Cabal.
 415
 416 =head1 COPYRIGHT AND LICENSE
 417
 418 This software is copyright (c) 2010 by Jesse Luehrs.
 419
 420 This is free software; you can redistribute it and/or modify it under
 421 the same terms as perl itself.
 422
 423 =cut
 424
 425 1;