lib/Package/Stash/PP.pm

   1 package Package::Stash::PP;
   2 use strict;
   3 use warnings;
   4 # ABSTRACT: pure perl implementation of the Package::Stash API
   5
   6 use B;
   7 use Carp qw(confess);
   8 use Scalar::Util qw(blessed reftype weaken);
   9 use Symbol;
  10 # before 5.12, assigning to the ISA glob would make it lose its magical ->isa
  11 # powers
  12 use constant BROKEN_ISA_ASSIGNMENT => ($] < 5.012);
  13 # before 5.10, stashes don't ever seem to drop to a refcount of zero, so
  14 # weakening them isn't helpful
  15 use constant BROKEN_WEAK_STASH     => ($] < 5.010);
  16 # before 5.10, the scalar slot was always treated as existing if the
  17 # glob existed
  18 use constant BROKEN_SCALAR_INITIALIZATION => ($] < 5.010);
  19
  20 =head1 SYNOPSIS
  21
  22   use Package::Stash;
  23
  24 =head1 DESCRIPTION
  25
  26 This is a backend for L<Package::Stash> implemented in pure perl, for those without a compiler or who would like to use this inline in scripts.
  27
  28 =cut
  29
  30 sub new {
  31     my $class = shift;
  32     my ($package) = @_;
  33
  34     if (!defined($package) || (ref($package) && ref($package) ne 'HASH')) {
  35         confess "Package::Stash->new must be passed the name of the "
  36               . "package to access";
  37     }
  38     elsif (ref($package) eq 'HASH') {
  39         confess "The pure perl implementation of Package::Stash doesn't "
  40               . "currently support anonymous stashes. You should install "
  41               . "Package::Stash::XS";
  42     }
  43     elsif ($package !~ /\A[0-9A-Z_a-z]+(?:::[0-9A-Z_a-z]+)*\z/) {
  44         confess "$package is not a module name";
  45     }
  46
  47     return bless {
  48         'package' => $package,
  49     }, $class;
  50 }
  51
  52 sub name {
  53     confess "Can't call name as a class method"
  54         unless blessed($_[0]);
  55     return $_[0]->{package};
  56 }
  57
  58 sub namespace {
  59     confess "Can't call namespace as a class method"
  60         unless blessed($_[0]);
  61
  62     if (BROKEN_WEAK_STASH) {
  63         no strict 'refs';
  64         return \%{$_[0]->name . '::'};
  65     }
  66     else {
  67         return $_[0]->{namespace} if defined $_[0]->{namespace};
  68
  69         {
  70             no strict 'refs';
  71             $_[0]->{namespace} = \%{$_[0]->name . '::'};
  72         }
  73
  74         weaken($_[0]->{namespace});
  75
  76         return $_[0]->{namespace};
  77     }
  78 }
  79
  80 {
  81     my %SIGIL_MAP = (
  82         '$' => 'SCALAR',
  83         '@' => 'ARRAY',
  84         '%' => 'HASH',
  85         '&' => 'CODE',
  86         ''  => 'IO',
  87     );
  88
  89     sub _deconstruct_variable_name {
  90         my ($self, $variable) = @_;
  91
  92         my @ret;
  93         if (ref($variable) eq 'HASH') {
  94             @ret = @{$variable}{qw[name sigil type]};
  95         }
  96         else {
  97             (defined $variable && length $variable)
  98                 || confess "You must pass a variable name";
  99
 100             my $sigil = substr($variable, 0, 1, '');
 101
 102             if (exists $SIGIL_MAP{$sigil}) {
 103                 @ret = ($variable, $sigil, $SIGIL_MAP{$sigil});
 104             }
 105             else {
 106                 @ret = ("${sigil}${variable}", '', $SIGIL_MAP{''});
 107             }
 108         }
 109
 110         # XXX in pure perl, this will access things in inner packages,
 111         # in xs, this will segfault - probably look more into this at
 112         # some point
 113         ($ret[0] !~ /::/)
 114             || confess "Variable names may not contain ::";
 115
 116         return @ret;
 117     }
 118 }
 119
 120 sub _valid_for_type {
 121     my $self = shift;
 122     my ($value, $type) = @_;
 123     if ($type eq 'HASH' || $type eq 'ARRAY'
 124      || $type eq 'IO'   || $type eq 'CODE') {
 125         return reftype($value) eq $type;
 126     }
 127     else {
 128         my $ref = reftype($value);
 129         return !defined($ref) || $ref eq 'SCALAR' || $ref eq 'REF' || $ref eq 'LVALUE' || $ref eq 'REGEXP' || $ref eq 'VSTRING';
 130     }
 131 }
 132
 133 sub add_symbol {
 134     my ($self, $variable, $initial_value, %opts) = @_;
 135
 136     my ($name, $sigil, $type) = $self->_deconstruct_variable_name($variable);
 137
 138     if (@_ > 2) {
 139         $self->_valid_for_type($initial_value, $type)
 140             || confess "$initial_value is not of type $type";
 141
 142         # cheap fail-fast check for PERLDBf_SUBLINE and '&'
 143         if ($^P and $^P & 0x10 && $sigil eq '&') {
 144             my $filename = $opts{filename};
 145             my $first_line_num = $opts{first_line_num};
 146
 147             (undef, $filename, $first_line_num) = caller
 148                 if not defined $filename;
 149
 150             my $last_line_num = $opts{last_line_num} || ($first_line_num ||= 0);
 151
 152             # http://perldoc.perl.org/perldebguts.html#Debugger-Internals
 153             $DB::sub{$self->name . '::' . $name} = "$filename:$first_line_num-$last_line_num";
 154         }
 155     }
 156
 157     my $namespace = $self->namespace;
 158     my $gv = $namespace->{$name} || Symbol::gensym;
 159     *$gv = ref $initial_value ? $initial_value : \$initial_value;
 160     $namespace->{$name} = *$gv;
 161 }
 162
 163 sub remove_glob {
 164     my ($self, $name) = @_;
 165     delete $self->namespace->{$name};
 166 }
 167
 168 sub has_symbol {
 169     my ($self, $variable) = @_;
 170
 171     my ($name, $sigil, $type) = $self->_deconstruct_variable_name($variable);
 172
 173     my $namespace = $self->namespace;
 174
 175     return unless exists $namespace->{$name};
 176
 177     my $entry_ref = \$namespace->{$name};
 178     if (reftype($entry_ref) eq 'GLOB') {
 179         if ($type eq 'SCALAR') {
 180             if (BROKEN_SCALAR_INITIALIZATION) {
 181                 return defined ${ *{$entry_ref}{$type} };
 182             }
 183             else {
 184                 return B::svref_2object($entry_ref)->SV->isa('B::SV');
 185             }
 186         }
 187         else {
 188             return defined *{$entry_ref}{$type};
 189         }
 190     }
 191     else {
 192         # a symbol table entry can be -1 (stub), string (stub with prototype),
 193         # or reference (constant)
 194         return $type eq 'CODE';
 195     }
 196 }
 197
 198 sub get_symbol {
 199     my ($self, $variable, %opts) = @_;
 200
 201     my ($name, $sigil, $type) = $self->_deconstruct_variable_name($variable);
 202
 203     my $namespace = $self->namespace;
 204
 205     if (!exists $namespace->{$name}) {
 206         if ($opts{vivify}) {
 207             if ($type eq 'ARRAY') {
 208                 if (BROKEN_ISA_ASSIGNMENT) {
 209                     $self->add_symbol(
 210                         $variable,
 211                         $name eq 'ISA' ? () : ([])
 212                     );
 213                 }
 214                 else {
 215                     $self->add_symbol($variable, []);
 216                 }
 217             }
 218             elsif ($type eq 'HASH') {
 219                 $self->add_symbol($variable, {});
 220             }
 221             elsif ($type eq 'SCALAR') {
 222                 $self->add_symbol($variable);
 223             }
 224             elsif ($type eq 'IO') {
 225                 $self->add_symbol($variable, Symbol::geniosym);
 226             }
 227             elsif ($type eq 'CODE') {
 228                 confess "Don't know how to vivify CODE variables";
 229             }
 230             else {
 231                 confess "Unknown type $type in vivication";
 232             }
 233         }
 234         else {
 235             return undef;
 236         }
 237     }
 238
 239     my $entry_ref = \$namespace->{$name};
 240
 241     if (ref($entry_ref) eq 'GLOB') {
 242         return *{$entry_ref}{$type};
 243     }
 244     else {
 245         if ($type eq 'CODE') {
 246             no strict 'refs';
 247             return \&{ $self->name . '::' . $name };
 248         }
 249         else {
 250             return undef;
 251         }
 252     }
 253 }
 254
 255 sub get_or_add_symbol {
 256     my $self = shift;
 257     $self->get_symbol(@_, vivify => 1);
 258 }
 259
 260 sub remove_symbol {
 261     my ($self, $variable) = @_;
 262
 263     my ($name, $sigil, $type) = $self->_deconstruct_variable_name($variable);
 264
 265     # FIXME:
 266     # no doubt this is grossly inefficient and
 267     # could be done much easier and faster in XS
 268
 269     my ($scalar_desc, $array_desc, $hash_desc, $code_desc, $io_desc) = (
 270         { sigil => '$', type => 'SCALAR', name => $name },
 271         { sigil => '@', type => 'ARRAY',  name => $name },
 272         { sigil => '%', type => 'HASH',   name => $name },
 273         { sigil => '&', type => 'CODE',   name => $name },
 274         { sigil => '',  type => 'IO',     name => $name },
 275     );
 276
 277     my ($scalar, $array, $hash, $code, $io);
 278     if ($type eq 'SCALAR') {
 279         $array  = $self->get_symbol($array_desc)  if $self->has_symbol($array_desc);
 280         $hash   = $self->get_symbol($hash_desc)   if $self->has_symbol($hash_desc);
 281         $code   = $self->get_symbol($code_desc)   if $self->has_symbol($code_desc);
 282         $io     = $self->get_symbol($io_desc)     if $self->has_symbol($io_desc);
 283     }
 284     elsif ($type eq 'ARRAY') {
 285         $scalar = $self->get_symbol($scalar_desc) if $self->has_symbol($scalar_desc) || BROKEN_SCALAR_INITIALIZATION;
 286         $hash   = $self->get_symbol($hash_desc)   if $self->has_symbol($hash_desc);
 287         $code   = $self->get_symbol($code_desc)   if $self->has_symbol($code_desc);
 288         $io     = $self->get_symbol($io_desc)     if $self->has_symbol($io_desc);
 289     }
 290     elsif ($type eq 'HASH') {
 291         $scalar = $self->get_symbol($scalar_desc) if $self->has_symbol($scalar_desc) || BROKEN_SCALAR_INITIALIZATION;
 292         $array  = $self->get_symbol($array_desc)  if $self->has_symbol($array_desc);
 293         $code   = $self->get_symbol($code_desc)   if $self->has_symbol($code_desc);
 294         $io     = $self->get_symbol($io_desc)     if $self->has_symbol($io_desc);
 295     }
 296     elsif ($type eq 'CODE') {
 297         $scalar = $self->get_symbol($scalar_desc) if $self->has_symbol($scalar_desc) || BROKEN_SCALAR_INITIALIZATION;
 298         $array  = $self->get_symbol($array_desc)  if $self->has_symbol($array_desc);
 299         $hash   = $self->get_symbol($hash_desc)   if $self->has_symbol($hash_desc);
 300         $io     = $self->get_symbol($io_desc)     if $self->has_symbol($io_desc);
 301     }
 302     elsif ($type eq 'IO') {
 303         $scalar = $self->get_symbol($scalar_desc) if $self->has_symbol($scalar_desc) || BROKEN_SCALAR_INITIALIZATION;
 304         $array  = $self->get_symbol($array_desc)  if $self->has_symbol($array_desc);
 305         $hash   = $self->get_symbol($hash_desc)   if $self->has_symbol($hash_desc);
 306         $code   = $self->get_symbol($code_desc)   if $self->has_symbol($code_desc);
 307     }
 308     else {
 309         confess "This should never ever ever happen";
 310     }
 311
 312     $self->remove_glob($name);
 313
 314     $self->add_symbol($scalar_desc => $scalar) if defined $scalar;
 315     $self->add_symbol($array_desc  => $array)  if defined $array;
 316     $self->add_symbol($hash_desc   => $hash)   if defined $hash;
 317     $self->add_symbol($code_desc   => $code)   if defined $code;
 318     $self->add_symbol($io_desc     => $io)     if defined $io;
 319 }
 320
 321 sub list_all_symbols {
 322     my ($self, $type_filter) = @_;
 323
 324     my $namespace = $self->namespace;
 325     return keys %{$namespace} unless defined $type_filter;
 326
 327     # NOTE:
 328     # or we can filter based on
 329     # type (SCALAR|ARRAY|HASH|CODE)
 330     if ($type_filter eq 'CODE') {
 331         return grep {
 332             # any non-typeglob in the symbol table is a constant or stub
 333             ref(\$namespace->{$_}) ne 'GLOB'
 334                 # regular subs are stored in the CODE slot of the typeglob
 335                 || defined(*{$namespace->{$_}}{CODE})
 336         } keys %{$namespace};
 337     }
 338     elsif ($type_filter eq 'SCALAR') {
 339         return grep {
 340             BROKEN_SCALAR_INITIALIZATION
 341                 ? (ref(\$namespace->{$_}) eq 'GLOB'
 342                       && defined(${*{$namespace->{$_}}{'SCALAR'}}))
 343                 : (do {
 344                       my $entry = \$namespace->{$_};
 345                       ref($entry) eq 'GLOB'
 346                           && B::svref_2object($entry)->SV->isa('B::SV')
 347                   })
 348         } keys %{$namespace};
 349     }
 350     else {
 351         return grep {
 352             ref(\$namespace->{$_}) eq 'GLOB'
 353                 && defined(*{$namespace->{$_}}{$type_filter})
 354         } keys %{$namespace};
 355     }
 356 }
 357
 358 sub get_all_symbols {
 359     my ($self, $type_filter) = @_;
 360
 361     my $namespace = $self->namespace;
 362     return { %{$namespace} } unless defined $type_filter;
 363
 364     return {
 365         map { $_ => $self->get_symbol({name => $_, type => $type_filter}) }
 366             $self->list_all_symbols($type_filter)
 367     }
 368 }
 369
 370 =head1 BUGS
 371
 372 =over 4
 373
 374 =item * remove_symbol also replaces the associated typeglob
 375
 376 This can cause unexpected behavior when doing manipulation at compile time -
 377 removing subroutines will still allow them to be called from within the package
 378 as subroutines (although they will not be available as methods). This can be
 379 considered a feature in some cases (this is how L<namespace::clean> works, for
 380 instance), but should not be relied upon - use C<remove_glob> directly if you
 381 want this behavior.
 382
 383 =item * Some minor memory leaks
 384
 385 The pure perl implementation has a couple minor memory leaks (see the TODO
 386 tests in t/20-leaks.t) that I'm having a hard time tracking down - these may be
 387 core perl bugs, it's hard to tell.
 388
 389 =back
 390
 391 Please report any bugs through RT: email
 392 C<bug-package-stash at rt.cpan.org>, or browse to
 393 L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Package-Stash>.
 394
 395 =head1 SEE ALSO
 396
 397 =over 4
 398
 399 =item * L<Class::MOP::Package>
 400
 401 This module is a factoring out of code that used to live here
 402
 403 =back
 404
 405 =head1 SUPPORT
 406
 407 You can find this documentation for this module with the perldoc command.
 408
 409     perldoc Package::Stash
 410
 411 You can also look for information at:
 412
 413 =over 4
 414
 415 =item * AnnoCPAN: Annotated CPAN documentation
 416
 417 L<http://annocpan.org/dist/Package-Stash>
 418
 419 =item * CPAN Ratings
 420
 421 L<http://cpanratings.perl.org/d/Package-Stash>
 422
 423 =item * RT: CPAN's request tracker
 424
 425 L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Package-Stash>
 426
 427 =item * Search CPAN
 428
 429 L<http://search.cpan.org/dist/Package-Stash>
 430
 431 =back
 432
 433 =head1 AUTHOR
 434
 435 Jesse Luehrs <doy at tozt dot net>
 436
 437 Mostly copied from code from L<Class::MOP::Package>, by Stevan Little and the
 438 Moose Cabal.
 439
 440 =begin Pod::Coverage
 441
 442 BROKEN_ISA_ASSIGNMENT
 443 add_symbol
 444 get_all_symbols
 445 get_or_add_symbol
 446 get_symbol
 447 has_symbol
 448 list_all_symbols
 449 name
 450 namespace
 451 new
 452 remove_glob
 453
 454 =end Pod::Coverage
 455
 456 =cut
 457
 458 1;