lib/Object/Remote/Connection.pm

   1 package Object::Remote::Connection;
   2
   3 use Object::Remote::Logging qw (:log :dlog router);
   4 use Object::Remote::Future;
   5 use Object::Remote::Null;
   6 use Object::Remote::Handle;
   7 use Object::Remote::CodeContainer;
   8 use Object::Remote::GlobProxy;
   9 use Object::Remote::GlobContainer;
  10 use Object::Remote::Tied;
  11 use Object::Remote;
  12 use Symbol;
  13 use IO::Handle;
  14 use POSIX ":sys_wait_h";
  15 use Module::Runtime qw(use_module);
  16 use Scalar::Util qw(weaken blessed refaddr openhandle);
  17 use JSON::PP qw(encode_json);
  18 use Moo;
  19
  20 BEGIN {
  21   router()->exclude_forwarding;
  22   $SIG{PIPE} = sub { log_debug { "Got a PIPE signal" } };
  23 }
  24
  25 END {
  26   log_debug { "Killing all child processes in the process group" };
  27
  28   #send SIGINT to the process group for our children
  29   kill(1, -2);
  30 }
  31
  32 has _id => ( is => 'ro', required => 1, default => sub { our $NEXT_CONNECTION_ID++ } );
  33
  34 has send_to_fh => (
  35   is => 'ro', required => 1,
  36   trigger => sub {
  37       my $self = $_[0];
  38       $_[1]->autoflush(1);
  39       Dlog_trace { my $id = $self->_id; "connection had send_to_fh set to $_"  } $_[1];
  40   },
  41 );
  42
  43 has read_channel => (
  44   is => 'ro', required => 1,
  45   trigger => sub {
  46     my ($self, $ch) = @_;
  47     my $id = $self->_id;
  48     Dlog_trace { "trigger for read_channel has been invoked for connection $id; file handle is $_" } $ch->fh;
  49     weaken($self);
  50     $ch->on_line_call(sub { $self->_receive(@_) });
  51     $ch->on_close_call(sub {
  52       log_trace { "invoking 'done' on on_close handler for connection id '$id'" };
  53       $self->on_close->done(@_);
  54     });
  55   },
  56 );
  57
  58 has on_close => (
  59   is => 'rw', default => sub { $_[0]->_install_future_handlers(CPS::Future->new) },
  60   trigger => sub {
  61       log_trace { "Installing handlers into future via trigger" };
  62       $_[0]->_install_future_handlers($_[1])
  63   },
  64 );
  65
  66 has child_pid => (is => 'ro');
  67
  68 has local_objects_by_id => (
  69   is => 'ro', default => sub { {} },
  70   coerce => sub { +{ %{$_[0]} } }, # shallow clone on the way in
  71 );
  72
  73 has remote_objects_by_id => (
  74   is => 'ro', default => sub { {} },
  75   coerce => sub { +{ %{$_[0]} } }, # shallow clone on the way in
  76 );
  77
  78 has outstanding_futures => (is => 'ro', default => sub { {} });
  79
  80 has _json => (
  81   is => 'lazy',
  82   handles => {
  83     _deserialize => 'decode',
  84     _encode => 'encode',
  85   },
  86 );
  87
  88 after BUILD => sub {
  89   my ($self) = @_;
  90   my $pid = $self->child_pid;
  91
  92   unless (defined $pid) {
  93       log_trace { "After BUILD invoked for connection but there was no pid" };
  94       return;
  95   }
  96
  97   log_trace { "Setting process group of child process '$pid'" };
  98
  99   setpgrp($self->child_pid, 1);
 100 };
 101
 102 sub BUILD { }
 103
 104 sub _fail_outstanding {
 105   my ($self, $error) = @_;
 106   Dlog_debug { "$$ Failing outstanding futures with '$error' for connection $_" } $self->_id;
 107   my $outstanding = $self->outstanding_futures;
 108   $_->fail("$error\n") for values %$outstanding;
 109   %$outstanding = ();
 110   return;
 111 }
 112
 113 sub _install_future_handlers {
 114     my ($self, $f) = @_;
 115     Dlog_trace { "Installing handlers into future for connection $_" } $self->_id;
 116     weaken($self);
 117     $f->on_done(sub {
 118       my $pid = $self->child_pid;
 119       Dlog_trace { "Executing on_done handler in future for connection $_" } $self->_id;
 120       $self->_fail_outstanding("Object::Remote connection lost: " . ($f->get)[0]);
 121       return unless defined $pid;
 122       log_debug { "Waiting for child '$pid' to exit" };
 123       my $ret = waitpid($pid, 0);
 124       if ($ret != $pid) {
 125         log_debug { "Waited for pid $pid but waitpid() returned $ret" };
 126         return;
 127       } elsif ($? & 127) {
 128           log_warn { "Remote interpreter did not exit cleanly" };
 129       } else {
 130         log_verbose {
 131           my $exit_value = $? >> 8;
 132           "Remote Perl interpreter exited with value '$exit_value'"
 133         };
 134       }
 135     });
 136     return $f;
 137 };
 138
 139 sub _id_to_remote_object {
 140   my ($self, $id) = @_;
 141   Dlog_trace { "fetching proxy for remote object with id '$id' for connection $_" } $self->_id;
 142   return bless({}, 'Object::Remote::Null') if $id eq 'NULL';
 143   (
 144     $self->remote_objects_by_id->{$id}
 145     or Object::Remote::Handle->new(connection => $self, id => $id)
 146   )->proxy;
 147 }
 148
 149 sub _build__json {
 150   weaken(my $self = shift);
 151   JSON::PP->new->filter_json_single_key_object(
 152     __remote_object__ => sub {
 153       $self->_id_to_remote_object(@_);
 154     }
 155   )->filter_json_single_key_object(
 156     __remote_code__ => sub {
 157       my $code_container = $self->_id_to_remote_object(@_);
 158       sub { $code_container->call(@_) };
 159     }
 160   )->filter_json_single_key_object(
 161     __scalar_ref__ => sub {
 162       my $value = shift;
 163       return \$value;
 164     }
 165   )->filter_json_single_key_object(
 166     __glob_ref__ => sub {
 167       my $glob_container = $self->_id_to_remote_object(@_);
 168       my $handle = Symbol::gensym;
 169       tie *$handle, 'Object::Remote::GlobProxy', $glob_container;
 170       return $handle;
 171     }
 172   )->filter_json_single_key_object(
 173     __remote_tied_hash__ => sub {
 174       my %tied_hash;
 175       tie %tied_hash, 'Object::Remote::Tied', $self->_id_to_remote_object(@_);
 176       return \%tied_hash;
 177     }
 178   )->filter_json_single_key_object(
 179     __remote_tied_array__ => sub {
 180       my @tied_array;
 181       tie @tied_array, 'Object::Remote::Tied', $self->_id_to_remote_object(@_);
 182       return \@tied_array;
 183     }
 184   );
 185 }
 186
 187 sub _load_if_possible {
 188   my ($class) = @_;
 189
 190   use_module($class);
 191
 192   if ($@) {
 193     log_debug { "Attempt at loading '$class' failed with '$@'" };
 194   }
 195
 196 }
 197
 198 BEGIN {
 199   unshift our @Guess, sub { blessed($_[0]) ? $_[0] : undef };
 200   map _load_if_possible($_), qw(
 201     Object::Remote::Connector::Local
 202     Object::Remote::Connector::LocalSudo
 203     Object::Remote::Connector::SSH
 204     Object::Remote::Connector::UNIX
 205   );
 206 }
 207
 208 sub conn_from_spec {
 209   my ($class, $spec, @args) = @_;
 210   foreach my $poss (do { our @Guess }) {
 211     if (my $conn = $poss->($spec, @args)) {
 212       return $conn;
 213     }
 214   }
 215
 216   return undef;
 217 }
 218
 219 sub new_from_spec {
 220   my ($class, $spec) = @_;
 221   return $spec if blessed $spec;
 222   my $conn = $class->conn_from_spec($spec);
 223
 224   die "Couldn't figure out what to do with ${spec}"
 225     unless defined $conn;
 226
 227   return $conn->maybe::start::connect;
 228 }
 229
 230 sub remote_object {
 231   my ($self, @args) = @_;
 232   Object::Remote::Handle->new(
 233     connection => $self, @args
 234   )->proxy;
 235 }
 236
 237 sub connect {
 238   my ($self, $to) = @_;
 239   Dlog_debug { "Creating connection to remote node '$to' for connection $_" } $self->_id;
 240   return await_future(
 241     $self->send_class_call(0, 'Object::Remote', connect => $to)
 242   );
 243 }
 244
 245 sub remote_sub {
 246   my ($self, $sub) = @_;
 247   my ($pkg, $name) = $sub =~ m/^(.*)::([^:]+)$/;
 248   Dlog_debug { "Invoking remote sub '$sub' for connection $_" } $self->_id;
 249   return await_future($self->send_class_call(0, $pkg, can => $name));
 250 }
 251
 252 sub send_class_call {
 253   my ($self, $ctx, @call) = @_;
 254   Dlog_trace { "Sending a class call for connection $_" } $self->_id;
 255   $self->send(call => class_call_handler => $ctx => call => @call);
 256 }
 257
 258 sub register_class_call_handler {
 259   my ($self) = @_;
 260   $self->local_objects_by_id->{'class_call_handler'} ||= do {
 261     my $o = $self->new_class_call_handler;
 262     $self->_local_object_to_id($o);
 263     $o;
 264   };
 265 }
 266
 267 sub new_class_call_handler {
 268   Object::Remote::CodeContainer->new(
 269     code => sub {
 270       my ($class, $method) = (shift, shift);
 271       use_module($class)->$method(@_);
 272     }
 273   );
 274 }
 275
 276 sub register_remote {
 277   my ($self, $remote) = @_;
 278   Dlog_trace { my $i = $remote->id; "Registered a remote object with id of '$i' for connection $_" } $self->_id;
 279   weaken($self->remote_objects_by_id->{$remote->id} = $remote);
 280   return $remote;
 281 }
 282
 283 sub send_free {
 284   my ($self, $id) = @_;
 285   Dlog_trace { "sending request to free object '$id' for connection $_" } $self->_id;
 286   #TODO this shows up some times when a remote side dies in the middle of a remote
 287   #method invocation - possibly only when the object is being constructed?
 288   #(in cleanup) Use of uninitialized value $id in delete at ../Object-Remote/lib/Object/Remote/Connection.
 289   delete $self->remote_objects_by_id->{$id};
 290   $self->_send([ free => $id ]);
 291 }
 292
 293 sub send {
 294   my ($self, $type, @call) = @_;
 295
 296   my $future = CPS::Future->new;
 297   my $remote = $self->remote_objects_by_id->{$call[0]};
 298
 299   unshift @call, $type => $self->_local_object_to_id($future);
 300
 301   my $outstanding = $self->outstanding_futures;
 302   $outstanding->{$future} = $future;
 303   $future->on_ready(sub {
 304     undef($remote);
 305     delete $outstanding->{$future}
 306   });
 307
 308   $self->_send(\@call);
 309
 310   return $future;
 311 }
 312
 313 sub send_discard {
 314   my ($self, $type, @call) = @_;
 315
 316   unshift @call, $type => 'NULL';
 317
 318   $self->_send(\@call);
 319 }
 320
 321 sub _send {
 322   my ($self, $to_send) = @_;
 323   my $fh = $self->send_to_fh;
 324   Dlog_trace { "Starting to serialize data in argument to _send for connection $_" } $self->_id;
 325   my $serialized = $self->_serialize($to_send)."\n";
 326   Dlog_trace { my $l = length($serialized); "serialization is completed; sending '$l' characters of serialized data to $_" } $fh;
 327   my $ret;
 328   eval {
 329     #TODO this should be converted over to a non-blocking ::WriteChannel class
 330     die "filehandle is not open" unless openhandle($fh);
 331     log_trace { "file handle has passed openhandle() test; printing to it" };
 332     $ret = print $fh $serialized;
 333     die "print was not successful: $!" unless defined $ret
 334   };
 335
 336   if ($@) {
 337     Dlog_debug { "exception encountered when trying to write to file handle $_: $@" } $fh;
 338     my $error = $@;
 339     chomp($error);
 340     $self->on_close->done("could not write to file handle: $error") unless $self->on_close->is_ready;
 341     return;
 342   }
 343
 344   return $ret;
 345 }
 346
 347 sub _serialize {
 348   my ($self, $data) = @_;
 349   local our @New_Ids = (-1);
 350   return eval {
 351     my $flat = $self->_encode($self->_deobjectify($data));
 352     $flat;
 353   } || do {
 354     my $err = $@; # won't get here if the eval doesn't die
 355     # don't keep refs to new things
 356     delete @{$self->local_objects_by_id}{@New_Ids};
 357     die "Error serializing: $err";
 358   };
 359 }
 360
 361 sub _local_object_to_id {
 362   my ($self, $object) = @_;
 363   my $id = refaddr($object);
 364   $self->local_objects_by_id->{$id} ||= do {
 365     push our(@New_Ids), $id if @New_Ids;
 366     $object;
 367   };
 368   return $id;
 369 }
 370
 371 sub _deobjectify {
 372   my ($self, $data) = @_;
 373   if (blessed($data)) {
 374     return +{ __remote_object__ => $self->_local_object_to_id($data) };
 375   } elsif (my $ref = ref($data)) {
 376     if ($ref eq 'HASH') {
 377       my $tied_to = tied(%$data);
 378       if(defined($tied_to)) {
 379         return +{__remote_tied_hash__ => $self->_local_object_to_id($tied_to)};
 380       } else {
 381         return +{ map +($_ => $self->_deobjectify($data->{$_})), keys %$data };
 382       }
 383     } elsif ($ref eq 'ARRAY') {
 384       my $tied_to = tied(@$data);
 385       if (defined($tied_to)) {
 386         return +{__remote_tied_array__ => $self->_local_object_to_id($tied_to)};
 387       } else {
 388         return [ map $self->_deobjectify($_), @$data ];
 389       }
 390     } elsif ($ref eq 'CODE') {
 391       my $id = $self->_local_object_to_id(
 392                  Object::Remote::CodeContainer->new(code => $data)
 393                );
 394       return +{ __remote_code__ => $id };
 395     } elsif ($ref eq 'SCALAR') {
 396       return +{ __scalar_ref__ => $$data };
 397     } elsif ($ref eq 'GLOB') {
 398       return +{ __glob_ref__ => $self->_local_object_to_id(
 399         Object::Remote::GlobContainer->new(handle => $data)
 400       ) };
 401     } else {
 402       die "Can't collapse reftype $ref";
 403     }
 404   }
 405   return $data; # plain scalar
 406 }
 407
 408 sub _receive {
 409   my ($self, $flat) = @_;
 410   Dlog_trace { my $l = length($flat); "Starting to deserialize $l characters of data for connection $_" } $self->_id;
 411   my ($type, @rest) = eval { @{$self->_deserialize($flat)} }
 412     or do { warn "Deserialize failed for ${flat}: $@"; return };
 413   Dlog_trace { "deserialization complete for connection $_" } $self->_id;
 414   eval { $self->${\"receive_${type}"}(@rest); 1 }
 415     or do { warn "Receive failed for ${flat}: $@"; return };
 416   return;
 417 }
 418
 419 sub receive_free {
 420   my ($self, $id) = @_;
 421   Dlog_trace { "got a receive_free for object '$id' for connection $_" } $self->_id;
 422   delete $self->local_objects_by_id->{$id}
 423     or warn "Free: no such object $id";
 424   return;
 425 }
 426
 427 sub receive_call {
 428   my ($self, $future_id, $id, @rest) = @_;
 429   Dlog_trace { "got a receive_call for object '$id' for connection $_" } $self->_id;
 430   my $future = $self->_id_to_remote_object($future_id);
 431   $future->{method} = 'call_discard_free';
 432   my $local = $self->local_objects_by_id->{$id}
 433     or do { $future->fail("No such object $id"); return };
 434   $self->_invoke($future, $local, @rest);
 435 }
 436
 437 sub receive_call_free {
 438   my ($self, $future, $id, @rest) = @_;
 439   Dlog_trace { "got a receive_call_free for object '$id' for connection $_" } $self->_id;
 440   $self->receive_call($future, $id, undef, @rest);
 441   $self->receive_free($id);
 442 }
 443
 444 sub _invoke {
 445   my ($self, $future, $local, $ctx, $method, @args) = @_;
 446   Dlog_trace { "got _invoke for a method named '$method' for connection $_" } $self->_id;
 447   if ($method =~ /^start::/) {
 448     my $f = $local->$method(@args);
 449     $f->on_done(sub { undef($f); $future->done(@_) });
 450     return unless $f;
 451     $f->on_fail(sub { undef($f); $future->fail(@_) });
 452     return;
 453   }
 454   my $do = sub { $local->$method(@args) };
 455   eval {
 456     $future->done(
 457       defined($ctx)
 458         ? ($ctx ? $do->() : scalar($do->()))
 459         : do { $do->(); () }
 460     );
 461     1;
 462   } or do { $future->fail($@); return; };
 463   return;
 464 }
 465
 466 1;
 467
 468 =head1 NAME
 469
 470 Object::Remote::Connection - An underlying connection for L<Object::Remote>
 471
 472 =head1 LAME
 473
 474 Shipping prioritised over writing this part up. Blame mst.
 475
 476 =cut