lib/Object/Remote/Connection.pm

   1 package Object::Remote::Connection;
   2
   3 use Object::Remote::Logging qw (:log :dlog);
   4 use Object::Remote::Future;
   5 use Object::Remote::Null;
   6 use Object::Remote::Handle;
   7 use Object::Remote::CodeContainer;
   8 use Object::Remote::GlobProxy;
   9 use Object::Remote::GlobContainer;
  10 use Object::Remote::Tied;
  11 use Object::Remote;
  12 use Symbol;
  13 use IO::Handle;
  14 use POSIX ":sys_wait_h";
  15 use Module::Runtime qw(use_module);
  16 use Scalar::Util qw(weaken blessed refaddr openhandle);
  17 use JSON::PP qw(encode_json);
  18 use Moo;
  19
  20 BEGIN {
  21   #this will reap child processes as soon
  22   #as they are done executing so the process
  23   #table cleans up as fast as possible but
  24   #anything that needs to call waitpid()
  25   #in the future to get the exit value of
  26   #a child will get trash results if
  27   #the signal handler was running.
  28   #If creating a child and getting the
  29   #exit value is required then set
  30   #a localized version of the signal
  31   #handler for CHLD to be 'IGNORE'
  32   #in the smallest block possible
  33   #and outside the block send
  34   #the process a CHLD signal
  35   #to reap anything that may
  36   #have exited while blocked
  37   #in waitpid()
  38   $SIG{CHLD} = sub {
  39     my $kid;
  40     log_trace { "CHLD signal handler is executing" };
  41     do {
  42       $kid = waitpid(-1, WNOHANG);
  43       log_debug { "waitpid() returned '$kid'" };
  44     } while $kid > 0;
  45     log_trace { "CHLD signal handler is done" };
  46   };
  47
  48   $SIG{PIPE} = sub { log_debug { "Got a PIPE signal" } };
  49 }
  50
  51 END {
  52   log_debug { "Killing all child processes in the process group" };
  53
  54   #send SIGINT to the process group for our children
  55   kill(1, -2);
  56 }
  57
  58
  59 our $DEBUG = !!$ENV{OBJECT_REMOTE_DEBUG};
  60 #numbering each connection allows it to be
  61 #tracked along with file handles in
  62 #the logs
  63
  64 has _id => ( is => 'ro', required => 1, default => sub { our $NEXT_CONNECTION_ID++ } );
  65
  66 has send_to_fh => (
  67   is => 'ro', required => 1,
  68   trigger => sub {
  69       my $self = $_[0];
  70       $_[1]->autoflush(1);
  71       Dlog_trace { my $id = $self->_id; "connection had send_to_fh set to $_"  } $_[1];
  72   },
  73 );
  74
  75 #TODO see if this is another case of the same bug below
  76 #where trigger never fires because the attribute isn't
  77 #actually set at any time
  78 has read_channel => (
  79   is => 'ro', required => 1,
  80   trigger => sub {
  81     my ($self, $ch) = @_;
  82     my $id = $self->_id;
  83     Dlog_trace { "trigger for read_channel has been invoked for connection $id; file handle is $_" } $ch->fh;
  84     weaken($self);
  85     $ch->on_line_call(sub { $self->_receive(@_) });
  86     $ch->on_close_call(sub {
  87         log_trace { "invoking 'done' on on_close handler for connection id '$id'" };
  88         $self->on_close->done(@_);
  89     });
  90   },
  91 );
  92
  93 #TODO properly fix this bug -
  94 #trigger can't ever be invoked with a default
  95 #value and the on_close attribute is read only....
  96 #the future never gets the on_done handler
  97 #installed
  98 sub BUILD {
  99   my ($self) = @_;
 100   $self->on_close(CPS::Future->new);
 101 }
 102
 103 after BUILD => sub {
 104   my ($self) = @_;
 105
 106   return unless defined $self->child_pid;
 107
 108   log_debug { "Setting process group of child process" };
 109
 110   setpgrp($self->child_pid, 1);
 111 };
 112
 113
 114 has on_close => (
 115   is => 'rw', default => sub { CPS::Future->new },
 116   trigger => sub {
 117     my ($self, $f) = @_;
 118     Dlog_trace { "trigger for on_close has been invoked for connection $_" } $self->_id;
 119     weaken($self);
 120     $f->on_done(sub {
 121       Dlog_trace { "failing all of the outstanding futures for connection $_" } $self->_id;
 122       $self->_fail_outstanding("Object::Remote connection lost: " . ($f->get)[0]);
 123     });
 124   }
 125 );
 126
 127 has child_pid => (is => 'ro');
 128
 129 has local_objects_by_id => (
 130   is => 'ro', default => sub { {} },
 131   coerce => sub { +{ %{$_[0]} } }, # shallow clone on the way in
 132 );
 133
 134 has remote_objects_by_id => (
 135   is => 'ro', default => sub { {} },
 136   coerce => sub { +{ %{$_[0]} } }, # shallow clone on the way in
 137 );
 138
 139 has outstanding_futures => (is => 'ro', default => sub { {} });
 140
 141 sub _fail_outstanding {
 142   my ($self, $error) = @_;
 143   Dlog_debug { "Failing outstanding futures with '$error' for connection $_" } $self->_id;
 144   my $outstanding = $self->outstanding_futures;
 145   $_->fail("$error\n") for values %$outstanding;
 146   %$outstanding = ();
 147   return;
 148 }
 149
 150 has _json => (
 151   is => 'lazy',
 152   handles => {
 153     _deserialize => 'decode',
 154     _encode => 'encode',
 155   },
 156 );
 157
 158 sub _id_to_remote_object {
 159   my ($self, $id) = @_;
 160   Dlog_trace { "fetching proxy for remote object with id '$id' for connection $_" } $self->_id;
 161   return bless({}, 'Object::Remote::Null') if $id eq 'NULL';
 162   (
 163     $self->remote_objects_by_id->{$id}
 164     or Object::Remote::Handle->new(connection => $self, id => $id)
 165   )->proxy;
 166 }
 167
 168 sub _build__json {
 169   weaken(my $self = shift);
 170   JSON::PP->new->filter_json_single_key_object(
 171     __remote_object__ => sub {
 172       $self->_id_to_remote_object(@_);
 173     }
 174   )->filter_json_single_key_object(
 175     __remote_code__ => sub {
 176       my $code_container = $self->_id_to_remote_object(@_);
 177       sub { $code_container->call(@_) };
 178     }
 179   )->filter_json_single_key_object(
 180     __scalar_ref__ => sub {
 181       my $value = shift;
 182       return \$value;
 183     }
 184   )->filter_json_single_key_object(
 185     __glob_ref__ => sub {
 186       my $glob_container = $self->_id_to_remote_object(@_);
 187       my $handle = Symbol::gensym;
 188       tie *$handle, 'Object::Remote::GlobProxy', $glob_container;
 189       return $handle;
 190     }
 191   )->filter_json_single_key_object(
 192     __remote_tied_hash__ => sub {
 193         my %tied_hash;
 194         tie %tied_hash, 'Object::Remote::Tied', $self->_id_to_remote_object(@_);
 195         return \%tied_hash;
 196     }
 197   )->filter_json_single_key_object(
 198     __remote_tied_array__ => sub {
 199         my @tied_array;
 200         tie @tied_array, 'Object::Remote::Tied', $self->_id_to_remote_object(@_);
 201         return \@tied_array;
 202     }
 203   );
 204 }
 205
 206 sub _load_if_possible {
 207   my ($class) = @_;
 208
 209   eval "require $class";
 210
 211   if ($@) {
 212     log_debug { "Attempt at loading '$class' failed with '$@'" };
 213   }
 214
 215 }
 216
 217 BEGIN {
 218   unshift our @Guess, sub { blessed($_[0]) ? $_[0] : undef };
 219   map _load_if_possible($_), qw(
 220     Object::Remote::Connector::Local
 221     Object::Remote::Connector::LocalSudo
 222     Object::Remote::Connector::SSH
 223     Object::Remote::Connector::UNIX
 224   );
 225 }
 226
 227 sub conn_from_spec {
 228   my ($class, $spec, @args) = @_;
 229   foreach my $poss (do { our @Guess }) {
 230     if (my $conn = $poss->($spec, @args)) {
 231       return $conn;
 232     }
 233   }
 234
 235   return undef;
 236 }
 237
 238 sub new_from_spec {
 239   my ($class, $spec) = @_;
 240   return $spec if blessed $spec;
 241   my $conn = $class->conn_from_spec($spec);
 242
 243   die "Couldn't figure out what to do with ${spec}"
 244     unless defined $conn;
 245
 246   return $conn->maybe::start::connect;
 247 }
 248
 249 sub remote_object {
 250   my ($self, @args) = @_;
 251   Object::Remote::Handle->new(
 252     connection => $self, @args
 253   )->proxy;
 254 }
 255
 256 sub connect {
 257   my ($self, $to) = @_;
 258   Dlog_debug { "Creating connection to remote node '$to' for connection $_" } $self->_id;
 259   return await_future(
 260     $self->send_class_call(0, 'Object::Remote', connect => $to)
 261   );
 262 }
 263
 264 sub remote_sub {
 265   my ($self, $sub) = @_;
 266   my ($pkg, $name) = $sub =~ m/^(.*)::([^:]+)$/;
 267   Dlog_debug { "Invoking remote sub '$sub' for connection $_" } $self->_id;
 268   return await_future($self->send_class_call(0, $pkg, can => $name));
 269 }
 270
 271 sub send_class_call {
 272   my ($self, $ctx, @call) = @_;
 273   Dlog_trace { "Sending a class call for connection $_" } $self->_id;
 274   $self->send(call => class_call_handler => $ctx => call => @call);
 275 }
 276
 277 sub register_class_call_handler {
 278   my ($self) = @_;
 279   $self->local_objects_by_id->{'class_call_handler'} ||= do {
 280     my $o = $self->new_class_call_handler;
 281     $self->_local_object_to_id($o);
 282     $o;
 283   };
 284 }
 285
 286 sub new_class_call_handler {
 287   Object::Remote::CodeContainer->new(
 288     code => sub {
 289       my ($class, $method) = (shift, shift);
 290       use_module($class)->$method(@_);
 291     }
 292   );
 293 }
 294
 295 sub register_remote {
 296   my ($self, $remote) = @_;
 297   Dlog_trace { my $i = $remote->id; "Registered a remote object with id of '$i' for connection $_" } $self->_id;
 298   weaken($self->remote_objects_by_id->{$remote->id} = $remote);
 299   return $remote;
 300 }
 301
 302 sub send_free {
 303   my ($self, $id) = @_;
 304   Dlog_trace { "sending request to free object '$id' for connection $_" } $self->_id;
 305   delete $self->remote_objects_by_id->{$id};
 306   $self->_send([ free => $id ]);
 307 }
 308
 309 sub send {
 310   my ($self, $type, @call) = @_;
 311
 312   my $future = CPS::Future->new;
 313   my $remote = $self->remote_objects_by_id->{$call[0]};
 314
 315   unshift @call, $type => $self->_local_object_to_id($future);
 316
 317   my $outstanding = $self->outstanding_futures;
 318   $outstanding->{$future} = $future;
 319   $future->on_ready(sub {
 320     undef($remote);
 321     delete $outstanding->{$future}
 322   });
 323
 324   $self->_send(\@call);
 325
 326   return $future;
 327 }
 328
 329 sub send_discard {
 330   my ($self, $type, @call) = @_;
 331
 332   unshift @call, $type => 'NULL';
 333
 334   $self->_send(\@call);
 335 }
 336
 337 sub _send {
 338   my ($self, $to_send) = @_;
 339   my $fh = $self->send_to_fh;
 340   Dlog_trace { "Starting to serialize data in argument to _send for connection $_" } $self->_id;
 341   my $serialized = $self->_serialize($to_send)."\n";
 342   Dlog_trace { my $l = length($serialized); "serialization is completed; sending '$l' characters of serialized data to $_" } $fh;
 343   #TODO this is very risky for deadlocks unless it's set to non-blocking and then with out extra
 344   #logic it could easily do short-writes to the remote side - how about taking this entire buffer
 345   #and having the run loop send it to the file handle so this doesn't block while the sending
 346   #is happening?
 347   my $ret;
 348   eval {
 349       local($SIG{PIPE}) = 'IGNORE';
 350       die "filehandle is not open" unless openhandle($fh);
 351       log_trace { "file handle has passed openhandle() test; printing to it" };
 352       $ret = print $fh $serialized;
 353       die "print was not successful: $!" unless defined $ret
 354   };
 355
 356   if ($@) {
 357       Dlog_debug { "exception encountered when trying to write to file handle $_: $@" } $fh;
 358       my $error = $@; chomp($error);
 359       $self->on_close->done("could not write to file handle: $error") unless $self->on_close->is_ready;
 360       return;
 361   }
 362
 363   return $ret;
 364 }
 365
 366 sub _serialize {
 367   my ($self, $data) = @_;
 368   local our @New_Ids = (-1);
 369   return eval {
 370     my $flat = $self->_encode($self->_deobjectify($data));
 371     warn "$$ >>> ${flat}\n" if $DEBUG;
 372     $flat;
 373   } || do {
 374     my $err = $@; # won't get here if the eval doesn't die
 375     # don't keep refs to new things
 376     delete @{$self->local_objects_by_id}{@New_Ids};
 377     die "Error serializing: $err";
 378   };
 379 }
 380
 381 sub _local_object_to_id {
 382   my ($self, $object) = @_;
 383   my $id = refaddr($object);
 384   $self->local_objects_by_id->{$id} ||= do {
 385     push our(@New_Ids), $id if @New_Ids;
 386     $object;
 387   };
 388   return $id;
 389 }
 390
 391 sub _deobjectify {
 392   my ($self, $data) = @_;
 393   if (blessed($data)) {
 394     return +{ __remote_object__ => $self->_local_object_to_id($data) };
 395   } elsif (my $ref = ref($data)) {
 396     if ($ref eq 'HASH') {
 397       my $tied_to = tied(%$data);
 398       if(defined($tied_to)) {
 399         return +{__remote_tied_hash__ => $self->_local_object_to_id($tied_to)};
 400       } else {
 401         return +{ map +($_ => $self->_deobjectify($data->{$_})), keys %$data };
 402       }
 403     } elsif ($ref eq 'ARRAY') {
 404       my $tied_to = tied(@$data);
 405       if (defined($tied_to)) {
 406         return +{__remote_tied_array__ => $self->_local_object_to_id($tied_to)};
 407       } else {
 408         return [ map $self->_deobjectify($_), @$data ];
 409       }
 410     } elsif ($ref eq 'CODE') {
 411       my $id = $self->_local_object_to_id(
 412                  Object::Remote::CodeContainer->new(code => $data)
 413                );
 414       return +{ __remote_code__ => $id };
 415     } elsif ($ref eq 'SCALAR') {
 416       return +{ __scalar_ref__ => $$data };
 417     } elsif ($ref eq 'GLOB') {
 418       return +{ __glob_ref__ => $self->_local_object_to_id(
 419         Object::Remote::GlobContainer->new(handle => $data)
 420       ) };
 421     } else {
 422       die "Can't collapse reftype $ref";
 423     }
 424   }
 425   return $data; # plain scalar
 426 }
 427
 428 sub _receive {
 429   my ($self, $flat) = @_;
 430   warn "$$ <<< $flat\n" if $DEBUG;
 431   Dlog_trace { my $l = length($flat); "Starting to deserialize $l characters of data for connection $_" } $self->_id;
 432   my ($type, @rest) = eval { @{$self->_deserialize($flat)} }
 433     or do { warn "Deserialize failed for ${flat}: $@"; return };
 434   Dlog_trace { "deserialization complete for connection $_" } $self->_id;
 435   eval { $self->${\"receive_${type}"}(@rest); 1 }
 436     or do { warn "Receive failed for ${flat}: $@"; return };
 437   return;
 438 }
 439
 440 sub receive_free {
 441   my ($self, $id) = @_;
 442   Dlog_trace { "got a receive_free for object '$id' for connection $_" } $self->_id;
 443   delete $self->local_objects_by_id->{$id}
 444     or warn "Free: no such object $id";
 445   return;
 446 }
 447
 448 sub receive_call {
 449   my ($self, $future_id, $id, @rest) = @_;
 450   Dlog_trace { "got a receive_call for object '$id' for connection $_" } $self->_id;
 451   my $future = $self->_id_to_remote_object($future_id);
 452   $future->{method} = 'call_discard_free';
 453   my $local = $self->local_objects_by_id->{$id}
 454     or do { $future->fail("No such object $id"); return };
 455   $self->_invoke($future, $local, @rest);
 456 }
 457
 458 sub receive_call_free {
 459   my ($self, $future, $id, @rest) = @_;
 460   Dlog_trace { "got a receive_call_free for object '$id' for connection $_" } $self->_id;
 461   $self->receive_call($future, $id, undef, @rest);
 462   $self->receive_free($id);
 463 }
 464
 465 sub _invoke {
 466   my ($self, $future, $local, $ctx, $method, @args) = @_;
 467   Dlog_trace { "got _invoke for a method named '$method' for connection $_" } $self->_id;
 468   if ($method =~ /^start::/) {
 469     my $f = $local->$method(@args);
 470     $f->on_done(sub { undef($f); $future->done(@_) });
 471     return unless $f;
 472     $f->on_fail(sub { undef($f); $future->fail(@_) });
 473     return;
 474   }
 475   my $do = sub { $local->$method(@args) };
 476   eval {
 477     $future->done(
 478       defined($ctx)
 479         ? ($ctx ? $do->() : scalar($do->()))
 480         : do { $do->(); () }
 481     );
 482     1;
 483   } or do { $future->fail($@); return; };
 484   return;
 485 }
 486
 487 1;
 488
 489 =head1 NAME
 490
 491 Object::Remote::Connection - An underlying connection for L<Object::Remote>
 492
 493 =head1 LAME
 494
 495 Shipping prioritised over writing this part up. Blame mst.
 496
 497 =cut