lib/Mouse.pm

   1 package Mouse;
   2 use 5.006_002;
   3
   4 use Mouse::Exporter; # enables strict and warnings
   5
   6 our $VERSION = '0.45';
   7
   8 use Carp         qw(confess);
   9 use Scalar::Util qw(blessed);
  10
  11 use Mouse::Util qw(load_class is_class_loaded get_code_package not_supported);
  12
  13 use Mouse::Meta::Module;
  14 use Mouse::Meta::Class;
  15 use Mouse::Meta::Role;
  16 use Mouse::Meta::Attribute;
  17 use Mouse::Object;
  18 use Mouse::Util::TypeConstraints ();
  19
  20 Mouse::Exporter->setup_import_methods(
  21     as_is => [qw(
  22         extends with
  23         has
  24         before after around
  25         override super
  26         augment  inner
  27     ),
  28         \&Scalar::Util::blessed,
  29         \&Carp::confess,
  30    ],
  31 );
  32
  33
  34 sub extends {
  35     Mouse::Meta::Class->initialize(scalar caller)->superclasses(@_);
  36     return;
  37 }
  38
  39 sub with {
  40     Mouse::Util::apply_all_roles(scalar(caller), @_);
  41     return;
  42 }
  43
  44 sub has {
  45     my $meta = Mouse::Meta::Class->initialize(scalar caller);
  46     my $name = shift;
  47
  48     $meta->throw_error(q{Usage: has 'name' => ( key => value, ... )})
  49         if @_ % 2; # odd number of arguments
  50
  51     if(ref $name){ # has [qw(foo bar)] => (...)
  52         for (@{$name}){
  53             $meta->add_attribute($_ => @_);
  54         }
  55     }
  56     else{ # has foo => (...)
  57         $meta->add_attribute($name => @_);
  58     }
  59     return;
  60 }
  61
  62 sub before {
  63     my $meta = Mouse::Meta::Class->initialize(scalar caller);
  64
  65     my $code = pop;
  66
  67     for (@_) {
  68         $meta->add_before_method_modifier($_ => $code);
  69     }
  70     return;
  71 }
  72
  73 sub after {
  74     my $meta = Mouse::Meta::Class->initialize(scalar caller);
  75
  76     my $code = pop;
  77
  78     for (@_) {
  79         $meta->add_after_method_modifier($_ => $code);
  80     }
  81     return;
  82 }
  83
  84 sub around {
  85     my $meta = Mouse::Meta::Class->initialize(scalar caller);
  86
  87     my $code = pop;
  88
  89     for (@_) {
  90         $meta->add_around_method_modifier($_ => $code);
  91     }
  92     return;
  93 }
  94
  95 our $SUPER_PACKAGE;
  96 our $SUPER_BODY;
  97 our @SUPER_ARGS;
  98
  99 sub super {
 100     # This check avoids a recursion loop - see
 101     # t/100_bugs/020_super_recursion.t
 102     return if  defined $SUPER_PACKAGE && $SUPER_PACKAGE ne caller();
 103     return if !defined $SUPER_BODY;
 104     $SUPER_BODY->(@SUPER_ARGS);
 105 }
 106
 107 sub override {
 108     # my($name, $method) = @_;
 109     Mouse::Meta::Class->initialize(scalar caller)->add_override_method_modifier(@_);
 110 }
 111
 112 our %INNER_BODY;
 113 our %INNER_ARGS;
 114
 115 sub inner {
 116     my $pkg = caller();
 117     if ( my $body = $INNER_BODY{$pkg} ) {
 118         my $args = $INNER_ARGS{$pkg};
 119         local $INNER_ARGS{$pkg};
 120         local $INNER_BODY{$pkg};
 121         return $body->(@{$args});
 122     }
 123     else {
 124         return;
 125     }
 126 }
 127
 128 sub augment {
 129     #my($name, $method) = @_;
 130     Mouse::Meta::Class->initialize(scalar caller)->add_augment_method_modifier(@_);
 131     return;
 132 }
 133
 134 sub init_meta {
 135     shift;
 136     my %args = @_;
 137
 138     my $class = $args{for_class}
 139                     or confess("Cannot call init_meta without specifying a for_class");
 140
 141     my $base_class = $args{base_class} || 'Mouse::Object';
 142     my $metaclass  = $args{metaclass}  || 'Mouse::Meta::Class';
 143
 144     my $meta = $metaclass->initialize($class);
 145
 146     $meta->add_method(meta => sub{
 147         return $metaclass->initialize(ref($_[0]) || $_[0]);
 148     });
 149
 150     $meta->superclasses($base_class)
 151         unless $meta->superclasses;
 152
 153     # make a class type for each Mouse class
 154     Mouse::Util::TypeConstraints::class_type($class)
 155         unless Mouse::Util::TypeConstraints::find_type_constraint($class);
 156
 157     return $meta;
 158 }
 159
 160 1;
 161 __END__
 162
 163 =head1 NAME
 164
 165 Mouse - Moose minus the antlers
 166
 167 =head1 VERSION
 168
 169 This document describes Mouse version 0.45
 170
 171 =head1 SYNOPSIS
 172
 173     package Point;
 174     use Mouse; # automatically turns on strict and warnings
 175
 176     has 'x' => (is => 'rw', isa => 'Int');
 177     has 'y' => (is => 'rw', isa => 'Int');
 178
 179     sub clear {
 180         my $self = shift;
 181         $self->x(0);
 182         $self->y(0);
 183     }
 184
 185     package Point3D;
 186     use Mouse;
 187
 188     extends 'Point';
 189
 190     has 'z' => (is => 'rw', isa => 'Int');
 191
 192     after 'clear' => sub {
 193         my $self = shift;
 194         $self->z(0);
 195     };
 196
 197 =head1 DESCRIPTION
 198
 199 L<Moose> is wonderful. B<Use Moose instead of Mouse.>
 200
 201 Unfortunately, Moose has a compile-time penalty. Though significant progress
 202 has been made over the years, the compile time penalty is a non-starter for
 203 some very specific applications. If you are writing a command-line application
 204 or CGI script where startup time is essential, you may not be able to use
 205 Moose. We recommend that you instead use L<HTTP::Engine> and FastCGI for the
 206 latter, if possible.
 207
 208 Mouse aims to alleviate this by providing a subset of Moose's functionality,
 209 faster.
 210
 211 We're also going as light on dependencies as possible. Mouse currently has
 212 B<no dependencies> except for testing modules.
 213
 214 =head2 MOOSE COMPATIBILITY
 215
 216 Compatibility with Moose has been the utmost concern. Fewer than 1% of the
 217 tests fail when run against Moose instead of Mouse. Mouse code coverage is also
 218 over 96%. Even the error messages are taken from Moose. The Mouse code just
 219 runs the test suite 4x faster.
 220
 221 The idea is that, if you need the extra power, you should be able to run
 222 C<s/Mouse/Moose/g> on your codebase and have nothing break. To that end,
 223 we have written L<Any::Moose> which will act as Mouse unless Moose is loaded,
 224 in which case it will act as Moose. Since Mouse is a little sloppier than
 225 Moose, if you run into weird errors, it would be worth running:
 226
 227     ANY_MOOSE=Moose perl your-script.pl
 228
 229 to see if the bug is caused by Mouse. Moose's diagnostics and validation are
 230 also much better.
 231
 232 See also L<Mouse::Spec> for compatibility and incompatibility with Moose.
 233
 234 =head2 MouseX
 235
 236 Please don't copy MooseX code to MouseX. If you need extensions, you really
 237 should upgrade to Moose. We don't need two parallel sets of extensions!
 238
 239 If you really must write a Mouse extension, please contact the Moose mailing
 240 list or #moose on IRC beforehand.
 241
 242 =head1 KEYWORDS
 243
 244 =head2 C<< $object->meta -> Mouse::Meta::Class >>
 245
 246 Returns this class' metaclass instance.
 247
 248 =head2 C<< extends superclasses >>
 249
 250 Sets this class' superclasses.
 251
 252 =head2 C<< before (method|methods) => CodeRef >>
 253
 254 Installs a "before" method modifier. See L<Moose/before>.
 255
 256 =head2 C<< after (method|methods) => CodeRef >>
 257
 258 Installs an "after" method modifier. See L<Moose/after>.
 259
 260 =head2 C<< around (method|methods) => CodeRef >>
 261
 262 Installs an "around" method modifier. See L<Moose/around>.
 263
 264 =head2 C<< has (name|names) => parameters >>
 265
 266 Adds an attribute (or if passed an arrayref of names, multiple attributes) to
 267 this class. Options:
 268
 269 =over 4
 270
 271 =item C<< is => ro|rw|bare >>
 272
 273 The I<is> option accepts either I<rw> (for read/write), I<ro> (for read
 274 only) or I<bare> (for nothing). These will create either a read/write accessor
 275 or a read-only accessor respectively, using the same name as the C<$name> of
 276 the attribute.
 277
 278 If you need more control over how your accessors are named, you can
 279 use the C<reader>, C<writer> and C<accessor> options, however if you
 280 use those, you won't need the I<is> option.
 281
 282 =item C<< isa => TypeName | ClassName >>
 283
 284 Provides type checking in the constructor and accessor. The following types are
 285 supported. Any unknown type is taken to be a class check
 286 (e.g. C<< isa => 'DateTime' >> would accept only L<DateTime> objects).
 287
 288     Any Item Bool Undef Defined Value Num Int Str ClassName
 289     Ref ScalarRef ArrayRef HashRef CodeRef RegexpRef GlobRef
 290     FileHandle Object
 291
 292 For more documentation on type constraints, see L<Mouse::Util::TypeConstraints>.
 293
 294 =item C<< does => RoleName >>
 295
 296 This will accept the name of a role which the value stored in this attribute
 297 is expected to have consumed.
 298
 299 =item C<< coerce => Bool >>
 300
 301 This will attempt to use coercion with the supplied type constraint to change
 302 the value passed into any accessors or constructors. You B<must> have supplied
 303 a type constraint in order for this to work. See L<Moose::Cookbook::Basics::Recipe5>
 304 for an example.
 305
 306 =item C<< required => Bool >>
 307
 308 Whether this attribute is required to have a value. If the attribute is lazy or
 309 has a builder, then providing a value for the attribute in the constructor is
 310 optional.
 311
 312 =item C<< init_arg => Str | Undef >>
 313
 314 Allows you to use a different key name in the constructor.  If undef, the
 315 attribute can't be passed to the constructor.
 316
 317 =item C<< default => Value | CodeRef >>
 318
 319 Sets the default value of the attribute. If the default is a coderef, it will
 320 be invoked to get the default value. Due to quirks of Perl, any bare reference
 321 is forbidden, you must wrap the reference in a coderef. Otherwise, all
 322 instances will share the same reference.
 323
 324 =item C<< lazy => Bool >>
 325
 326 If specified, the default is calculated on demand instead of in the
 327 constructor.
 328
 329 =item C<< predicate => Str >>
 330
 331 Lets you specify a method name for installing a predicate method, which checks
 332 that the attribute has a value. It will not invoke a lazy default or builder
 333 method.
 334
 335 =item C<< clearer => Str >>
 336
 337 Lets you specify a method name for installing a clearer method, which clears
 338 the attribute's value from the instance. On the next read, lazy or builder will
 339 be invoked.
 340
 341 =item C<< handles => HashRef|ArrayRef|Regexp >>
 342
 343 Lets you specify methods to delegate to the attribute. ArrayRef forwards the
 344 given method names to method calls on the attribute. HashRef maps local method
 345 names to remote method names called on the attribute. Other forms of
 346 L</handles>, such as RoleName and CodeRef, are not yet supported.
 347
 348 =item C<< weak_ref => Bool >>
 349
 350 Lets you automatically weaken any reference stored in the attribute.
 351
 352 Use of this feature requires L<Scalar::Util>!
 353
 354 =item C<< trigger => CodeRef >>
 355
 356 Any time the attribute's value is set (either through the accessor or the constructor), the trigger is called on it. The trigger receives as arguments the instance, the new value, and the attribute instance.
 357
 358 =item C<< builder => Str >>
 359
 360 Defines a method name to be called to provide the default value of the
 361 attribute. C<< builder => 'build_foo' >> is mostly equivalent to
 362 C<< default => sub { $_[0]->build_foo } >>.
 363
 364 =item C<< auto_deref => Bool >>
 365
 366 Allows you to automatically dereference ArrayRef and HashRef attributes in list
 367 context. In scalar context, the reference is returned (NOT the list length or
 368 bucket status). You must specify an appropriate type constraint to use
 369 auto_deref.
 370
 371 =item C<< lazy_build => Bool >>
 372
 373 Automatically define the following options:
 374
 375     has $attr => (
 376         # ...
 377         lazy      => 1
 378         builder   => "_build_$attr",
 379         clearer   => "clear_$attr",
 380         predicate => "has_$attr",
 381     );
 382
 383 =back
 384
 385 =head2 C<< confess(message) -> BOOM >>
 386
 387 L<Carp/confess> for your convenience.
 388
 389 =head2 C<< blessed(value) -> ClassName | undef >>
 390
 391 L<Scalar::Util/blessed> for your convenience.
 392
 393 =head1 MISC
 394
 395 =head2 import
 396
 397 Importing Mouse will default your class' superclass list to L<Mouse::Object>.
 398 You may use L</extends> to replace the superclass list.
 399
 400 =head2 unimport
 401
 402 Please unimport Mouse (C<no Mouse>) so that if someone calls one of the
 403 keywords (such as L</extends>) it will break loudly instead breaking subtly.
 404
 405 =head1 SOURCE CODE ACCESS
 406
 407 We have a public git repository:
 408
 409  git clone git://git.moose.perl.org/Mouse.git
 410
 411 =head1 DEPENDENCIES
 412
 413 Perl 5.6.2 or later.
 414
 415 =head1 SEE ALSO
 416
 417 L<Mouse::Spec>
 418
 419 L<Moose>
 420
 421 L<Moose::Manual>
 422
 423 L<Moose::Cookbook>
 424
 425 L<Class::MOP>
 426
 427 =head1 AUTHORS
 428
 429 Shawn M Moore E<lt>sartak at gmail.comE<gt>
 430
 431 Yuval Kogman E<lt>nothingmuch at woobling.orgE<gt>
 432
 433 tokuhirom
 434
 435 Yappo
 436
 437 wu-lee
 438
 439 Goro Fuji (gfx) E<lt>gfuji at cpan.orgE<gt>
 440
 441 with plenty of code borrowed from L<Class::MOP> and L<Moose>
 442
 443 =head1 BUGS
 444
 445 All complex software has bugs lurking in it, and this module is no exception.
 446 Please report any bugs to C<bug-mouse at rt.cpan.org>, or through the web
 447 interface at L<http://rt.cpan.org/Public/Dist/Display.html?Name=Mouse>
 448
 449 =head1 COPYRIGHT AND LICENSE
 450
 451 Copyright 2008-2009 Infinity Interactive, Inc.
 452
 453 http://www.iinteractive.com/
 454
 455 This program is free software; you can redistribute it and/or modify it
 456 under the same terms as Perl itself.
 457
 458 =cut
 459