lib/Mouse/Util.pm

   1 package Mouse::Util;
   2 use Mouse::Exporter; # enables strict and warnings
   3
   4 sub get_linear_isa($;$); # must be here
   5
   6 BEGIN{
   7     # This is used in Mouse::PurePerl
   8     Mouse::Exporter->setup_import_methods(
   9         as_is => [qw(
  10             find_meta
  11             does_role
  12             resolve_metaclass_alias
  13             apply_all_roles
  14             english_list
  15
  16             load_class
  17             is_class_loaded
  18
  19             get_linear_isa
  20             get_code_info
  21
  22             get_code_package
  23             get_code_ref
  24
  25             not_supported
  26
  27             does meta dump
  28         )],
  29         groups => {
  30             default => [], # export no functions by default
  31
  32             # The ':meta' group is 'use metaclass' for Mouse
  33             meta    => [qw(does meta dump)],
  34         },
  35     );
  36
  37
  38     # Because Mouse::Util is loaded first in all the Mouse sub-modules,
  39     # XS loader is placed here, not in Mouse.pm.
  40
  41     our $VERSION = '0.47';
  42
  43     my $xs = !(exists $INC{'Mouse/PurePerl.pm'} || $ENV{MOUSE_PUREPERL});
  44
  45     if($xs){
  46         # XXX: XSLoader tries to get the object path from caller's file name
  47         #      $hack_mouse_file fools its mechanism
  48
  49         (my $hack_mouse_file = __FILE__) =~ s/.Util//; # .../Mouse/Util.pm -> .../Mouse.pm
  50         $xs = eval sprintf("#line %d %s\n", __LINE__, $hack_mouse_file) . q{
  51             require XSLoader;
  52             XSLoader::load('Mouse', $VERSION);
  53             Mouse::Util->import({ into => 'Mouse::Meta::Method::Constructor::XS' }, ':meta');
  54             Mouse::Util->import({ into => 'Mouse::Meta::Method::Destructor::XS'  }, ':meta');
  55             Mouse::Util->import({ into => 'Mouse::Meta::Method::Accessor::XS'    }, ':meta');
  56             return 1;
  57         } || 0;
  58         #warn $@ if $@;
  59     }
  60
  61     if(!$xs){
  62         require 'Mouse/PurePerl.pm'; # we don't want to create its namespace
  63     }
  64
  65     *MOUSE_XS = sub(){ $xs };
  66 }
  67
  68 use Carp         ();
  69 use Scalar::Util ();
  70
  71 use constant _MOUSE_VERBOSE => !!$ENV{MOUSE_VERBOSE};
  72
  73 # aliases as public APIs
  74 # it must be 'require', not 'use', because Mouse::Meta::Module depends on Mouse::Util
  75 require Mouse::Meta::Module; # for the entities of metaclass cache utilities
  76
  77 BEGIN {
  78     *class_of                    = \&Mouse::Meta::Module::_class_of;
  79     *get_metaclass_by_name       = \&Mouse::Meta::Module::_get_metaclass_by_name;
  80     *get_all_metaclass_instances = \&Mouse::Meta::Module::_get_all_metaclass_instances;
  81     *get_all_metaclass_names     = \&Mouse::Meta::Module::_get_all_metaclass_names;
  82
  83     # is-a predicates
  84     #generate_isa_predicate_for('Mouse::Meta::TypeConstraint' => 'is_a_type_constraint');
  85     #generate_isa_predicate_for('Mouse::Meta::Class'          => 'is_a_metaclass');
  86     #generate_isa_predicate_for('Mouse::Meta::Role'           => 'is_a_metarole');
  87
  88     # duck type predicates
  89     generate_can_predicate_for(['_compiled_type_constraint']  => 'is_a_type_constraint');
  90     generate_can_predicate_for(['create_anon_class']          => 'is_a_metaclass');
  91     generate_can_predicate_for(['create_anon_role']           => 'is_a_metarole');
  92 }
  93
  94 our $in_global_destruction = 0;
  95 END{ $in_global_destruction = 1 }
  96
  97 # Moose::Util compatible utilities
  98
  99 sub find_meta{
 100     return class_of( $_[0] );
 101 }
 102
 103 sub does_role{
 104     my ($class_or_obj, $role_name) = @_;
 105
 106     my $meta = class_of($class_or_obj);
 107
 108     (defined $role_name)
 109         || ($meta || 'Mouse::Meta::Class')->throw_error("You must supply a role name to does()");
 110
 111     return defined($meta) && $meta->does_role($role_name);
 112 }
 113
 114 BEGIN {
 115     my $get_linear_isa;
 116     if ($] >= 5.009_005) {
 117         require mro;
 118         $get_linear_isa = \&mro::get_linear_isa;
 119     } else {
 120 #       VVVVV   CODE TAKEN FROM MRO::COMPAT   VVVVV
 121         my $_get_linear_isa_dfs; # this recurses so it isn't pretty
 122         $_get_linear_isa_dfs = sub {
 123             my($classname) = @_;
 124
 125             my @lin = ($classname);
 126             my %stored;
 127
 128             no strict 'refs';
 129             foreach my $parent (@{"$classname\::ISA"}) {
 130                 my $plin = $_get_linear_isa_dfs->($parent);
 131                 foreach  my $p(@$plin) {
 132                     next if exists $stored{$p};
 133                     push(@lin, $p);
 134                     $stored{$p} = 1;
 135                 }
 136             }
 137             return \@lin;
 138         };
 139 #       ^^^^^   CODE TAKEN FROM MRO::COMPAT   ^^^^^
 140
 141         eval{ require Class::C3 };
 142
 143         # MRO::Compat::__get_linear_isa has no prototype, so
 144         # we define a prototyped version for compatibility with core's
 145         # See also MRO::Compat::__get_linear_isa.
 146         $get_linear_isa = sub ($;$){
 147             my($classname, $type) = @_;
 148             package # hide from PAUSE
 149                 Class::C3;
 150             if(!defined $type){
 151                 our %MRO;
 152                 $type = exists $MRO{$classname} ? 'c3' : 'dfs';
 153             }
 154             return $type eq 'c3'
 155                 ? [calculateMRO($classname)]
 156                 : $_get_linear_isa_dfs->($classname);
 157         };
 158     }
 159
 160     *get_linear_isa = $get_linear_isa;
 161 }
 162
 163
 164 # taken from Mouse::Util (0.90)
 165 {
 166     my %cache;
 167
 168     sub resolve_metaclass_alias {
 169         my ( $type, $metaclass_name, %options ) = @_;
 170
 171         my $cache_key = $type . q{ } . ( $options{trait} ? '-Trait' : '' );
 172
 173         return $cache{$cache_key}{$metaclass_name} ||= do{
 174
 175             my $possible_full_name = join '::',
 176                 'Mouse::Meta', $type, 'Custom', ($options{trait} ? 'Trait' : ()), $metaclass_name
 177             ;
 178
 179             my $loaded_class = load_first_existing_class(
 180                 $possible_full_name,
 181                 $metaclass_name
 182             );
 183
 184             $loaded_class->can('register_implementation')
 185                 ? $loaded_class->register_implementation
 186                 : $loaded_class;
 187         };
 188     }
 189 }
 190
 191 # Utilities from Class::MOP
 192
 193 sub get_code_info;
 194 sub get_code_package;
 195
 196 # taken from Class/MOP.pm
 197 sub is_valid_class_name {
 198     my $class = shift;
 199
 200     return 0 if ref($class);
 201     return 0 unless defined($class);
 202
 203     return 1 if $class =~ /\A \w+ (?: :: \w+ )* \z/xms;
 204
 205     return 0;
 206 }
 207
 208 # taken from Class/MOP.pm
 209 sub load_first_existing_class {
 210     my @classes = @_
 211       or return;
 212
 213     my %exceptions;
 214     for my $class (@classes) {
 215         my $e = _try_load_one_class($class);
 216
 217         if ($e) {
 218             $exceptions{$class} = $e;
 219         }
 220         else {
 221             return $class;
 222         }
 223     }
 224
 225     # not found
 226     Carp::confess join(
 227         "\n",
 228         map {
 229             sprintf( "Could not load class (%s) because : %s",
 230                 $_, $exceptions{$_} )
 231           } @classes
 232     );
 233 }
 234
 235 # taken from Class/MOP.pm
 236 my %is_class_loaded_cache;
 237 sub _try_load_one_class {
 238     my $class = shift;
 239
 240     unless ( is_valid_class_name($class) ) {
 241         my $display = defined($class) ? $class : 'undef';
 242         Carp::confess "Invalid class name ($display)";
 243     }
 244
 245     return undef if $is_class_loaded_cache{$class} ||= is_class_loaded($class);
 246
 247     my $file = $class . '.pm';
 248     $file =~ s{::}{/}g;
 249
 250     return do {
 251         local $@;
 252         eval { require($file) };
 253         $@;
 254     };
 255 }
 256
 257
 258 sub load_class {
 259     my $class = shift;
 260     my $e = _try_load_one_class($class);
 261     Carp::confess "Could not load class ($class) because : $e" if $e;
 262
 263     return 1;
 264 }
 265
 266 sub is_class_loaded;
 267
 268 sub apply_all_roles {
 269     my $applicant = Scalar::Util::blessed($_[0])
 270         ?                                shift   # instance
 271         : Mouse::Meta::Class->initialize(shift); # class or role name
 272
 273     my @roles;
 274
 275     # Basis of Data::OptList
 276     my $max = scalar(@_);
 277     for (my $i = 0; $i < $max ; $i++) {
 278         if ($i + 1 < $max && ref($_[$i + 1])) {
 279             push @roles, [ $_[$i] => $_[++$i] ];
 280         } else {
 281             push @roles, [ $_[$i] => undef ];
 282         }
 283         my $role_name = $roles[-1][0];
 284         load_class($role_name);
 285
 286         is_a_metarole( get_metaclass_by_name($role_name) )
 287             || $applicant->meta->throw_error("You can only consume roles, $role_name is not a Mouse role");
 288     }
 289
 290     if ( scalar @roles == 1 ) {
 291         my ( $role_name, $params ) = @{ $roles[0] };
 292         get_metaclass_by_name($role_name)->apply( $applicant, defined $params ? $params : () );
 293     }
 294     else {
 295         Mouse::Meta::Role->combine(@roles)->apply($applicant);
 296     }
 297     return;
 298 }
 299
 300 # taken from Moose::Util 0.90
 301 sub english_list {
 302     return $_[0] if @_ == 1;
 303
 304     my @items = sort @_;
 305
 306     return "$items[0] and $items[1]" if @items == 2;
 307
 308     my $tail = pop @items;
 309
 310     return join q{, }, @items, "and $tail";
 311 }
 312
 313 # common utilities
 314
 315 sub not_supported{
 316     my($feature) = @_;
 317
 318     $feature ||= ( caller(1) )[3]; # subroutine name
 319
 320     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 321     Carp::confess("Mouse does not currently support $feature");
 322 }
 323
 324 # general meta() method
 325 sub meta :method{
 326     return Mouse::Meta::Class->initialize(ref($_[0]) || $_[0]);
 327 }
 328
 329 # general dump() method
 330 sub dump :method {
 331     my($self, $maxdepth) = @_;
 332
 333     require 'Data/Dumper.pm'; # we don't want to create its namespace
 334     my $dd = Data::Dumper->new([$self]);
 335     $dd->Maxdepth(defined($maxdepth) ? $maxdepth : 2);
 336     $dd->Indent(1);
 337     return $dd->Dump();
 338 }
 339
 340 # general does() method
 341 sub does :method;
 342 *does = \&does_role; # alias
 343
 344 1;
 345 __END__
 346
 347 =head1 NAME
 348
 349 Mouse::Util - Features, with or without their dependencies
 350
 351 =head1 VERSION
 352
 353 This document describes Mouse version 0.47
 354
 355 =head1 IMPLEMENTATIONS FOR
 356
 357 =head2 Moose::Util
 358
 359 =head3 C<find_meta>
 360
 361 =head3 C<does_role>
 362
 363 =head3 C<resolve_metaclass_alias>
 364
 365 =head3 C<apply_all_roles>
 366
 367 =head3 C<english_list>
 368
 369 =head2 Class::MOP
 370
 371 =head3 C<< is_class_loaded(ClassName) -> Bool >>
 372
 373 Returns whether C<ClassName> is actually loaded or not. It uses a heuristic which
 374 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 375 locally-defined method.
 376
 377 =head3 C<< load_class(ClassName) >>
 378
 379 This will load a given C<ClassName> (or die if it is not loadable).
 380 This function can be used in place of tricks like
 381 C<eval "use $module"> or using C<require>.
 382
 383 =head3 C<< Mouse::Util::class_of(ClassName or Object) >>
 384
 385 =head3 C<< Mouse::Util::get_metaclass_by_name(ClassName) >>
 386
 387 =head3 C<< Mouse::Util::get_all_metaclass_instances() >>
 388
 389 =head3 C<< Mouse::Util::get_all_metaclass_names() >>
 390
 391 =head2 MRO::Compat
 392
 393 =head3 C<get_linear_isa>
 394
 395 =head2 Sub::Identify
 396
 397 =head3 C<get_code_info>
 398
 399 =head1 Mouse specific utilities
 400
 401 =head3 C<not_supported>
 402
 403 =head3 C<get_code_package>
 404
 405 =head3 C<get_code_ref>
 406
 407 =head1 SEE ALSO
 408
 409 L<Moose::Util>
 410
 411 L<Class::MOP>
 412
 413 L<Sub::Identify>
 414
 415 L<MRO::Compat>
 416
 417 =cut
 418