lib/Mouse/Util.pm

   1 package Mouse::Util;
   2 use Mouse::Exporter; # enables strict and warnings
   3
   4 sub get_linear_isa($;$); # must be here
   5
   6 BEGIN{
   7     # This is used in Mouse::PurePerl
   8     Mouse::Exporter->setup_import_methods(
   9         as_is => [qw(
  10             find_meta
  11             does_role
  12             resolve_metaclass_alias
  13             apply_all_roles
  14             english_list
  15
  16             load_class
  17             is_class_loaded
  18
  19             get_linear_isa
  20             get_code_info
  21
  22             get_code_package
  23             get_code_ref
  24
  25             not_supported
  26
  27             does meta dump
  28         )],
  29         groups => {
  30             default => [], # export no functions by default
  31
  32             # The ':meta' group is 'use metaclass' for Mouse
  33             meta    => [qw(does meta dump)],
  34         },
  35     );
  36
  37
  38     # Because Mouse::Util is loaded first in all the Mouse sub-modules,
  39     # XS loader is placed here, not in Mouse.pm.
  40
  41     our $VERSION = '0.45';
  42
  43     my $xs = !(exists $INC{'Mouse/PurePerl.pm'} || $ENV{MOUSE_PUREPERL});
  44
  45     if($xs){
  46         # XXX: XSLoader tries to get the object path from caller's file name
  47         #      $hack_mouse_file fools its mechanism
  48
  49         (my $hack_mouse_file = __FILE__) =~ s/.Util//; # .../Mouse/Util.pm -> .../Mouse.pm
  50         $xs = eval sprintf("#line %d %s\n", __LINE__, $hack_mouse_file) . q{
  51             require XSLoader;
  52             XSLoader::load('Mouse', $VERSION);
  53             Mouse::Util->import({ into => 'Mouse::Meta::Method::Constructor::XS' }, ':meta');
  54             Mouse::Util->import({ into => 'Mouse::Meta::Method::Destructor::XS'  }, ':meta');
  55             Mouse::Util->import({ into => 'Mouse::Meta::Method::Accessor::XS'    }, ':meta');
  56             return 1;
  57         } || 0;
  58         #warn $@ if $@;
  59     }
  60
  61     if(!$xs){
  62         require 'Mouse/PurePerl.pm'; # we don't want to create its namespace
  63     }
  64
  65     *MOUSE_XS = sub(){ $xs };
  66 }
  67
  68 use Carp         ();
  69 use Scalar::Util ();
  70
  71 use constant _MOUSE_VERBOSE => !!$ENV{MOUSE_VERBOSE};
  72
  73 # aliases as public APIs
  74 # it must be 'require', not 'use', because Mouse::Meta::Module depends on Mouse::Util
  75 require Mouse::Meta::Module; # for the entities of metaclass cache utilities
  76
  77 BEGIN {
  78     *class_of                    = \&Mouse::Meta::Module::_class_of;
  79     *get_metaclass_by_name       = \&Mouse::Meta::Module::_get_metaclass_by_name;
  80     *get_all_metaclass_instances = \&Mouse::Meta::Module::_get_all_metaclass_instances;
  81     *get_all_metaclass_names     = \&Mouse::Meta::Module::_get_all_metaclass_names;
  82
  83     # is-a predicates
  84     #generate_isa_predicate_for('Mouse::Meta::TypeConstraint' => 'is_a_type_constraint');
  85     #generate_isa_predicate_for('Mouse::Meta::Class'          => 'is_a_metaclass');
  86     #generate_isa_predicate_for('Mouse::Meta::Role'           => 'is_a_metarole');
  87
  88     # duck type predicates
  89     generate_can_predicate_for(['_compiled_type_constraint']  => 'is_a_type_constraint');
  90     generate_can_predicate_for(['create_anon_class']          => 'is_a_metaclass');
  91     generate_can_predicate_for(['create_anon_role']           => 'is_a_metarole');
  92 }
  93
  94 our $in_global_destruction = 0;
  95 END{ $in_global_destruction = 1 }
  96
  97 # Moose::Util compatible utilities
  98
  99 sub find_meta{
 100     return class_of( $_[0] );
 101 }
 102
 103 sub does_role{
 104     my ($class_or_obj, $role_name) = @_;
 105
 106     my $meta = class_of($class_or_obj);
 107
 108     (defined $role_name)
 109         || ($meta || 'Mouse::Meta::Class')->throw_error("You must supply a role name to does()");
 110
 111     return defined($meta) && $meta->does_role($role_name);
 112 }
 113
 114 BEGIN {
 115     my $get_linear_isa;
 116     if ($] >= 5.009_005) {
 117         require mro;
 118         $get_linear_isa = \&mro::get_linear_isa;
 119     } else {
 120 #       VVVVV   CODE TAKEN FROM MRO::COMPAT   VVVVV
 121         my $_get_linear_isa_dfs; # this recurses so it isn't pretty
 122         $_get_linear_isa_dfs = sub {
 123             my($classname) = @_;
 124
 125             my @lin = ($classname);
 126             my %stored;
 127
 128             no strict 'refs';
 129             foreach my $parent (@{"$classname\::ISA"}) {
 130                 my $plin = $_get_linear_isa_dfs->($parent);
 131                 foreach  my $p(@$plin) {
 132                     next if exists $stored{$p};
 133                     push(@lin, $p);
 134                     $stored{$p} = 1;
 135                 }
 136             }
 137             return \@lin;
 138         };
 139 #       ^^^^^   CODE TAKEN FROM MRO::COMPAT   ^^^^^
 140
 141         # MRO::Compat::__get_linear_isa has no prototype, so
 142         # we define a prototyped version for compatibility with core's
 143         # See also MRO::Compat::__get_linear_isa.
 144         $get_linear_isa = sub ($;$){
 145             my($classname, $type) = @_;
 146             package # hide from PAUSE
 147                 Class::C3;
 148             if(!defined $type){
 149                 our %MRO;
 150                 $type = exists $MRO{$classname} ? 'c3' : 'dfs';
 151             }
 152             if($type eq 'c3'){
 153                 require Class::C3;
 154                 return [ calculateMRO($classname) ];
 155             }
 156             elsif($type eq 'dfs'){
 157                 return $_get_linear_isa_dfs->($classname);
 158             }
 159             else{
 160                 Carp::croak("Unknown mro type '$type'");
 161             }
 162         };
 163     }
 164
 165     *get_linear_isa = $get_linear_isa;
 166 }
 167
 168
 169 # taken from Mouse::Util (0.90)
 170 {
 171     my %cache;
 172
 173     sub resolve_metaclass_alias {
 174         my ( $type, $metaclass_name, %options ) = @_;
 175
 176         my @trait     = $options{trait} ? ('Trait') : ();
 177         my $cache_key = join '-',
 178             $type, @trait, $metaclass_name;
 179
 180         return $cache{$cache_key} ||= do{
 181
 182             my $possible_full_name = join '::',
 183                 'Mouse::Meta', $type, 'Custom', @trait, $metaclass_name
 184             ;
 185
 186             my $loaded_class = load_first_existing_class(
 187                 $possible_full_name,
 188                 $metaclass_name
 189             );
 190
 191             $loaded_class->can('register_implementation')
 192                 ? $loaded_class->register_implementation
 193                 : $loaded_class;
 194         };
 195     }
 196 }
 197
 198 # Utilities from Class::MOP
 199
 200 sub get_code_info;
 201 sub get_code_package;
 202
 203 # taken from Class/MOP.pm
 204 sub is_valid_class_name {
 205     my $class = shift;
 206
 207     return 0 if ref($class);
 208     return 0 unless defined($class);
 209
 210     return 1 if $class =~ /\A \w+ (?: :: \w+ )* \z/xms;
 211
 212     return 0;
 213 }
 214
 215 # taken from Class/MOP.pm
 216 sub load_first_existing_class {
 217     my @classes = @_
 218       or return;
 219
 220     my %exceptions;
 221     for my $class (@classes) {
 222         my $e = _try_load_one_class($class);
 223
 224         if ($e) {
 225             $exceptions{$class} = $e;
 226         }
 227         else {
 228             return $class;
 229         }
 230     }
 231
 232     # not found
 233     Carp::confess join(
 234         "\n",
 235         map {
 236             sprintf( "Could not load class (%s) because : %s",
 237                 $_, $exceptions{$_} )
 238           } @classes
 239     );
 240 }
 241
 242 # taken from Class/MOP.pm
 243 my %is_class_loaded_cache;
 244 sub _try_load_one_class {
 245     my $class = shift;
 246
 247     unless ( is_valid_class_name($class) ) {
 248         my $display = defined($class) ? $class : 'undef';
 249         Carp::confess "Invalid class name ($display)";
 250     }
 251
 252     return undef if $is_class_loaded_cache{$class} ||= is_class_loaded($class);
 253
 254     my $file = $class . '.pm';
 255     $file =~ s{::}{/}g;
 256
 257     return do {
 258         local $@;
 259         eval { require($file) };
 260         $@;
 261     };
 262 }
 263
 264
 265 sub load_class {
 266     my $class = shift;
 267     my $e = _try_load_one_class($class);
 268     Carp::confess "Could not load class ($class) because : $e" if $e;
 269
 270     return 1;
 271 }
 272
 273 sub is_class_loaded;
 274
 275 sub apply_all_roles {
 276     my $applicant = Scalar::Util::blessed($_[0])
 277         ?                                shift   # instance
 278         : Mouse::Meta::Class->initialize(shift); # class or role name
 279
 280     my @roles;
 281
 282     # Basis of Data::OptList
 283     my $max = scalar(@_);
 284     for (my $i = 0; $i < $max ; $i++) {
 285         my $role_name = $_[$i];
 286
 287         if ($i + 1 < $max && ref($_[$i + 1])) {
 288             push @roles, [ $role_name=> $_[++$i] ];
 289         } else {
 290             push @roles, [ $role_name => undef ];
 291         }
 292         load_class($role_name);
 293
 294         is_a_metarole( get_metaclass_by_name($role_name) )
 295             || $applicant->meta->throw_error("You can only consume roles, $role_name is not a Mouse role");
 296     }
 297
 298     if ( scalar @roles == 1 ) {
 299         my ( $role_name, $params ) = @{ $roles[0] };
 300         get_metaclass_by_name($role_name)->apply( $applicant, defined $params ? $params : () );
 301     }
 302     else {
 303         Mouse::Meta::Role->combine(@roles)->apply($applicant);
 304     }
 305     return;
 306 }
 307
 308 # taken from Moose::Util 0.90
 309 sub english_list {
 310     return $_[0] if @_ == 1;
 311
 312     my @items = sort @_;
 313
 314     return "$items[0] and $items[1]" if @items == 2;
 315
 316     my $tail = pop @items;
 317
 318     return join q{, }, @items, "and $tail";
 319 }
 320
 321 # common utilities
 322
 323 sub not_supported{
 324     my($feature) = @_;
 325
 326     $feature ||= ( caller(1) )[3]; # subroutine name
 327
 328     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 329     Carp::confess("Mouse does not currently support $feature");
 330 }
 331
 332 # general meta() method
 333 sub meta :method{
 334     return Mouse::Meta::Class->initialize(ref($_[0]) || $_[0]);
 335 }
 336
 337 # general dump() method
 338 sub dump :method {
 339     my($self, $maxdepth) = @_;
 340
 341     require 'Data/Dumper.pm'; # we don't want to create its namespace
 342     my $dd = Data::Dumper->new([$self]);
 343     $dd->Maxdepth(defined($maxdepth) ? $maxdepth : 2);
 344     $dd->Indent(1);
 345     return $dd->Dump();
 346 }
 347
 348 # general does() method
 349 sub does :method;
 350 *does = \&does_role; # alias
 351
 352 1;
 353 __END__
 354
 355 =head1 NAME
 356
 357 Mouse::Util - Features, with or without their dependencies
 358
 359 =head1 VERSION
 360
 361 This document describes Mouse version 0.45
 362
 363 =head1 IMPLEMENTATIONS FOR
 364
 365 =head2 Moose::Util
 366
 367 =head3 C<find_meta>
 368
 369 =head3 C<does_role>
 370
 371 =head3 C<resolve_metaclass_alias>
 372
 373 =head3 C<apply_all_roles>
 374
 375 =head3 C<english_list>
 376
 377 =head2 Class::MOP
 378
 379 =head3 C<< is_class_loaded(ClassName) -> Bool >>
 380
 381 Returns whether C<ClassName> is actually loaded or not. It uses a heuristic which
 382 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 383 locally-defined method.
 384
 385 =head3 C<< load_class(ClassName) >>
 386
 387 This will load a given C<ClassName> (or die if it is not loadable).
 388 This function can be used in place of tricks like
 389 C<eval "use $module"> or using C<require>.
 390
 391 =head3 C<< Mouse::Util::class_of(ClassName or Object) >>
 392
 393 =head3 C<< Mouse::Util::get_metaclass_by_name(ClassName) >>
 394
 395 =head3 C<< Mouse::Util::get_all_metaclass_instances() >>
 396
 397 =head3 C<< Mouse::Util::get_all_metaclass_names() >>
 398
 399 =head2 MRO::Compat
 400
 401 =head3 C<get_linear_isa>
 402
 403 =head2 Sub::Identify
 404
 405 =head3 C<get_code_info>
 406
 407 =head1 Mouse specific utilities
 408
 409 =head3 C<not_supported>
 410
 411 =head3 C<get_code_package>
 412
 413 =head3 C<get_code_ref>
 414
 415 =head1 SEE ALSO
 416
 417 L<Moose::Util>
 418
 419 L<Class::MOP>
 420
 421 L<Sub::Identify>
 422
 423 L<MRO::Compat>
 424
 425 =cut
 426