lib/Mouse/Meta/Method/Constructor.pm

   1 package Mouse::Meta::Method::Constructor;
   2 use Mouse::Util qw(:meta); # enables strict and warnings
   3
   4 use constant _MOUSE_DEBUG => !!$ENV{MOUSE_DEBUG};
   5
   6 sub _inline_slot{
   7     my(undef, $self_var, $attr_name) = @_;
   8     return sprintf '%s->{q{%s}}', $self_var, $attr_name;
   9 }
  10
  11 sub _generate_constructor {
  12     my ($class, $metaclass, $args) = @_;
  13
  14     my $associated_metaclass_name = $metaclass->name;
  15
  16     my $buildall      = $class->_generate_BUILDALL($metaclass);
  17     my $buildargs     = $class->_generate_BUILDARGS($metaclass);
  18     my $initializer   = $metaclass->{_initialize_object} ||= do {
  19        $class->_generate_initialize_object($metaclass);
  20     };
  21     my $source = sprintf(<<'EOT', __FILE__, $metaclass->name, $buildargs, $buildall);
  22 #line 1 "%s"
  23         package %s;
  24         sub {
  25             my $class = shift;
  26             return $class->Mouse::Object::new(@_)
  27                 if $class ne __PACKAGE__;
  28             # BUILDARGS
  29             %s;
  30             my $instance = bless {}, $class;
  31             $metaclass->$initializer($instance, $args, 0);
  32             # BUILDALL
  33             %s;
  34             return $instance;
  35         }
  36 EOT
  37     warn $source if _MOUSE_DEBUG;
  38     my $body;
  39     my $e = do{
  40         local $@;
  41         $body = eval $source;
  42         $@;
  43     };
  44     die $e if $e;
  45     return $body;
  46 }
  47
  48 sub _generate_initialize_object {
  49     my ($method_class, $metaclass) = @_;
  50     my @attrs  = $metaclass->get_all_attributes;
  51
  52     my @checks = map { $_ && $_->_compiled_type_constraint }
  53                  map { $_->type_constraint } @attrs;
  54
  55     my @res;
  56
  57     my $has_triggers;
  58     my $strict = $metaclass->strict_constructor;
  59
  60     if($strict){
  61         push @res, 'my $used = 0;';
  62     }
  63
  64     for my $index (0 .. @attrs - 1) {
  65         my $code = '';
  66
  67         my $attr = $attrs[$index];
  68         my $key  = $attr->name;
  69
  70         my $init_arg        = $attr->init_arg;
  71         my $type_constraint = $attr->type_constraint;
  72         my $is_weak_ref     = $attr->is_weak_ref;
  73         my $need_coercion;
  74
  75         my $instance_slot  = $method_class->_inline_slot('$instance', $key);
  76         my $attr_var       = "\$attrs[$index]";
  77         my $constraint_var;
  78
  79         if(defined $type_constraint){
  80              $constraint_var = "$attr_var\->{type_constraint}";
  81              $need_coercion  = ($attr->should_coerce && $type_constraint->has_coercion);
  82         }
  83
  84         $code .= "# initialize $key\n";
  85
  86         my $post_process = '';
  87         if(defined $type_constraint){
  88             $post_process .= "\$checks[$index]->($instance_slot)\n";
  89             $post_process .= "  or $attr_var->_throw_type_constraint_error($instance_slot, $constraint_var);\n";
  90         }
  91         if($is_weak_ref){
  92             $post_process  = "Scalar::Util::weaken($instance_slot) "
  93                              . "if ref $instance_slot;\n";
  94         }
  95
  96         # build cde for an attribute
  97         if (defined $init_arg) {
  98             my $value = "\$args->{q{$init_arg}}";
  99
 100             $code .= "if (exists $value) {\n";
 101
 102             if($need_coercion){
 103                 $value = "$constraint_var->coerce($value)";
 104             }
 105
 106             $code .= "$instance_slot = $value;\n";
 107             $code .= $post_process;
 108
 109             if ($attr->has_trigger) {
 110                 $has_triggers++;
 111                 $code .= "push \@triggers, [$attr_var\->{trigger}, $instance_slot];\n";
 112             }
 113
 114             if ($strict){
 115                 $code .= '++$used;' . "\n";
 116             }
 117
 118             $code .= "\n} else {\n"; # $value exists
 119         }
 120
 121         if ($attr->has_default || $attr->has_builder) {
 122             unless ($attr->is_lazy) {
 123                 my $default = $attr->default;
 124                 my $builder = $attr->builder;
 125
 126                 my $value;
 127                 if (defined($builder)) {
 128                     $value = "\$instance->$builder()";
 129                 }
 130                 elsif (ref($default) eq 'CODE') {
 131                     $value = "$attr_var\->{default}->(\$instance)";
 132                 }
 133                 elsif (defined($default)) {
 134                     $value = "$attr_var\->{default}";
 135                 }
 136                 else {
 137                     $value = 'undef';
 138                 }
 139
 140                 if($need_coercion){
 141                     $value = "$constraint_var->coerce($value)";
 142                 }
 143
 144                 $code .= "$instance_slot = $value;\n";
 145                 $code .= $post_process;
 146             }
 147         }
 148         elsif ($attr->is_required) {
 149             $code .= "\$meta->throw_error('Attribute ($key) is required')";
 150             $code .= "    unless \$is_cloning;\n";
 151         }
 152
 153         $code .= "}\n" if defined $init_arg;
 154
 155         push @res, $code;
 156     }
 157
 158     if($strict){
 159         push @res, q{if($used < keys %{$args})}
 160             . q{{ $meta->_report_unknown_args(\@attrs, $args) }};
 161     }
 162
 163     if($metaclass->is_anon_class){
 164         push @res, q{$instance->{__METACLASS__} = $meta;};
 165     }
 166
 167     if($has_triggers){
 168         unshift @res, q{my @triggers;};
 169         push    @res, q{$_->[0]->($instance, $_->[1]) for @triggers;};
 170     }
 171
 172     my $source = sprintf <<'EOT', __FILE__, $metaclass->name, join "\n", @res;
 173 #line 1 "%s"
 174     package %s;
 175     sub {
 176         my($meta, $instance, $args, $is_cloning) = @_;
 177         %s;
 178         return $instance;
 179     }
 180 EOT
 181     warn $source if _MOUSE_DEBUG;
 182     my $body;
 183     my $e = do {
 184         local $@;
 185         $body = eval $source;
 186         $@;
 187     };
 188     die $e if $e;
 189     return $body;
 190 }
 191
 192 sub _generate_BUILDARGS {
 193     my(undef, $metaclass) = @_;
 194
 195     my $class = $metaclass->name;
 196     if ( $class->can('BUILDARGS') && $class->can('BUILDARGS') != \&Mouse::Object::BUILDARGS ) {
 197         return 'my $args = $class->BUILDARGS(@_)';
 198     }
 199
 200     return <<'...';
 201         my $args;
 202         if ( scalar @_ == 1 ) {
 203             ( ref( $_[0] ) eq 'HASH' )
 204                 || Carp::confess "Single parameters to new() must be a HASH ref";
 205             $args = +{ %{ $_[0] } };
 206         }
 207         else {
 208             $args = +{@_};
 209         }
 210 ...
 211 }
 212
 213 sub _generate_BUILDALL {
 214     my (undef, $metaclass) = @_;
 215
 216     return '' unless $metaclass->name->can('BUILD');
 217
 218     my @code;
 219     for my $class ($metaclass->linearized_isa) {
 220         if (Mouse::Util::get_code_ref($class, 'BUILD')) {
 221             unshift  @code, qq{${class}::BUILD(\$instance, \$args);};
 222         }
 223     }
 224     return join "\n", @code;
 225 }
 226
 227 1;
 228 __END__
 229
 230 =head1 NAME
 231
 232 Mouse::Meta::Method::Constructor - A Mouse method generator for constructors
 233
 234 =head1 VERSION
 235
 236 This document describes Mouse version 0.74
 237
 238 =head1 SEE ALSO
 239
 240 L<Moose::Meta::Method::Constructor>
 241
 242 =cut