lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use Mouse::Util qw(:meta); # enables strict and warnings
   3
   4 use Carp ();
   5
   6 use Mouse::Meta::TypeConstraint;
   7
   8 #my @attributes = qw(
   9 #    name init_arg required
  10 #    is
  11 #    isa does coerce
  12 #    accessor reader writer predicate clearer
  13 #    default builder lazy lazy_build
  14 #    auto_deref trigger
  15 #    metaclass traits
  16 #
  17 #    handles
  18 #    documentation
  19 #
  20 #    type_constraint
  21 #);
  22
  23 sub _process_options{
  24     my($class, $name, $args) = @_;
  25
  26     # taken from Class::MOP::Attribute::new
  27
  28     defined($name)
  29         or $class->throw_error('You must provide a name for the attribute');
  30
  31     if(!exists $args->{init_arg}){
  32         $args->{init_arg} = $name;
  33     }
  34
  35     # 'required' requires eigher 'init_arg', 'builder', or 'default'
  36     my $can_be_required = defined( $args->{init_arg} );
  37
  38     if(exists $args->{builder}){
  39         # XXX:
  40         # Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
  41         # This feature will be changed in a future. (gfx)
  42         $class->throw_error('builder must be a defined scalar value which is a method name')
  43             #if ref $args->{builder} || !defined $args->{builder};
  44             if !defined $args->{builder};
  45
  46         $can_be_required++;
  47     }
  48     elsif(exists $args->{default}){
  49         if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
  50             $class->throw_error("References are not allowed as default values, you must "
  51                               . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
  52         }
  53         $can_be_required++;
  54     }
  55
  56     if( $args->{required} && !$can_be_required ) {
  57         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
  58     }
  59
  60     # taken from Mouse::Meta::Attribute->new and _process_args->
  61
  62     if(exists $args->{is}){
  63         my $is = $args->{is};
  64
  65         if($is eq 'ro'){
  66             $args->{reader} ||= $name;
  67         }
  68         elsif($is eq 'rw'){
  69             if(exists $args->{writer}){
  70                 $args->{reader} ||= $name;
  71              }
  72              else{
  73                 $args->{accessor} ||= $name;
  74              }
  75         }
  76         elsif($is eq 'bare'){
  77             # do nothing, but don't complain (later) about missing methods
  78         }
  79         else{
  80             $is = 'undef' if !defined $is;
  81             $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
  82         }
  83     }
  84
  85     my $tc;
  86     if(exists $args->{isa}){
  87         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
  88     }
  89     elsif(exists $args->{does}){
  90         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
  91     }
  92     $tc = $args->{type_constraint};
  93
  94     if($args->{coerce}){
  95         defined($tc)
  96             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
  97
  98         $args->{weak_ref}
  99             && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
 100     }
 101
 102     if ($args->{lazy_build}) {
 103         exists($args->{default})
 104             && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
 105
 106         $args->{lazy}      = 1;
 107         $args->{builder} ||= "_build_${name}";
 108         if ($name =~ /^_/) {
 109             $args->{clearer}   ||= "_clear${name}";
 110             $args->{predicate} ||= "_has${name}";
 111         }
 112         else {
 113             $args->{clearer}   ||= "clear_${name}";
 114             $args->{predicate} ||= "has_${name}";
 115         }
 116     }
 117
 118     if ($args->{auto_deref}) {
 119         defined($tc)
 120             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
 121
 122         ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
 123             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
 124     }
 125
 126     if (exists $args->{trigger}) {
 127         ('CODE' eq ref $args->{trigger})
 128             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
 129     }
 130
 131     if ($args->{lazy}) {
 132         (exists $args->{default} || defined $args->{builder})
 133             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
 134     }
 135
 136     return;
 137 }
 138
 139 sub new {
 140     my $class = shift;
 141     my $name  = shift;
 142
 143     my %args  = (@_ == 1) ? %{ $_[0] } : @_;
 144
 145     $class->_process_options($name, \%args);
 146
 147     $args{name} = $name;
 148
 149     my $self = bless \%args, $class;
 150
 151     # extra attributes
 152     if($class ne __PACKAGE__){
 153         $class->meta->_initialize_object($self, \%args);
 154     }
 155
 156 # XXX: there is no fast way to check attribute validity
 157 #    my @bad = ...;
 158 #    if(@bad){
 159 #        @bad = sort @bad;
 160 #        Carp::cluck("Found unknown argument(s) passed to '$name' attribute constructor in '$class': @bad");
 161 #    }
 162
 163     return $self;
 164 }
 165
 166 sub has_read_method      { $_[0]->has_reader || $_[0]->has_accessor }
 167 sub has_write_method     { $_[0]->has_writer || $_[0]->has_accessor }
 168
 169 sub interpolate_class{
 170     my($class, $args) = @_;
 171
 172     if(my $metaclass = delete $args->{metaclass}){
 173         $class = Mouse::Util::resolve_metaclass_alias( Attribute => $metaclass );
 174     }
 175
 176     my @traits;
 177     if(my $traits_ref = delete $args->{traits}){
 178
 179         for (my $i = 0; $i < @{$traits_ref}; $i++) {
 180             my $trait = Mouse::Util::resolve_metaclass_alias(Attribute => $traits_ref->[$i], trait => 1);
 181
 182             next if $class->does($trait);
 183
 184             push @traits, $trait;
 185
 186             # are there options?
 187             push @traits, $traits_ref->[++$i]
 188                 if ref($traits_ref->[$i+1]);
 189         }
 190
 191         if (@traits) {
 192             $class = Mouse::Meta::Class->create_anon_class(
 193                 superclasses => [ $class ],
 194                 roles        => \@traits,
 195                 cache        => 1,
 196             )->name;
 197         }
 198     }
 199
 200     return( $class, @traits );
 201 }
 202
 203 sub _coerce_and_verify {
 204     my($self, $value, $instance) = @_;
 205
 206     my $type_constraint = $self->{type_constraint};
 207     return $value if !defined $type_constraint;
 208
 209     if ($self->should_coerce && $type_constraint->has_coercion) {
 210         $value = $type_constraint->coerce($value);
 211     }
 212
 213     $self->verify_against_type_constraint($value);
 214
 215     return $value;
 216 }
 217
 218 sub verify_against_type_constraint {
 219     my ($self, $value) = @_;
 220
 221     my $type_constraint = $self->{type_constraint};
 222     return 1 if !$type_constraint;
 223     return 1 if $type_constraint->check($value);
 224
 225     $self->_throw_type_constraint_error($value, $type_constraint);
 226 }
 227
 228 sub _throw_type_constraint_error {
 229     my($self, $value, $type) = @_;
 230
 231     $self->throw_error(
 232         sprintf q{Attribute (%s) does not pass the type constraint because: %s},
 233             $self->name,
 234             $type->get_message($value),
 235     );
 236 }
 237
 238 sub clone_and_inherit_options{
 239     my($self, %args) = @_;
 240
 241     my($attribute_class, @traits) = ref($self)->interpolate_class(\%args);
 242
 243     $args{traits} = \@traits if @traits;
 244     # do not inherit the 'handles' attribute
 245     foreach my $name(keys %{$self}){
 246         if(!exists $args{$name} && $name ne 'handles'){
 247             $args{$name} = $self->{$name};
 248         }
 249     }
 250     return $attribute_class->new($self->name, %args);
 251 }
 252
 253 sub get_read_method {
 254     return $_[0]->reader || $_[0]->accessor
 255 }
 256 sub get_write_method {
 257     return $_[0]->writer || $_[0]->accessor
 258 }
 259
 260 sub _get_accessor_method_ref {
 261     my($self, $type, $generator) = @_;
 262
 263     my $metaclass = $self->associated_class
 264         || $self->throw_error('No asocciated class for ' . $self->name);
 265
 266     my $accessor = $self->$type();
 267     if($accessor){
 268         return $metaclass->get_method_body($accessor);
 269     }
 270     else{
 271         return $self->accessor_metaclass->$generator($self, $metaclass);
 272     }
 273 }
 274
 275 sub get_read_method_ref{
 276     my($self) = @_;
 277     return $self->{_read_method_ref} ||= $self->_get_accessor_method_ref('get_read_method', '_generate_reader');
 278 }
 279
 280 sub get_write_method_ref{
 281     my($self) = @_;
 282     return $self->{_write_method_ref} ||= $self->_get_accessor_method_ref('get_write_method', '_generate_writer');
 283 }
 284
 285 sub set_value {
 286     my($self, $object, $value) = @_;
 287     return $self->get_write_method_ref()->($object, $value);
 288 }
 289
 290 sub get_value {
 291     my($self, $object) = @_;
 292     return $self->get_read_method_ref()->($object);
 293 }
 294
 295 sub has_value {
 296     my($self, $object) = @_;
 297     my $accessor_ref = $self->{_predicate_ref}
 298         ||= $self->_get_accessor_method_ref('predicate', '_generate_predicate');
 299
 300     return $accessor_ref->($object);
 301 }
 302
 303 sub clear_value {
 304     my($self, $object) = @_;
 305     my $accessor_ref = $self->{_crealer_ref}
 306         ||= $self->_get_accessor_method_ref('clearer', '_generate_clearer');
 307
 308     return $accessor_ref->($object);
 309 }
 310
 311
 312 sub associate_method{
 313     my ($attribute, $method_name) = @_;
 314     $attribute->{associated_methods}++;
 315     return;
 316 }
 317
 318 sub install_accessors{
 319     my($attribute) = @_;
 320
 321     my $metaclass      = $attribute->associated_class;
 322     my $accessor_class = $attribute->accessor_metaclass;
 323
 324     foreach my $type(qw(accessor reader writer predicate clearer)){
 325         if(exists $attribute->{$type}){
 326             my $generator = '_generate_' . $type;
 327             my $code      = $accessor_class->$generator($attribute, $metaclass);
 328             $metaclass->add_method($attribute->{$type} => $code);
 329             $attribute->associate_method($attribute->{$type});
 330         }
 331     }
 332
 333     # install delegation
 334     if(exists $attribute->{handles}){
 335         my %handles = $attribute->_canonicalize_handles($attribute->{handles});
 336
 337         while(my($handle, $method_to_call) = each %handles){
 338             $metaclass->add_method($handle =>
 339                 $attribute->_make_delegation_method(
 340                     $handle, $method_to_call));
 341
 342             $attribute->associate_method($handle);
 343         }
 344     }
 345
 346     return;
 347 }
 348
 349 sub delegation_metaclass() { 'Mouse::Meta::Method::Delegation' }
 350
 351 sub _canonicalize_handles {
 352     my($self, $handles) = @_;
 353
 354     if (ref($handles) eq 'HASH') {
 355         return %$handles;
 356     }
 357     elsif (ref($handles) eq 'ARRAY') {
 358         return map { $_ => $_ } @$handles;
 359     }
 360     elsif (ref($handles) eq 'Regexp') {
 361         my $class_or_role = ($self->{isa} || $self->{does})
 362             || $self->throw_error("Cannot delegate methods based on a Regexp without a type constraint (isa)");
 363
 364         my $meta = Mouse::Meta::Class->initialize("$class_or_role"); # "" for stringify
 365         return map  { $_ => $_ }
 366                grep { !Mouse::Object->can($_) && $_ =~ $handles }
 367                    Mouse::Util::is_a_metarole($meta)
 368                         ? $meta->get_method_list
 369                         : $meta->get_all_method_names;
 370     }
 371     else {
 372         $self->throw_error("Unable to canonicalize the 'handles' option with $handles");
 373     }
 374 }
 375
 376 sub _make_delegation_method {
 377     my($self, $handle, $method_to_call) = @_;
 378     my $delegator = $self->delegation_metaclass;
 379     Mouse::Util::load_class($delegator);
 380
 381     return $delegator->_generate_delegation($self, $handle, $method_to_call);
 382 }
 383
 384 sub throw_error{
 385     my $self = shift;
 386
 387     my $metaclass = (ref $self && $self->associated_class) || 'Mouse::Meta::Class';
 388     $metaclass->throw_error(@_, depth => 1);
 389 }
 390
 391 1;
 392 __END__
 393
 394 =head1 NAME
 395
 396 Mouse::Meta::Attribute - The Mouse attribute metaclass
 397
 398 =head1 VERSION
 399
 400 This document describes Mouse version 0.45
 401
 402 =head1 METHODS
 403
 404 =head2 C<< new(%options) -> Mouse::Meta::Attribute >>
 405
 406 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 407
 408 It adds the following options to the constructor:
 409
 410 =over 4
 411
 412 =item C<< is => 'ro', 'rw', 'bare' >>
 413
 414 This provides a shorthand for specifying the C<reader>, C<writer>, or
 415 C<accessor> names. If the attribute is read-only ('ro') then it will
 416 have a C<reader> method with the same attribute as the name.
 417
 418 If it is read-write ('rw') then it will have an C<accessor> method
 419 with the same name. If you provide an explicit C<writer> for a
 420 read-write attribute, then you will have a C<reader> with the same
 421 name as the attribute, and a C<writer> with the name you provided.
 422
 423 Use 'bare' when you are deliberately not installing any methods
 424 (accessor, reader, etc.) associated with this attribute; otherwise,
 425 Moose will issue a deprecation warning when this attribute is added to a
 426 metaclass.
 427
 428 =item C<< isa => Type >>
 429
 430 This option accepts a type. The type can be a string, which should be
 431 a type name. If the type name is unknown, it is assumed to be a class
 432 name.
 433
 434 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 435
 436 If you I<also> provide a C<does> option, then your C<isa> option must
 437 be a class name, and that class must do the role specified with
 438 C<does>.
 439
 440 =item C<< does => Role >>
 441
 442 This is short-hand for saying that the attribute's type must be an
 443 object which does the named role.
 444
 445 B<This option is not yet supported.>
 446
 447 =item C<< coerce => Bool >>
 448
 449 This option is only valid for objects with a type constraint
 450 (C<isa>). If this is true, then coercions will be applied whenever
 451 this attribute is set.
 452
 453 You can make both this and the C<weak_ref> option true.
 454
 455 =item C<< trigger => CodeRef >>
 456
 457 This option accepts a subroutine reference, which will be called after
 458 the attribute is set.
 459
 460 =item C<< required => Bool >>
 461
 462 An attribute which is required must be provided to the constructor. An
 463 attribute which is required can also have a C<default> or C<builder>,
 464 which will satisfy its required-ness.
 465
 466 A required attribute must have a C<default>, C<builder> or a
 467 non-C<undef> C<init_arg>
 468
 469 =item C<< lazy => Bool >>
 470
 471 A lazy attribute must have a C<default> or C<builder>. When an
 472 attribute is lazy, the default value will not be calculated until the
 473 attribute is read.
 474
 475 =item C<< weak_ref => Bool >>
 476
 477 If this is true, the attribute's value will be stored as a weak
 478 reference.
 479
 480 =item C<< auto_deref => Bool >>
 481
 482 If this is true, then the reader will dereference the value when it is
 483 called. The attribute must have a type constraint which defines the
 484 attribute as an array or hash reference.
 485
 486 =item C<< lazy_build => Bool >>
 487
 488 Setting this to true makes the attribute lazy and provides a number of
 489 default methods.
 490
 491   has 'size' => (
 492       is         => 'ro',
 493       lazy_build => 1,
 494   );
 495
 496 is equivalent to this:
 497
 498   has 'size' => (
 499       is        => 'ro',
 500       lazy      => 1,
 501       builder   => '_build_size',
 502       clearer   => 'clear_size',
 503       predicate => 'has_size',
 504   );
 505
 506 =back
 507
 508 =head2 C<< associate_method(MethodName) >>
 509
 510 Associates a method with the attribute. Typically, this is called internally
 511 when an attribute generates its accessors.
 512
 513 Currently the argument I<MethodName> is ignored in Mouse.
 514
 515 =head2 C<< verify_against_type_constraint(Item) -> TRUE | ERROR >>
 516
 517 Checks that the given value passes this attribute's type constraint. Returns C<true>
 518 on success, otherwise C<confess>es.
 519
 520 =head2 C<< clone_and_inherit_options(options) -> Mouse::Meta::Attribute >>
 521
 522 Creates a new attribute in the owner class, inheriting options from parent classes.
 523 Accessors and helper methods are installed. Some error checking is done.
 524
 525 =head2 C<< get_read_method_ref >>
 526
 527 =head2 C<< get_write_method_ref >>
 528
 529 Returns the subroutine reference of a method suitable for reading or
 530 writing the attribute's value in the associated class. These methods
 531 always return a subroutine reference, regardless of whether or not the
 532 attribute is read- or write-only.
 533
 534 =head1 SEE ALSO
 535
 536 L<Moose::Meta::Attribute>
 537
 538 L<Class::MOP::Attribute>
 539
 540 =cut
 541