lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use Mouse::Util qw(:meta); # enables strict and warnings
   3
   4 use Carp ();
   5
   6 use Mouse::Meta::TypeConstraint;
   7
   8 sub _process_options{
   9     my($class, $name, $args) = @_;
  10
  11     # taken from Class::MOP::Attribute::new
  12
  13     defined($name)
  14         or $class->throw_error('You must provide a name for the attribute');
  15
  16     if(!exists $args->{init_arg}){
  17         $args->{init_arg} = $name;
  18     }
  19
  20     # 'required' requires eigher 'init_arg', 'builder', or 'default'
  21     my $can_be_required = defined( $args->{init_arg} );
  22
  23     if(exists $args->{builder}){
  24         # XXX:
  25         # Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
  26         # This feature will be changed in a future. (gfx)
  27         $class->throw_error('builder must be a defined scalar value which is a method name')
  28             #if ref $args->{builder} || !defined $args->{builder};
  29             if !defined $args->{builder};
  30
  31         $can_be_required++;
  32     }
  33     elsif(exists $args->{default}){
  34         if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
  35             $class->throw_error("References are not allowed as default values, you must "
  36                               . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
  37         }
  38         $can_be_required++;
  39     }
  40
  41     if( $args->{required} && !$can_be_required ) {
  42         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
  43     }
  44
  45     # taken from Mouse::Meta::Attribute->new and _process_args->
  46
  47     if(exists $args->{is}){
  48         my $is = $args->{is};
  49
  50         if($is eq 'ro'){
  51             $args->{reader} ||= $name;
  52         }
  53         elsif($is eq 'rw'){
  54             if(exists $args->{writer}){
  55                 $args->{reader} ||= $name;
  56              }
  57              else{
  58                 $args->{accessor} ||= $name;
  59              }
  60         }
  61         elsif($is eq 'bare'){
  62             # do nothing, but don't complain (later) about missing methods
  63         }
  64         else{
  65             $is = 'undef' if !defined $is;
  66             $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
  67         }
  68     }
  69
  70     my $tc;
  71     if(exists $args->{isa}){
  72         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
  73     }
  74     elsif(exists $args->{does}){
  75         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
  76     }
  77     $tc = $args->{type_constraint};
  78
  79     if($args->{coerce}){
  80         defined($tc)
  81             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
  82
  83         $args->{weak_ref}
  84             && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
  85     }
  86
  87     if ($args->{lazy_build}) {
  88         exists($args->{default})
  89             && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
  90
  91         $args->{lazy}      = 1;
  92         $args->{builder} ||= "_build_${name}";
  93         if ($name =~ /^_/) {
  94             $args->{clearer}   ||= "_clear${name}";
  95             $args->{predicate} ||= "_has${name}";
  96         }
  97         else {
  98             $args->{clearer}   ||= "clear_${name}";
  99             $args->{predicate} ||= "has_${name}";
 100         }
 101     }
 102
 103     if ($args->{auto_deref}) {
 104         defined($tc)
 105             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
 106
 107         ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
 108             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
 109     }
 110
 111     if (exists $args->{trigger}) {
 112         ('CODE' eq ref $args->{trigger})
 113             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
 114     }
 115
 116     if ($args->{lazy}) {
 117         (exists $args->{default} || defined $args->{builder})
 118             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
 119     }
 120
 121     return;
 122 }
 123
 124 sub new {
 125     my $class = shift;
 126     my $name  = shift;
 127
 128     my %args  = (@_ == 1) ? %{ $_[0] } : @_;
 129
 130     $class->_process_options($name, \%args);
 131
 132     $args{name} = $name;
 133
 134     my $self = bless \%args, $class;
 135
 136     # extra attributes
 137     if($class ne __PACKAGE__){
 138         $class->meta->_initialize_object($self, \%args);
 139     }
 140
 141 # XXX: there is no fast way to check attribute validity
 142 #    my @bad = ...;
 143 #    if(@bad){
 144 #        @bad = sort @bad;
 145 #        Carp::cluck("Found unknown argument(s) passed to '$name' attribute constructor in '$class': @bad");
 146 #    }
 147
 148     return $self;
 149 }
 150
 151 sub has_read_method      { $_[0]->has_reader || $_[0]->has_accessor }
 152 sub has_write_method     { $_[0]->has_writer || $_[0]->has_accessor }
 153
 154 sub interpolate_class{
 155     my($class, $args) = @_;
 156
 157     if(my $metaclass = delete $args->{metaclass}){
 158         $class = Mouse::Util::resolve_metaclass_alias( Attribute => $metaclass );
 159     }
 160
 161     my @traits;
 162     if(my $traits_ref = delete $args->{traits}){
 163
 164         for (my $i = 0; $i < @{$traits_ref}; $i++) {
 165             my $trait = Mouse::Util::resolve_metaclass_alias(Attribute => $traits_ref->[$i], trait => 1);
 166
 167             next if $class->does($trait);
 168
 169             push @traits, $trait;
 170
 171             # are there options?
 172             push @traits, $traits_ref->[++$i]
 173                 if ref($traits_ref->[$i+1]);
 174         }
 175
 176         if (@traits) {
 177             $class = Mouse::Meta::Class->create_anon_class(
 178                 superclasses => [ $class ],
 179                 roles        => \@traits,
 180                 cache        => 1,
 181             )->name;
 182         }
 183     }
 184
 185     return( $class, @traits );
 186 }
 187
 188 sub _coerce_and_verify {
 189     my($self, $value, $instance) = @_;
 190
 191     my $type_constraint = $self->{type_constraint};
 192     return $value if !defined $type_constraint;
 193
 194     if ($self->should_coerce && $type_constraint->has_coercion) {
 195         $value = $type_constraint->coerce($value);
 196     }
 197
 198     $self->verify_against_type_constraint($value);
 199
 200     return $value;
 201 }
 202
 203 sub verify_against_type_constraint {
 204     my ($self, $value) = @_;
 205
 206     my $type_constraint = $self->{type_constraint};
 207     return 1 if !$type_constraint;
 208     return 1 if $type_constraint->check($value);
 209
 210     $self->_throw_type_constraint_error($value, $type_constraint);
 211 }
 212
 213 sub _throw_type_constraint_error {
 214     my($self, $value, $type) = @_;
 215
 216     $self->throw_error(
 217         sprintf q{Attribute (%s) does not pass the type constraint because: %s},
 218             $self->name,
 219             $type->get_message($value),
 220     );
 221 }
 222
 223 sub clone_and_inherit_options{
 224     my($self, %args) = @_;
 225
 226     my($attribute_class, @traits) = ref($self)->interpolate_class(\%args);
 227
 228     $args{traits} = \@traits if @traits;
 229     # do not inherit the 'handles' attribute
 230     foreach my $name(keys %{$self}){
 231         if(!exists $args{$name} && $name ne 'handles'){
 232             $args{$name} = $self->{$name};
 233         }
 234     }
 235     return $attribute_class->new($self->name, %args);
 236 }
 237
 238 sub get_read_method {
 239     return $_[0]->reader || $_[0]->accessor
 240 }
 241 sub get_write_method {
 242     return $_[0]->writer || $_[0]->accessor
 243 }
 244
 245 sub _get_accessor_method_ref {
 246     my($self, $type, $generator) = @_;
 247
 248     my $metaclass = $self->associated_class
 249         || $self->throw_error('No asocciated class for ' . $self->name);
 250
 251     my $accessor = $self->$type();
 252     if($accessor){
 253         return $metaclass->get_method_body($accessor);
 254     }
 255     else{
 256         return $self->accessor_metaclass->$generator($self, $metaclass);
 257     }
 258 }
 259
 260 sub get_read_method_ref{
 261     my($self) = @_;
 262     return $self->{_read_method_ref} ||= $self->_get_accessor_method_ref('get_read_method', '_generate_reader');
 263 }
 264
 265 sub get_write_method_ref{
 266     my($self) = @_;
 267     return $self->{_write_method_ref} ||= $self->_get_accessor_method_ref('get_write_method', '_generate_writer');
 268 }
 269
 270 sub set_value {
 271     my($self, $object, $value) = @_;
 272     return $self->get_write_method_ref()->($object, $value);
 273 }
 274
 275 sub get_value {
 276     my($self, $object) = @_;
 277     return $self->get_read_method_ref()->($object);
 278 }
 279
 280 sub has_value {
 281     my($self, $object) = @_;
 282     my $accessor_ref = $self->{_predicate_ref}
 283         ||= $self->_get_accessor_method_ref('predicate', '_generate_predicate');
 284
 285     return $accessor_ref->($object);
 286 }
 287
 288 sub clear_value {
 289     my($self, $object) = @_;
 290     my $accessor_ref = $self->{_crealer_ref}
 291         ||= $self->_get_accessor_method_ref('clearer', '_generate_clearer');
 292
 293     return $accessor_ref->($object);
 294 }
 295
 296
 297 sub associate_method{
 298     my ($attribute, $method_name) = @_;
 299     $attribute->{associated_methods}++;
 300     return;
 301 }
 302
 303 sub install_accessors{
 304     my($attribute) = @_;
 305
 306     my $metaclass      = $attribute->associated_class;
 307     my $accessor_class = $attribute->accessor_metaclass;
 308
 309     foreach my $type(qw(accessor reader writer predicate clearer)){
 310         if(exists $attribute->{$type}){
 311             my $generator = '_generate_' . $type;
 312             my $code      = $accessor_class->$generator($attribute, $metaclass);
 313             $metaclass->add_method($attribute->{$type} => $code);
 314             $attribute->associate_method($attribute->{$type});
 315         }
 316     }
 317
 318     # install delegation
 319     if(exists $attribute->{handles}){
 320         my %handles = $attribute->_canonicalize_handles($attribute->{handles});
 321
 322         while(my($handle, $method_to_call) = each %handles){
 323             $metaclass->add_method($handle =>
 324                 $attribute->_make_delegation_method(
 325                     $handle, $method_to_call));
 326
 327             $attribute->associate_method($handle);
 328         }
 329     }
 330
 331     return;
 332 }
 333
 334 sub delegation_metaclass() { 'Mouse::Meta::Method::Delegation' }
 335
 336 sub _canonicalize_handles {
 337     my($self, $handles) = @_;
 338
 339     if (ref($handles) eq 'HASH') {
 340         return %$handles;
 341     }
 342     elsif (ref($handles) eq 'ARRAY') {
 343         return map { $_ => $_ } @$handles;
 344     }
 345     elsif (ref($handles) eq 'Regexp') {
 346         my $class_or_role = ($self->{isa} || $self->{does})
 347             || $self->throw_error("Cannot delegate methods based on a Regexp without a type constraint (isa)");
 348
 349         my $meta = Mouse::Meta::Class->initialize("$class_or_role"); # "" for stringify
 350         return map  { $_ => $_ }
 351                grep { !Mouse::Object->can($_) && $_ =~ $handles }
 352                    Mouse::Util::is_a_metarole($meta)
 353                         ? $meta->get_method_list
 354                         : $meta->get_all_method_names;
 355     }
 356     else {
 357         $self->throw_error("Unable to canonicalize the 'handles' option with $handles");
 358     }
 359 }
 360
 361 sub _make_delegation_method {
 362     my($self, $handle, $method_to_call) = @_;
 363     my $delegator = $self->delegation_metaclass;
 364     Mouse::Util::load_class($delegator);
 365
 366     return $delegator->_generate_delegation($self, $handle, $method_to_call);
 367 }
 368
 369 sub throw_error{
 370     my $self = shift;
 371
 372     my $metaclass = (ref $self && $self->associated_class) || 'Mouse::Meta::Class';
 373     $metaclass->throw_error(@_, depth => 1);
 374 }
 375
 376 1;
 377 __END__
 378
 379 =head1 NAME
 380
 381 Mouse::Meta::Attribute - The Mouse attribute metaclass
 382
 383 =head1 VERSION
 384
 385 This document describes Mouse version 0.45
 386
 387 =head1 METHODS
 388
 389 =head2 C<< new(%options) -> Mouse::Meta::Attribute >>
 390
 391 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 392
 393 It adds the following options to the constructor:
 394
 395 =over 4
 396
 397 =item C<< is => 'ro', 'rw', 'bare' >>
 398
 399 This provides a shorthand for specifying the C<reader>, C<writer>, or
 400 C<accessor> names. If the attribute is read-only ('ro') then it will
 401 have a C<reader> method with the same attribute as the name.
 402
 403 If it is read-write ('rw') then it will have an C<accessor> method
 404 with the same name. If you provide an explicit C<writer> for a
 405 read-write attribute, then you will have a C<reader> with the same
 406 name as the attribute, and a C<writer> with the name you provided.
 407
 408 Use 'bare' when you are deliberately not installing any methods
 409 (accessor, reader, etc.) associated with this attribute; otherwise,
 410 Moose will issue a deprecation warning when this attribute is added to a
 411 metaclass.
 412
 413 =item C<< isa => Type >>
 414
 415 This option accepts a type. The type can be a string, which should be
 416 a type name. If the type name is unknown, it is assumed to be a class
 417 name.
 418
 419 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 420
 421 If you I<also> provide a C<does> option, then your C<isa> option must
 422 be a class name, and that class must do the role specified with
 423 C<does>.
 424
 425 =item C<< does => Role >>
 426
 427 This is short-hand for saying that the attribute's type must be an
 428 object which does the named role.
 429
 430 B<This option is not yet supported.>
 431
 432 =item C<< coerce => Bool >>
 433
 434 This option is only valid for objects with a type constraint
 435 (C<isa>). If this is true, then coercions will be applied whenever
 436 this attribute is set.
 437
 438 You can make both this and the C<weak_ref> option true.
 439
 440 =item C<< trigger => CodeRef >>
 441
 442 This option accepts a subroutine reference, which will be called after
 443 the attribute is set.
 444
 445 =item C<< required => Bool >>
 446
 447 An attribute which is required must be provided to the constructor. An
 448 attribute which is required can also have a C<default> or C<builder>,
 449 which will satisfy its required-ness.
 450
 451 A required attribute must have a C<default>, C<builder> or a
 452 non-C<undef> C<init_arg>
 453
 454 =item C<< lazy => Bool >>
 455
 456 A lazy attribute must have a C<default> or C<builder>. When an
 457 attribute is lazy, the default value will not be calculated until the
 458 attribute is read.
 459
 460 =item C<< weak_ref => Bool >>
 461
 462 If this is true, the attribute's value will be stored as a weak
 463 reference.
 464
 465 =item C<< auto_deref => Bool >>
 466
 467 If this is true, then the reader will dereference the value when it is
 468 called. The attribute must have a type constraint which defines the
 469 attribute as an array or hash reference.
 470
 471 =item C<< lazy_build => Bool >>
 472
 473 Setting this to true makes the attribute lazy and provides a number of
 474 default methods.
 475
 476   has 'size' => (
 477       is         => 'ro',
 478       lazy_build => 1,
 479   );
 480
 481 is equivalent to this:
 482
 483   has 'size' => (
 484       is        => 'ro',
 485       lazy      => 1,
 486       builder   => '_build_size',
 487       clearer   => 'clear_size',
 488       predicate => 'has_size',
 489   );
 490
 491 =back
 492
 493 =head2 C<< associate_method(MethodName) >>
 494
 495 Associates a method with the attribute. Typically, this is called internally
 496 when an attribute generates its accessors.
 497
 498 Currently the argument I<MethodName> is ignored in Mouse.
 499
 500 =head2 C<< verify_against_type_constraint(Item) -> TRUE | ERROR >>
 501
 502 Checks that the given value passes this attribute's type constraint. Returns C<true>
 503 on success, otherwise C<confess>es.
 504
 505 =head2 C<< clone_and_inherit_options(options) -> Mouse::Meta::Attribute >>
 506
 507 Creates a new attribute in the owner class, inheriting options from parent classes.
 508 Accessors and helper methods are installed. Some error checking is done.
 509
 510 =head2 C<< get_read_method_ref >>
 511
 512 =head2 C<< get_write_method_ref >>
 513
 514 Returns the subroutine reference of a method suitable for reading or
 515 writing the attribute's value in the associated class. These methods
 516 always return a subroutine reference, regardless of whether or not the
 517 attribute is read- or write-only.
 518
 519 =head1 SEE ALSO
 520
 521 L<Moose::Meta::Attribute>
 522
 523 L<Class::MOP::Attribute>
 524
 525 =cut
 526