lib/MooseX/Types/Log/Dispatch.pm

   1 package MooseX::Types::Log::Dispatch;
   2
   3 use MooseX::Types -declare => [ 'LogLevel', 'Logger' ];
   4
   5 use MooseX::Types::Moose qw/Str HashRef ArrayRef/;
   6 use Log::Dispatch;
   7
   8 our $VERSION = '0.002000';
   9
  10 subtype LogLevel,
  11   as Str,
  12   where { Log::Dispatch->level_is_valid( $_ ) },
  13   message { "'$_' is not a valid Log::Dispatch log level." };
  14
  15 class_type Logger, { class => 'Log::Dispatch' };
  16
  17 coerce Logger,
  18   from HashRef,
  19   via { Log::Dispatch->new( %$_ ) };
  20
  21 coerce Logger,
  22   from ArrayRef,
  23   via { Log::Dispatch->new( outputs => $_ ) };
  24
  25 1;
  26
  27 __END__;
  28
  29 =head1 NAME
  30
  31 MooseX::Types::Log::Dispatch - L<Log::Dispatch> related constraints and coercions for
  32 Moose
  33
  34 =head1 SYNOPSIS
  35
  36     package MyFoo;
  37     use MooseX::Types::Log::Dispatch qw(Logger LogLevel);
  38
  39     has logger => (
  40         isa => Logger,
  41         is => 'ro',
  42         coerce => 1,
  43     );
  44
  45     has event_log_level => (
  46         isa => LogLevel,
  47         is => 'ro',
  48     );
  49
  50     sub some_event_happened {
  51       my ($self, $event) = @_;
  52       $self->logger->log( level => $self->event_log_level, message => "$event happened");
  53     }
  54
  55     my $obj1 = MyFoos->new(
  56       event_log_level => 'debug',
  57       logger => [ ['Screen', min_level => 'notice' ] ]
  58     );
  59
  60     ## or
  61
  62     my $obj2 = MyFoos->new(
  63       event_log_level => 'warning',
  64       logger => { outputs => [ ['Screen', min_level => 'debug' ] ] }
  65     );
  66
  67     $obj1->some_event_happened('zoom'); #nothing prints
  68     $obj2->some_event_happened('zoom'); # 'zoom happened' prints
  69
  70 =head1 DESCRIPTION
  71
  72 This module provides Moose TypeConstraints that are believed to be useful when
  73 working with Log::Dispatch;
  74
  75 =head1 AVAILABLE CONSTRAINTS
  76
  77 =head2 Logger
  78
  79 Class type for 'Log::Dispatch' optional coercion will turn dereference a
  80 hash reference and pass it to 'new' or treat an array reference as a list
  81 of C<outputs>.
  82
  83 =head2 LogLevel
  84
  85 A subtype of 'Str', this should be a string that is a valid L<Log::Dispatch>
  86 log level like: 0, 1, 2 ,3 ,4 ,5 ,6 ,7, info, debug, notice, warn, warning,
  87 err, error, crit, critical, alert, emerg, and emergency
  88
  89 =head1 AUTHOR
  90
  91 Guillermo Roditi (groditi) E<lt>groditi@cpan.orgE<gt>
  92
  93 =head1 COPYRIGHT AND LICENSE
  94
  95 Copyright (c) 2010 Guillermo Roditi. This program is free software; you can
  96 redistribute it and/or modify it under the same terms as Perl itself.
  97
  98 =cut
  99