lib/MooseX/Storage.pm

   1
   2 package MooseX::Storage;
   3 use Moose qw(confess);
   4
   5 use MooseX::Storage::Meta::Attribute::DoNotSerialize;
   6
   7 our $VERSION   = '0.18';
   8 our $AUTHORITY = 'cpan:STEVAN';
   9
  10 sub import {
  11     my $pkg = caller();
  12
  13     return if $pkg eq 'main';
  14
  15     ($pkg->can('meta'))
  16         || confess "This package can only be used in Moose based classes";
  17
  18     $pkg->meta->add_method('Storage' => __PACKAGE__->meta->find_method_by_name('_injected_storage_role_generator'));
  19 }
  20
  21 sub _injected_storage_role_generator {
  22     my %params = @_;
  23
  24     if (exists $params{'base'}) {
  25         $params{'base'} = ('Base::' . $params{'base'});
  26     }
  27     else {
  28         $params{'base'} = 'Basic';
  29     }
  30
  31     my @roles = (
  32         ('MooseX::Storage::' . $params{'base'}),
  33     );
  34
  35     # NOTE:
  36     # you don't have to have a format
  37     # role, this just means you dont
  38     # get anything other than pack/unpack
  39     push @roles => 'MooseX::Storage::Format::' . $params{'format'}
  40         if exists $params{'format'};
  41
  42     # NOTE:
  43     # many IO roles don't make sense unless
  44     # you have also have a format role chosen
  45     # too, the exception being StorableFile
  46     if (exists $params{'io'}) {
  47         # NOTE:
  48         # we dont need this code anymore, cause
  49         # the role composition will catch it for
  50         # us. This allows the StorableFile to work
  51         #(exists $params{'format'})
  52         #    || confess "You must specify a format role in order to use an IO role";
  53         push @roles => 'MooseX::Storage::IO::' . $params{'io'};
  54     }
  55
  56     # Note:
  57     # These traits alter the behaviour of the engine, the user can
  58     # specify these per role-usage
  59     for my $trait ( @{ $params{'traits'} ||= [] } ) {
  60         push @roles, 'MooseX::Storage::Traits::'.$trait;
  61     }
  62
  63     Class::MOP::load_class($_)
  64         || die "Could not load role (" . $_ . ")"
  65             foreach @roles;
  66
  67     return @roles;
  68 }
  69
  70 1;
  71
  72 __END__
  73
  74 =pod
  75
  76 =head1 NAME
  77
  78 MooseX::Storage - A serialization framework for Moose classes
  79
  80 =head1 SYNOPSIS
  81
  82   package Point;
  83   use Moose;
  84   use MooseX::Storage;
  85
  86   our $VERSION = '0.01';
  87
  88   with Storage('format' => 'JSON', 'io' => 'File');
  89
  90   has 'x' => (is => 'rw', isa => 'Int');
  91   has 'y' => (is => 'rw', isa => 'Int');
  92
  93   1;
  94
  95   my $p = Point->new(x => 10, y => 10);
  96
  97   ## methods to pack/unpack an
  98   ## object in perl data structures
  99
 100   # pack the class into a hash
 101   $p->pack(); # { __CLASS__ => 'Point-0.01', x => 10, y => 10 }
 102
 103   # unpack the hash into a class
 104   my $p2 = Point->unpack({ __CLASS__ => 'Point-0.01', x => 10, y => 10 });
 105
 106   ## methods to freeze/thaw into
 107   ## a specified serialization format
 108   ## (in this case JSON)
 109
 110   # pack the class into a JSON string
 111   $p->freeze(); # { "__CLASS__" : "Point-0.01", "x" : 10, "y" : 10 }
 112
 113   # unpack the JSON string into a class
 114   my $p2 = Point->thaw('{ "__CLASS__" : "Point-0.01", "x" : 10, "y" : 10 }');
 115
 116   ## methods to load/store a class
 117   ## on the file system
 118
 119   $p->store('my_point.json');
 120
 121   my $p2 = Point->load('my_point.json');
 122
 123 =head1 DESCRIPTION
 124
 125 MooseX::Storage is a serialization framework for Moose, it provides
 126 a very flexible and highly pluggable way to serialize Moose classes
 127 to a number of different formats and styles.
 128
 129 =head2 Important Note
 130
 131 This is still an early release of this module, so use with caution.
 132 It's outward facing serialization API should be considered stable,
 133 but I still reserve the right to make tweaks if I need too. Anything
 134 beyond the basic pack/unpack, freeze/thaw and load/store should not
 135 be relied on.
 136
 137 =head2 Levels of Serialization
 138
 139 There are 3 levels to the serialization, each of which builds upon
 140 the other and each of which can be customized to the specific needs
 141 of your class.
 142
 143 =over 4
 144
 145 =item B<base>
 146
 147 The first (base) level is C<pack> and C<unpack>. In this level the
 148 class is serialized into a Perl HASH reference, it is tagged with the
 149 class name and each instance attribute is stored. Very simple.
 150
 151 This level is not optional, it is the bare minumum that
 152 MooseX::Storage provides and all other levels build on top of this.
 153
 154 =item B<format>
 155
 156 The second (format) level is C<freeze> and C<thaw>. In this level the
 157 output of C<pack> is sent to C<freeze> or the output of C<thaw> is sent
 158 to C<unpack>. This levels primary role is to convert to and from the
 159 specific serialization format and Perl land.
 160
 161 This level is optional, if you don't want/need it, you don't have to
 162 have it. You can just use C<pack>/C<unpack> instead.
 163
 164 =item B<io>
 165
 166 The third (io) level is C<load> and C<store>. In this level we are reading
 167 and writing data to file/network/database/etc.
 168
 169 This level is also optional, in most cases it does require a C<format> role
 170 to also be used, the expection being the C<StorableFile> role.
 171
 172 =back
 173
 174 =head2 Behaviour modifiers
 175
 176 The serialization behaviour can be changed by supplying C<traits>.
 177 This can be done as follows:
 178
 179   use MooseX::Storage;
 180   with Storage( traits => [Trait1, Trait2,...] );
 181
 182 The following traits are currently bundled with C<MooseX::Storage>:
 183
 184 =over 4
 185
 186 =item OnlyWhenBuilt
 187
 188 Only attributes that have been built (ie, where the predicate returns
 189 'true') will be serialized. This avoids any potentially expensive computations.
 190
 191 See L<MooseX::Storage::Traits::OnlyWhenBuilt> for details.
 192
 193 =back
 194
 195 =head2 How we serialize
 196
 197 There are always limits to any serialization framework, there are just
 198 some things which are really difficult to serialize properly and some
 199 things which cannot be serialized at all.
 200
 201 =head2 What can be serialized?
 202
 203 Currently only numbers, string, ARRAY refs, HASH refs and other
 204 MooseX::Storage enabled objects are supported.
 205
 206 With Array and Hash references the first level down is inspected and
 207 any objects found are serialized/deserialized for you. We do not do
 208 this recusively by default, however this feature may become an
 209 option eventually.
 210
 211 The specific serialize/deserialize routine is determined by the
 212 Moose type constraint a specific attribute has. In most cases subtypes
 213 of the supported types are handled correctly, and there is a facility
 214 for adding handlers for custom types as well. This will get documented
 215 eventually, but it is currently still in development.
 216
 217 =head2 What can not be serialized?
 218
 219 We do not support CODE references yet, but this support might be added
 220 in using B::Deparse or some other deep magic.
 221
 222 Scalar refs are not supported, mostly because there is no way to know
 223 if the value being referenced will be there when the object is inflated.
 224 I highly doubt will be ever support this in a general sense, but it
 225 would be possible to add this yourself for a small specific case.
 226
 227 Circular references are specifically disallowed, however if you break
 228 the cycles yourself then re-assemble them later you can get around this.
 229 The reason we disallow circular refs is because they are not always supported
 230 in all formats we use, and they tend to be very tricky to do for all
 231 possible cases. It is almost always something you want to have tight control
 232 over anyway.
 233
 234 =head1 CAVEAT
 235
 236 This is B<not> a persistence framework, changes to your object after
 237 you load or store it will not be reflected in the stored class.
 238
 239 =head1 EXPORTS
 240
 241 =over 4
 242
 243 =item B<Storage (%options)>
 244
 245 This module will export the C<Storage> method will can be used to
 246 load a specific set of MooseX::Storage roles to implement a specific
 247 combination of features. It is meant to make things easier, but it
 248 is by no means the only way. You can still compose your roles by
 249 hand if you like.
 250
 251 =back
 252
 253 =head1 METHODS
 254
 255 =over 4
 256
 257 =item B<import>
 258
 259 =back
 260
 261 =head2 Introspection
 262
 263 =over 4
 264
 265 =item B<meta>
 266
 267 =back
 268
 269 =head1 TODO
 270
 271 This module needs docs and probably a Cookbook of some kind as well.
 272 This is an early release, so that is my excuse for now :)
 273
 274 For the time being, please read the tests and feel free to email me
 275 if you have any questions. This module can also be discussed on IRC
 276 in the #moose channel on irc.perl.org.
 277
 278 =head1 BUGS
 279
 280 All complex software has bugs lurking in it, and this module is no
 281 exception. If you find a bug please either email me, or add the bug
 282 to cpan-RT.
 283
 284 =head1 AUTHOR
 285
 286 Chris Prather E<lt>chris.prather@iinteractive.comE<gt>
 287
 288 Stevan Little E<lt>stevan.little@iinteractive.comE<gt>
 289
 290 Yuval Kogman E<lt>yuval.kogman@iinteractive.comE<gt>
 291
 292 =head1 COPYRIGHT AND LICENSE
 293
 294 Copyright 2007-2008 by Infinity Interactive, Inc.
 295
 296 L<http://www.iinteractive.com>
 297
 298 This library is free software; you can redistribute it and/or modify
 299 it under the same terms as Perl itself.
 300
 301 =cut