lib/MooseX/AttributeHelpers/Base.pm

   1
   2 package MooseX::AttributeHelpers::Base;
   3 use Moose;
   4 use Moose::Util::TypeConstraints;
   5
   6 our $VERSION   = '0.02';
   7 our $AUTHORITY = 'cpan:STEVAN';
   8
   9 extends 'Moose::Meta::Attribute';
  10
  11 # this is the method map you define ...
  12 has 'provides' => (
  13     is      => 'ro',
  14     isa     => 'HashRef',
  15     default => sub {{}}
  16 );
  17
  18
  19 # these next two are the possible methods
  20 # you can use in the 'provides' map.
  21
  22 # provide a Class or Role which we can
  23 # collect the method providers from
  24 has 'method_provider' => (
  25     is        => 'ro',
  26     isa       => 'ClassName',
  27     predicate => 'has_method_provider',
  28 );
  29
  30 # or you can provide a HASH ref of anon subs
  31 # yourself. This will also collect and store
  32 # the methods from a method_provider as well
  33 has 'method_constructors' => (
  34     is      => 'ro',
  35     isa     => 'HashRef',
  36     lazy    => 1,
  37     default => sub {
  38         my $self = shift;
  39         return +{} unless $self->has_method_provider;
  40         # or grab them from the role/class
  41         my $method_provider = $self->method_provider->meta;
  42         return +{
  43             map {
  44                 $_ => $method_provider->get_method($_)
  45             } $method_provider->get_method_list
  46         };
  47     },
  48 );
  49
  50 # extend the parents stuff to make sure
  51 # certain bits are now required ...
  52 has '+$!default'       => (required => 1);
  53 has '+type_constraint' => (required => 1);
  54
  55 ## Methods called prior to instantiation
  56
  57 sub helper_type { () }
  58
  59 sub process_options_for_provides {
  60     my ($self, $options) = @_;
  61
  62     if (my $type = $self->helper_type) {
  63         (exists $options->{isa})
  64             || confess "You must define a type with the $type metaclass";
  65
  66         my $isa = $options->{isa};
  67
  68         unless (blessed($isa) && $isa->isa('Moose::Meta::TypeConstraint')) {
  69             $isa = find_type_constraint($isa);
  70         }
  71
  72         ($isa->is_a_type_of($type))
  73             || confess "The type constraint for a $type ($options->{isa}) must be a subtype of $type";
  74     }
  75 }
  76
  77 before '_process_options' => sub {
  78     my ($self, $name, $options) = @_;
  79     $self->process_options_for_provides($options, $name);
  80 };
  81
  82 ## methods called after instantiation
  83
  84 # this confirms that provides has
  85 # all valid possibilities in it
  86 sub check_provides_values {
  87     my $self = shift;
  88
  89     my $method_constructors = $self->method_constructors;
  90
  91     foreach my $key (keys %{$self->provides}) {
  92         (exists $method_constructors->{$key})
  93             || confess "$key is an unsupported method type";
  94     }
  95 }
  96
  97 after 'install_accessors' => sub {
  98     my $attr  = shift;
  99     my $class = $attr->associated_class;
 100
 101     # grab the reader and writer methods
 102     # as well, this will be useful for
 103     # our method provider constructors
 104     my ($attr_reader, $attr_writer);
 105     if (my $reader = $attr->get_read_method) {
 106         $attr_reader = $class->get_method($reader);
 107     }
 108     else {
 109         $attr_reader = sub { $attr->get_value(@_) };
 110     }
 111
 112     if (my $writer = $attr->get_write_method) {
 113         $attr_writer = $class->get_method($writer);
 114     }
 115     else {
 116         $attr_writer = sub { $attr->set_value(@_) };
 117     }
 118
 119     # before we install them, lets
 120     # make sure they are valid
 121     $attr->check_provides_values;
 122
 123     my $method_constructors = $attr->method_constructors;
 124
 125     foreach my $key (keys %{$attr->provides}) {
 126
 127         my $method_name = $attr->provides->{$key};
 128         my $method_body = $method_constructors->{$key}->(
 129             $attr,
 130             $attr_reader,
 131             $attr_writer,
 132         );
 133
 134         if ($class->has_method($method_name)) {
 135             confess "The method ($method_name) already exists in class (" . $class->name . ")";
 136         }
 137
 138         $class->add_method($method_name =>
 139             MooseX::AttributeHelpers::Meta::Method::Provided->wrap(
 140                 $method_body,
 141             )
 142         );
 143     }
 144 };
 145
 146 no Moose;
 147 no Moose::Util::TypeConstraints;
 148
 149 1;
 150
 151 __END__
 152
 153 =pod
 154
 155 =head1 NAME
 156
 157 MooseX::AttributeHelpers::Base - Base class for attribute helpers
 158
 159 =head1 DESCRIPTION
 160
 161 Documentation to come.
 162
 163 =head1 ATTRIBUTES
 164
 165 =over 4
 166
 167 =item B<provides>
 168
 169 =item B<method_provider>
 170
 171 =item B<method_constructors>
 172
 173 =back
 174
 175 =head1 EXTENDED ATTRIBUTES
 176
 177 =over 4
 178
 179 =item B<$!default>
 180
 181 C<$!default> is now required.
 182
 183 =item B<type_constraint>
 184
 185 C<type_constraint> is now required.
 186
 187 =back
 188
 189 =head1 METHODS
 190
 191 =over 4
 192
 193 =item B<helper_type>
 194
 195 =item B<check_provides_values>
 196
 197 =item B<has_default>
 198
 199 =item B<has_method_provider>
 200
 201 =item B<has_type_constraint>
 202
 203 =item B<install_accessors>
 204
 205 =item B<process_options_for_provides>
 206
 207 =back
 208
 209 =head1 BUGS
 210
 211 All complex software has bugs lurking in it, and this module is no
 212 exception. If you find a bug please either email me, or add the bug
 213 to cpan-RT.
 214
 215 =head1 AUTHOR
 216
 217 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 218
 219 =head1 COPYRIGHT AND LICENSE
 220
 221 Copyright 2007 by Infinity Interactive, Inc.
 222
 223 L<http://www.iinteractive.com>
 224
 225 This library is free software; you can redistribute it and/or modify
 226 it under the same terms as Perl itself.
 227
 228 =cut