lib/MooseX/AttributeHelpers/Base.pm

   1
   2 package MooseX::AttributeHelpers::Base;
   3 use Moose;
   4 use Moose::Util::TypeConstraints;
   5
   6 our $VERSION   = '0.01';
   7 our $AUTHORITY = 'cpan:STEVAN';
   8
   9 extends 'Moose::Meta::Attribute';
  10
  11 # this is the method map you define ...
  12 has 'provides' => (
  13     is       => 'ro',
  14     isa      => 'HashRef',
  15     required => 1,
  16 );
  17
  18
  19 # these next two are the possible methods
  20 # you can use in the 'provides' map.
  21
  22 # provide a Class or Role which we can
  23 # collect the method providers from
  24 has 'method_provider' => (
  25     is        => 'ro',
  26     isa       => 'ClassName',
  27     predicate => 'has_method_provider',
  28 );
  29
  30 # or you can provide a HASH ref of anon subs
  31 # yourself. This will also collect and store
  32 # the methods from a method_provider as well
  33 has 'method_constructors' => (
  34     is      => 'ro',
  35     isa     => 'HashRef',
  36     lazy    => 1,
  37     default => sub {
  38         my $self = shift;
  39         return +{} unless $self->has_method_provider;
  40         # or grab them from the role/class
  41         my $method_provider = $self->method_provider->meta;
  42         return +{
  43             map {
  44                 $_ => $method_provider->get_method($_)
  45             } $method_provider->get_method_list
  46         };
  47     }
  48 );
  49
  50 # extend the parents stuff to make sure
  51 # certain bits are now required ...
  52 has '+$!default'       => (required => 1);
  53 has '+type_constraint' => (required => 1);
  54
  55 ## Methods called prior to instantiation
  56
  57 sub helper_type { () }
  58
  59 sub process_options_for_provides {
  60     my ($self, $options) = @_;
  61
  62     if (my $type = $self->helper_type) {
  63         (exists $options->{isa})
  64             || confess "You must define a type with the $type metaclass";
  65
  66         my $isa = $options->{isa};
  67
  68         unless (blessed($isa) && $isa->isa('Moose::Meta::TypeConstraint')) {
  69             $isa = find_type_constraint($isa);
  70         }
  71
  72         ($isa->is_a_type_of($type))
  73             || confess "The type constraint for a $type ($options->{isa}) must be a subtype of $type";
  74     }
  75 }
  76
  77 before '_process_options' => sub {
  78     my ($self, $name, $options) = @_;
  79     if (exists $options->{provides}) {
  80         $self->process_options_for_provides($options);
  81     }
  82 };
  83
  84 ## methods called after instantiation
  85
  86 # this confirms that provides has
  87 # all valid possibilities in it
  88 sub check_provides_values {
  89     my $self = shift;
  90
  91     my $method_constructors = $self->method_constructors;
  92
  93     foreach my $key (keys %{$self->provides}) {
  94         (exists $method_constructors->{$key})
  95             || confess "$key is an unsupported method type";
  96     }
  97 }
  98
  99 after 'install_accessors' => sub {
 100     my $attr  = shift;
 101     my $class = $attr->associated_class;
 102
 103     # before we install them, lets
 104     # make sure they are valid
 105     $attr->check_provides_values;
 106
 107     my $method_constructors = $attr->method_constructors;
 108
 109     foreach my $key (keys %{$attr->provides}) {
 110
 111         my $method_name = $attr->provides->{$key};
 112         my $method_body = $method_constructors->{$key}->($attr);
 113
 114         if ($class->has_method($method_name)) {
 115             confess "The method ($method_name) already exists in class (" . $class->name . ")";
 116         }
 117
 118         $class->add_method($method_name =>
 119             MooseX::AttributeHelpers::Meta::Method::Provided->wrap(
 120                 $method_body,
 121             )
 122         );
 123     }
 124 };
 125
 126 no Moose;
 127 no Moose::Util::TypeConstraints;
 128
 129 1;
 130
 131 __END__
 132
 133 =pod
 134
 135 =head1 NAME
 136
 137 MooseX::AttributeHelpers::Base
 138
 139 =head1 SYNOPSIS
 140
 141 =head1 DESCRIPTION
 142
 143 =head1 METHODS
 144
 145 =head1 BUGS
 146
 147 All complex software has bugs lurking in it, and this module is no
 148 exception. If you find a bug please either email me, or add the bug
 149 to cpan-RT.
 150
 151 =head1 AUTHOR
 152
 153 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 154
 155 =head1 COPYRIGHT AND LICENSE
 156
 157 Copyright 2007 by Infinity Interactive, Inc.
 158
 159 L<http://www.iinteractive.com>
 160
 161 This library is free software; you can redistribute it and/or modify
 162 it under the same terms as Perl itself.
 163
 164 =cut