lib/Moose.pm

   1
   2 package Moose;
   3
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION = '0.09_03';
   8
   9 use Scalar::Util 'blessed', 'reftype';
  10 use Carp         'confess';
  11 use Sub::Name    'subname';
  12
  13 use UNIVERSAL::require;
  14 use Sub::Exporter;
  15
  16 use Class::MOP;
  17
  18 use Moose::Meta::Class;
  19 use Moose::Meta::TypeConstraint;
  20 use Moose::Meta::TypeCoercion;
  21 use Moose::Meta::Attribute;
  22 use Moose::Meta::Instance;
  23
  24 use Moose::Object;
  25 use Moose::Util::TypeConstraints;
  26
  27 {
  28     my $CALLER;
  29
  30     sub _init_meta {
  31         my $class = $CALLER;
  32
  33         # make a subtype for each Moose class
  34         subtype $class
  35             => as 'Object'
  36             => where { $_->isa($class) }
  37         unless find_type_constraint($class);
  38
  39         my $meta;
  40         if ($class->can('meta')) {
  41             # NOTE:
  42             # this is the case where the metaclass pragma
  43             # was used before the 'use Moose' statement to
  44             # override a specific class
  45             $meta = $class->meta();
  46             (blessed($meta) && $meta->isa('Moose::Meta::Class'))
  47                 || confess "Whoops, not møøsey enough";
  48         }
  49         else {
  50             # NOTE:
  51             # this is broken currently, we actually need
  52             # to allow the possiblity of an inherited
  53             # meta, which will not be visible until the
  54             # user 'extends' first. This needs to have
  55             # more intelligence to it
  56             $meta = Moose::Meta::Class->initialize($class);
  57             $meta->add_method('meta' => sub {
  58                 # re-initialize so it inherits properly
  59                 Moose::Meta::Class->initialize(blessed($_[0]) || $_[0]);
  60             })
  61         }
  62
  63         # make sure they inherit from Moose::Object
  64         $meta->superclasses('Moose::Object')
  65            unless $meta->superclasses();
  66     }
  67
  68     my %exports = (
  69         extends => sub {
  70             my $class = $CALLER;
  71             return subname 'Moose::extends' => sub (@) {
  72                 confess "Must derive at least one class" unless @_;
  73                 _load_all_classes(@_);
  74                 # this checks the metaclass to make sure
  75                 # it is correct, sometimes it can get out
  76                 # of sync when the classes are being built
  77                 my $meta = $class->meta->_fix_metaclass_incompatability(@_);
  78                 $meta->superclasses(@_);
  79             };
  80         },
  81         with => sub {
  82             my $class = $CALLER;
  83             return subname 'Moose::with' => sub (@) {
  84                 my (@roles) = @_;
  85                 confess "Must specify at least one role" unless @roles;
  86                 _load_all_classes(@roles);
  87                 $class->meta->_apply_all_roles(@roles);
  88             };
  89         },
  90         has => sub {
  91             my $class = $CALLER;
  92             return subname 'Moose::has' => sub ($;%) {
  93                 my ($name, %options) = @_;
  94                 $class->meta->_process_attribute($name, %options);
  95             };
  96         },
  97         before => sub {
  98             my $class = $CALLER;
  99             return subname 'Moose::before' => sub (@&) {
 100                 my $code = pop @_;
 101                 my $meta = $class->meta;
 102                 $meta->add_before_method_modifier($_, $code) for @_;
 103             };
 104         },
 105         after => sub {
 106             my $class = $CALLER;
 107             return subname 'Moose::after' => sub (@&) {
 108                 my $code = pop @_;
 109                 my $meta = $class->meta;
 110                 $meta->add_after_method_modifier($_, $code) for @_;
 111             };
 112         },
 113         around => sub {
 114             my $class = $CALLER;
 115             return subname 'Moose::around' => sub (@&) {
 116                 my $code = pop @_;
 117                 my $meta = $class->meta;
 118                 $meta->add_around_method_modifier($_, $code) for @_;
 119             };
 120         },
 121         super => sub {
 122             return subname 'Moose::super' => sub {};
 123         },
 124         override => sub {
 125             my $class = $CALLER;
 126             return subname 'Moose::override' => sub ($&) {
 127                 my ($name, $method) = @_;
 128                 $class->meta->add_override_method_modifier($name => $method);
 129             };
 130         },
 131         inner => sub {
 132             return subname 'Moose::inner' => sub {};
 133         },
 134         augment => sub {
 135             my $class = $CALLER;
 136             return subname 'Moose::augment' => sub (@&) {
 137                 my ($name, $method) = @_;
 138                 $class->meta->add_augment_method_modifier($name => $method);
 139             };
 140         },
 141         confess => sub {
 142             return \&Carp::confess;
 143         },
 144         blessed => sub {
 145             return \&Scalar::Util::blessed;
 146         }
 147     );
 148
 149     my $exporter = Sub::Exporter::build_exporter({
 150         exports => \%exports,
 151         groups  => {
 152             default => [':all']
 153         }
 154     });
 155
 156     sub import {
 157         $CALLER = caller();
 158
 159         strict->import;
 160         warnings->import;
 161
 162         # we should never export to main
 163         return if $CALLER eq 'main';
 164
 165         _init_meta();
 166
 167         goto $exporter;
 168     }
 169 }
 170
 171 ## Utility functions
 172
 173 sub _load_all_classes {
 174     foreach my $super (@_) {
 175         # see if this is already
 176         # loaded in the symbol table
 177         next if _is_class_already_loaded($super);
 178         # otherwise require it ...
 179         ($super->require)
 180             || confess "Could not load superclass '$super' because : " . $UNIVERSAL::require::ERROR;
 181     }
 182 }
 183
 184 sub _is_class_already_loaded {
 185         my $name = shift;
 186         no strict 'refs';
 187         return 1 if defined ${"${name}::VERSION"} || defined @{"${name}::ISA"};
 188         foreach (keys %{"${name}::"}) {
 189                 next if substr($_, -2, 2) eq '::';
 190                 return 1 if defined &{"${name}::$_"};
 191         }
 192     return 0;
 193 }
 194
 195 1;
 196
 197 __END__
 198
 199 =pod
 200
 201 =head1 NAME
 202
 203 Moose - Moose, it's the new Camel
 204
 205 =head1 SYNOPSIS
 206
 207   package Point;
 208   use strict;
 209   use warnings;
 210   use Moose;
 211
 212   has 'x' => (is => 'rw', isa => 'Int');
 213   has 'y' => (is => 'rw', isa => 'Int');
 214
 215   sub clear {
 216       my $self = shift;
 217       $self->x(0);
 218       $self->y(0);
 219   }
 220
 221   package Point3D;
 222   use strict;
 223   use warnings;
 224   use Moose;
 225
 226   extends 'Point';
 227
 228   has 'z' => (is => 'rw', isa => 'Int');
 229
 230   after 'clear' => sub {
 231       my $self = shift;
 232       $self->z(0);
 233   };
 234
 235 =head1 CAVEAT
 236
 237 Moose is a rapidly maturing module, and is already being used by
 238 a number of people. It's test suite is growing larger by the day,
 239 and the docs should soon follow.
 240
 241 This said, Moose is not yet finished, and should still be considered
 242 to be evolving. Much of the outer API is stable, but the internals
 243 are still subject to change (although not without serious thought
 244 given to it).
 245
 246 For more details, please refer to the L<FUTURE PLANS> section of
 247 this document.
 248
 249 =head1 DESCRIPTION
 250
 251 Moose is an extension of the Perl 5 object system.
 252
 253 =head2 Another object system!?!?
 254
 255 Yes, I know there has been an explosion recently of new ways to
 256 build object's in Perl 5, most of them based on inside-out objects,
 257 and other such things. Moose is different because it is not a new
 258 object system for Perl 5, but instead an extension of the existing
 259 object system.
 260
 261 Moose is built on top of L<Class::MOP>, which is a metaclass system
 262 for Perl 5. This means that Moose not only makes building normal
 263 Perl 5 objects better, but it also provides the power of metaclass
 264 programming.
 265
 266 =head2 Can I use this in production? Or is this just an experiment?
 267
 268 Moose is I<based> on the prototypes and experiments I did for the Perl 6
 269 meta-model, however Moose is B<NOT> an experiment/prototype, it is
 270 for B<real>. I will be deploying Moose into production environments later
 271 this year, and I have all intentions of using it as my de-facto class
 272 builderfrom now on.
 273
 274 =head2 Is Moose just Perl 6 in Perl 5?
 275
 276 No. While Moose is very much inspired by Perl 6, it is not. Instead, it
 277 is an OO system for Perl 5. I built Moose because I was tired or writing
 278 the same old boring Perl 5 OO code, and drooling over Perl 6 OO. So
 279 instead of switching to Ruby, I wrote Moose :)
 280
 281 =head1 BUILDING CLASSES WITH MOOSE
 282
 283 Moose makes every attempt to provide as much convience during class
 284 construction/definition, but still stay out of your way if you want
 285 it to. Here are a few items to note when building classes with Moose.
 286
 287 Unless specified with C<extends>, any class which uses Moose will
 288 inherit from L<Moose::Object>.
 289
 290 Moose will also manage all attributes (including inherited ones) that
 291 are defined with C<has>. And assuming that you call C<new> which is
 292 inherited from L<Moose::Object>, then this includes properly initializing
 293 all instance slots, setting defaults where approprtiate and performing any
 294 type constraint checking or coercion.
 295
 296 =head1 EXPORTED FUNCTIONS
 297
 298 Moose will export a number of functions into the class's namespace, which
 299 can then be used to set up the class. These functions all work directly
 300 on the current class.
 301
 302 =over 4
 303
 304 =item B<meta>
 305
 306 This is a method which provides access to the current class's metaclass.
 307
 308 =item B<extends (@superclasses)>
 309
 310 This function will set the superclass(es) for the current class.
 311
 312 This approach is recommended instead of C<use base>, because C<use base>
 313 actually C<push>es onto the class's C<@ISA>, whereas C<extends> will
 314 replace it. This is important to ensure that classes which do not have
 315 superclasses properly inherit from L<Moose::Object>.
 316
 317 =item B<with (@roles)>
 318
 319 This will apply a given set of C<@roles> to the local class. Role support
 320 is currently under heavy development, see L<Moose::Role> for more details.
 321
 322 =item B<has ($name, %options)>
 323
 324 This will install an attribute of a given C<$name> into the current class.
 325 The list of C<%options> are the same as those provided by
 326 L<Class::MOP::Attribute>, in addition to the list below which are provided
 327 by Moose (L<Moose::Meta::Attribute> to be more specific):
 328
 329 =over 4
 330
 331 =item I<is =E<gt> 'rw'|'ro'>
 332
 333 The I<is> option accepts either I<rw> (for read/write) or I<ro> (for read
 334 only). These will create either a read/write accessor or a read-only
 335 accessor respectively, using the same name as the C<$name> of the attribute.
 336
 337 If you need more control over how your accessors are named, you can use the
 338 I<reader>, I<writer> and I<accessor> options inherited from L<Class::MOP::Attribute>.
 339
 340 =item I<isa =E<gt> $type_name>
 341
 342 The I<isa> option uses Moose's type constraint facilities to set up runtime
 343 type checking for this attribute. Moose will perform the checks during class
 344 construction, and within any accessors. The C<$type_name> argument must be a
 345 string. The string can be either a class name, or a type defined using
 346 Moose's type defintion features.
 347
 348 =item I<coerce =E<gt> (1|0)>
 349
 350 This will attempt to use coercion with the supplied type constraint to change
 351 the value passed into any accessors of constructors. You B<must> have supplied
 352 a type constraint in order for this to work. See L<Moose::Cookbook::Recipe5>
 353 for an example usage.
 354
 355 =item I<does =E<gt> $role_name>
 356
 357 This will accept the name of a role which the value stored in this attribute
 358 is expected to have consumed.
 359
 360 =item I<required =E<gt> (1|0)>
 361
 362 This marks the attribute as being required. This means a value must be supplied
 363 during class construction, and the attribute can never be set to C<undef> with
 364 an accessor.
 365
 366 =item I<weak_ref =E<gt> (1|0)>
 367
 368 This will tell the class to strore the value of this attribute as a weakened
 369 reference. If an attribute is a weakened reference, it can B<not> also be coerced.
 370
 371 =item I<lazy =E<gt> (1|0)>
 372
 373 This will tell the class to not create this slot until absolutely nessecary.
 374 If an attribute is marked as lazy it B<must> have a default supplied.
 375
 376 =item I<auto_deref =E<gt> (1|0)>
 377
 378 This tells the accessor whether to automatically de-reference the value returned.
 379 This is only legal if your C<isa> option is either an C<ArrayRef> or C<HashRef>.
 380
 381 =item I<trigger =E<gt> $code>
 382
 383 The trigger option is a CODE reference which will be called after the value of
 384 the attribute is set. The CODE ref will be passed the instance itself, the
 385 updated value and the attribute meta-object (this is for more advanced fiddling
 386 and can typically be ignored in most cases). You can B<not> have a trigger on
 387 a read-only attribute.
 388
 389 =item I<handles =E<gt> [ @handles ]>
 390
 391 There is experimental support for attribute delegation using the C<handles>
 392 option. More docs to come later.
 393
 394 =back
 395
 396 =item B<before $name|@names =E<gt> sub { ... }>
 397
 398 =item B<after $name|@names =E<gt> sub { ... }>
 399
 400 =item B<around $name|@names =E<gt> sub { ... }>
 401
 402 This three items are syntactic sugar for the before, after and around method
 403 modifier features that L<Class::MOP> provides. More information on these can
 404 be found in the L<Class::MOP> documentation for now.
 405
 406 =item B<super>
 407
 408 The keyword C<super> is a noop when called outside of an C<override> method. In
 409 the context of an C<override> method, it will call the next most appropriate
 410 superclass method with the same arguments as the original method.
 411
 412 =item B<override ($name, &sub)>
 413
 414 An C<override> method, is a way of explictly saying "I am overriding this
 415 method from my superclass". You can call C<super> within this method, and
 416 it will work as expected. The same thing I<can> be accomplished with a normal
 417 method call and the C<SUPER::> pseudo-package, it is really your choice.
 418
 419 =item B<inner>
 420
 421 The keyword C<inner>, much like C<super>, is a no-op outside of the context of
 422 an C<augment> method. You can think of C<inner> as being the inverse of
 423 C<super>, the details of how C<inner> and C<augment> work is best described in
 424 the L<Moose::Cookbook>.
 425
 426 =item B<augment ($name, &sub)>
 427
 428 An C<augment> method, is a way of explictly saying "I am augmenting this
 429 method from my superclass". Once again, the details of how C<inner> and
 430 C<augment> work is best described in the L<Moose::Cookbook>.
 431
 432 =item B<confess>
 433
 434 This is the C<Carp::confess> function, and exported here beause I use it
 435 all the time. This feature may change in the future, so you have been warned.
 436
 437 =item B<blessed>
 438
 439 This is the C<Scalar::Uti::blessed> function, it is exported here beause I
 440 use it all the time. It is highly recommended that this is used instead of
 441 C<ref> anywhere you need to test for an object's class name.
 442
 443 =back
 444
 445 =head1 FUTURE PLANS
 446
 447 Here is just a sampling of the plans we have in store for Moose:
 448
 449 =over 4
 450
 451 =item *
 452
 453 Compiling Moose classes/roles into C<.pmc> files for faster loading and execution.
 454
 455 =item *
 456
 457 Supporting sealed and finalized classes in Moose. This will allow greater control
 458 of the extensions of frameworks and such.
 459
 460 =back
 461
 462 =head1 MISC.
 463
 464 =head2 What does Moose stand for??
 465
 466 Moose doesn't stand for one thing in particular, however, if you
 467 want, here are a few of my favorites, feel free to contribute
 468 more :)
 469
 470 =over 4
 471
 472 =item Make Other Object Systems Envious
 473
 474 =item Makes Object Orientation So Easy
 475
 476 =item Makes Object Orientation Spiffy- Er  (sorry ingy)
 477
 478 =item Most Other Object Systems Emasculate
 479
 480 =item Moose Often Ovulate Sorta Early
 481
 482 =item Moose Offers Often Super Extensions
 483
 484 =item Meta Object Orientation Syntax Extensions
 485
 486 =back
 487
 488 =head1 CAVEATS
 489
 490 =over 4
 491
 492 =item *
 493
 494 It should be noted that C<super> and C<inner> can B<not> be used in the same
 495 method. However, they can be combined together with the same class hierarchy,
 496 see F<t/014_override_augment_inner_super.t> for an example.
 497
 498 The reason that this is so is because C<super> is only valid within a method
 499 with the C<override> modifier, and C<inner> will never be valid within an
 500 C<override> method. In fact, C<augment> will skip over any C<override> methods
 501 when searching for it's appropriate C<inner>.
 502
 503 This might seem like a restriction, but I am of the opinion that keeping these
 504 two features seperate (but interoperable) actually makes them easy to use since
 505 their behavior is then easier to predict. Time will tell if I am right or not.
 506
 507 =back
 508
 509 =head1 ACKNOWLEDGEMENTS
 510
 511 =over 4
 512
 513 =item I blame Sam Vilain for introducing me to the insanity that is meta-models.
 514
 515 =item I blame Audrey Tang for then encouraging my meta-model habit in #perl6.
 516
 517 =item Without Yuval "nothingmuch" Kogman this module would not be possible,
 518 and it certainly wouldn't have this name ;P
 519
 520 =item The basis of the TypeContraints module was Rob Kinyon's idea
 521 originally, I just ran with it.
 522
 523 =item Thanks to mst & chansen and the whole #moose poose for all the
 524 ideas/feature-requests/encouragement
 525
 526 =back
 527
 528 =head1 SEE ALSO
 529
 530 =over 4
 531
 532 =item L<Class::MOP> documentation
 533
 534 =item The #moose channel on irc.perl.org
 535
 536 =item L<http://forum2.org/moose/>
 537
 538 =item L<http://www.cs.utah.edu/plt/publications/oopsla04-gff.pdf>
 539
 540 This paper (suggested by lbr on #moose) was what lead to the implementation
 541 of the C<super>/C<overrride> and C<inner>/C<augment> features. If you really
 542 want to understand this feature, I suggest you read this.
 543
 544 =back
 545
 546 =head1 BUGS
 547
 548 All complex software has bugs lurking in it, and this module is no
 549 exception. If you find a bug please either email me, or add the bug
 550 to cpan-RT.
 551
 552 =head1 AUTHOR
 553
 554 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 555
 556 Christian Hansen E<lt>chansen@cpan.orgE<gt>
 557
 558 Yuval Kogman E<lt>nothingmuch@woobling.orgE<gt>
 559
 560 =head1 COPYRIGHT AND LICENSE
 561
 562 Copyright 2006 by Infinity Interactive, Inc.
 563
 564 L<http://www.iinteractive.com>
 565
 566 This library is free software; you can redistribute it and/or modify
 567 it under the same terms as Perl itself.
 568
 569 =cut