lib/Moose.pm

   1
   2 package Moose;
   3
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION = '0.03';
   8
   9 use Scalar::Util 'blessed', 'reftype';
  10 use Carp         'confess';
  11 use Sub::Name    'subname';
  12
  13 use UNIVERSAL::require;
  14
  15 use Class::MOP;
  16
  17 use Moose::Meta::Class;
  18 use Moose::Meta::Attribute;
  19 use Moose::Meta::TypeConstraint;
  20 use Moose::Meta::TypeCoercion;
  21
  22 use Moose::Object;
  23 use Moose::Util::TypeConstraints;
  24
  25 sub import {
  26         shift;
  27         my $pkg = caller();
  28
  29         # we should never export to main
  30         return if $pkg eq 'main';
  31
  32         Moose::Util::TypeConstraints->import($pkg);
  33
  34         # make a subtype for each Moose class
  35     subtype $pkg
  36         => as Object
  37         => where { $_->isa($pkg) };
  38
  39         my $meta;
  40         if ($pkg->can('meta')) {
  41                 $meta = $pkg->meta();
  42                 (blessed($meta) && $meta->isa('Class::MOP::Class'))
  43                         || confess "Whoops, not møøsey enough";
  44         }
  45         else {
  46                 $meta = Moose::Meta::Class->initialize($pkg => (
  47                         ':attribute_metaclass' => 'Moose::Meta::Attribute'
  48                 ));
  49                 $meta->add_method('meta' => sub {
  50                         # re-initialize so it inherits properly
  51                         Moose::Meta::Class->initialize($pkg => (
  52                                 ':attribute_metaclass' => 'Moose::Meta::Attribute'
  53                         ));
  54                 })
  55         }
  56
  57         # NOTE:
  58         # &alias_method will install the method, but it
  59         # will not name it with
  60
  61         # handle superclasses
  62         $meta->alias_method('extends' => subname 'Moose::extends' => sub {
  63             foreach my $super (@_) {
  64                 # see if this is already
  65                 # loaded in the symbol table
  66             next if _is_class_already_loaded($super);
  67             # otherwise require it ...
  68             ($super->require)
  69                     || confess "Could not load superclass '$super' because : " . $UNIVERSAL::require::ERROR;
  70             }
  71             $meta->superclasses(@_)
  72         });
  73
  74         # handle attributes
  75         $meta->alias_method('has' => subname 'Moose::has' => sub {
  76                 my ($name, %options) = @_;
  77                 if (exists $options{is}) {
  78                         if ($options{is} eq 'ro') {
  79                                 $options{reader} = $name;
  80                         }
  81                         elsif ($options{is} eq 'rw') {
  82                                 $options{accessor} = $name;
  83                         }
  84                 }
  85                 if (exists $options{isa}) {
  86                     # allow for anon-subtypes here ...
  87                     if (blessed($options{isa}) && $options{isa}->isa('Moose::Meta::TypeConstraint')) {
  88                                 $options{type_constraint} = $options{isa};
  89                         }
  90                         else {
  91                             # otherwise assume it is a constraint
  92                             my $constraint = find_type_constraint($options{isa});
  93                             # if the constraing it not found ....
  94                             unless (defined $constraint) {
  95                                 # assume it is a foreign class, and make
  96                                 # an anon constraint for it
  97                                 $constraint = subtype Object => where { $_->isa($options{isa}) };
  98                             }
  99                 $options{type_constraint} = $constraint;
 100                         }
 101                 }
 102                 $meta->add_attribute($name, %options)
 103         });
 104
 105         # handle method modifers
 106         $meta->alias_method('before' => subname 'Moose::before' => sub {
 107                 my $code = pop @_;
 108                 $meta->add_before_method_modifier($_, $code) for @_;
 109         });
 110         $meta->alias_method('after'  => subname 'Moose::after' => sub {
 111                 my $code = pop @_;
 112                 $meta->add_after_method_modifier($_, $code) for @_;
 113         });
 114         $meta->alias_method('around' => subname 'Moose::around' => sub {
 115                 my $code = pop @_;
 116                 $meta->add_around_method_modifier($_, $code) for @_;
 117         });
 118
 119         # make sure they inherit from Moose::Object
 120         $meta->superclasses('Moose::Object')
 121        unless $meta->superclasses();
 122
 123         # we recommend using these things
 124         # so export them for them
 125         $meta->alias_method('confess' => \&Carp::confess);
 126         $meta->alias_method('blessed' => \&Scalar::Util::blessed);
 127 }
 128
 129 sub _is_class_already_loaded {
 130         my $name = shift;
 131         no strict 'refs';
 132         return 1 if defined ${"${name}::VERSION"} || defined @{"${name}::ISA"};
 133         foreach (keys %{"${name}::"}) {
 134                 next if substr($_, -2, 2) eq '::';
 135                 return 1 if defined &{"${name}::$_"};
 136         }
 137     return 0;
 138 }
 139
 140 1;
 141
 142 __END__
 143
 144 =pod
 145
 146 =head1 NAME
 147
 148 Moose - Moose, it's the new Camel
 149
 150 =head1 SYNOPSIS
 151
 152   package Point;
 153   use Moose;
 154
 155   has 'x' => (isa => 'Int', is => 'rw');
 156   has 'y' => (isa => 'Int', is => 'rw');
 157
 158   sub clear {
 159       my $self = shift;
 160       $self->x(0);
 161       $self->y(0);
 162   }
 163
 164   package Point3D;
 165   use Moose;
 166
 167   extends 'Point';
 168
 169   has 'z' => (isa => 'Int');
 170
 171   after 'clear' => sub {
 172       my $self = shift;
 173       $self->{z} = 0;
 174   };
 175
 176 =head1 CAVEAT
 177
 178 This is a B<very> early release of this module, it still needs
 179 some fine tuning and B<lots> more documentation. I am adopting
 180 the I<release early and release often> approach with this module,
 181 so keep an eye on your favorite CPAN mirror!
 182
 183 =head1 DESCRIPTION
 184
 185 Moose is an extension of the Perl 5 object system.
 186
 187 =head2 Another object system!?!?
 188
 189 Yes, I know there has been an explosion recently of new ways to
 190 build object's in Perl 5, most of them based on inside-out objects,
 191 and other such things. Moose is different because it is not a new
 192 object system for Perl 5, but instead an extension of the existing
 193 object system.
 194
 195 Moose is built on top of L<Class::MOP>, which is a metaclass system
 196 for Perl 5. This means that Moose not only makes building normal
 197 Perl 5 objects better, but it also provides the power of metaclass
 198 programming.
 199
 200 =head2 What does Moose stand for??
 201
 202 Moose doesn't stand for one thing in particular, however, if you
 203 want, here are a few of my favorites, feel free to contribute
 204 more :)
 205
 206 =over 4
 207
 208 =item Make Other Object Systems Envious
 209
 210 =item Makes Object Orientation So Easy
 211
 212 =item Makes Object Orientation Spiffy- Er  (sorry ingy)
 213
 214 =item Most Other Object Systems Emasculate
 215
 216 =item My Overcraft Overfilled (with) Some Eels
 217
 218 =item Moose Often Ovulate Sorta Early
 219
 220 =item Many Overloaded Object Systems Exists
 221
 222 =item Moose Offers Often Super Extensions
 223
 224 =back
 225
 226 =head1 BUILDING CLASSES WITH MOOSE
 227
 228 Moose makes every attempt to provide as much convience during class
 229 construction/definition, but still stay out of your way if you want
 230 it to. Here are some of the features Moose provides:
 231
 232 Unless specified with C<extends>, any class which uses Moose will
 233 inherit from L<Moose::Object>.
 234
 235 Moose will also manage all attributes (including inherited ones) that
 236 are defined with C<has>. And assuming that you call C<new> which is
 237 inherited from L<Moose::Object>, then this includes properly initializing
 238 all instance slots, setting defaults where approprtiate and performing any
 239 type constraint checking or coercion.
 240
 241 =head1 EXPORTED FUNCTIONS
 242
 243 Moose will export a number of functions into the class's namespace, which
 244 can then be used to set up the class. These functions all work directly
 245 on the current class.
 246
 247 =over 4
 248
 249 =item B<meta>
 250
 251 This is a method which provides access to the current class's metaclass.
 252
 253 =item B<extends (@superclasses)>
 254
 255 This function will set the superclass(es) for the current class.
 256
 257 This approach is recommended instead of C<use base>, because C<use base>
 258 actually C<push>es onto the class's C<@ISA>, whereas C<extends> will
 259 replace it. This is important to ensure that classes which do not have
 260 superclasses properly inherit from L<Moose::Object>.
 261
 262 =item B<has ($name, %options)>
 263
 264 This will install an attribute of a given C<$name> into the current class.
 265 The list of C<%options> are the same as those provided by both
 266 L<Class::MOP::Attribute> and L<Moose::Meta::Attribute>, in addition to a
 267 few convience ones provided by Moose which are listed below:
 268
 269 =over 4
 270
 271 =item I<is =E<gt> 'rw'|'ro'>
 272
 273 The I<is> option accepts either I<rw> (for read/write) or I<ro> (for read
 274 only). These will create either a read/write accessor or a read-only
 275 accessor respectively, using the same name as the C<$name> of the attribute.
 276
 277 If you need more control over how your accessors are named, you can use the
 278 I<reader>, I<writer> and I<accessor> options inherited from L<Moose::Meta::Attribute>.
 279
 280 =item I<isa =E<gt> $type_name>
 281
 282 The I<isa> option uses Moose's type constraint facilities to set up runtime
 283 type checking for this attribute. Moose will perform the checks during class
 284 construction, and within any accessors. The C<$type_name> argument must be a
 285 string. The string can be either a class name, or a type defined using
 286 Moose's type defintion features.
 287
 288 =back
 289
 290 =item B<before $name|@names =E<gt> sub { ... }>
 291
 292 =item B<after $name|@names =E<gt> sub { ... }>
 293
 294 =item B<around $name|@names =E<gt> sub { ... }>
 295
 296 This three items are syntactic sugar for the before, after and around method
 297 modifier features that L<Class::MOP> provides. More information on these can
 298 be found in the L<Class::MOP> documentation for now.
 299
 300 =item B<confess>
 301
 302 This is the C<Carp::confess> function, and exported here beause I use it
 303 all the time. This feature may change in the future, so you have been warned.
 304
 305 =item B<blessed>
 306
 307 This is the C<Scalar::Uti::blessed> function, it is exported here beause I
 308 use it all the time. It is highly recommended that this is used instead of
 309 C<ref> anywhere you need to test for an object's class name.
 310
 311 =back
 312
 313 =head1 ACKNOWLEDGEMENTS
 314
 315 =over 4
 316
 317 =item I blame Sam Vilain for introducing me to the insanity that is meta-models.
 318
 319 =item I blame Audrey Tang for then encouraging my meta-model habit in #perl6.
 320
 321 =item Without Yuval "nothingmuch" Kogman this module would not be possible,
 322 and it certainly wouldn't have this name ;P
 323
 324 =item The basis of the TypeContraints module was Rob Kinyon's idea
 325 originally, I just ran with it.
 326
 327 =item Thanks to mst & chansen and the whole #moose poose for all the
 328 ideas/feature-requests/encouragement
 329
 330 =back
 331
 332 =head1 SEE ALSO
 333
 334 =over 4
 335
 336 =item L<Class::MOP> documentation
 337
 338 =item The #moose channel on irc.perl.org
 339
 340 =item L<http://forum2.org/moose/>
 341
 342 =back
 343
 344 =head1 BUGS
 345
 346 All complex software has bugs lurking in it, and this module is no
 347 exception. If you find a bug please either email me, or add the bug
 348 to cpan-RT.
 349
 350 =head1 AUTHOR
 351
 352 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 353
 354 =head1 COPYRIGHT AND LICENSE
 355
 356 Copyright 2006 by Infinity Interactive, Inc.
 357
 358 L<http://www.iinteractive.com>
 359
 360 This library is free software; you can redistribute it and/or modify
 361 it under the same terms as Perl itself.
 362
 363 =cut