lib/Moose.pm

   1
   2 package Moose;
   3
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION = '0.05';
   8
   9 use Scalar::Util 'blessed', 'reftype';
  10 use Carp         'confess';
  11 use Sub::Name    'subname';
  12
  13 use UNIVERSAL::require;
  14 use Sub::Exporter;
  15
  16 use Class::MOP;
  17
  18 use Moose::Meta::Class;
  19 use Moose::Meta::TypeConstraint;
  20 use Moose::Meta::TypeCoercion;
  21 use Moose::Meta::Attribute;
  22 use Moose::Meta::Instance;
  23
  24 use Moose::Object;
  25 use Moose::Util::TypeConstraints;
  26
  27 {
  28     my ( $CALLER, %METAS );
  29
  30     sub _find_meta {
  31         my $class = $CALLER;
  32
  33         return $METAS{$class} if exists $METAS{$class};
  34
  35         # make a subtype for each Moose class
  36         subtype $class
  37             => as 'Object'
  38             => where { $_->isa($class) }
  39         unless find_type_constraint($class);
  40
  41         my $meta;
  42         if ($class->can('meta')) {
  43             $meta = $class->meta();
  44             (blessed($meta) && $meta->isa('Moose::Meta::Class'))
  45                 || confess "Whoops, not møøsey enough";
  46         }
  47         else {
  48             $meta = Moose::Meta::Class->initialize($class);
  49             $meta->add_method('meta' => sub {
  50                 # re-initialize so it inherits properly
  51                 Moose::Meta::Class->initialize(blessed($_[0]) || $_[0]);
  52             })
  53         }
  54
  55         # make sure they inherit from Moose::Object
  56         $meta->superclasses('Moose::Object')
  57            unless $meta->superclasses();
  58
  59         return $METAS{$class} = $meta;
  60     }
  61
  62     my %exports = (
  63         extends => sub {
  64             my $meta = _find_meta();
  65             return subname 'Moose::extends' => sub {
  66                 _load_all_classes(@_);
  67                 $meta->superclasses(@_)
  68             };
  69         },
  70         with => sub {
  71             my $meta = _find_meta();
  72             return subname 'Moose::with' => sub {
  73                 my ($role) = @_;
  74                 _load_all_classes($role);
  75                 $role->meta->apply($meta);
  76             };
  77         },
  78         has => sub {
  79             my $meta = _find_meta();
  80             return subname 'Moose::has' => sub {
  81                 my ($name, %options) = @_;
  82                 if ($name =~ /^\+(.*)/) {
  83                     my $inherited_attr = $meta->find_attribute_by_name($1);
  84                     (defined $inherited_attr)
  85                         || confess "Could not find an attribute by the name of '$1' to inherit from";
  86                     my $new_attr = $inherited_attr->clone_and_inherit_options(%options);
  87                     $meta->add_attribute($new_attr);
  88                 }
  89                 else {
  90                     if ($options{metaclass}) {
  91                         _load_all_classes($options{metaclass});
  92                         $meta->add_attribute($options{metaclass}->new($name, %options));
  93                     }
  94                     else {
  95                         $meta->add_attribute($name, %options);
  96                     }
  97                 }
  98             };
  99         },
 100         before => sub {
 101             my $meta = _find_meta();
 102             return subname 'Moose::before' => sub {
 103                 my $code = pop @_;
 104                 $meta->add_before_method_modifier($_, $code) for @_;
 105             };
 106         },
 107         after => sub {
 108             my $meta = _find_meta();
 109             return subname 'Moose::after' => sub {
 110                 my $code = pop @_;
 111                 $meta->add_after_method_modifier($_, $code) for @_;
 112             };
 113         },
 114         around => sub {
 115             my $meta = _find_meta();
 116             return subname 'Moose::around' => sub {
 117                 my $code = pop @_;
 118                 $meta->add_around_method_modifier($_, $code) for @_;
 119             };
 120         },
 121         super => sub {
 122             my $meta = _find_meta();
 123             return subname 'Moose::super' => sub {};
 124         },
 125         override => sub {
 126             my $meta = _find_meta();
 127             return subname 'Moose::override' => sub {
 128                 my ($name, $method) = @_;
 129                 $meta->add_override_method_modifier($name => $method);
 130             };
 131         },
 132         inner => sub {
 133             my $meta = _find_meta();
 134             return subname 'Moose::inner' => sub {};
 135         },
 136         augment => sub {
 137             my $meta = _find_meta();
 138             return subname 'Moose::augment' => sub {
 139                 my ($name, $method) = @_;
 140                 $meta->add_augment_method_modifier($name => $method);
 141             };
 142         },
 143         confess => sub {
 144             return \&Carp::confess;
 145         },
 146         blessed => sub {
 147             return \&Scalar::Util::blessed;
 148         },
 149         all_methods => sub {
 150             sub () {
 151                 sub {
 152                     my ( $class, $delegate_class ) = @_;
 153                     $delegate_class->compute_all_applicable_methods();
 154                 }
 155             }
 156         }
 157     );
 158
 159     my $exporter = Sub::Exporter::build_exporter({
 160         exports => \%exports,
 161         groups  => {
 162             default => [':all']
 163         }
 164     });
 165
 166     sub import {
 167         $CALLER = caller();
 168
 169         # we should never export to main
 170         return if $CALLER eq 'main';
 171
 172         goto $exporter;
 173     }
 174 }
 175
 176 ## Utility functions
 177
 178 sub _load_all_classes {
 179     foreach my $super (@_) {
 180         # see if this is already
 181         # loaded in the symbol table
 182         next if _is_class_already_loaded($super);
 183         # otherwise require it ...
 184         ($super->require)
 185             || confess "Could not load superclass '$super' because : " . $UNIVERSAL::require::ERROR;
 186     }
 187 }
 188
 189 sub _is_class_already_loaded {
 190         my $name = shift;
 191         no strict 'refs';
 192         return 1 if defined ${"${name}::VERSION"} || defined @{"${name}::ISA"};
 193         foreach (keys %{"${name}::"}) {
 194                 next if substr($_, -2, 2) eq '::';
 195                 return 1 if defined &{"${name}::$_"};
 196         }
 197     return 0;
 198 }
 199
 200 1;
 201
 202 __END__
 203
 204 =pod
 205
 206 =head1 NAME
 207
 208 Moose - Moose, it's the new Camel
 209
 210 =head1 SYNOPSIS
 211
 212   package Point;
 213   use Moose;
 214
 215   has 'x' => (isa => 'Int', is => 'rw');
 216   has 'y' => (isa => 'Int', is => 'rw');
 217
 218   sub clear {
 219       my $self = shift;
 220       $self->x(0);
 221       $self->y(0);
 222   }
 223
 224   package Point3D;
 225   use Moose;
 226
 227   extends 'Point';
 228
 229   has 'z' => (isa => 'Int');
 230
 231   after 'clear' => sub {
 232       my $self = shift;
 233       $self->{z} = 0;
 234   };
 235
 236 =head1 CAVEAT
 237
 238 This is an early release of this module, it still needs
 239 some fine tuning and B<lots> more documentation. I am adopting
 240 the I<release early and release often> approach with this module,
 241 so keep an eye on your favorite CPAN mirror!
 242
 243 =head1 DESCRIPTION
 244
 245 Moose is an extension of the Perl 5 object system.
 246
 247 =head2 Another object system!?!?
 248
 249 Yes, I know there has been an explosion recently of new ways to
 250 build object's in Perl 5, most of them based on inside-out objects,
 251 and other such things. Moose is different because it is not a new
 252 object system for Perl 5, but instead an extension of the existing
 253 object system.
 254
 255 Moose is built on top of L<Class::MOP>, which is a metaclass system
 256 for Perl 5. This means that Moose not only makes building normal
 257 Perl 5 objects better, but it also provides the power of metaclass
 258 programming.
 259
 260 =head2 What does Moose stand for??
 261
 262 Moose doesn't stand for one thing in particular, however, if you
 263 want, here are a few of my favorites, feel free to contribute
 264 more :)
 265
 266 =over 4
 267
 268 =item Make Other Object Systems Envious
 269
 270 =item Makes Object Orientation So Easy
 271
 272 =item Makes Object Orientation Spiffy- Er  (sorry ingy)
 273
 274 =item Most Other Object Systems Emasculate
 275
 276 =item My Overcraft Overfilled (with) Some Eels
 277
 278 =item Moose Often Ovulate Sorta Early
 279
 280 =item Many Overloaded Object Systems Exists
 281
 282 =item Moose Offers Often Super Extensions
 283
 284 =item Meta Object Orientation Syntax Extensions
 285
 286 =back
 287
 288 =head1 BUILDING CLASSES WITH MOOSE
 289
 290 Moose makes every attempt to provide as much convience during class
 291 construction/definition, but still stay out of your way if you want
 292 it to. Here are some of the features Moose provides:
 293
 294 Unless specified with C<extends>, any class which uses Moose will
 295 inherit from L<Moose::Object>.
 296
 297 Moose will also manage all attributes (including inherited ones) that
 298 are defined with C<has>. And assuming that you call C<new> which is
 299 inherited from L<Moose::Object>, then this includes properly initializing
 300 all instance slots, setting defaults where approprtiate and performing any
 301 type constraint checking or coercion.
 302
 303 For more details, see the ever expanding L<Moose::Cookbook>.
 304
 305 =head1 EXPORTED FUNCTIONS
 306
 307 Moose will export a number of functions into the class's namespace, which
 308 can then be used to set up the class. These functions all work directly
 309 on the current class.
 310
 311 =over 4
 312
 313 =item B<meta>
 314
 315 This is a method which provides access to the current class's metaclass.
 316
 317 =item B<extends (@superclasses)>
 318
 319 This function will set the superclass(es) for the current class.
 320
 321 This approach is recommended instead of C<use base>, because C<use base>
 322 actually C<push>es onto the class's C<@ISA>, whereas C<extends> will
 323 replace it. This is important to ensure that classes which do not have
 324 superclasses properly inherit from L<Moose::Object>.
 325
 326 =item B<with ($role)>
 327
 328 This will apply a given C<$role> to the local class. Role support is
 329 currently very experimental, see L<Moose::Role> for more details.
 330
 331 =item B<has ($name, %options)>
 332
 333 This will install an attribute of a given C<$name> into the current class.
 334 The list of C<%options> are the same as those provided by both
 335 L<Class::MOP::Attribute> and L<Moose::Meta::Attribute>, in addition to a
 336 few convience ones provided by Moose which are listed below:
 337
 338 =over 4
 339
 340 =item I<is =E<gt> 'rw'|'ro'>
 341
 342 The I<is> option accepts either I<rw> (for read/write) or I<ro> (for read
 343 only). These will create either a read/write accessor or a read-only
 344 accessor respectively, using the same name as the C<$name> of the attribute.
 345
 346 If you need more control over how your accessors are named, you can use the
 347 I<reader>, I<writer> and I<accessor> options inherited from L<Moose::Meta::Attribute>.
 348
 349 =item I<isa =E<gt> $type_name>
 350
 351 The I<isa> option uses Moose's type constraint facilities to set up runtime
 352 type checking for this attribute. Moose will perform the checks during class
 353 construction, and within any accessors. The C<$type_name> argument must be a
 354 string. The string can be either a class name, or a type defined using
 355 Moose's type defintion features.
 356
 357 =item I<coerce =E<gt> (1|0)>
 358
 359 This will attempt to use coercion with the supplied type constraint to change
 360 the value passed into any accessors of constructors. You B<must> have supplied
 361 a type constraint in order for this to work. See L<Moose::Cookbook::Recipe5>
 362 for an example usage.
 363
 364 =item I<does =E<gt> $role_name>
 365
 366 This will accept the name of a role which the value stored in this attribute
 367 is expected to have consumed.
 368
 369 =item I<required =E<gt> (1|0)>
 370
 371 This marks the attribute as being required. This means a value must be supplied
 372 during class construction, and the attribute can never be set to C<undef> with
 373 an accessor.
 374
 375 =item I<weak_ref =E<gt> (1|0)>
 376
 377 This will tell the class to strore the value of this attribute as a weakened
 378 reference. If an attribute is a weakened reference, it can B<not> also be coerced.
 379
 380 =item I<lazy =E<gt> (1|0)>
 381
 382 This will tell the class to not create this slot until absolutely nessecary.
 383 If an attribute is marked as lazy it B<must> have a default supplied.
 384
 385 =item I<trigger =E<gt> $code>
 386
 387 The trigger option is a CODE reference which will be called after the value of
 388 the attribute is set. The CODE ref will be passed the instance itself, the
 389 updated value and the attribute meta-object (this is for more advanced fiddling
 390 and can typically be ignored in most cases). You can B<not> have a trigger on
 391 a read-only attribute.
 392
 393 =back
 394
 395 =item B<before $name|@names =E<gt> sub { ... }>
 396
 397 =item B<after $name|@names =E<gt> sub { ... }>
 398
 399 =item B<around $name|@names =E<gt> sub { ... }>
 400
 401 This three items are syntactic sugar for the before, after and around method
 402 modifier features that L<Class::MOP> provides. More information on these can
 403 be found in the L<Class::MOP> documentation for now.
 404
 405 =item B<super>
 406
 407 The keyword C<super> is a noop when called outside of an C<override> method. In
 408 the context of an C<override> method, it will call the next most appropriate
 409 superclass method with the same arguments as the original method.
 410
 411 =item B<override ($name, &sub)>
 412
 413 An C<override> method, is a way of explictly saying "I am overriding this
 414 method from my superclass". You can call C<super> within this method, and
 415 it will work as expected. The same thing I<can> be accomplished with a normal
 416 method call and the C<SUPER::> pseudo-package, it is really your choice.
 417
 418 =item B<inner>
 419
 420 The keyword C<inner>, much like C<super>, is a no-op outside of the context of
 421 an C<augment> method. You can think of C<inner> as being the inverse of
 422 C<super>, the details of how C<inner> and C<augment> work is best described in
 423 the L<Moose::Cookbook>.
 424
 425 =item B<augment ($name, &sub)>
 426
 427 An C<augment> method, is a way of explictly saying "I am augmenting this
 428 method from my superclass". Once again, the details of how C<inner> and
 429 C<augment> work is best described in the L<Moose::Cookbook>.
 430
 431 =item B<confess>
 432
 433 This is the C<Carp::confess> function, and exported here beause I use it
 434 all the time. This feature may change in the future, so you have been warned.
 435
 436 =item B<blessed>
 437
 438 This is the C<Scalar::Uti::blessed> function, it is exported here beause I
 439 use it all the time. It is highly recommended that this is used instead of
 440 C<ref> anywhere you need to test for an object's class name.
 441
 442 =back
 443
 444 =head1 CAVEATS
 445
 446 =over 4
 447
 448 =item *
 449
 450 It should be noted that C<super> and C<inner> can B<not> be used in the same
 451 method. However, they can be combined together with the same class hierarchy,
 452 see F<t/014_override_augment_inner_super.t> for an example.
 453
 454 The reason that this is so is because C<super> is only valid within a method
 455 with the C<override> modifier, and C<inner> will never be valid within an
 456 C<override> method. In fact, C<augment> will skip over any C<override> methods
 457 when searching for it's appropriate C<inner>.
 458
 459 This might seem like a restriction, but I am of the opinion that keeping these
 460 two features seperate (but interoperable) actually makes them easy to use since
 461 their behavior is then easier to predict. Time will tell if I am right or not.
 462
 463 =back
 464
 465 =head1 ACKNOWLEDGEMENTS
 466
 467 =over 4
 468
 469 =item I blame Sam Vilain for introducing me to the insanity that is meta-models.
 470
 471 =item I blame Audrey Tang for then encouraging my meta-model habit in #perl6.
 472
 473 =item Without Yuval "nothingmuch" Kogman this module would not be possible,
 474 and it certainly wouldn't have this name ;P
 475
 476 =item The basis of the TypeContraints module was Rob Kinyon's idea
 477 originally, I just ran with it.
 478
 479 =item Thanks to mst & chansen and the whole #moose poose for all the
 480 ideas/feature-requests/encouragement
 481
 482 =back
 483
 484 =head1 SEE ALSO
 485
 486 =over 4
 487
 488 =item L<Class::MOP> documentation
 489
 490 =item The #moose channel on irc.perl.org
 491
 492 =item L<http://forum2.org/moose/>
 493
 494 =item L<http://www.cs.utah.edu/plt/publications/oopsla04-gff.pdf>
 495
 496 This paper (suggested by lbr on #moose) was what lead to the implementation
 497 of the C<super>/C<overrride> and C<inner>/C<augment> features. If you really
 498 want to understand this feature, I suggest you read this.
 499
 500 =back
 501
 502 =head1 BUGS
 503
 504 All complex software has bugs lurking in it, and this module is no
 505 exception. If you find a bug please either email me, or add the bug
 506 to cpan-RT.
 507
 508 =head1 AUTHOR
 509
 510 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 511
 512 =head1 COPYRIGHT AND LICENSE
 513
 514 Copyright 2006 by Infinity Interactive, Inc.
 515
 516 L<http://www.iinteractive.com>
 517
 518 This library is free software; you can redistribute it and/or modify
 519 it under the same terms as Perl itself.
 520
 521 =cut