lib/Moose/Util/TypeConstraints.pm

   1
   2 package Moose::Util::TypeConstraints;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp ();
   8 use List::MoreUtils qw( all );
   9 use Scalar::Util 'blessed';
  10 use Moose::Exporter;
  11
  12 our $VERSION   = '0.71';
  13 $VERSION = eval $VERSION;
  14 our $AUTHORITY = 'cpan:STEVAN';
  15
  16 ## --------------------------------------------------------
  17 # Prototyped subs must be predeclared because we have a
  18 # circular dependency with Moose::Meta::Attribute et. al.
  19 # so in case of us being use'd first the predeclaration
  20 # ensures the prototypes are in scope when consumers are
  21 # compiled.
  22
  23 # dah sugah!
  24 sub where       (&);
  25 sub via         (&);
  26 sub message     (&);
  27 sub optimize_as (&);
  28
  29 ## private stuff ...
  30 sub _create_type_constraint ($$$;$$);
  31 sub _install_type_coercions ($$);
  32
  33 ## --------------------------------------------------------
  34
  35 use Moose::Meta::TypeConstraint;
  36 use Moose::Meta::TypeConstraint::Union;
  37 use Moose::Meta::TypeConstraint::Parameterized;
  38 use Moose::Meta::TypeConstraint::Parameterizable;
  39 use Moose::Meta::TypeConstraint::Class;
  40 use Moose::Meta::TypeConstraint::Role;
  41 use Moose::Meta::TypeConstraint::Enum;
  42 use Moose::Meta::TypeCoercion;
  43 use Moose::Meta::TypeCoercion::Union;
  44 use Moose::Meta::TypeConstraint::Registry;
  45 use Moose::Util::TypeConstraints::OptimizedConstraints;
  46
  47 Moose::Exporter->setup_import_methods(
  48     as_is => [
  49         qw(
  50             type subtype class_type role_type maybe_type
  51             as where message optimize_as
  52             coerce from via
  53             enum
  54             find_type_constraint
  55             register_type_constraint )
  56     ],
  57     _export_to_main => 1,
  58 );
  59
  60 ## --------------------------------------------------------
  61 ## type registry and some useful functions for it
  62 ## --------------------------------------------------------
  63
  64 my $REGISTRY = Moose::Meta::TypeConstraint::Registry->new;
  65
  66 sub get_type_constraint_registry         { $REGISTRY }
  67 sub list_all_type_constraints            { keys %{$REGISTRY->type_constraints} }
  68 sub export_type_constraints_as_functions {
  69     my $pkg = caller();
  70     no strict 'refs';
  71     foreach my $constraint (keys %{$REGISTRY->type_constraints}) {
  72         my $tc = $REGISTRY->get_type_constraint($constraint)->_compiled_type_constraint;
  73         *{"${pkg}::${constraint}"} = sub { $tc->($_[0]) ? 1 : undef }; # the undef is for compat
  74     }
  75 }
  76
  77 sub create_type_constraint_union {
  78     my @type_constraint_names;
  79
  80     if (scalar @_ == 1 && _detect_type_constraint_union($_[0])) {
  81         @type_constraint_names = _parse_type_constraint_union($_[0]);
  82     }
  83     else {
  84         @type_constraint_names = @_;
  85     }
  86
  87     (scalar @type_constraint_names >= 2)
  88         || __PACKAGE__->_throw_error("You must pass in at least 2 type names to make a union");
  89
  90     my @type_constraints = map {
  91         find_or_parse_type_constraint($_) ||
  92          __PACKAGE__->_throw_error("Could not locate type constraint ($_) for the union");
  93     } @type_constraint_names;
  94
  95     return Moose::Meta::TypeConstraint::Union->new(
  96         type_constraints => \@type_constraints
  97     );
  98 }
  99
 100 sub create_parameterized_type_constraint {
 101     my $type_constraint_name = shift;
 102     my ($base_type, $type_parameter) = _parse_parameterized_type_constraint($type_constraint_name);
 103
 104     (defined $base_type && defined $type_parameter)
 105         || __PACKAGE__->_throw_error("Could not parse type name ($type_constraint_name) correctly");
 106
 107     if ($REGISTRY->has_type_constraint($base_type)) {
 108         my $base_type_tc = $REGISTRY->get_type_constraint($base_type);
 109         return _create_parameterized_type_constraint(
 110             $base_type_tc,
 111             $type_parameter
 112         );
 113     } else {
 114         __PACKAGE__->_throw_error("Could not locate the base type ($base_type)");
 115     }
 116 }
 117
 118 sub _create_parameterized_type_constraint {
 119     my ( $base_type_tc, $type_parameter ) = @_;
 120     if ( $base_type_tc->can('parameterize') ) {
 121         return $base_type_tc->parameterize($type_parameter);
 122     } else {
 123         return Moose::Meta::TypeConstraint::Parameterized->new(
 124             name => $base_type_tc->name . '[' . $type_parameter . ']',
 125             parent => $base_type_tc,
 126             type_parameter => find_or_create_isa_type_constraint($type_parameter),
 127         );
 128     }
 129 }
 130
 131 #should we also support optimized checks?
 132 sub create_class_type_constraint {
 133     my ( $class, $options ) = @_;
 134
 135     # too early for this check
 136     #find_type_constraint("ClassName")->check($class)
 137     #    || __PACKAGE__->_throw_error("Can't create a class type constraint because '$class' is not a class name");
 138
 139     my %options = (
 140         class => $class,
 141         name  => $class,
 142         %{ $options || {} },
 143     );
 144
 145     $options{name} ||= "__ANON__";
 146
 147     Moose::Meta::TypeConstraint::Class->new( %options );
 148 }
 149
 150 sub create_role_type_constraint {
 151     my ( $role, $options ) = @_;
 152
 153     # too early for this check
 154     #find_type_constraint("ClassName")->check($class)
 155     #    || __PACKAGE__->_throw_error("Can't create a class type constraint because '$class' is not a class name");
 156
 157     my %options = (
 158         role => $role,
 159         name => $role,
 160         %{ $options || {} },
 161     );
 162
 163     $options{name} ||= "__ANON__";
 164
 165     Moose::Meta::TypeConstraint::Role->new( %options );
 166 }
 167
 168
 169 sub find_or_create_type_constraint {
 170     my ( $type_constraint_name, $options_for_anon_type ) = @_;
 171
 172     if ( my $constraint = find_or_parse_type_constraint($type_constraint_name) ) {
 173         return $constraint;
 174     }
 175     elsif ( defined $options_for_anon_type ) {
 176         # NOTE:
 177         # if there is no $options_for_anon_type
 178         # specified, then we assume they don't
 179         # want to create one, and return nothing.
 180
 181         # otherwise assume that we should create
 182         # an ANON type with the $options_for_anon_type
 183         # options which can be passed in. It should
 184         # be noted that these don't get registered
 185         # so we need to return it.
 186         # - SL
 187         return Moose::Meta::TypeConstraint->new(
 188             name => '__ANON__',
 189             %{$options_for_anon_type}
 190         );
 191     }
 192
 193     return;
 194 }
 195
 196 sub find_or_create_isa_type_constraint {
 197     my $type_constraint_name = shift;
 198     find_or_parse_type_constraint($type_constraint_name) || create_class_type_constraint($type_constraint_name)
 199 }
 200
 201 sub find_or_create_does_type_constraint {
 202     my $type_constraint_name = shift;
 203     find_or_parse_type_constraint($type_constraint_name) || create_role_type_constraint($type_constraint_name)
 204 }
 205
 206 sub find_or_parse_type_constraint {
 207     my $type_constraint_name = normalize_type_constraint_name(shift);
 208     my $constraint;
 209
 210     if ($constraint = find_type_constraint($type_constraint_name)) {
 211         return $constraint;
 212     } elsif (_detect_type_constraint_union($type_constraint_name)) {
 213         $constraint = create_type_constraint_union($type_constraint_name);
 214     } elsif (_detect_parameterized_type_constraint($type_constraint_name)) {
 215         $constraint = create_parameterized_type_constraint($type_constraint_name);
 216     } else {
 217         return;
 218     }
 219
 220     $REGISTRY->add_type_constraint($constraint);
 221     return $constraint;
 222 }
 223
 224 sub normalize_type_constraint_name {
 225     my $type_constraint_name = shift;
 226     $type_constraint_name =~ s/\s//g;
 227     return $type_constraint_name;
 228 }
 229
 230 sub _confess {
 231     my $error = shift;
 232
 233     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 234     Carp::confess($error);
 235 }
 236
 237 ## --------------------------------------------------------
 238 ## exported functions ...
 239 ## --------------------------------------------------------
 240
 241 sub find_type_constraint {
 242     my $type = shift;
 243
 244     if ( blessed $type and $type->isa("Moose::Meta::TypeConstraint") ) {
 245         return $type;
 246     }
 247     else {
 248         return unless $REGISTRY->has_type_constraint($type);
 249         return $REGISTRY->get_type_constraint($type);
 250     }
 251 }
 252
 253 sub register_type_constraint {
 254     my $constraint = shift;
 255     __PACKAGE__->_throw_error("can't register an unnamed type constraint") unless defined $constraint->name;
 256     $REGISTRY->add_type_constraint($constraint);
 257     return $constraint;
 258 }
 259
 260 # type constructors
 261
 262 sub type {
 263     splice(@_, 1, 0, undef);
 264     goto &_create_type_constraint;
 265 }
 266
 267 sub subtype {
 268     # NOTE:
 269     # this adds an undef for the name
 270     # if this is an anon-subtype:
 271     #   subtype(Num => where { $_ % 2 == 0 }) # anon 'even' subtype
 272     #     or
 273     #   subtype(Num => where { $_ % 2 == 0 }) message { "$_ must be an even number" }
 274     #
 275     # but if the last arg is not a code ref then it is a subtype
 276     # alias:
 277     #
 278     #   subtype(MyNumbers => as Num); # now MyNumbers is the same as Num
 279     # ... yeah I know it's ugly code
 280     # - SL
 281     unshift @_ => undef if scalar @_ == 2 && ( 'CODE' eq ref( $_[-1] ) );
 282     unshift @_ => undef
 283         if scalar @_ == 3 && all { ref($_) =~ /^(?:CODE|HASH)$/ } @_[ 1, 2 ];
 284     goto &_create_type_constraint;
 285 }
 286
 287 sub class_type {
 288     register_type_constraint(
 289         create_class_type_constraint(
 290             $_[0],
 291             ( defined($_[1]) ? $_[1] : () ),
 292         )
 293     );
 294 }
 295
 296 sub role_type ($;$) {
 297     register_type_constraint(
 298         create_role_type_constraint(
 299             $_[0],
 300             ( defined($_[1]) ? $_[1] : () ),
 301         )
 302     );
 303 }
 304
 305 sub maybe_type {
 306     my ($type_parameter) = @_;
 307
 308     register_type_constraint(
 309         $REGISTRY->get_type_constraint('Maybe')->parameterize($type_parameter)
 310     );
 311 }
 312
 313 sub coerce {
 314     my ($type_name, @coercion_map) = @_;
 315     _install_type_coercions($type_name, \@coercion_map);
 316 }
 317
 318 sub as          { @_ }
 319 sub from        { @_ }
 320 sub where   (&) { $_[0] }
 321 sub via     (&) { $_[0] }
 322
 323 sub message     (&) { +{ message   => $_[0] } }
 324 sub optimize_as (&) { +{ optimized => $_[0] } }
 325
 326 sub enum {
 327     my ($type_name, @values) = @_;
 328     # NOTE:
 329     # if only an array-ref is passed then
 330     # you get an anon-enum
 331     # - SL
 332     if (ref $type_name eq 'ARRAY' && !@values) {
 333         @values    = @$type_name;
 334         $type_name = undef;
 335     }
 336     (scalar @values >= 2)
 337         || __PACKAGE__->_throw_error("You must have at least two values to enumerate through");
 338     my %valid = map { $_ => 1 } @values;
 339
 340     register_type_constraint(
 341         create_enum_type_constraint(
 342             $type_name,
 343             \@values,
 344         )
 345     );
 346 }
 347
 348 sub create_enum_type_constraint {
 349     my ( $type_name, $values ) = @_;
 350
 351     Moose::Meta::TypeConstraint::Enum->new(
 352         name   => $type_name || '__ANON__',
 353         values => $values,
 354     );
 355 }
 356
 357 ## --------------------------------------------------------
 358 ## desugaring functions ...
 359 ## --------------------------------------------------------
 360
 361 sub _create_type_constraint ($$$;$$) {
 362     my $name   = shift;
 363     my $parent = shift;
 364     my $check  = shift;
 365
 366     my ( $message, $optimized );
 367     for (@_) {
 368         $message   = $_->{message}   if exists $_->{message};
 369         $optimized = $_->{optimized} if exists $_->{optimized};
 370     }
 371
 372     my $pkg_defined_in = scalar( caller(0) );
 373
 374     if ( defined $name ) {
 375         my $type = $REGISTRY->get_type_constraint($name);
 376
 377         ( $type->_package_defined_in eq $pkg_defined_in )
 378             || _confess(
 379                   "The type constraint '$name' has already been created in "
 380                 . $type->_package_defined_in
 381                 . " and cannot be created again in "
 382                 . $pkg_defined_in )
 383             if defined $type;
 384
 385         $name =~ /^[\w:\.]+$/
 386             or die qq{$name contains invalid characters for a type name.}
 387             . qq{ Names can contain alphanumeric character, ":", and "."\n};
 388     }
 389
 390     my %opts = (
 391         name => $name,
 392         package_defined_in => $pkg_defined_in,
 393
 394         ( $check     ? ( constraint => $check )     : () ),
 395         ( $message   ? ( message    => $message )   : () ),
 396         ( $optimized ? ( optimized  => $optimized ) : () ),
 397     );
 398
 399     my $constraint;
 400     if ( defined $parent
 401         and $parent
 402         = blessed $parent ? $parent : find_or_create_isa_type_constraint($parent) )
 403     {
 404         $constraint = $parent->create_child_type(%opts);
 405     }
 406     else {
 407         $constraint = Moose::Meta::TypeConstraint->new(%opts);
 408     }
 409
 410     $REGISTRY->add_type_constraint($constraint)
 411         if defined $name;
 412
 413     return $constraint;
 414 }
 415
 416 sub _install_type_coercions ($$) {
 417     my ($type_name, $coercion_map) = @_;
 418     my $type = find_type_constraint($type_name);
 419     (defined $type)
 420         || __PACKAGE__->_throw_error("Cannot find type '$type_name', perhaps you forgot to load it.");
 421     if ($type->has_coercion) {
 422         $type->coercion->add_type_coercions(@$coercion_map);
 423     }
 424     else {
 425         my $type_coercion = Moose::Meta::TypeCoercion->new(
 426             type_coercion_map => $coercion_map,
 427             type_constraint   => $type
 428         );
 429         $type->coercion($type_coercion);
 430     }
 431 }
 432
 433 ## --------------------------------------------------------
 434 ## type notation parsing ...
 435 ## --------------------------------------------------------
 436
 437 {
 438     # All I have to say is mugwump++ cause I know
 439     # do not even have enough regexp-fu to be able
 440     # to have written this (I can only barely
 441     # understand it as it is)
 442     # - SL
 443
 444     use re "eval";
 445
 446     my $valid_chars = qr{[\w:\.]};
 447     my $type_atom   = qr{ $valid_chars+ };
 448
 449     my $any;
 450
 451     my $type                = qr{  $valid_chars+  (?: \[ \s* (??{$any})   \s* \] )? }x;
 452     my $type_capture_parts  = qr{ ($valid_chars+) (?: \[ \s* ((??{$any})) \s* \] )? }x;
 453     my $type_with_parameter = qr{  $valid_chars+      \[ \s* (??{$any})   \s* \]    }x;
 454
 455     my $op_union = qr{ \s* \| \s* }x;
 456     my $union    = qr{ $type (?: $op_union $type )+ }x;
 457
 458     $any = qr{ $type | $union }x;
 459
 460     sub _parse_parameterized_type_constraint {
 461         { no warnings 'void'; $any; } # force capture of interpolated lexical
 462         $_[0] =~ m{ $type_capture_parts }x;
 463         return ($1, $2);
 464     }
 465
 466     sub _detect_parameterized_type_constraint {
 467         { no warnings 'void'; $any; } # force capture of interpolated lexical
 468         $_[0] =~ m{ ^ $type_with_parameter $ }x;
 469     }
 470
 471     sub _parse_type_constraint_union {
 472         { no warnings 'void'; $any; } # force capture of interpolated lexical
 473         my $given = shift;
 474         my @rv;
 475         while ( $given =~ m{ \G (?: $op_union )? ($type) }gcx ) {
 476             push @rv => $1;
 477         }
 478         (pos($given) eq length($given))
 479             || __PACKAGE__->_throw_error("'$given' didn't parse (parse-pos="
 480                      . pos($given)
 481                      . " and str-length="
 482                      . length($given)
 483                      . ")");
 484         @rv;
 485     }
 486
 487     sub _detect_type_constraint_union {
 488         { no warnings 'void'; $any; } # force capture of interpolated lexical
 489         $_[0] =~ m{^ $type $op_union $type ( $op_union .* )? $}x;
 490     }
 491 }
 492
 493 ## --------------------------------------------------------
 494 # define some basic built-in types
 495 ## --------------------------------------------------------
 496
 497 # By making these classes immutable before creating all the types we
 498 # below, we avoid repeatedly calling the slow MOP-based accessors.
 499 $_->make_immutable(
 500     inline_constructor => 1,
 501     constructor_name   => "_new",
 502
 503     # these are Class::MOP accessors, so they need inlining
 504     inline_accessors => 1
 505     ) for grep { $_->is_mutable }
 506     map { $_->meta }
 507     qw(
 508     Moose::Meta::TypeConstraint
 509     Moose::Meta::TypeConstraint::Union
 510     Moose::Meta::TypeConstraint::Parameterized
 511     Moose::Meta::TypeConstraint::Parameterizable
 512     Moose::Meta::TypeConstraint::Class
 513     Moose::Meta::TypeConstraint::Role
 514     Moose::Meta::TypeConstraint::Enum
 515     Moose::Meta::TypeConstraint::Registry
 516 );
 517
 518 type 'Any'  => where { 1 }; # meta-type including all
 519 type 'Item' => where { 1 }; # base-type
 520
 521 subtype 'Undef'   => as 'Item' => where { !defined($_) };
 522 subtype 'Defined' => as 'Item' => where {  defined($_) };
 523
 524 subtype 'Bool'
 525     => as 'Item'
 526     => where { !defined($_) || $_ eq "" || "$_" eq '1' || "$_" eq '0' };
 527
 528 subtype 'Value'
 529     => as 'Defined'
 530     => where { !ref($_) }
 531     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Value;
 532
 533 subtype 'Ref'
 534     => as 'Defined'
 535     => where {  ref($_) }
 536     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Ref;
 537
 538 subtype 'Str'
 539     => as 'Value'
 540     => where { 1 }
 541     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Str;
 542
 543 subtype 'Num'
 544     => as 'Value'
 545     => where { Scalar::Util::looks_like_number($_) }
 546     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Num;
 547
 548 subtype 'Int'
 549     => as 'Num'
 550     => where { "$_" =~ /^-?[0-9]+$/ }
 551     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Int;
 552
 553 subtype 'ScalarRef' => as 'Ref' => where { ref($_) eq 'SCALAR' } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::ScalarRef;
 554 subtype 'CodeRef'   => as 'Ref' => where { ref($_) eq 'CODE'   } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::CodeRef;
 555 subtype 'RegexpRef' => as 'Ref' => where { ref($_) eq 'Regexp' } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::RegexpRef;
 556 subtype 'GlobRef'   => as 'Ref' => where { ref($_) eq 'GLOB'   } => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::GlobRef;
 557
 558 # NOTE:
 559 # scalar filehandles are GLOB refs,
 560 # but a GLOB ref is not always a filehandle
 561 subtype 'FileHandle'
 562     => as 'GlobRef'
 563     => where { Scalar::Util::openhandle($_) || ( blessed($_) && $_->isa("IO::Handle") ) }
 564     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::FileHandle;
 565
 566 # NOTE:
 567 # blessed(qr/.../) returns true,.. how odd
 568 subtype 'Object'
 569     => as 'Ref'
 570     => where { blessed($_) && blessed($_) ne 'Regexp' }
 571     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Object;
 572
 573 subtype 'Role'
 574     => as 'Object'
 575     => where { $_->can('does') }
 576     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::Role;
 577
 578 my $_class_name_checker = sub {};
 579
 580 subtype 'ClassName'
 581     => as 'Str'
 582     => where { Class::MOP::is_class_loaded($_) }
 583     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::ClassName;
 584
 585 subtype 'RoleName'
 586     => as 'ClassName'
 587     => where { (($_->can('meta') || return)->($_) || return)->isa('Moose::Meta::Role') }
 588     => optimize_as \&Moose::Util::TypeConstraints::OptimizedConstraints::RoleName;    ;
 589
 590 ## --------------------------------------------------------
 591 # parameterizable types ...
 592
 593 $REGISTRY->add_type_constraint(
 594     Moose::Meta::TypeConstraint::Parameterizable->new(
 595         name                 => 'ArrayRef',
 596         package_defined_in   => __PACKAGE__,
 597         parent               => find_type_constraint('Ref'),
 598         constraint           => sub { ref($_) eq 'ARRAY'  },
 599         optimized            => \&Moose::Util::TypeConstraints::OptimizedConstraints::ArrayRef,
 600         constraint_generator => sub {
 601             my $type_parameter = shift;
 602             my $check = $type_parameter->_compiled_type_constraint;
 603             return sub {
 604                 foreach my $x (@$_) {
 605                     ($check->($x)) || return
 606                 } 1;
 607             }
 608         }
 609     )
 610 );
 611
 612 $REGISTRY->add_type_constraint(
 613     Moose::Meta::TypeConstraint::Parameterizable->new(
 614         name                 => 'HashRef',
 615         package_defined_in   => __PACKAGE__,
 616         parent               => find_type_constraint('Ref'),
 617         constraint           => sub { ref($_) eq 'HASH'  },
 618         optimized            => \&Moose::Util::TypeConstraints::OptimizedConstraints::HashRef,
 619         constraint_generator => sub {
 620             my $type_parameter = shift;
 621             my $check = $type_parameter->_compiled_type_constraint;
 622             return sub {
 623                 foreach my $x (values %$_) {
 624                     ($check->($x)) || return
 625                 } 1;
 626             }
 627         }
 628     )
 629 );
 630
 631 $REGISTRY->add_type_constraint(
 632     Moose::Meta::TypeConstraint::Parameterizable->new(
 633         name                 => 'Maybe',
 634         package_defined_in   => __PACKAGE__,
 635         parent               => find_type_constraint('Item'),
 636         constraint           => sub { 1 },
 637         constraint_generator => sub {
 638             my $type_parameter = shift;
 639             my $check = $type_parameter->_compiled_type_constraint;
 640             return sub {
 641                 return 1 if not(defined($_)) || $check->($_);
 642                 return;
 643             }
 644         }
 645     )
 646 );
 647
 648 my @PARAMETERIZABLE_TYPES = map {
 649     $REGISTRY->get_type_constraint($_)
 650 } qw[ArrayRef HashRef Maybe];
 651
 652 sub get_all_parameterizable_types { @PARAMETERIZABLE_TYPES }
 653 sub add_parameterizable_type {
 654     my $type = shift;
 655     (blessed $type && $type->isa('Moose::Meta::TypeConstraint::Parameterizable'))
 656         || __PACKAGE__->_throw_error("Type must be a Moose::Meta::TypeConstraint::Parameterizable not $type");
 657     push @PARAMETERIZABLE_TYPES => $type;
 658 }
 659
 660 ## --------------------------------------------------------
 661 # end of built-in types ...
 662 ## --------------------------------------------------------
 663
 664 {
 665     my @BUILTINS = list_all_type_constraints();
 666     sub list_all_builtin_type_constraints { @BUILTINS }
 667 }
 668
 669 sub _throw_error {
 670     shift;
 671     require Moose;
 672     unshift @_, 'Moose';
 673     goto &Moose::throw_error;
 674 }
 675
 676 1;
 677
 678 __END__
 679
 680 =pod
 681
 682 =head1 NAME
 683
 684 Moose::Util::TypeConstraints - Type constraint system for Moose
 685
 686 =head1 SYNOPSIS
 687
 688   use Moose::Util::TypeConstraints;
 689
 690   type 'Num' => where { Scalar::Util::looks_like_number($_) };
 691
 692   subtype 'Natural'
 693       => as 'Int'
 694       => where { $_ > 0 };
 695
 696   subtype 'NaturalLessThanTen'
 697       => as 'Natural'
 698       => where { $_ < 10 }
 699       => message { "This number ($_) is not less than ten!" };
 700
 701   coerce 'Num'
 702       => from 'Str'
 703         => via { 0+$_ };
 704
 705   enum 'RGBColors' => qw(red green blue);
 706
 707 =head1 DESCRIPTION
 708
 709 This module provides Moose with the ability to create custom type
 710 constraints to be used in attribute definition.
 711
 712 =head2 Important Caveat
 713
 714 This is B<NOT> a type system for Perl 5. These are type constraints,
 715 and they are not used by Moose unless you tell it to. No type
 716 inference is performed, expression are not typed, etc. etc. etc.
 717
 718 This is simply a means of creating small constraint functions which
 719 can be used to simplify your own type-checking code, with the added
 720 side benefit of making your intentions clearer through self-documentation.
 721
 722 =head2 Slightly Less Important Caveat
 723
 724 It is B<always> a good idea to quote your type and subtype names.
 725
 726 This is to prevent perl from trying to execute the call as an indirect
 727 object call. This issue only seems to come up when you have a subtype
 728 the same name as a valid class, but when the issue does arise it tends
 729 to be quite annoying to debug.
 730
 731 So for instance, this:
 732
 733   subtype DateTime => as Object => where { $_->isa('DateTime') };
 734
 735 will I<Just Work>, while this:
 736
 737   use DateTime;
 738   subtype DateTime => as Object => where { $_->isa('DateTime') };
 739
 740 will fail silently and cause many headaches. The simple way to solve
 741 this, as well as future proof your subtypes from classes which have
 742 yet to have been created yet, is to simply do this:
 743
 744   use DateTime;
 745   subtype 'DateTime' => as 'Object' => where { $_->isa('DateTime') };
 746
 747 =head2 Default Type Constraints
 748
 749 This module also provides a simple hierarchy for Perl 5 types, here is
 750 that hierarchy represented visually.
 751
 752   Any
 753   Item
 754       Bool
 755       Maybe[`a]
 756       Undef
 757       Defined
 758           Value
 759               Num
 760                 Int
 761               Str
 762                 ClassName
 763                 RoleName
 764           Ref
 765               ScalarRef
 766               ArrayRef[`a]
 767               HashRef[`a]
 768               CodeRef
 769               RegexpRef
 770               GlobRef
 771                 FileHandle
 772               Object
 773                 Role
 774
 775 B<NOTE:> Any type followed by a type parameter C<[`a]> can be
 776 parameterized, this means you can say:
 777
 778   ArrayRef[Int]    # an array of integers
 779   HashRef[CodeRef] # a hash of str to CODE ref mappings
 780   Maybe[Str]       # value may be a string, may be undefined
 781
 782 If Moose finds a name in brackets that it does not recognize as an
 783 existing type, it assumes that this is a class name, for example
 784 C<ArrayRef[DateTime]>.
 785
 786 B<NOTE:> Unless you parameterize a type, then it is invalid to
 787 include the square brackets. I.e. C<ArrayRef[]> will be
 788 literally interpreted as a type name.
 789
 790 B<NOTE:> The C<Undef> type constraint for the most part works
 791 correctly now, but edge cases may still exist, please use it
 792 sparingly.
 793
 794 B<NOTE:> The C<ClassName> type constraint does a complex package
 795 existence check. This means that your class B<must> be loaded for
 796 this type constraint to pass. I know this is not ideal for all,
 797 but it is a saner restriction than most others.
 798
 799 B<NOTE:> The C<RoleName> constraint checks a string is I<package name>
 800 which is a role, like C<'MyApp::Role::Comparable'>. The C<Role>
 801 constraint checks that an I<object> does the named role.
 802
 803 =head2 Type Constraint Naming
 804
 805 Type name declared via this module can only contain alphanumeric
 806 characters, colons (:), and periods (.).
 807
 808 Since the types created by this module are global, it is suggested
 809 that you namespace your types just as you would namespace your
 810 modules. So instead of creating a I<Color> type for your B<My::Graphics>
 811 module, you would call the type I<My.Graphics.Color> instead.
 812
 813 =head2 Use with Other Constraint Modules
 814
 815 This module should play fairly nicely with other constraint
 816 modules with only some slight tweaking. The C<where> clause
 817 in types is expected to be a C<CODE> reference which checks
 818 it's first argument and returns a boolean. Since most constraint
 819 modules work in a similar way, it should be simple to adapt
 820 them to work with Moose.
 821
 822 For instance, this is how you could use it with
 823 L<Declare::Constraints::Simple> to declare a completely new type.
 824
 825   type 'HashOfArrayOfObjects'
 826       => IsHashRef(
 827           -keys   => HasLength,
 828           -values => IsArrayRef( IsObject ));
 829
 830 For more examples see the F<t/200_examples/204_example_w_DCS.t>
 831 test file.
 832
 833 Here is an example of using L<Test::Deep> and it's non-test
 834 related C<eq_deeply> function.
 835
 836   type 'ArrayOfHashOfBarsAndRandomNumbers'
 837       => where {
 838           eq_deeply($_,
 839               array_each(subhashof({
 840                   bar           => isa('Bar'),
 841                   random_number => ignore()
 842               })))
 843         };
 844
 845 For a complete example see the
 846 F<t/200_examples/205_example_w_TestDeep.t> test file.
 847
 848 =head1 FUNCTIONS
 849
 850 =head2 Type Constraint Constructors
 851
 852 The following functions are used to create type constraints.
 853 They will then register the type constraints in a global store
 854 where Moose can get to them if it needs to.
 855
 856 See the L<SYNOPSIS> for an example of how to use these.
 857
 858 =over 4
 859
 860 =item B<type ($name, $where_clause)>
 861
 862 This creates a base type, which has no parent.
 863
 864 =item B<subtype ($name, $parent, $where_clause, ?$message)>
 865
 866 This creates a named subtype.
 867
 868 If you provide a parent that Moose does not recognize, it will
 869 automatically create a new class type constraint for this name.
 870
 871 =item B<subtype ($parent, $where_clause, ?$message)>
 872
 873 This creates an unnamed subtype and will return the type
 874 constraint meta-object, which will be an instance of
 875 L<Moose::Meta::TypeConstraint>.
 876
 877 =item B<class_type ($class, ?$options)>
 878
 879 Creates a new subtype of C<Object> with the name C<$class> and the
 880 metaclass L<Moose::Meta::TypeConstraint::Class>.
 881
 882 =item B<role_type ($role, ?$options)>
 883
 884 Creates a C<Role> type constraint with the name C<$role> and the
 885 metaclass L<Moose::Meta::TypeConstraint::Role>.
 886
 887 =item B<maybe_type ($type)>
 888
 889 Creates a type constraint for either C<undef> or something of the
 890 given type.
 891
 892 =item B<enum ($name, @values)>
 893
 894 This will create a basic subtype for a given set of strings.
 895 The resulting constraint will be a subtype of C<Str> and
 896 will match any of the items in C<@values>. It is case sensitive.
 897 See the L<SYNOPSIS> for a simple example.
 898
 899 B<NOTE:> This is not a true proper enum type, it is simply
 900 a convenient constraint builder.
 901
 902 =item B<enum (\@values)>
 903
 904 If passed an ARRAY reference instead of the C<$name>, C<@values> pair,
 905 this will create an unnamed enum. This can then be used in an attribute
 906 definition like so:
 907
 908   has 'sort_order' => (
 909       is  => 'ro',
 910       isa => enum([qw[ ascending descending ]]),
 911   );
 912
 913 =item B<as>
 914
 915 This is just sugar for the type constraint construction syntax.
 916
 917 =item B<where>
 918
 919 This is just sugar for the type constraint construction syntax.
 920
 921 Takes a block/code ref as an argument. When the type constraint is
 922 tested, the supplied code is run with the value to be tested in
 923 $_. This block should return true or false to indicate whether or not
 924 the constraint check passed.
 925
 926 =item B<message>
 927
 928 This is just sugar for the type constraint construction syntax.
 929
 930 Takes a block/code ref as an argument. When the type constraint fails,
 931 then the code block is run (with the value provided in $_). This code
 932 ref should return a string, which will be used in the text of the
 933 exception thrown.
 934
 935 =item B<optimize_as>
 936
 937 This can be used to define a "hand optimized" version of your
 938 type constraint which can be used to avoid traversing a subtype
 939 constraint hierarchy.
 940
 941 B<NOTE:> You should only use this if you know what you are doing,
 942 all the built in types use this, so your subtypes (assuming they
 943 are shallow) will not likely need to use this.
 944
 945 =back
 946
 947 =head2 Type Coercion Constructors
 948
 949 Type constraints can also contain type coercions as well. If you
 950 ask your accessor to coerce, then Moose will run the type-coercion
 951 code first, followed by the type constraint check. This feature
 952 should be used carefully as it is very powerful and could easily
 953 take off a limb if you are not careful.
 954
 955 See the L<SYNOPSIS> for an example of how to use these.
 956
 957 =over 4
 958
 959 =item B<coerce>
 960
 961 =item B<from>
 962
 963 This is just sugar for the type coercion construction syntax.
 964
 965 =item B<via>
 966
 967 This is just sugar for the type coercion construction syntax.
 968
 969 =back
 970
 971 =head2 Type Constraint Construction & Locating
 972
 973 =over 4
 974
 975 =item B<normalize_type_constraint_name ($type_constraint_name)>
 976
 977 Given a string that is expected to match a type constraint, will normalize the
 978 string so that extra whitespace and newlines are removed.
 979
 980 =item B<create_type_constraint_union ($pipe_separated_types | @type_constraint_names)>
 981
 982 Given string with C<$pipe_separated_types> or a list of C<@type_constraint_names>,
 983 this will return a L<Moose::Meta::TypeConstraint::Union> instance.
 984
 985 =item B<create_parameterized_type_constraint ($type_name)>
 986
 987 Given a C<$type_name> in the form of:
 988
 989   BaseType[ContainerType]
 990
 991 this will extract the base type and container type and build an instance of
 992 L<Moose::Meta::TypeConstraint::Parameterized> for it.
 993
 994 =item B<create_class_type_constraint ($class, ?$options)>
 995
 996 Given a class name it will create a new L<Moose::Meta::TypeConstraint::Class>
 997 object for that class name.
 998
 999 =item B<create_role_type_constraint ($role, ?$options)>
1000
1001 Given a role name it will create a new L<Moose::Meta::TypeConstraint::Role>
1002 object for that role name.
1003
1004 =item B<create_enum_type_constraint ($name, $values)>
1005
1006 =item B<find_or_parse_type_constraint ($type_name)>
1007
1008 This will attempt to find or create a type constraint given the a C<$type_name>.
1009 If it cannot find it in the registry, it will see if it should be a union or
1010 container type an create one if appropriate
1011
1012 =item B<find_or_create_type_constraint ($type_name, ?$options_for_anon_type)>
1013
1014 This function will first call C<find_or_parse_type_constraint> with the type name.
1015
1016 If no type is found or created, but C<$options_for_anon_type> are provided, it
1017 will create the corresponding type.
1018
1019 This was used by the C<does> and C<isa> parameters to L<Moose::Meta::Attribute>
1020 and are now superseded by C<find_or_create_isa_type_constraint> and
1021 C<find_or_create_does_type_constraint>.
1022
1023 =item B<find_or_create_isa_type_constraint ($type_name)>
1024
1025 =item B<find_or_create_does_type_constraint ($type_name)>
1026
1027 Attempts to parse the type name using C<find_or_parse_type_constraint> and if
1028 no appropriate constraint is found will create a new anonymous one.
1029
1030 The C<isa> variant will use C<create_class_type_constraint> and the C<does>
1031 variant will use C<create_role_type_constraint>.
1032
1033 =item B<find_type_constraint ($type_name)>
1034
1035 This function can be used to locate a specific type constraint
1036 meta-object, of the class L<Moose::Meta::TypeConstraint> or a
1037 derivative. What you do with it from there is up to you :)
1038
1039 =item B<register_type_constraint ($type_object)>
1040
1041 This function will register a named type constraint with the type registry.
1042
1043 =item B<get_type_constraint_registry>
1044
1045 Fetch the L<Moose::Meta::TypeConstraint::Registry> object which
1046 keeps track of all type constraints.
1047
1048 =item B<list_all_type_constraints>
1049
1050 This will return a list of type constraint names, you can then
1051 fetch them using C<find_type_constraint ($type_name)> if you
1052 want to.
1053
1054 =item B<list_all_builtin_type_constraints>
1055
1056 This will return a list of builtin type constraints, meaning,
1057 those which are defined in this module. See the section
1058 labeled L<Default Type Constraints> for a complete list.
1059
1060 =item B<export_type_constraints_as_functions>
1061
1062 This will export all the current type constraints as functions
1063 into the caller's namespace. Right now, this is mostly used for
1064 testing, but it might prove useful to others.
1065
1066 =item B<get_all_parameterizable_types>
1067
1068 This returns all the parameterizable types that have been registered.
1069
1070 =item B<add_parameterizable_type ($type)>
1071
1072 Adds C<$type> to the list of parameterizable types
1073
1074 =back
1075
1076 =head2 Namespace Management
1077
1078 =over 4
1079
1080 =item B<unimport>
1081
1082 This will remove all the type constraint keywords from the
1083 calling class namespace.
1084
1085 =back
1086
1087 =head1 BUGS
1088
1089 All complex software has bugs lurking in it, and this module is no
1090 exception. If you find a bug please either email me, or add the bug
1091 to cpan-RT.
1092
1093 =head1 AUTHOR
1094
1095 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1096
1097 =head1 COPYRIGHT AND LICENSE
1098
1099 Copyright 2006-2009 by Infinity Interactive, Inc.
1100
1101 L<http://www.iinteractive.com>
1102
1103 This library is free software; you can redistribute it and/or modify
1104 it under the same terms as Perl itself.
1105
1106 =cut