lib/Moose/Util/TypeConstraints/OptimizedConstraints.pm

   1 package Moose::Util::TypeConstraints::OptimizedConstraints;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Class::MOP;
   7 use Moose::Deprecated;
   8 use Scalar::Util 'blessed', 'looks_like_number';
   9
  10 our $AUTHORITY = 'cpan:STEVAN';
  11
  12 sub Value { defined($_[0]) && !ref($_[0]) }
  13
  14 sub Ref { ref($_[0]) }
  15
  16 # We need to use a temporary here to flatten LVALUEs, for instance as in
  17 # Str(substr($_,0,255)).
  18 sub Str {
  19     my $value = $_[0];
  20     defined($value) && ref(\$value) eq 'SCALAR'
  21 }
  22
  23 sub Num { !ref($_[0]) && looks_like_number($_[0]) }
  24
  25 # using a temporary here because regex matching promotes an IV to a PV,
  26 # and that confuses some things (like JSON.pm)
  27 sub Int {
  28     my $value = $_[0];
  29     defined($value) && !ref($value) && $value =~ /^-?[0-9]+$/
  30 }
  31
  32 sub ScalarRef { ref($_[0]) eq 'SCALAR' || ref($_[0]) eq 'REF' }
  33 sub ArrayRef  { ref($_[0]) eq 'ARRAY'  }
  34 sub HashRef   { ref($_[0]) eq 'HASH'   }
  35 sub CodeRef   { ref($_[0]) eq 'CODE'   }
  36 sub RegexpRef { ref($_[0]) eq 'Regexp' }
  37 sub GlobRef   { ref($_[0]) eq 'GLOB'   }
  38
  39 sub FileHandle { ref($_[0]) eq 'GLOB' && Scalar::Util::openhandle($_[0]) or blessed($_[0]) && $_[0]->isa("IO::Handle") }
  40
  41 sub Object { blessed($_[0]) && blessed($_[0]) ne 'Regexp' }
  42
  43 sub Role {
  44     Moose::Deprecated::deprecated(
  45         feature => 'Role type',
  46         message =>
  47             'The Role type has been deprecated. Maybe you meant to create a RoleName type?'
  48     );
  49     blessed( $_[0] ) && $_[0]->can('does');
  50 }
  51
  52 sub ClassName {
  53     return Class::MOP::is_class_loaded( $_[0] );
  54 }
  55
  56 sub RoleName {
  57     ClassName($_[0])
  58     && (Class::MOP::class_of($_[0]) || return)->isa('Moose::Meta::Role')
  59 }
  60
  61 # NOTE:
  62 # we have XS versions too, ...
  63 # 04:09 <@konobi> nothingmuch: konobi.co.uk/code/utilsxs.tar.gz
  64 # 04:09 <@konobi> or utilxs.tar.gz iirc
  65
  66 1;
  67
  68 __END__
  69
  70 =pod
  71
  72 =head1 NAME
  73
  74 Moose::Util::TypeConstraints::OptimizedConstraints - Optimized constraint
  75 bodies for various moose types
  76
  77 =head1 DESCRIPTION
  78
  79 This file contains the hand optimized versions of Moose type constraints,
  80 no user serviceable parts inside.
  81
  82 =head1 FUNCTIONS
  83
  84 =over 4
  85
  86 =item C<Value>
  87
  88 =item C<Ref>
  89
  90 =item C<Str>
  91
  92 =item C<Num>
  93
  94 =item C<Int>
  95
  96 =item C<ScalarRef>
  97
  98 =item C<ArrayRef>
  99
 100 =item C<HashRef>
 101
 102 =item C<CodeRef>
 103
 104 =item C<RegexpRef>
 105
 106 =item C<GlobRef>
 107
 108 =item C<FileHandle>
 109
 110 =item C<Object>
 111
 112 =item C<Role>
 113
 114 =item C<ClassName>
 115
 116 =item C<RoleName>
 117
 118 =back
 119
 120 =head1 BUGS
 121
 122 See L<Moose/BUGS> for details on reporting bugs.
 123
 124 =cut