lib/Moose/Object.pm

   1
   2 package Moose::Object;
   3
   4 use strict;
   5 use warnings;
   6
   7 use if ( not our $__mx_is_compiled ), 'Moose::Meta::Class';
   8 use if ( not our $__mx_is_compiled ), metaclass => 'Moose::Meta::Class';
   9
  10 our $VERSION   = '0.72';
  11 $VERSION = eval $VERSION;
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 sub new {
  15     my $class = shift;
  16     my $params = $class->BUILDARGS(@_);
  17     my $self = $class->meta->new_object($params);
  18     $self->BUILDALL($params);
  19     return $self;
  20 }
  21
  22 sub BUILDARGS {
  23     my $class = shift;
  24     if ( scalar @_ == 1 ) {
  25         unless ( defined $_[0] && ref $_[0] eq 'HASH' ) {
  26             $class->meta->throw_error(
  27                 "Single parameters to new() must be a HASH ref",
  28                 data => $_[0] );
  29         }
  30         return { %{ $_[0] } };
  31     }
  32     else {
  33         return {@_};
  34     }
  35 }
  36
  37 sub BUILDALL {
  38     # NOTE: we ask Perl if we even
  39     # need to do this first, to avoid
  40     # extra meta level calls
  41     return unless $_[0]->can('BUILD');
  42     my ($self, $params) = @_;
  43     foreach my $method (reverse $self->meta->find_all_methods_by_name('BUILD')) {
  44         $method->{code}->execute($self, $params);
  45     }
  46 }
  47
  48 sub DEMOLISHALL {
  49     my $self = shift;
  50     # NOTE: we ask Perl if we even
  51     # need to do this first, to avoid
  52     # extra meta level calls
  53     return unless $self->can('DEMOLISH');
  54     foreach my $method ($self->meta->find_all_methods_by_name('DEMOLISH')) {
  55         $method->{code}->execute($self);
  56     }
  57 }
  58
  59 sub DESTROY {
  60     # if we have an exception here ...
  61     if ($@) {
  62         # localize the $@ ...
  63         local $@;
  64         # run DEMOLISHALL ourselves, ...
  65         $_[0]->DEMOLISHALL;
  66         # and return ...
  67         return;
  68     }
  69     # otherwise it is normal destruction
  70     $_[0]->DEMOLISHALL;
  71 }
  72
  73 # support for UNIVERSAL::DOES ...
  74 BEGIN {
  75     my $does = UNIVERSAL->can("DOES") ? "SUPER::DOES" : "isa";
  76     eval 'sub DOES {
  77         my ( $self, $class_or_role_name ) = @_;
  78         return $self->'.$does.'($class_or_role_name)
  79             || $self->does($class_or_role_name);
  80     }';
  81 }
  82
  83 # new does() methods will be created
  84 # as appropiate see Moose::Meta::Role
  85 sub does {
  86     my ($self, $role_name) = @_;
  87     my $meta = $self->meta;
  88     (defined $role_name)
  89         || $meta->throw_error("You much supply a role name to does()");
  90     foreach my $class ($meta->class_precedence_list) {
  91         my $m = $meta->initialize($class);
  92         return 1
  93             if $m->can('does_role') && $m->does_role($role_name);
  94     }
  95     return 0;
  96 }
  97
  98 sub dump {
  99     my $self = shift;
 100     require Data::Dumper;
 101     local $Data::Dumper::Maxdepth = shift if @_;
 102     Data::Dumper::Dumper $self;
 103 }
 104
 105 1;
 106
 107 __END__
 108
 109 =pod
 110
 111 =head1 NAME
 112
 113 Moose::Object - The base object for Moose
 114
 115 =head1 DESCRIPTION
 116
 117 This serves as the base object for all Moose classes. Every
 118 effort will be made to ensure that all classes which C<use Moose>
 119 will inherit from this class. It provides a default constructor
 120 and destructor, which run all the BUILD and DEMOLISH methods in
 121 the class tree.
 122
 123 You don't actually I<need> to inherit from this in order to
 124 use Moose though. It is just here to make life easier.
 125
 126 =head1 METHODS
 127
 128 =over 4
 129
 130 =item B<meta>
 131
 132 This will return the metaclass associated with the given class.
 133
 134 =item B<new>
 135
 136 This will call C<BUILDARGS>, create a new instance and call C<BUILDALL>.
 137
 138 =item B<BUILDARGS>
 139
 140 This method processes an argument list into a hash reference. It is used by
 141 C<new>.
 142
 143 =item B<BUILDALL>
 144
 145 This will call every C<BUILD> method in the inheritance hierarchy,
 146 and pass it a hash-ref of the the C<%params> passed to C<new>.
 147
 148 =item B<DEMOLISHALL>
 149
 150 This will call every C<DEMOLISH> method in the inheritance hierarchy.
 151
 152 =item B<does ($role_name)>
 153
 154 This will check if the invocant's class C<does> a given C<$role_name>.
 155 This is similar to C<isa> for object, but it checks the roles instead.
 156
 157 =item B<DOES ($class_or_role_name)>
 158
 159 A Moose Role aware implementation of L<UNIVERSAL/DOES>.
 160
 161 C<DOES> is equivalent to C<isa> or C<does>.
 162
 163 =item B<dump ($maxdepth)>
 164
 165 C'mon, how many times have you written the following code while debugging:
 166
 167  use Data::Dumper;
 168  warn Dumper $obj;
 169
 170 It can get seriously annoying, so why not just use this.
 171
 172 =back
 173
 174 =head1 BUGS
 175
 176 All complex software has bugs lurking in it, and this module is no
 177 exception. If you find a bug please either email me, or add the bug
 178 to cpan-RT.
 179
 180 =head1 AUTHOR
 181
 182 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 183
 184 =head1 COPYRIGHT AND LICENSE
 185
 186 Copyright 2006-2009 by Infinity Interactive, Inc.
 187
 188 L<http://www.iinteractive.com>
 189
 190 This library is free software; you can redistribute it and/or modify
 191 it under the same terms as Perl itself.
 192
 193 =cut