lib/Moose/Object.pm

   1
   2 package Moose::Object;
   3
   4 use strict;
   5 use warnings;
   6
   7 use if ( not our $__mx_is_compiled ), 'Moose::Meta::Class';
   8 use if ( not our $__mx_is_compiled ), metaclass => 'Moose::Meta::Class';
   9
  10 use Carp 'confess';
  11
  12 our $VERSION   = '0.12';
  13 our $AUTHORITY = 'cpan:STEVAN';
  14
  15 sub new {
  16     my $class = shift;
  17     my %params;
  18     if (scalar @_ == 1) {
  19         if (defined $_[0]) {
  20             (ref($_[0]) eq 'HASH')
  21                 || confess "Single parameters to new() must be a HASH ref";
  22             %params = %{$_[0]};
  23         }
  24     }
  25     else {
  26         %params = @_;
  27     }
  28     my $self = $class->meta->new_object(%params);
  29     $self->BUILDALL(\%params);
  30     return $self;
  31 }
  32
  33 sub BUILDALL {
  34     # NOTE: we ask Perl if we even
  35     # need to do this first, to avoid
  36     # extra meta level calls
  37     return unless $_[0]->can('BUILD');
  38     my ($self, $params) = @_;
  39     foreach my $method (reverse $self->meta->find_all_methods_by_name('BUILD')) {
  40         $method->{code}->($self, $params);
  41     }
  42 }
  43
  44 sub DEMOLISHALL {
  45     # NOTE: we ask Perl if we even
  46     # need to do this first, to avoid
  47     # extra meta level calls
  48     return unless $_[0]->can('DEMOLISH');
  49     my $self = shift;
  50     {
  51         local $@;
  52         foreach my $method ($self->meta->find_all_methods_by_name('DEMOLISH')) {
  53             $method->{code}->($self);
  54         }
  55     }
  56 }
  57
  58 sub DESTROY { goto &DEMOLISHALL }
  59
  60 # new does() methods will be created
  61 # as approiate see Moose::Meta::Role
  62 sub does {
  63     my ($self, $role_name) = @_;
  64     (defined $role_name)
  65         || confess "You much supply a role name to does()";
  66     my $meta = $self->meta;
  67     foreach my $class ($meta->class_precedence_list) {
  68         my $m = $meta->initialize($class);
  69         return 1
  70             if $m->can('does_role') && $m->does_role($role_name);
  71     }
  72     return 0;
  73 }
  74
  75 # RANT:
  76 # Cmon, how many times have you written
  77 # the following code while debugging:
  78 #
  79 #  use Data::Dumper;
  80 #  warn Dumper \%thing;
  81 #
  82 # It can get seriously annoying, so why
  83 # not just do this ...
  84 sub dump {
  85     my $self = shift;
  86     require Data::Dumper;
  87     local $Data::Dumper::Maxdepth = shift if @_;
  88     Data::Dumper::Dumper $self;
  89 }
  90
  91 1;
  92
  93 __END__
  94
  95 =pod
  96
  97 =head1 NAME
  98
  99 Moose::Object - The base object for Moose
 100
 101 =head1 DESCRIPTION
 102
 103 This serves as the base object for all Moose classes. Every
 104 effort will be made to ensure that all classes which C<use Moose>
 105 will inherit from this class. It provides a default constructor
 106 and destructor, which run all the BUILD and DEMOLISH methods in
 107 the class tree.
 108
 109 You don't actually I<need> to inherit from this in order to
 110 use Moose though. It is just here to make life easier.
 111
 112 =head1 METHODS
 113
 114 =over 4
 115
 116 =item B<meta>
 117
 118 This will return the metaclass associated with the given class.
 119
 120 =item B<new>
 121
 122 This will create a new instance and call C<BUILDALL>.
 123
 124 =item B<BUILDALL>
 125
 126 This will call every C<BUILD> method in the inheritance hierarchy,
 127 and pass it a hash-ref of the the C<%params> passed to C<new>.
 128
 129 =item B<DEMOLISHALL>
 130
 131 This will call every C<DEMOLISH> method in the inheritance hierarchy.
 132
 133 =item B<does ($role_name)>
 134
 135 This will check if the invocant's class C<does> a given C<$role_name>.
 136 This is similar to C<isa> for object, but it checks the roles instead.
 137
 138 =item B<dump ($maxdepth)>
 139
 140 Cmon, how many times have you written the following code while debugging:
 141
 142  use Data::Dumper;
 143  warn Dumper $obj;
 144
 145 It can get seriously annoying, so why not just use this.
 146
 147 =back
 148
 149 =head1 BUGS
 150
 151 All complex software has bugs lurking in it, and this module is no
 152 exception. If you find a bug please either email me, or add the bug
 153 to cpan-RT.
 154
 155 =head1 AUTHOR
 156
 157 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 158
 159 =head1 COPYRIGHT AND LICENSE
 160
 161 Copyright 2006-2008 by Infinity Interactive, Inc.
 162
 163 L<http://www.iinteractive.com>
 164
 165 This library is free software; you can redistribute it and/or modify
 166 it under the same terms as Perl itself.
 167
 168 =cut