lib/Moose/Meta/TypeConstraint.pm

   1
   2 package Moose::Meta::TypeConstraint;
   3
   4 use strict;
   5 use warnings;
   6 use metaclass;
   7
   8 use overload '""'     => sub { shift->name },   # stringify to tc name
   9              fallback => 1;
  10
  11 use Carp         'confess';
  12 use Scalar::Util qw(blessed refaddr);
  13
  14 use base qw(Class::MOP::Object);
  15
  16 our $VERSION   = '0.56';
  17 our $AUTHORITY = 'cpan:STEVAN';
  18
  19 __PACKAGE__->meta->add_attribute('name'       => (reader => 'name'));
  20 __PACKAGE__->meta->add_attribute('parent'     => (
  21     reader    => 'parent',
  22     predicate => 'has_parent',
  23 ));
  24
  25 my $null_constraint = sub { 1 };
  26 __PACKAGE__->meta->add_attribute('constraint' => (
  27     reader  => 'constraint',
  28     writer  => '_set_constraint',
  29     default => sub { $null_constraint }
  30 ));
  31 __PACKAGE__->meta->add_attribute('message'   => (
  32     accessor  => 'message',
  33     predicate => 'has_message'
  34 ));
  35 __PACKAGE__->meta->add_attribute('coercion'   => (
  36     accessor  => 'coercion',
  37     predicate => 'has_coercion'
  38 ));
  39 __PACKAGE__->meta->add_attribute('hand_optimized_type_constraint' => (
  40     init_arg  => 'optimized',
  41     accessor  => 'hand_optimized_type_constraint',
  42     predicate => 'has_hand_optimized_type_constraint',
  43 ));
  44
  45 sub parents {
  46     my $self;
  47     $self->parent;
  48 }
  49
  50 # private accessors
  51
  52 __PACKAGE__->meta->add_attribute('compiled_type_constraint' => (
  53     accessor  => '_compiled_type_constraint',
  54     predicate => '_has_compiled_type_constraint'
  55 ));
  56 __PACKAGE__->meta->add_attribute('package_defined_in' => (
  57     accessor => '_package_defined_in'
  58 ));
  59
  60 sub new {
  61     my $class = shift;
  62     my $self  = $class->_new(@_);
  63     $self->compile_type_constraint()
  64         unless $self->_has_compiled_type_constraint;
  65     return $self;
  66 }
  67
  68 sub coerce   { ((shift)->coercion || confess "Cannot coerce without a type coercion")->coerce(@_) }
  69 sub check    { $_[0]->_compiled_type_constraint->($_[1]) ? 1 : undef }
  70 sub validate {
  71     my ($self, $value) = @_;
  72     if ($self->_compiled_type_constraint->($value)) {
  73         return undef;
  74     }
  75     else {
  76         $self->get_message($value);
  77     }
  78 }
  79
  80 sub get_message {
  81     my ($self, $value) = @_;
  82     if (my $msg = $self->message) {
  83         local $_ = $value;
  84         return $msg->($value);
  85     }
  86     else {
  87         $value = (defined $value ? overload::StrVal($value) : 'undef');
  88         return "Validation failed for '" . $self->name . "' failed with value $value";
  89     }
  90 }
  91
  92 ## type predicates ...
  93
  94 sub equals {
  95     my ( $self, $type_or_name ) = @_;
  96
  97     my $other = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  98
  99     return 1 if refaddr($self) == refaddr($other);
 100
 101     if ( $self->has_hand_optimized_type_constraint and $other->has_hand_optimized_type_constraint ) {
 102         return 1 if $self->hand_optimized_type_constraint == $other->hand_optimized_type_constraint;
 103     }
 104
 105     return unless $self->constraint == $other->constraint;
 106
 107     if ( $self->has_parent ) {
 108         return unless $other->has_parent;
 109         return unless $self->parent->equals( $other->parent );
 110     } else {
 111         return if $other->has_parent;
 112     }
 113
 114     return 1;
 115 }
 116
 117 sub is_a_type_of {
 118     my ($self, $type_or_name) = @_;
 119
 120     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
 121
 122     ($self->equals($type) || $self->is_subtype_of($type));
 123 }
 124
 125 sub is_subtype_of {
 126     my ($self, $type_or_name) = @_;
 127
 128     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
 129
 130     my $current = $self;
 131
 132     while (my $parent = $current->parent) {
 133         return 1 if $parent->equals($type);
 134         $current = $parent;
 135     }
 136
 137     return 0;
 138 }
 139
 140 ## compiling the type constraint
 141
 142 sub compile_type_constraint {
 143     my $self = shift;
 144     $self->_compiled_type_constraint($self->_actually_compile_type_constraint);
 145 }
 146
 147 ## type compilers ...
 148
 149 sub _actually_compile_type_constraint {
 150     my $self = shift;
 151
 152     return $self->_compile_hand_optimized_type_constraint
 153         if $self->has_hand_optimized_type_constraint;
 154
 155     my $check = $self->constraint;
 156     (defined $check)
 157         || confess "Could not compile type constraint '"
 158                 . $self->name
 159                 . "' because no constraint check";
 160
 161     return $self->_compile_subtype($check)
 162         if $self->has_parent;
 163
 164     return $self->_compile_type($check);
 165 }
 166
 167 sub _compile_hand_optimized_type_constraint {
 168     my $self = shift;
 169
 170     my $type_constraint = $self->hand_optimized_type_constraint;
 171
 172     confess unless ref $type_constraint;
 173
 174     return $type_constraint;
 175 }
 176
 177 sub _compile_subtype {
 178     my ($self, $check) = @_;
 179
 180     # gather all the parent constraintss in order
 181     my @parents;
 182     my $optimized_parent;
 183     foreach my $parent ($self->_collect_all_parents) {
 184         # if a parent is optimized, the optimized constraint already includes
 185         # all of its parents tcs, so we can break the loop
 186         if ($parent->has_hand_optimized_type_constraint) {
 187             push @parents => $optimized_parent = $parent->hand_optimized_type_constraint;
 188             last;
 189         }
 190         else {
 191             push @parents => $parent->constraint;
 192         }
 193     }
 194
 195     @parents = grep { $_ != $null_constraint } reverse @parents;
 196
 197     unless ( @parents ) {
 198         return $self->_compile_type($check);
 199     } elsif( $optimized_parent and @parents == 1 ) {
 200         # the case of just one optimized parent is optimized to prevent
 201         # looping and the unnecessary localization
 202         if ( $check == $null_constraint ) {
 203             return $optimized_parent;
 204         } else {
 205             return Class::MOP::subname($self->name, sub {
 206                 return undef unless $optimized_parent->($_[0]);
 207                 local $_ = $_[0];
 208                 $check->($_[0]);
 209             });
 210         }
 211     } else {
 212         # general case, check all the constraints, from the first parent to ourselves
 213         my @checks = @parents;
 214         push @checks, $check if $check != $null_constraint;
 215         return Class::MOP::subname($self->name => sub {
 216             local $_ = $_[0];
 217             foreach my $check (@checks) {
 218                 return undef unless $check->($_[0]);
 219             }
 220             return 1;
 221         });
 222     }
 223 }
 224
 225 sub _compile_type {
 226     my ($self, $check) = @_;
 227
 228     return $check if $check == $null_constraint; # Item, Any
 229
 230     return Class::MOP::subname($self->name => sub {
 231         local $_ = $_[0];
 232         $check->($_[0]);
 233     });
 234 }
 235
 236 ## other utils ...
 237
 238 sub _collect_all_parents {
 239     my $self = shift;
 240     my @parents;
 241     my $current = $self->parent;
 242     while (defined $current) {
 243         push @parents => $current;
 244         $current = $current->parent;
 245     }
 246     return @parents;
 247 }
 248
 249 ## this should get deprecated actually ...
 250
 251 sub union { Carp::croak "DEPRECATED" }
 252
 253 1;
 254
 255 __END__
 256
 257 =pod
 258
 259 =head1 NAME
 260
 261 Moose::Meta::TypeConstraint - The Moose Type Constraint metaclass
 262
 263 =head1 DESCRIPTION
 264
 265 For the most part, the only time you will ever encounter an
 266 instance of this class is if you are doing some serious deep
 267 introspection. This API should not be considered final, but
 268 it is B<highly unlikely> that this will matter to a regular
 269 Moose user.
 270
 271 If you wish to use features at this depth, please come to the
 272 #moose IRC channel on irc.perl.org and we can talk :)
 273
 274 =head1 METHODS
 275
 276 =over 4
 277
 278 =item B<meta>
 279
 280 =item B<new>
 281
 282 =item B<equals ($type_name_or_object)>
 283
 284 =item B<is_a_type_of ($type_name_or_object)>
 285
 286 This checks the current type name, and if it does not match,
 287 checks if it is a subtype of it.
 288
 289 =item B<is_subtype_of ($type_name_or_object)>
 290
 291 =item B<compile_type_constraint>
 292
 293 =item B<coerce ($value)>
 294
 295 This will apply the type-coercion if applicable.
 296
 297 =item B<check ($value)>
 298
 299 This method will return a true (C<1>) if the C<$value> passes the
 300 constraint, and false (C<0>) otherwise.
 301
 302 =item B<validate ($value)>
 303
 304 This method is similar to C<check>, but it deals with the error
 305 message. If the C<$value> passes the constraint, C<undef> will be
 306 returned. If the C<$value> does B<not> pass the constraint, then
 307 the C<message> will be used to construct a custom error message.
 308
 309 =item B<name>
 310
 311 =item B<parent>
 312
 313 =item B<has_parent>
 314
 315 =item B<parents>
 316
 317 =item B<constraint>
 318
 319 =item B<has_message>
 320
 321 =item B<message>
 322
 323 =item B<get_message ($value)>
 324
 325 =item B<has_coercion>
 326
 327 =item B<coercion>
 328
 329 =item B<hand_optimized_type_constraint>
 330
 331 =item B<has_hand_optimized_type_constraint>
 332
 333 =back
 334
 335 =head2 DEPRECATED METHOD
 336
 337 =over 4
 338
 339 =item B<union>
 340
 341 This was just bad idea on my part,.. use the L<Moose::Meta::TypeConstraint::Union>
 342 itself instead.
 343
 344 =back
 345
 346 =head1 BUGS
 347
 348 All complex software has bugs lurking in it, and this module is no
 349 exception. If you find a bug please either email me, or add the bug
 350 to cpan-RT.
 351
 352 =head1 AUTHOR
 353
 354 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 355
 356 =head1 COPYRIGHT AND LICENSE
 357
 358 Copyright 2006-2008 by Infinity Interactive, Inc.
 359
 360 L<http://www.iinteractive.com>
 361
 362 This library is free software; you can redistribute it and/or modify
 363 it under the same terms as Perl itself.
 364
 365 =cut