lib/Moose/Meta/TypeConstraint/Class.pm

   1 package Moose::Meta::TypeConstraint::Class;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 use B;
   8 use Scalar::Util 'blessed';
   9 use Moose::Util::TypeConstraints ();
  10
  11 use base 'Moose::Meta::TypeConstraint';
  12
  13 __PACKAGE__->meta->add_attribute('class' => (
  14     reader => 'class',
  15 ));
  16
  17 my $inliner = sub {
  18     my $self = shift;
  19     my $val  = shift;
  20
  21     return 'Scalar::Util::blessed(' . $val . ')'
  22              . ' && ' . $val . '->isa(' . B::perlstring($self->class) . ')';
  23 };
  24
  25 sub new {
  26     my ( $class, %args ) = @_;
  27
  28     $args{parent}
  29         = Moose::Util::TypeConstraints::find_type_constraint('Object');
  30
  31     my $class_name = $args{class};
  32     $args{constraint} = sub { $_[0]->isa($class_name) };
  33
  34     $args{inlined} = $inliner;
  35
  36     my $self = $class->_new( \%args );
  37
  38     $self->compile_type_constraint();
  39
  40     return $self;
  41 }
  42
  43 sub parents {
  44     my $self = shift;
  45     return (
  46         $self->parent,
  47         map {
  48             # FIXME find_type_constraint might find a TC named after the class but that isn't really it
  49             # I did this anyway since it's a convention that preceded TypeConstraint::Class, and it should DWIM
  50             # if anybody thinks this problematic please discuss on IRC.
  51             # a possible fix is to add by attr indexing to the type registry to find types of a certain property
  52             # regardless of their name
  53             Moose::Util::TypeConstraints::find_type_constraint($_)
  54                 ||
  55             __PACKAGE__->new( class => $_, name => "__ANON__" )
  56         } Class::MOP::class_of($self->class)->superclasses,
  57     );
  58 }
  59
  60 sub equals {
  61     my ( $self, $type_or_name ) = @_;
  62
  63     my $other = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  64
  65     return unless defined $other;
  66     return unless $other->isa(__PACKAGE__);
  67
  68     return $self->class eq $other->class;
  69 }
  70
  71 sub is_a_type_of {
  72     my ($self, $type_or_name) = @_;
  73
  74     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  75
  76     ($self->equals($type) || $self->is_subtype_of($type_or_name));
  77 }
  78
  79 sub is_subtype_of {
  80     my ($self, $type_or_name_or_class ) = @_;
  81
  82     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name_or_class);
  83
  84     if ( not defined $type ) {
  85         if ( not ref $type_or_name_or_class ) {
  86             # it might be a class
  87             return 1 if $self->class->isa( $type_or_name_or_class );
  88         }
  89         return;
  90     }
  91
  92     if ( $type->isa(__PACKAGE__) && $type->class ne $self->class) {
  93         # if $type_or_name_or_class isn't a class, it might be the TC name of another ::Class type
  94         # or it could also just be a type object in this branch
  95         return $self->class->isa( $type->class );
  96     } else {
  97         # the only other thing we are a subtype of is Object
  98         $self->SUPER::is_subtype_of($type);
  99     }
 100 }
 101
 102 # This is a bit counter-intuitive, but a child type of a Class type
 103 # constraint is not itself a Class type constraint (it has no class
 104 # attribute). This whole create_child_type thing needs some changing
 105 # though, probably making MMC->new a factory or something.
 106 sub create_child_type {
 107     my ($self, @args) = @_;
 108     return Moose::Meta::TypeConstraint->new(@args, parent => $self);
 109 }
 110
 111 sub get_message {
 112     my $self = shift;
 113     my ($value) = @_;
 114
 115     if ($self->has_message) {
 116         return $self->SUPER::get_message(@_);
 117     }
 118
 119     $value = (defined $value ? overload::StrVal($value) : 'undef');
 120     return "Validation failed for '" . $self->name . "' with value $value (not isa " . $self->class . ")";
 121 }
 122
 123 1;
 124
 125 # ABSTRACT: Class/TypeConstraint parallel hierarchy
 126
 127 __END__
 128
 129 =pod
 130
 131 =head1 DESCRIPTION
 132
 133 This class represents type constraints for a class.
 134
 135 =head1 INHERITANCE
 136
 137 C<Moose::Meta::TypeConstraint::Class> is a subclass of
 138 L<Moose::Meta::TypeConstraint>.
 139
 140 =head1 METHODS
 141
 142 =over 4
 143
 144 =item B<< Moose::Meta::TypeConstraint::Class->new(%options) >>
 145
 146 This creates a new class type constraint based on the given
 147 C<%options>.
 148
 149 It takes the same options as its parent, with two exceptions. First,
 150 it requires an additional option, C<class>, which is name of the
 151 constraint's class.  Second, it automatically sets the parent to the
 152 C<Object> type.
 153
 154 The constructor also overrides the hand optimized type constraint with
 155 one it creates internally.
 156
 157 =item B<< $constraint->class >>
 158
 159 Returns the class name associated with the constraint.
 160
 161 =item B<< $constraint->parents >>
 162
 163 Returns all the type's parent types, corresponding to its parent
 164 classes.
 165
 166 =item B<< $constraint->is_subtype_of($type_name_or_object) >>
 167
 168 If the given type is also a class type, then this checks that the
 169 type's class is a subclass of the other type's class.
 170
 171 Otherwise it falls back to the implementation in
 172 L<Moose::Meta::TypeConstraint>.
 173
 174 =item B<< $constraint->create_child_type(%options) >>
 175
 176 This returns a new L<Moose::Meta::TypeConstraint> object with the type
 177 as its parent.
 178
 179 Note that it does I<not> return a
 180 C<Moose::Meta::TypeConstraint::Class> object!
 181
 182 =item B<< $constraint->get_message($value) >>
 183
 184 This is the same as L<Moose::Meta::TypeConstraint/get_message> except
 185 that it explicitly says C<isa> was checked. This is to help users deal
 186 with accidentally autovivified type constraints.
 187
 188 =back
 189
 190 =head1 BUGS
 191
 192 See L<Moose/BUGS> for details on reporting bugs.
 193
 194 =cut