lib/Moose/Meta/Role.pm

   1
   2 package Moose::Meta::Role;
   3
   4 use strict;
   5 use warnings;
   6 use metaclass;
   7
   8 use Carp         'confess';
   9 use Scalar::Util 'blessed', 'reftype';
  10
  11 our $VERSION   = '0.13';
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 use Moose::Meta::Class;
  15 use Moose::Meta::Role::Method;
  16 use Moose::Meta::Role::Method::Required;
  17
  18 use base 'Class::MOP::Module';
  19
  20 ## ------------------------------------------------------------------
  21 ## NOTE:
  22 ## I normally don't do this, but I am doing
  23 ## a whole bunch of meta-programmin in this
  24 ## module, so it just makes sense. For a clearer
  25 ## picture of what is going on in the next
  26 ## several lines of code, look at the really
  27 ## big comment at the end of this file (right
  28 ## before the POD).
  29 ## - SL
  30 ## ------------------------------------------------------------------
  31
  32 my $META = __PACKAGE__->meta;
  33
  34 ## ------------------------------------------------------------------
  35 ## attributes ...
  36
  37 # NOTE:
  38 # since roles are lazy, we hold all the attributes
  39 # of the individual role in 'statis' until which
  40 # time when it is applied to a class. This means
  41 # keeping a lot of things in hash maps, so we are
  42 # using a little of that meta-programmin' magic
  43 # here an saving lots of extra typin. And since
  44 # many of these attributes above require similar
  45 # functionality to support them, so we again use
  46 # the wonders of meta-programmin' to deliver a
  47 # very compact solution to this normally verbose
  48 # problem.
  49 # - SL
  50
  51 foreach my $action (
  52     {
  53         name        => 'excluded_roles_map',
  54         attr_reader => 'get_excluded_roles_map' ,
  55         methods     => {
  56             add       => 'add_excluded_roles',
  57             get_list  => 'get_excluded_roles_list',
  58             existence => 'excludes_role',
  59         }
  60     },
  61     {
  62         name        => 'required_methods',
  63         attr_reader => 'get_required_methods_map',
  64         methods     => {
  65             add       => 'add_required_methods',
  66             remove    => 'remove_required_methods',
  67             get_list  => 'get_required_method_list',
  68             existence => 'requires_method',
  69         }
  70     },
  71     {
  72         name        => 'attribute_map',
  73         attr_reader => 'get_attribute_map',
  74         methods     => {
  75             get       => 'get_attribute',
  76             get_list  => 'get_attribute_list',
  77             existence => 'has_attribute',
  78             remove    => 'remove_attribute',
  79         }
  80     }
  81 ) {
  82
  83     my $attr_reader = $action->{attr_reader};
  84     my $methods     = $action->{methods};
  85
  86     # create the attribute
  87     $META->add_attribute($action->{name} => (
  88         reader  => $attr_reader,
  89         default => sub { {} }
  90     ));
  91
  92     # create some helper methods
  93     $META->add_method($methods->{add} => sub {
  94         my ($self, @values) = @_;
  95         $self->$attr_reader->{$_} = undef foreach @values;
  96     }) if exists $methods->{add};
  97
  98     $META->add_method($methods->{get_list} => sub {
  99         my ($self) = @_;
 100         keys %{$self->$attr_reader};
 101     }) if exists $methods->{get_list};
 102
 103     $META->add_method($methods->{get} => sub {
 104         my ($self, $name) = @_;
 105         $self->$attr_reader->{$name}
 106     }) if exists $methods->{get};
 107
 108     $META->add_method($methods->{existence} => sub {
 109         my ($self, $name) = @_;
 110         exists $self->$attr_reader->{$name} ? 1 : 0;
 111     }) if exists $methods->{existence};
 112
 113     $META->add_method($methods->{remove} => sub {
 114         my ($self, @values) = @_;
 115         delete $self->$attr_reader->{$_} foreach @values;
 116     }) if exists $methods->{remove};
 117 }
 118
 119 ## some things don't always fit, so they go here ...
 120
 121 sub add_attribute {
 122     my $self = shift;
 123     my $name = shift;
 124     my $attr_desc;
 125     if (scalar @_ == 1 && ref($_[0]) eq 'HASH') {
 126         $attr_desc = $_[0];
 127     }
 128     else {
 129         $attr_desc = { @_ };
 130     }
 131     $self->get_attribute_map->{$name} = $attr_desc;
 132 }
 133
 134 # DEPRECATED
 135 # sub _clean_up_required_methods {
 136 #     my $self = shift;
 137 #     foreach my $method ($self->get_required_method_list) {
 138 #         $self->remove_required_methods($method)
 139 #             if $self->has_method($method);
 140 #     }
 141 # }
 142
 143 ## ------------------------------------------------------------------
 144 ## method modifiers
 145
 146 # NOTE:
 147 # the before/around/after method modifiers are
 148 # stored by name, but there can be many methods
 149 # then associated with that name. So again we have
 150 # lots of similar functionality, so we can do some
 151 # meta-programmin' and save some time.
 152 # - SL
 153
 154 foreach my $modifier_type (qw[ before around after ]) {
 155
 156     my $attr_reader = "get_${modifier_type}_method_modifiers_map";
 157
 158     # create the attribute ...
 159     $META->add_attribute("${modifier_type}_method_modifiers" => (
 160         reader  => $attr_reader,
 161         default => sub { {} }
 162     ));
 163
 164     # and some helper methods ...
 165     $META->add_method("get_${modifier_type}_method_modifiers" => sub {
 166         my ($self, $method_name) = @_;
 167         #return () unless exists $self->$attr_reader->{$method_name};
 168         @{$self->$attr_reader->{$method_name}};
 169     });
 170
 171     $META->add_method("has_${modifier_type}_method_modifiers" => sub {
 172         my ($self, $method_name) = @_;
 173         # NOTE:
 174         # for now we assume that if it exists,..
 175         # it has at least one modifier in it
 176         (exists $self->$attr_reader->{$method_name}) ? 1 : 0;
 177     });
 178
 179     $META->add_method("add_${modifier_type}_method_modifier" => sub {
 180         my ($self, $method_name, $method) = @_;
 181
 182         $self->$attr_reader->{$method_name} = []
 183             unless exists $self->$attr_reader->{$method_name};
 184
 185         my $modifiers = $self->$attr_reader->{$method_name};
 186
 187         # NOTE:
 188         # check to see that we aren't adding the
 189         # same code twice. We err in favor of the
 190         # first on here, this may not be as expected
 191         foreach my $modifier (@{$modifiers}) {
 192             return if $modifier == $method;
 193         }
 194
 195         push @{$modifiers} => $method;
 196     });
 197
 198 }
 199
 200 ## ------------------------------------------------------------------
 201 ## override method mofidiers
 202
 203 $META->add_attribute('override_method_modifiers' => (
 204     reader  => 'get_override_method_modifiers_map',
 205     default => sub { {} }
 206 ));
 207
 208 # NOTE:
 209 # these are a little different because there
 210 # can only be one per name, whereas the other
 211 # method modifiers can have multiples.
 212 # - SL
 213
 214 sub add_override_method_modifier {
 215     my ($self, $method_name, $method) = @_;
 216     (!$self->has_method($method_name))
 217         || confess "Cannot add an override of method '$method_name' " .
 218                    "because there is a local version of '$method_name'";
 219     $self->get_override_method_modifiers_map->{$method_name} = $method;
 220 }
 221
 222 sub has_override_method_modifier {
 223     my ($self, $method_name) = @_;
 224     # NOTE:
 225     # for now we assume that if it exists,..
 226     # it has at least one modifier in it
 227     (exists $self->get_override_method_modifiers_map->{$method_name}) ? 1 : 0;
 228 }
 229
 230 sub get_override_method_modifier {
 231     my ($self, $method_name) = @_;
 232     $self->get_override_method_modifiers_map->{$method_name};
 233 }
 234
 235 ## general list accessor ...
 236
 237 sub get_method_modifier_list {
 238     my ($self, $modifier_type) = @_;
 239     my $accessor = "get_${modifier_type}_method_modifiers_map";
 240     keys %{$self->$accessor};
 241 }
 242
 243 ## ------------------------------------------------------------------
 244 ## subroles
 245
 246 __PACKAGE__->meta->add_attribute('roles' => (
 247     reader  => 'get_roles',
 248     default => sub { [] }
 249 ));
 250
 251 sub add_role {
 252     my ($self, $role) = @_;
 253     (blessed($role) && $role->isa('Moose::Meta::Role'))
 254         || confess "Roles must be instances of Moose::Meta::Role";
 255     push @{$self->get_roles} => $role;
 256 }
 257
 258 sub calculate_all_roles {
 259     my $self = shift;
 260     my %seen;
 261     grep {
 262         !$seen{$_->name}++
 263     } ($self, map {
 264                   $_->calculate_all_roles
 265               } @{ $self->get_roles });
 266 }
 267
 268 sub does_role {
 269     my ($self, $role_name) = @_;
 270     (defined $role_name)
 271         || confess "You must supply a role name to look for";
 272     # if we are it,.. then return true
 273     return 1 if $role_name eq $self->name;
 274     # otherwise.. check our children
 275     foreach my $role (@{$self->get_roles}) {
 276         return 1 if $role->does_role($role_name);
 277     }
 278     return 0;
 279 }
 280
 281 ## ------------------------------------------------------------------
 282 ## methods
 283
 284 sub method_metaclass { 'Moose::Meta::Role::Method' }
 285
 286 sub get_method_map {
 287     my $self = shift;
 288     my $map  = {};
 289
 290     my $role_name        = $self->name;
 291     my $method_metaclass = $self->method_metaclass;
 292
 293     foreach my $symbol ($self->list_all_package_symbols('CODE')) {
 294
 295         my $code = $self->get_package_symbol('&' . $symbol);
 296
 297         my ($pkg, $name) = Class::MOP::get_code_info($code);
 298
 299         if ($pkg->can('meta')
 300             # NOTE:
 301             # we don't know what ->meta we are calling
 302             # here, so we need to be careful cause it
 303             # just might blow up at us, or just complain
 304             # loudly (in the case of Curses.pm) so we
 305             # just be a little overly cautious here.
 306             # - SL
 307             && eval { no warnings; blessed($pkg->meta) }
 308             && $pkg->meta->isa('Moose::Meta::Role')) {
 309             my $role = $pkg->meta->name;
 310             next unless $self->does_role($role);
 311         }
 312         else {
 313             # NOTE:
 314             # in 5.10 constant.pm the constants show up
 315             # as being in the right package, but in pre-5.10
 316             # they show up as constant::__ANON__ so we
 317             # make an exception here to be sure that things
 318             # work as expected in both.
 319             # - SL
 320             unless ($pkg eq 'constant' && $name eq '__ANON__') {
 321                 next if ($pkg  || '') ne $role_name ||
 322                         (($name || '') ne '__ANON__' && ($pkg  || '') ne $role_name);
 323             }
 324         }
 325
 326         $map->{$symbol} = $method_metaclass->wrap(
 327             $code,
 328             package_name => $role_name,
 329             name         => $name
 330         );
 331     }
 332
 333     return $map;
 334 }
 335
 336 sub get_method {
 337     my ($self, $name) = @_;
 338     $self->get_method_map->{$name};
 339 }
 340
 341 sub has_method {
 342     my ($self, $name) = @_;
 343     exists $self->get_method_map->{$name} ? 1 : 0
 344 }
 345
 346 sub find_method_by_name { (shift)->get_method(@_) }
 347
 348 sub get_method_list {
 349     my $self = shift;
 350     grep { !/^meta$/ } keys %{$self->get_method_map};
 351 }
 352
 353 sub alias_method {
 354     my ($self, $method_name, $method) = @_;
 355     (defined $method_name && $method_name)
 356         || confess "You must define a method name";
 357
 358     my $body = (blessed($method) ? $method->body : $method);
 359     ('CODE' eq (reftype($body) || ''))
 360         || confess "Your code block must be a CODE reference";
 361
 362     $self->add_package_symbol("&${method_name}" => $body);
 363 }
 364
 365 ## ------------------------------------------------------------------
 366 ## role construction
 367 ## ------------------------------------------------------------------
 368
 369 sub apply {
 370     my ($self, $other, @args) = @_;
 371
 372     (blessed($other))
 373         || confess "You must pass in an blessed instance";
 374
 375     if ($other->isa('Moose::Meta::Role')) {
 376         require Moose::Meta::Role::Application::ToRole;
 377         return Moose::Meta::Role::Application::ToRole->new(@args)->apply($self, $other);
 378     }
 379     elsif ($other->isa('Moose::Meta::Class')) {
 380         require Moose::Meta::Role::Application::ToClass;
 381         return Moose::Meta::Role::Application::ToClass->new(@args)->apply($self, $other);
 382     }
 383     else {
 384         require Moose::Meta::Role::Application::ToInstance;
 385         return Moose::Meta::Role::Application::ToInstance->new(@args)->apply($self, $other);
 386     }
 387 }
 388
 389 sub combine {
 390     my ($class, @role_specs) = @_;
 391
 392     require Moose::Meta::Role::Application::RoleSummation;
 393     require Moose::Meta::Role::Composite;
 394
 395     my (@roles, %role_params);
 396     while (@role_specs) {
 397         my ($role, $params) = @{ splice @role_specs, 0, 1 };
 398         push @roles => $role->meta;
 399         next unless defined $params;
 400         $role_params{$role} = $params;
 401     }
 402
 403     my $c = Moose::Meta::Role::Composite->new(roles => \@roles);
 404     Moose::Meta::Role::Application::RoleSummation->new(
 405         role_params => \%role_params
 406     )->apply($c);
 407
 408     return $c;
 409 }
 410
 411 #####################################################################
 412 ## NOTE:
 413 ## This is Moose::Meta::Role as defined by Moose (plus the use of
 414 ## MooseX::AttributeHelpers module). It is here as a reference to
 415 ## make it easier to see what is happening above with all the meta
 416 ## programming. - SL
 417 #####################################################################
 418 #
 419 # has 'roles' => (
 420 #     metaclass => 'Collection::Array',
 421 #     reader    => 'get_roles',
 422 #     isa       => 'ArrayRef[Moose::Meta::Roles]',
 423 #     default   => sub { [] },
 424 #     provides  => {
 425 #         'push' => 'add_role',
 426 #     }
 427 # );
 428 #
 429 # has 'excluded_roles_map' => (
 430 #     metaclass => 'Collection::Hash',
 431 #     reader    => 'get_excluded_roles_map',
 432 #     isa       => 'HashRef[Str]',
 433 #     provides  => {
 434 #         # Not exactly set, cause it sets multiple
 435 #         'set'    => 'add_excluded_roles',
 436 #         'keys'   => 'get_excluded_roles_list',
 437 #         'exists' => 'excludes_role',
 438 #     }
 439 # );
 440 #
 441 # has 'attribute_map' => (
 442 #     metaclass => 'Collection::Hash',
 443 #     reader    => 'get_attribute_map',
 444 #     isa       => 'HashRef[Str]',
 445 #     provides => {
 446 #         # 'set'  => 'add_attribute' # has some special crap in it
 447 #         'get'    => 'get_attribute',
 448 #         'keys'   => 'get_attribute_list',
 449 #         'exists' => 'has_attribute',
 450 #         # Not exactly delete, cause it sets multiple
 451 #         'delete' => 'remove_attribute',
 452 #     }
 453 # );
 454 #
 455 # has 'required_methods' => (
 456 #     metaclass => 'Collection::Hash',
 457 #     reader    => 'get_required_methods_map',
 458 #     isa       => 'HashRef[Str]',
 459 #     provides  => {
 460 #         # not exactly set, or delete since it works for multiple
 461 #         'set'    => 'add_required_methods',
 462 #         'delete' => 'remove_required_methods',
 463 #         'keys'   => 'get_required_method_list',
 464 #         'exists' => 'requires_method',
 465 #     }
 466 # );
 467 #
 468 # # the before, around and after modifiers are
 469 # # HASH keyed by method-name, with ARRAY of
 470 # # CODE refs to apply in that order
 471 #
 472 # has 'before_method_modifiers' => (
 473 #     metaclass => 'Collection::Hash',
 474 #     reader    => 'get_before_method_modifiers_map',
 475 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 476 #     provides  => {
 477 #         'keys'   => 'get_before_method_modifiers',
 478 #         'exists' => 'has_before_method_modifiers',
 479 #         # This actually makes sure there is an
 480 #         # ARRAY at the given key, and pushed onto
 481 #         # it. It also checks for duplicates as well
 482 #         # 'add'  => 'add_before_method_modifier'
 483 #     }
 484 # );
 485 #
 486 # has 'after_method_modifiers' => (
 487 #     metaclass => 'Collection::Hash',
 488 #     reader    =>'get_after_method_modifiers_map',
 489 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 490 #     provides  => {
 491 #         'keys'   => 'get_after_method_modifiers',
 492 #         'exists' => 'has_after_method_modifiers',
 493 #         # This actually makes sure there is an
 494 #         # ARRAY at the given key, and pushed onto
 495 #         # it. It also checks for duplicates as well
 496 #         # 'add'  => 'add_after_method_modifier'
 497 #     }
 498 # );
 499 #
 500 # has 'around_method_modifiers' => (
 501 #     metaclass => 'Collection::Hash',
 502 #     reader    =>'get_around_method_modifiers_map',
 503 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 504 #     provides  => {
 505 #         'keys'   => 'get_around_method_modifiers',
 506 #         'exists' => 'has_around_method_modifiers',
 507 #         # This actually makes sure there is an
 508 #         # ARRAY at the given key, and pushed onto
 509 #         # it. It also checks for duplicates as well
 510 #         # 'add'  => 'add_around_method_modifier'
 511 #     }
 512 # );
 513 #
 514 # # override is similar to the other modifiers
 515 # # except that it is not an ARRAY of code refs
 516 # # but instead just a single name->code mapping
 517 #
 518 # has 'override_method_modifiers' => (
 519 #     metaclass => 'Collection::Hash',
 520 #     reader    =>'get_override_method_modifiers_map',
 521 #     isa       => 'HashRef[CodeRef]',
 522 #     provides  => {
 523 #         'keys'   => 'get_override_method_modifier',
 524 #         'exists' => 'has_override_method_modifier',
 525 #         'add'    => 'add_override_method_modifier', # checks for local method ..
 526 #     }
 527 # );
 528 #
 529 #####################################################################
 530
 531
 532 1;
 533
 534 __END__
 535
 536 =pod
 537
 538 =head1 NAME
 539
 540 Moose::Meta::Role - The Moose Role metaclass
 541
 542 =head1 DESCRIPTION
 543
 544 Please see L<Moose::Role> for more information about roles.
 545 For the most part, this has no user-serviceable parts inside
 546 this module. It's API is still subject to some change (although
 547 probably not that much really).
 548
 549 =head1 METHODS
 550
 551 =over 4
 552
 553 =item B<meta>
 554
 555 =item B<new>
 556
 557 =item B<apply>
 558
 559 =item B<combine>
 560
 561 =back
 562
 563 =over 4
 564
 565 =item B<name>
 566
 567 =item B<version>
 568
 569 =item B<role_meta>
 570
 571 =back
 572
 573 =over 4
 574
 575 =item B<get_roles>
 576
 577 =item B<add_role>
 578
 579 =item B<does_role>
 580
 581 =back
 582
 583 =over 4
 584
 585 =item B<add_excluded_roles>
 586
 587 =item B<excludes_role>
 588
 589 =item B<get_excluded_roles_list>
 590
 591 =item B<get_excluded_roles_map>
 592
 593 =item B<calculate_all_roles>
 594
 595 =back
 596
 597 =over 4
 598
 599 =item B<method_metaclass>
 600
 601 =item B<find_method_by_name>
 602
 603 =item B<get_method>
 604
 605 =item B<has_method>
 606
 607 =item B<alias_method>
 608
 609 =item B<get_method_list>
 610
 611 =item B<get_method_map>
 612
 613 =item B<update_package_cache_flag>
 614
 615 =item B<reset_package_cache_flag>
 616
 617 =back
 618
 619 =over 4
 620
 621 =item B<add_attribute>
 622
 623 =item B<has_attribute>
 624
 625 =item B<get_attribute>
 626
 627 =item B<get_attribute_list>
 628
 629 =item B<get_attribute_map>
 630
 631 =item B<remove_attribute>
 632
 633 =back
 634
 635 =over 4
 636
 637 =item B<add_required_methods>
 638
 639 =item B<remove_required_methods>
 640
 641 =item B<get_required_method_list>
 642
 643 =item B<get_required_methods_map>
 644
 645 =item B<requires_method>
 646
 647 =back
 648
 649 =over 4
 650
 651 =item B<add_after_method_modifier>
 652
 653 =item B<add_around_method_modifier>
 654
 655 =item B<add_before_method_modifier>
 656
 657 =item B<add_override_method_modifier>
 658
 659 =over 4
 660
 661 =back
 662
 663 =item B<has_after_method_modifiers>
 664
 665 =item B<has_around_method_modifiers>
 666
 667 =item B<has_before_method_modifiers>
 668
 669 =item B<has_override_method_modifier>
 670
 671 =over 4
 672
 673 =back
 674
 675 =item B<get_after_method_modifiers>
 676
 677 =item B<get_around_method_modifiers>
 678
 679 =item B<get_before_method_modifiers>
 680
 681 =item B<get_method_modifier_list>
 682
 683 =over 4
 684
 685 =back
 686
 687 =item B<get_override_method_modifier>
 688
 689 =item B<get_after_method_modifiers_map>
 690
 691 =item B<get_around_method_modifiers_map>
 692
 693 =item B<get_before_method_modifiers_map>
 694
 695 =item B<get_override_method_modifiers_map>
 696
 697 =back
 698
 699 =head1 BUGS
 700
 701 All complex software has bugs lurking in it, and this module is no
 702 exception. If you find a bug please either email me, or add the bug
 703 to cpan-RT.
 704
 705 =head1 AUTHOR
 706
 707 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 708
 709 =head1 COPYRIGHT AND LICENSE
 710
 711 Copyright 2006-2008 by Infinity Interactive, Inc.
 712
 713 L<http://www.iinteractive.com>
 714
 715 This library is free software; you can redistribute it and/or modify
 716 it under the same terms as Perl itself.
 717
 718 =cut