lib/Moose/Meta/Role.pm

   1
   2 package Moose::Meta::Role;
   3
   4 use strict;
   5 use warnings;
   6 use metaclass;
   7
   8 use Scalar::Util 'blessed';
   9 use Carp         'confess';
  10
  11 our $VERSION   = '0.64';
  12 $VERSION = eval $VERSION;
  13 our $AUTHORITY = 'cpan:STEVAN';
  14
  15 use Moose::Meta::Class;
  16 use Moose::Meta::Role::Method;
  17 use Moose::Meta::Role::Method::Required;
  18
  19 use base 'Class::MOP::Module';
  20
  21 ## ------------------------------------------------------------------
  22 ## NOTE:
  23 ## I normally don't do this, but I am doing
  24 ## a whole bunch of meta-programmin in this
  25 ## module, so it just makes sense. For a clearer
  26 ## picture of what is going on in the next
  27 ## several lines of code, look at the really
  28 ## big comment at the end of this file (right
  29 ## before the POD).
  30 ## - SL
  31 ## ------------------------------------------------------------------
  32
  33 my $META = __PACKAGE__->meta;
  34
  35 ## ------------------------------------------------------------------
  36 ## attributes ...
  37
  38 # NOTE:
  39 # since roles are lazy, we hold all the attributes
  40 # of the individual role in 'statis' until which
  41 # time when it is applied to a class. This means
  42 # keeping a lot of things in hash maps, so we are
  43 # using a little of that meta-programmin' magic
  44 # here an saving lots of extra typin. And since
  45 # many of these attributes above require similar
  46 # functionality to support them, so we again use
  47 # the wonders of meta-programmin' to deliver a
  48 # very compact solution to this normally verbose
  49 # problem.
  50 # - SL
  51
  52 foreach my $action (
  53     {
  54         name        => 'excluded_roles_map',
  55         attr_reader => 'get_excluded_roles_map' ,
  56         methods     => {
  57             add       => 'add_excluded_roles',
  58             get_list  => 'get_excluded_roles_list',
  59             existence => 'excludes_role',
  60         }
  61     },
  62     {
  63         name        => 'required_methods',
  64         attr_reader => 'get_required_methods_map',
  65         methods     => {
  66             add       => 'add_required_methods',
  67             remove    => 'remove_required_methods',
  68             get_list  => 'get_required_method_list',
  69             existence => 'requires_method',
  70         }
  71     },
  72     {
  73         name        => 'attribute_map',
  74         attr_reader => 'get_attribute_map',
  75         methods     => {
  76             get       => 'get_attribute',
  77             get_list  => 'get_attribute_list',
  78             existence => 'has_attribute',
  79             remove    => 'remove_attribute',
  80         }
  81     }
  82 ) {
  83
  84     my $attr_reader = $action->{attr_reader};
  85     my $methods     = $action->{methods};
  86
  87     # create the attribute
  88     $META->add_attribute($action->{name} => (
  89         reader  => $attr_reader,
  90         default => sub { {} }
  91     ));
  92
  93     # create some helper methods
  94     $META->add_method($methods->{add} => sub {
  95         my ($self, @values) = @_;
  96         $self->$attr_reader->{$_} = undef foreach @values;
  97     }) if exists $methods->{add};
  98
  99     $META->add_method($methods->{get_list} => sub {
 100         my ($self) = @_;
 101         keys %{$self->$attr_reader};
 102     }) if exists $methods->{get_list};
 103
 104     $META->add_method($methods->{get} => sub {
 105         my ($self, $name) = @_;
 106         $self->$attr_reader->{$name}
 107     }) if exists $methods->{get};
 108
 109     $META->add_method($methods->{existence} => sub {
 110         my ($self, $name) = @_;
 111         exists $self->$attr_reader->{$name} ? 1 : 0;
 112     }) if exists $methods->{existence};
 113
 114     $META->add_method($methods->{remove} => sub {
 115         my ($self, @values) = @_;
 116         delete $self->$attr_reader->{$_} foreach @values;
 117     }) if exists $methods->{remove};
 118 }
 119
 120 ## some things don't always fit, so they go here ...
 121
 122 sub add_attribute {
 123     my $self = shift;
 124     my $name = shift;
 125     (defined $name && $name)
 126         || Moose->throw_error("You must provide a name for the attribute");
 127     my $attr_desc;
 128     if (scalar @_ == 1 && ref($_[0]) eq 'HASH') {
 129         $attr_desc = $_[0];
 130     }
 131     else {
 132         $attr_desc = { @_ };
 133     }
 134     $self->get_attribute_map->{$name} = $attr_desc;
 135 }
 136
 137 # DEPRECATED
 138 # sub _clean_up_required_methods {
 139 #     my $self = shift;
 140 #     foreach my $method ($self->get_required_method_list) {
 141 #         $self->remove_required_methods($method)
 142 #             if $self->has_method($method);
 143 #     }
 144 # }
 145
 146 ## ------------------------------------------------------------------
 147 ## method modifiers
 148
 149 # NOTE:
 150 # the before/around/after method modifiers are
 151 # stored by name, but there can be many methods
 152 # then associated with that name. So again we have
 153 # lots of similar functionality, so we can do some
 154 # meta-programmin' and save some time.
 155 # - SL
 156
 157 foreach my $modifier_type (qw[ before around after ]) {
 158
 159     my $attr_reader = "get_${modifier_type}_method_modifiers_map";
 160
 161     # create the attribute ...
 162     $META->add_attribute("${modifier_type}_method_modifiers" => (
 163         reader  => $attr_reader,
 164         default => sub { {} }
 165     ));
 166
 167     # and some helper methods ...
 168     $META->add_method("get_${modifier_type}_method_modifiers" => sub {
 169         my ($self, $method_name) = @_;
 170         #return () unless exists $self->$attr_reader->{$method_name};
 171         @{$self->$attr_reader->{$method_name}};
 172     });
 173
 174     $META->add_method("has_${modifier_type}_method_modifiers" => sub {
 175         my ($self, $method_name) = @_;
 176         # NOTE:
 177         # for now we assume that if it exists,..
 178         # it has at least one modifier in it
 179         (exists $self->$attr_reader->{$method_name}) ? 1 : 0;
 180     });
 181
 182     $META->add_method("add_${modifier_type}_method_modifier" => sub {
 183         my ($self, $method_name, $method) = @_;
 184
 185         $self->$attr_reader->{$method_name} = []
 186             unless exists $self->$attr_reader->{$method_name};
 187
 188         my $modifiers = $self->$attr_reader->{$method_name};
 189
 190         # NOTE:
 191         # check to see that we aren't adding the
 192         # same code twice. We err in favor of the
 193         # first on here, this may not be as expected
 194         foreach my $modifier (@{$modifiers}) {
 195             return if $modifier == $method;
 196         }
 197
 198         push @{$modifiers} => $method;
 199     });
 200
 201 }
 202
 203 ## ------------------------------------------------------------------
 204 ## override method mofidiers
 205
 206 $META->add_attribute('override_method_modifiers' => (
 207     reader  => 'get_override_method_modifiers_map',
 208     default => sub { {} }
 209 ));
 210
 211 # NOTE:
 212 # these are a little different because there
 213 # can only be one per name, whereas the other
 214 # method modifiers can have multiples.
 215 # - SL
 216
 217 sub add_override_method_modifier {
 218     my ($self, $method_name, $method) = @_;
 219     (!$self->has_method($method_name))
 220         || Moose->throw_error("Cannot add an override of method '$method_name' " .
 221                    "because there is a local version of '$method_name'");
 222     $self->get_override_method_modifiers_map->{$method_name} = $method;
 223 }
 224
 225 sub has_override_method_modifier {
 226     my ($self, $method_name) = @_;
 227     # NOTE:
 228     # for now we assume that if it exists,..
 229     # it has at least one modifier in it
 230     (exists $self->get_override_method_modifiers_map->{$method_name}) ? 1 : 0;
 231 }
 232
 233 sub get_override_method_modifier {
 234     my ($self, $method_name) = @_;
 235     $self->get_override_method_modifiers_map->{$method_name};
 236 }
 237
 238 ## general list accessor ...
 239
 240 sub get_method_modifier_list {
 241     my ($self, $modifier_type) = @_;
 242     my $accessor = "get_${modifier_type}_method_modifiers_map";
 243     keys %{$self->$accessor};
 244 }
 245
 246 sub reset_package_cache_flag  { (shift)->{'_package_cache_flag'} = undef }
 247 sub update_package_cache_flag {
 248     my $self = shift;
 249     $self->{'_package_cache_flag'} = Class::MOP::check_package_cache_flag($self->name);
 250 }
 251
 252
 253
 254 ## ------------------------------------------------------------------
 255 ## subroles
 256
 257 __PACKAGE__->meta->add_attribute('roles' => (
 258     reader  => 'get_roles',
 259     default => sub { [] }
 260 ));
 261
 262 sub add_role {
 263     my ($self, $role) = @_;
 264     (blessed($role) && $role->isa('Moose::Meta::Role'))
 265         || Moose->throw_error("Roles must be instances of Moose::Meta::Role");
 266     push @{$self->get_roles} => $role;
 267     $self->reset_package_cache_flag;
 268 }
 269
 270 sub calculate_all_roles {
 271     my $self = shift;
 272     my %seen;
 273     grep {
 274         !$seen{$_->name}++
 275     } ($self, map {
 276                   $_->calculate_all_roles
 277               } @{ $self->get_roles });
 278 }
 279
 280 sub does_role {
 281     my ($self, $role_name) = @_;
 282     (defined $role_name)
 283         || Moose->throw_error("You must supply a role name to look for");
 284     # if we are it,.. then return true
 285     return 1 if $role_name eq $self->name;
 286     # otherwise.. check our children
 287     foreach my $role (@{$self->get_roles}) {
 288         return 1 if $role->does_role($role_name);
 289     }
 290     return 0;
 291 }
 292
 293 ## ------------------------------------------------------------------
 294 ## methods
 295
 296 sub method_metaclass { 'Moose::Meta::Role::Method' }
 297
 298 sub get_method_map {
 299     my $self = shift;
 300
 301     my $current = Class::MOP::check_package_cache_flag($self->name);
 302
 303     if (defined $self->{'_package_cache_flag'} && $self->{'_package_cache_flag'} == $current) {
 304         return $self->{'methods'} ||= {};
 305     }
 306
 307     $self->{_package_cache_flag} = $current;
 308
 309     my $map  = $self->{'methods'} ||= {};
 310
 311     my $role_name        = $self->name;
 312     my $method_metaclass = $self->method_metaclass;
 313
 314     my $all_code = $self->get_all_package_symbols('CODE');
 315
 316     foreach my $symbol (keys %{ $all_code }) {
 317         my $code = $all_code->{$symbol};
 318
 319         next if exists  $map->{$symbol} &&
 320                 defined $map->{$symbol} &&
 321                         $map->{$symbol}->body == $code;
 322
 323         my ($pkg, $name) = Class::MOP::get_code_info($code);
 324
 325         if ($pkg->can('meta')
 326             # NOTE:
 327             # we don't know what ->meta we are calling
 328             # here, so we need to be careful cause it
 329             # just might blow up at us, or just complain
 330             # loudly (in the case of Curses.pm) so we
 331             # just be a little overly cautious here.
 332             # - SL
 333             && eval { no warnings; blessed($pkg->meta) } # FIXME calls meta
 334             && $pkg->meta->isa('Moose::Meta::Role')) {
 335             my $role = $pkg->meta->name;
 336             next unless $self->does_role($role);
 337         }
 338         else {
 339             # NOTE:
 340             # in 5.10 constant.pm the constants show up
 341             # as being in the right package, but in pre-5.10
 342             # they show up as constant::__ANON__ so we
 343             # make an exception here to be sure that things
 344             # work as expected in both.
 345             # - SL
 346             unless ($pkg eq 'constant' && $name eq '__ANON__') {
 347                 next if ($pkg  || '') ne $role_name ||
 348                         (($name || '') ne '__ANON__' && ($pkg  || '') ne $role_name);
 349             }
 350         }
 351
 352         $map->{$symbol} = $method_metaclass->wrap(
 353             $code,
 354             package_name => $role_name,
 355             name         => $name
 356         );
 357     }
 358
 359     return $map;
 360 }
 361
 362 sub get_method {
 363     my ($self, $name) = @_;
 364     $self->get_method_map->{$name};
 365 }
 366
 367 sub has_method {
 368     my ($self, $name) = @_;
 369     exists $self->get_method_map->{$name} ? 1 : 0
 370 }
 371
 372 # FIXME this is copy-pasted from Class::MOP::Class
 373 # refactor to inherit from some common base
 374 sub wrap_method_body {
 375     my ( $self, %args ) = @_;
 376
 377     ('CODE' eq ref $args{body})
 378         || Moose->throw_error("Your code block must be a CODE reference");
 379
 380     $self->method_metaclass->wrap(
 381         package_name => $self->name,
 382         %args,
 383     );
 384 }
 385
 386 sub add_method {
 387     my ($self, $method_name, $method) = @_;
 388     (defined $method_name && $method_name)
 389     || Moose->throw_error("You must define a method name");
 390
 391     my $body;
 392     if (blessed($method)) {
 393         $body = $method->body;
 394         if ($method->package_name ne $self->name) {
 395             $method = $method->clone(
 396                 package_name => $self->name,
 397                 name         => $method_name
 398             ) if $method->can('clone');
 399         }
 400     }
 401     else {
 402         $body = $method;
 403         $method = $self->wrap_method_body( body => $body, name => $method_name );
 404     }
 405
 406     $method->attach_to_class($self);
 407
 408     $self->get_method_map->{$method_name} = $method;
 409
 410     my $full_method_name = ($self->name . '::' . $method_name);
 411     $self->add_package_symbol(
 412         { sigil => '&', type => 'CODE', name => $method_name },
 413         Class::MOP::subname($full_method_name => $body)
 414     );
 415
 416     $self->update_package_cache_flag; # still valid, since we just added the method to the map, and if it was invalid before that then get_method_map updated it
 417 }
 418
 419 sub find_method_by_name { (shift)->get_method(@_) }
 420
 421 sub get_method_list {
 422     my $self = shift;
 423     grep { !/^meta$/ } keys %{$self->get_method_map};
 424 }
 425
 426 sub alias_method {
 427     my $self = shift;
 428
 429     $self->add_method(@_);
 430 }
 431
 432 ## ------------------------------------------------------------------
 433 ## role construction
 434 ## ------------------------------------------------------------------
 435
 436 sub apply {
 437     my ($self, $other, @args) = @_;
 438
 439     (blessed($other))
 440         || Moose->throw_error("You must pass in an blessed instance");
 441
 442     if ($other->isa('Moose::Meta::Role')) {
 443         require Moose::Meta::Role::Application::ToRole;
 444         return Moose::Meta::Role::Application::ToRole->new(@args)->apply($self, $other);
 445     }
 446     elsif ($other->isa('Moose::Meta::Class')) {
 447         require Moose::Meta::Role::Application::ToClass;
 448         return Moose::Meta::Role::Application::ToClass->new(@args)->apply($self, $other);
 449     }
 450     else {
 451         require Moose::Meta::Role::Application::ToInstance;
 452         return Moose::Meta::Role::Application::ToInstance->new(@args)->apply($self, $other);
 453     }
 454 }
 455
 456 sub combine {
 457     my ($class, @role_specs) = @_;
 458
 459     require Moose::Meta::Role::Application::RoleSummation;
 460     require Moose::Meta::Role::Composite;
 461
 462     my (@roles, %role_params);
 463     while (@role_specs) {
 464         my ($role, $params) = @{ splice @role_specs, 0, 1 };
 465         push @roles => $role->meta;
 466         next unless defined $params;
 467         $role_params{$role} = $params;
 468     }
 469
 470     my $c = Moose::Meta::Role::Composite->new(roles => \@roles);
 471     Moose::Meta::Role::Application::RoleSummation->new(
 472         role_params => \%role_params
 473     )->apply($c);
 474
 475     return $c;
 476 }
 477
 478 sub create {
 479     my ( $role, $package_name, %options ) = @_;
 480
 481     $options{package} = $package_name;
 482
 483     (ref $options{attributes} eq 'HASH')
 484         || confess "You must pass a HASH ref of attributes"
 485             if exists $options{attributes};
 486
 487     (ref $options{methods} eq 'HASH')
 488         || confess "You must pass a HASH ref of methods"
 489             if exists $options{methods};
 490
 491     $role->SUPER::create(%options);
 492
 493     my (%initialize_options) = %options;
 494     delete @initialize_options{qw(
 495         package
 496         attributes
 497         methods
 498         version
 499         authority
 500     )};
 501
 502     my $meta = $role->initialize( $package_name => %initialize_options );
 503
 504     # FIXME totally lame
 505     $meta->add_method('meta' => sub {
 506         $role->initialize(ref($_[0]) || $_[0]);
 507     });
 508
 509     if (exists $options{attributes}) {
 510         foreach my $attribute_name (keys %{$options{attributes}}) {
 511             my $attr = $options{attributes}->{$attribute_name};
 512             $meta->add_attribute($attribute_name => $attr);
 513         }
 514     }
 515
 516     if (exists $options{methods}) {
 517         foreach my $method_name (keys %{$options{methods}}) {
 518             $meta->add_method($method_name, $options{methods}->{$method_name});
 519         }
 520     }
 521
 522     Class::MOP::weaken_metaclass($meta->name)
 523         if $meta->is_anon_role;
 524
 525     return $meta;
 526 }
 527
 528 # anonymous roles. most of it is copied straight out of Class::MOP::Class.
 529 # an intrepid hacker might find great riches if he unifies this code with that
 530 # code in Class::MOP::Module or Class::MOP::Package
 531 {
 532     # NOTE:
 533     # this should be sufficient, if you have a
 534     # use case where it is not, write a test and
 535     # I will change it.
 536     my $ANON_ROLE_SERIAL = 0;
 537
 538     # NOTE:
 539     # we need a sufficiently annoying prefix
 540     # this should suffice for now, this is
 541     # used in a couple of places below, so
 542     # need to put it up here for now.
 543     my $ANON_ROLE_PREFIX = 'Moose::Meta::Role::__ANON__::SERIAL::';
 544
 545     sub is_anon_role {
 546         my $self = shift;
 547         no warnings 'uninitialized';
 548         $self->name =~ /^$ANON_ROLE_PREFIX/;
 549     }
 550
 551     sub create_anon_role {
 552         my ($role, %options) = @_;
 553         my $package_name = $ANON_ROLE_PREFIX . ++$ANON_ROLE_SERIAL;
 554         return $role->create($package_name, %options);
 555     }
 556
 557     # NOTE:
 558     # this will only get called for
 559     # anon-roles, all other calls
 560     # are assumed to occur during
 561     # global destruction and so don't
 562     # really need to be handled explicitly
 563     sub DESTROY {
 564         my $self = shift;
 565
 566         return if Class::MOP::in_global_destruction(); # it'll happen soon anyway and this just makes things more complicated
 567
 568         no warnings 'uninitialized';
 569         return unless $self->name =~ /^$ANON_ROLE_PREFIX/;
 570
 571         # XXX: is this necessary for us? I don't understand what it's doing
 572         # -sartak
 573
 574         # Moose does a weird thing where it replaces the metaclass for
 575         # class when fixing metaclass incompatibility. In that case,
 576         # we don't want to clean out the namespace now. We can detect
 577         # that because Moose will explicitly update the singleton
 578         # cache in Class::MOP.
 579         #my $current_meta = Class::MOP::get_metaclass_by_name($self->name);
 580         #return if $current_meta ne $self;
 581
 582         my ($serial_id) = ($self->name =~ /^$ANON_ROLE_PREFIX(\d+)/);
 583         no strict 'refs';
 584         foreach my $key (keys %{$ANON_ROLE_PREFIX . $serial_id}) {
 585             delete ${$ANON_ROLE_PREFIX . $serial_id}{$key};
 586         }
 587         delete ${'main::' . $ANON_ROLE_PREFIX}{$serial_id . '::'};
 588     }
 589 }
 590
 591 #####################################################################
 592 ## NOTE:
 593 ## This is Moose::Meta::Role as defined by Moose (plus the use of
 594 ## MooseX::AttributeHelpers module). It is here as a reference to
 595 ## make it easier to see what is happening above with all the meta
 596 ## programming. - SL
 597 #####################################################################
 598 #
 599 # has 'roles' => (
 600 #     metaclass => 'Collection::Array',
 601 #     reader    => 'get_roles',
 602 #     isa       => 'ArrayRef[Moose::Meta::Roles]',
 603 #     default   => sub { [] },
 604 #     provides  => {
 605 #         'push' => 'add_role',
 606 #     }
 607 # );
 608 #
 609 # has 'excluded_roles_map' => (
 610 #     metaclass => 'Collection::Hash',
 611 #     reader    => 'get_excluded_roles_map',
 612 #     isa       => 'HashRef[Str]',
 613 #     provides  => {
 614 #         # Not exactly set, cause it sets multiple
 615 #         'set'    => 'add_excluded_roles',
 616 #         'keys'   => 'get_excluded_roles_list',
 617 #         'exists' => 'excludes_role',
 618 #     }
 619 # );
 620 #
 621 # has 'attribute_map' => (
 622 #     metaclass => 'Collection::Hash',
 623 #     reader    => 'get_attribute_map',
 624 #     isa       => 'HashRef[Str]',
 625 #     provides => {
 626 #         # 'set'  => 'add_attribute' # has some special crap in it
 627 #         'get'    => 'get_attribute',
 628 #         'keys'   => 'get_attribute_list',
 629 #         'exists' => 'has_attribute',
 630 #         # Not exactly delete, cause it sets multiple
 631 #         'delete' => 'remove_attribute',
 632 #     }
 633 # );
 634 #
 635 # has 'required_methods' => (
 636 #     metaclass => 'Collection::Hash',
 637 #     reader    => 'get_required_methods_map',
 638 #     isa       => 'HashRef[Str]',
 639 #     provides  => {
 640 #         # not exactly set, or delete since it works for multiple
 641 #         'set'    => 'add_required_methods',
 642 #         'delete' => 'remove_required_methods',
 643 #         'keys'   => 'get_required_method_list',
 644 #         'exists' => 'requires_method',
 645 #     }
 646 # );
 647 #
 648 # # the before, around and after modifiers are
 649 # # HASH keyed by method-name, with ARRAY of
 650 # # CODE refs to apply in that order
 651 #
 652 # has 'before_method_modifiers' => (
 653 #     metaclass => 'Collection::Hash',
 654 #     reader    => 'get_before_method_modifiers_map',
 655 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 656 #     provides  => {
 657 #         'keys'   => 'get_before_method_modifiers',
 658 #         'exists' => 'has_before_method_modifiers',
 659 #         # This actually makes sure there is an
 660 #         # ARRAY at the given key, and pushed onto
 661 #         # it. It also checks for duplicates as well
 662 #         # 'add'  => 'add_before_method_modifier'
 663 #     }
 664 # );
 665 #
 666 # has 'after_method_modifiers' => (
 667 #     metaclass => 'Collection::Hash',
 668 #     reader    =>'get_after_method_modifiers_map',
 669 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 670 #     provides  => {
 671 #         'keys'   => 'get_after_method_modifiers',
 672 #         'exists' => 'has_after_method_modifiers',
 673 #         # This actually makes sure there is an
 674 #         # ARRAY at the given key, and pushed onto
 675 #         # it. It also checks for duplicates as well
 676 #         # 'add'  => 'add_after_method_modifier'
 677 #     }
 678 # );
 679 #
 680 # has 'around_method_modifiers' => (
 681 #     metaclass => 'Collection::Hash',
 682 #     reader    =>'get_around_method_modifiers_map',
 683 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 684 #     provides  => {
 685 #         'keys'   => 'get_around_method_modifiers',
 686 #         'exists' => 'has_around_method_modifiers',
 687 #         # This actually makes sure there is an
 688 #         # ARRAY at the given key, and pushed onto
 689 #         # it. It also checks for duplicates as well
 690 #         # 'add'  => 'add_around_method_modifier'
 691 #     }
 692 # );
 693 #
 694 # # override is similar to the other modifiers
 695 # # except that it is not an ARRAY of code refs
 696 # # but instead just a single name->code mapping
 697 #
 698 # has 'override_method_modifiers' => (
 699 #     metaclass => 'Collection::Hash',
 700 #     reader    =>'get_override_method_modifiers_map',
 701 #     isa       => 'HashRef[CodeRef]',
 702 #     provides  => {
 703 #         'keys'   => 'get_override_method_modifier',
 704 #         'exists' => 'has_override_method_modifier',
 705 #         'add'    => 'add_override_method_modifier', # checks for local method ..
 706 #     }
 707 # );
 708 #
 709 #####################################################################
 710
 711
 712 1;
 713
 714 __END__
 715
 716 =pod
 717
 718 =head1 NAME
 719
 720 Moose::Meta::Role - The Moose Role metaclass
 721
 722 =head1 DESCRIPTION
 723
 724 Please see L<Moose::Role> for more information about roles.
 725 For the most part, this has no user-serviceable parts inside
 726 this module. It's API is still subject to some change (although
 727 probably not that much really).
 728
 729 =head1 METHODS
 730
 731 =over 4
 732
 733 =item B<meta>
 734
 735 =item B<new>
 736
 737 =item B<apply>
 738
 739 =item B<apply_to_metaclass_instance>
 740
 741 =item B<combine>
 742
 743 =back
 744
 745 =over 4
 746
 747 =item B<name>
 748
 749 =item B<version>
 750
 751 =item B<role_meta>
 752
 753 =back
 754
 755 =over 4
 756
 757 =item B<get_roles>
 758
 759 =item B<add_role>
 760
 761 =item B<does_role>
 762
 763 =back
 764
 765 =over 4
 766
 767 =item B<add_excluded_roles>
 768
 769 =item B<excludes_role>
 770
 771 =item B<get_excluded_roles_list>
 772
 773 =item B<get_excluded_roles_map>
 774
 775 =item B<calculate_all_roles>
 776
 777 =back
 778
 779 =over 4
 780
 781 =item B<method_metaclass>
 782
 783 =item B<find_method_by_name>
 784
 785 =item B<get_method>
 786
 787 =item B<has_method>
 788
 789 =item B<add_method>
 790
 791 =item B<wrap_method_body>
 792
 793 =item B<alias_method>
 794
 795 =item B<get_method_list>
 796
 797 =item B<get_method_map>
 798
 799 =item B<update_package_cache_flag>
 800
 801 =item B<reset_package_cache_flag>
 802
 803 =back
 804
 805 =over 4
 806
 807 =item B<add_attribute>
 808
 809 =item B<has_attribute>
 810
 811 =item B<get_attribute>
 812
 813 =item B<get_attribute_list>
 814
 815 =item B<get_attribute_map>
 816
 817 =item B<remove_attribute>
 818
 819 =back
 820
 821 =over 4
 822
 823 =item B<add_required_methods>
 824
 825 =item B<remove_required_methods>
 826
 827 =item B<get_required_method_list>
 828
 829 =item B<get_required_methods_map>
 830
 831 =item B<requires_method>
 832
 833 =back
 834
 835 =over 4
 836
 837 =item B<add_after_method_modifier>
 838
 839 =item B<add_around_method_modifier>
 840
 841 =item B<add_before_method_modifier>
 842
 843 =item B<add_override_method_modifier>
 844
 845 =over 4
 846
 847 =back
 848
 849 =item B<has_after_method_modifiers>
 850
 851 =item B<has_around_method_modifiers>
 852
 853 =item B<has_before_method_modifiers>
 854
 855 =item B<has_override_method_modifier>
 856
 857 =over 4
 858
 859 =back
 860
 861 =item B<get_after_method_modifiers>
 862
 863 =item B<get_around_method_modifiers>
 864
 865 =item B<get_before_method_modifiers>
 866
 867 =item B<get_method_modifier_list>
 868
 869 =over 4
 870
 871 =back
 872
 873 =item B<get_override_method_modifier>
 874
 875 =item B<get_after_method_modifiers_map>
 876
 877 =item B<get_around_method_modifiers_map>
 878
 879 =item B<get_before_method_modifiers_map>
 880
 881 =item B<get_override_method_modifiers_map>
 882
 883 =back
 884
 885 =over 4
 886
 887 =item B<create>
 888
 889 =item B<create_anon_role>
 890
 891 =item B<is_anon_role>
 892
 893 =back
 894
 895 =head1 BUGS
 896
 897 All complex software has bugs lurking in it, and this module is no
 898 exception. If you find a bug please either email me, or add the bug
 899 to cpan-RT.
 900
 901 =head1 AUTHOR
 902
 903 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 904
 905 =head1 COPYRIGHT AND LICENSE
 906
 907 Copyright 2006-2008 by Infinity Interactive, Inc.
 908
 909 L<http://www.iinteractive.com>
 910
 911 This library is free software; you can redistribute it and/or modify
 912 it under the same terms as Perl itself.
 913
 914 =cut