lib/Moose/Meta/Role.pm

   1
   2 package Moose::Meta::Role;
   3
   4 use strict;
   5 use warnings;
   6 use metaclass;
   7
   8 use Carp         'confess';
   9 use Scalar::Util 'blessed';
  10
  11 our $VERSION   = '0.56';
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 use Moose::Meta::Class;
  15 use Moose::Meta::Role::Method;
  16 use Moose::Meta::Role::Method::Required;
  17
  18 use base 'Class::MOP::Module';
  19
  20 ## ------------------------------------------------------------------
  21 ## NOTE:
  22 ## I normally don't do this, but I am doing
  23 ## a whole bunch of meta-programmin in this
  24 ## module, so it just makes sense. For a clearer
  25 ## picture of what is going on in the next
  26 ## several lines of code, look at the really
  27 ## big comment at the end of this file (right
  28 ## before the POD).
  29 ## - SL
  30 ## ------------------------------------------------------------------
  31
  32 my $META = __PACKAGE__->meta;
  33
  34 ## ------------------------------------------------------------------
  35 ## attributes ...
  36
  37 # NOTE:
  38 # since roles are lazy, we hold all the attributes
  39 # of the individual role in 'statis' until which
  40 # time when it is applied to a class. This means
  41 # keeping a lot of things in hash maps, so we are
  42 # using a little of that meta-programmin' magic
  43 # here an saving lots of extra typin. And since
  44 # many of these attributes above require similar
  45 # functionality to support them, so we again use
  46 # the wonders of meta-programmin' to deliver a
  47 # very compact solution to this normally verbose
  48 # problem.
  49 # - SL
  50
  51 foreach my $action (
  52     {
  53         name        => 'excluded_roles_map',
  54         attr_reader => 'get_excluded_roles_map' ,
  55         methods     => {
  56             add       => 'add_excluded_roles',
  57             get_list  => 'get_excluded_roles_list',
  58             existence => 'excludes_role',
  59         }
  60     },
  61     {
  62         name        => 'required_methods',
  63         attr_reader => 'get_required_methods_map',
  64         methods     => {
  65             add       => 'add_required_methods',
  66             remove    => 'remove_required_methods',
  67             get_list  => 'get_required_method_list',
  68             existence => 'requires_method',
  69         }
  70     },
  71     {
  72         name        => 'attribute_map',
  73         attr_reader => 'get_attribute_map',
  74         methods     => {
  75             get       => 'get_attribute',
  76             get_list  => 'get_attribute_list',
  77             existence => 'has_attribute',
  78             remove    => 'remove_attribute',
  79         }
  80     }
  81 ) {
  82
  83     my $attr_reader = $action->{attr_reader};
  84     my $methods     = $action->{methods};
  85
  86     # create the attribute
  87     $META->add_attribute($action->{name} => (
  88         reader  => $attr_reader,
  89         default => sub { {} }
  90     ));
  91
  92     # create some helper methods
  93     $META->add_method($methods->{add} => sub {
  94         my ($self, @values) = @_;
  95         $self->$attr_reader->{$_} = undef foreach @values;
  96     }) if exists $methods->{add};
  97
  98     $META->add_method($methods->{get_list} => sub {
  99         my ($self) = @_;
 100         keys %{$self->$attr_reader};
 101     }) if exists $methods->{get_list};
 102
 103     $META->add_method($methods->{get} => sub {
 104         my ($self, $name) = @_;
 105         $self->$attr_reader->{$name}
 106     }) if exists $methods->{get};
 107
 108     $META->add_method($methods->{existence} => sub {
 109         my ($self, $name) = @_;
 110         exists $self->$attr_reader->{$name} ? 1 : 0;
 111     }) if exists $methods->{existence};
 112
 113     $META->add_method($methods->{remove} => sub {
 114         my ($self, @values) = @_;
 115         delete $self->$attr_reader->{$_} foreach @values;
 116     }) if exists $methods->{remove};
 117 }
 118
 119 ## some things don't always fit, so they go here ...
 120
 121 sub add_attribute {
 122     my $self = shift;
 123     my $name = shift;
 124     my $attr_desc;
 125     if (scalar @_ == 1 && ref($_[0]) eq 'HASH') {
 126         $attr_desc = $_[0];
 127     }
 128     else {
 129         $attr_desc = { @_ };
 130     }
 131     $self->get_attribute_map->{$name} = $attr_desc;
 132 }
 133
 134 # DEPRECATED
 135 # sub _clean_up_required_methods {
 136 #     my $self = shift;
 137 #     foreach my $method ($self->get_required_method_list) {
 138 #         $self->remove_required_methods($method)
 139 #             if $self->has_method($method);
 140 #     }
 141 # }
 142
 143 ## ------------------------------------------------------------------
 144 ## method modifiers
 145
 146 # NOTE:
 147 # the before/around/after method modifiers are
 148 # stored by name, but there can be many methods
 149 # then associated with that name. So again we have
 150 # lots of similar functionality, so we can do some
 151 # meta-programmin' and save some time.
 152 # - SL
 153
 154 foreach my $modifier_type (qw[ before around after ]) {
 155
 156     my $attr_reader = "get_${modifier_type}_method_modifiers_map";
 157
 158     # create the attribute ...
 159     $META->add_attribute("${modifier_type}_method_modifiers" => (
 160         reader  => $attr_reader,
 161         default => sub { {} }
 162     ));
 163
 164     # and some helper methods ...
 165     $META->add_method("get_${modifier_type}_method_modifiers" => sub {
 166         my ($self, $method_name) = @_;
 167         #return () unless exists $self->$attr_reader->{$method_name};
 168         @{$self->$attr_reader->{$method_name}};
 169     });
 170
 171     $META->add_method("has_${modifier_type}_method_modifiers" => sub {
 172         my ($self, $method_name) = @_;
 173         # NOTE:
 174         # for now we assume that if it exists,..
 175         # it has at least one modifier in it
 176         (exists $self->$attr_reader->{$method_name}) ? 1 : 0;
 177     });
 178
 179     $META->add_method("add_${modifier_type}_method_modifier" => sub {
 180         my ($self, $method_name, $method) = @_;
 181
 182         $self->$attr_reader->{$method_name} = []
 183             unless exists $self->$attr_reader->{$method_name};
 184
 185         my $modifiers = $self->$attr_reader->{$method_name};
 186
 187         # NOTE:
 188         # check to see that we aren't adding the
 189         # same code twice. We err in favor of the
 190         # first on here, this may not be as expected
 191         foreach my $modifier (@{$modifiers}) {
 192             return if $modifier == $method;
 193         }
 194
 195         push @{$modifiers} => $method;
 196     });
 197
 198 }
 199
 200 ## ------------------------------------------------------------------
 201 ## override method mofidiers
 202
 203 $META->add_attribute('override_method_modifiers' => (
 204     reader  => 'get_override_method_modifiers_map',
 205     default => sub { {} }
 206 ));
 207
 208 # NOTE:
 209 # these are a little different because there
 210 # can only be one per name, whereas the other
 211 # method modifiers can have multiples.
 212 # - SL
 213
 214 sub add_override_method_modifier {
 215     my ($self, $method_name, $method) = @_;
 216     (!$self->has_method($method_name))
 217         || confess "Cannot add an override of method '$method_name' " .
 218                    "because there is a local version of '$method_name'";
 219     $self->get_override_method_modifiers_map->{$method_name} = $method;
 220 }
 221
 222 sub has_override_method_modifier {
 223     my ($self, $method_name) = @_;
 224     # NOTE:
 225     # for now we assume that if it exists,..
 226     # it has at least one modifier in it
 227     (exists $self->get_override_method_modifiers_map->{$method_name}) ? 1 : 0;
 228 }
 229
 230 sub get_override_method_modifier {
 231     my ($self, $method_name) = @_;
 232     $self->get_override_method_modifiers_map->{$method_name};
 233 }
 234
 235 ## general list accessor ...
 236
 237 sub get_method_modifier_list {
 238     my ($self, $modifier_type) = @_;
 239     my $accessor = "get_${modifier_type}_method_modifiers_map";
 240     keys %{$self->$accessor};
 241 }
 242
 243 ## ------------------------------------------------------------------
 244 ## subroles
 245
 246 __PACKAGE__->meta->add_attribute('roles' => (
 247     reader  => 'get_roles',
 248     default => sub { [] }
 249 ));
 250
 251 sub add_role {
 252     my ($self, $role) = @_;
 253     (blessed($role) && $role->isa('Moose::Meta::Role'))
 254         || confess "Roles must be instances of Moose::Meta::Role";
 255     push @{$self->get_roles} => $role;
 256 }
 257
 258 sub calculate_all_roles {
 259     my $self = shift;
 260     my %seen;
 261     grep {
 262         !$seen{$_->name}++
 263     } ($self, map {
 264                   $_->calculate_all_roles
 265               } @{ $self->get_roles });
 266 }
 267
 268 sub does_role {
 269     my ($self, $role_name) = @_;
 270     (defined $role_name)
 271         || confess "You must supply a role name to look for";
 272     # if we are it,.. then return true
 273     return 1 if $role_name eq $self->name;
 274     # otherwise.. check our children
 275     foreach my $role (@{$self->get_roles}) {
 276         return 1 if $role->does_role($role_name);
 277     }
 278     return 0;
 279 }
 280
 281 ## ------------------------------------------------------------------
 282 ## methods
 283
 284 sub method_metaclass { 'Moose::Meta::Role::Method' }
 285
 286 sub get_method_map {
 287     my $self = shift;
 288
 289     my $current = Class::MOP::check_package_cache_flag($self->name);
 290
 291     if (defined $self->{'_package_cache_flag'} && $self->{'_package_cache_flag'} == $current) {
 292         return $self->{'methods'} ||= {};
 293     }
 294
 295     $self->{_package_cache_flag} = $current;
 296
 297     my $map  = $self->{'methods'} ||= {};
 298
 299     my $role_name        = $self->name;
 300     my $method_metaclass = $self->method_metaclass;
 301
 302     my %all_code = $self->get_all_package_symbols('CODE');
 303
 304     foreach my $symbol (keys %all_code) {
 305         my $code = $all_code{$symbol};
 306
 307         next if exists  $map->{$symbol} &&
 308                 defined $map->{$symbol} &&
 309                         $map->{$symbol}->body == $code;
 310
 311         my ($pkg, $name) = Class::MOP::get_code_info($code);
 312
 313         if ($pkg->can('meta')
 314             # NOTE:
 315             # we don't know what ->meta we are calling
 316             # here, so we need to be careful cause it
 317             # just might blow up at us, or just complain
 318             # loudly (in the case of Curses.pm) so we
 319             # just be a little overly cautious here.
 320             # - SL
 321             && eval { no warnings; blessed($pkg->meta) } # FIXME calls meta
 322             && $pkg->meta->isa('Moose::Meta::Role')) {
 323             my $role = $pkg->meta->name;
 324             next unless $self->does_role($role);
 325         }
 326         else {
 327             # NOTE:
 328             # in 5.10 constant.pm the constants show up
 329             # as being in the right package, but in pre-5.10
 330             # they show up as constant::__ANON__ so we
 331             # make an exception here to be sure that things
 332             # work as expected in both.
 333             # - SL
 334             unless ($pkg eq 'constant' && $name eq '__ANON__') {
 335                 next if ($pkg  || '') ne $role_name ||
 336                         (($name || '') ne '__ANON__' && ($pkg  || '') ne $role_name);
 337             }
 338         }
 339
 340         $map->{$symbol} = $method_metaclass->wrap(
 341             $code,
 342             package_name => $role_name,
 343             name         => $name
 344         );
 345     }
 346
 347     return $map;
 348 }
 349
 350 sub get_method {
 351     my ($self, $name) = @_;
 352     $self->get_method_map->{$name};
 353 }
 354
 355 sub has_method {
 356     my ($self, $name) = @_;
 357     exists $self->get_method_map->{$name} ? 1 : 0
 358 }
 359
 360 sub find_method_by_name { (shift)->get_method(@_) }
 361
 362 sub get_method_list {
 363     my $self = shift;
 364     grep { !/^meta$/ } keys %{$self->get_method_map};
 365 }
 366
 367 sub alias_method {
 368     my ($self, $method_name, $method) = @_;
 369     (defined $method_name && $method_name)
 370         || confess "You must define a method name";
 371
 372     my $body = (blessed($method) ? $method->body : $method);
 373     ('CODE' eq ref($body))
 374         || confess "Your code block must be a CODE reference";
 375
 376     $self->add_package_symbol(
 377         { sigil => '&', type => 'CODE', name => $method_name },
 378         $body
 379     );
 380 }
 381
 382 ## ------------------------------------------------------------------
 383 ## role construction
 384 ## ------------------------------------------------------------------
 385
 386 sub apply {
 387     my ($self, $other, @args) = @_;
 388
 389     (blessed($other))
 390         || confess "You must pass in an blessed instance";
 391
 392     if ($other->isa('Moose::Meta::Role')) {
 393         require Moose::Meta::Role::Application::ToRole;
 394         return Moose::Meta::Role::Application::ToRole->new(@args)->apply($self, $other);
 395     }
 396     elsif ($other->isa('Moose::Meta::Class')) {
 397         require Moose::Meta::Role::Application::ToClass;
 398         return Moose::Meta::Role::Application::ToClass->new(@args)->apply($self, $other);
 399     }
 400     else {
 401         require Moose::Meta::Role::Application::ToInstance;
 402         return Moose::Meta::Role::Application::ToInstance->new(@args)->apply($self, $other);
 403     }
 404 }
 405
 406 sub combine {
 407     my ($class, @role_specs) = @_;
 408
 409     require Moose::Meta::Role::Application::RoleSummation;
 410     require Moose::Meta::Role::Composite;
 411
 412     my (@roles, %role_params);
 413     while (@role_specs) {
 414         my ($role, $params) = @{ splice @role_specs, 0, 1 };
 415         push @roles => $role->meta;
 416         next unless defined $params;
 417         $role_params{$role} = $params;
 418     }
 419
 420     my $c = Moose::Meta::Role::Composite->new(roles => \@roles);
 421     Moose::Meta::Role::Application::RoleSummation->new(
 422         role_params => \%role_params
 423     )->apply($c);
 424
 425     return $c;
 426 }
 427
 428 #####################################################################
 429 ## NOTE:
 430 ## This is Moose::Meta::Role as defined by Moose (plus the use of
 431 ## MooseX::AttributeHelpers module). It is here as a reference to
 432 ## make it easier to see what is happening above with all the meta
 433 ## programming. - SL
 434 #####################################################################
 435 #
 436 # has 'roles' => (
 437 #     metaclass => 'Collection::Array',
 438 #     reader    => 'get_roles',
 439 #     isa       => 'ArrayRef[Moose::Meta::Roles]',
 440 #     default   => sub { [] },
 441 #     provides  => {
 442 #         'push' => 'add_role',
 443 #     }
 444 # );
 445 #
 446 # has 'excluded_roles_map' => (
 447 #     metaclass => 'Collection::Hash',
 448 #     reader    => 'get_excluded_roles_map',
 449 #     isa       => 'HashRef[Str]',
 450 #     provides  => {
 451 #         # Not exactly set, cause it sets multiple
 452 #         'set'    => 'add_excluded_roles',
 453 #         'keys'   => 'get_excluded_roles_list',
 454 #         'exists' => 'excludes_role',
 455 #     }
 456 # );
 457 #
 458 # has 'attribute_map' => (
 459 #     metaclass => 'Collection::Hash',
 460 #     reader    => 'get_attribute_map',
 461 #     isa       => 'HashRef[Str]',
 462 #     provides => {
 463 #         # 'set'  => 'add_attribute' # has some special crap in it
 464 #         'get'    => 'get_attribute',
 465 #         'keys'   => 'get_attribute_list',
 466 #         'exists' => 'has_attribute',
 467 #         # Not exactly delete, cause it sets multiple
 468 #         'delete' => 'remove_attribute',
 469 #     }
 470 # );
 471 #
 472 # has 'required_methods' => (
 473 #     metaclass => 'Collection::Hash',
 474 #     reader    => 'get_required_methods_map',
 475 #     isa       => 'HashRef[Str]',
 476 #     provides  => {
 477 #         # not exactly set, or delete since it works for multiple
 478 #         'set'    => 'add_required_methods',
 479 #         'delete' => 'remove_required_methods',
 480 #         'keys'   => 'get_required_method_list',
 481 #         'exists' => 'requires_method',
 482 #     }
 483 # );
 484 #
 485 # # the before, around and after modifiers are
 486 # # HASH keyed by method-name, with ARRAY of
 487 # # CODE refs to apply in that order
 488 #
 489 # has 'before_method_modifiers' => (
 490 #     metaclass => 'Collection::Hash',
 491 #     reader    => 'get_before_method_modifiers_map',
 492 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 493 #     provides  => {
 494 #         'keys'   => 'get_before_method_modifiers',
 495 #         'exists' => 'has_before_method_modifiers',
 496 #         # This actually makes sure there is an
 497 #         # ARRAY at the given key, and pushed onto
 498 #         # it. It also checks for duplicates as well
 499 #         # 'add'  => 'add_before_method_modifier'
 500 #     }
 501 # );
 502 #
 503 # has 'after_method_modifiers' => (
 504 #     metaclass => 'Collection::Hash',
 505 #     reader    =>'get_after_method_modifiers_map',
 506 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 507 #     provides  => {
 508 #         'keys'   => 'get_after_method_modifiers',
 509 #         'exists' => 'has_after_method_modifiers',
 510 #         # This actually makes sure there is an
 511 #         # ARRAY at the given key, and pushed onto
 512 #         # it. It also checks for duplicates as well
 513 #         # 'add'  => 'add_after_method_modifier'
 514 #     }
 515 # );
 516 #
 517 # has 'around_method_modifiers' => (
 518 #     metaclass => 'Collection::Hash',
 519 #     reader    =>'get_around_method_modifiers_map',
 520 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 521 #     provides  => {
 522 #         'keys'   => 'get_around_method_modifiers',
 523 #         'exists' => 'has_around_method_modifiers',
 524 #         # This actually makes sure there is an
 525 #         # ARRAY at the given key, and pushed onto
 526 #         # it. It also checks for duplicates as well
 527 #         # 'add'  => 'add_around_method_modifier'
 528 #     }
 529 # );
 530 #
 531 # # override is similar to the other modifiers
 532 # # except that it is not an ARRAY of code refs
 533 # # but instead just a single name->code mapping
 534 #
 535 # has 'override_method_modifiers' => (
 536 #     metaclass => 'Collection::Hash',
 537 #     reader    =>'get_override_method_modifiers_map',
 538 #     isa       => 'HashRef[CodeRef]',
 539 #     provides  => {
 540 #         'keys'   => 'get_override_method_modifier',
 541 #         'exists' => 'has_override_method_modifier',
 542 #         'add'    => 'add_override_method_modifier', # checks for local method ..
 543 #     }
 544 # );
 545 #
 546 #####################################################################
 547
 548
 549 1;
 550
 551 __END__
 552
 553 =pod
 554
 555 =head1 NAME
 556
 557 Moose::Meta::Role - The Moose Role metaclass
 558
 559 =head1 DESCRIPTION
 560
 561 Please see L<Moose::Role> for more information about roles.
 562 For the most part, this has no user-serviceable parts inside
 563 this module. It's API is still subject to some change (although
 564 probably not that much really).
 565
 566 =head1 METHODS
 567
 568 =over 4
 569
 570 =item B<meta>
 571
 572 =item B<new>
 573
 574 =item B<apply>
 575
 576 =item B<combine>
 577
 578 =back
 579
 580 =over 4
 581
 582 =item B<name>
 583
 584 =item B<version>
 585
 586 =item B<role_meta>
 587
 588 =back
 589
 590 =over 4
 591
 592 =item B<get_roles>
 593
 594 =item B<add_role>
 595
 596 =item B<does_role>
 597
 598 =back
 599
 600 =over 4
 601
 602 =item B<add_excluded_roles>
 603
 604 =item B<excludes_role>
 605
 606 =item B<get_excluded_roles_list>
 607
 608 =item B<get_excluded_roles_map>
 609
 610 =item B<calculate_all_roles>
 611
 612 =back
 613
 614 =over 4
 615
 616 =item B<method_metaclass>
 617
 618 =item B<find_method_by_name>
 619
 620 =item B<get_method>
 621
 622 =item B<has_method>
 623
 624 =item B<alias_method>
 625
 626 =item B<get_method_list>
 627
 628 =item B<get_method_map>
 629
 630 =item B<update_package_cache_flag>
 631
 632 =item B<reset_package_cache_flag>
 633
 634 =back
 635
 636 =over 4
 637
 638 =item B<add_attribute>
 639
 640 =item B<has_attribute>
 641
 642 =item B<get_attribute>
 643
 644 =item B<get_attribute_list>
 645
 646 =item B<get_attribute_map>
 647
 648 =item B<remove_attribute>
 649
 650 =back
 651
 652 =over 4
 653
 654 =item B<add_required_methods>
 655
 656 =item B<remove_required_methods>
 657
 658 =item B<get_required_method_list>
 659
 660 =item B<get_required_methods_map>
 661
 662 =item B<requires_method>
 663
 664 =back
 665
 666 =over 4
 667
 668 =item B<add_after_method_modifier>
 669
 670 =item B<add_around_method_modifier>
 671
 672 =item B<add_before_method_modifier>
 673
 674 =item B<add_override_method_modifier>
 675
 676 =over 4
 677
 678 =back
 679
 680 =item B<has_after_method_modifiers>
 681
 682 =item B<has_around_method_modifiers>
 683
 684 =item B<has_before_method_modifiers>
 685
 686 =item B<has_override_method_modifier>
 687
 688 =over 4
 689
 690 =back
 691
 692 =item B<get_after_method_modifiers>
 693
 694 =item B<get_around_method_modifiers>
 695
 696 =item B<get_before_method_modifiers>
 697
 698 =item B<get_method_modifier_list>
 699
 700 =over 4
 701
 702 =back
 703
 704 =item B<get_override_method_modifier>
 705
 706 =item B<get_after_method_modifiers_map>
 707
 708 =item B<get_around_method_modifiers_map>
 709
 710 =item B<get_before_method_modifiers_map>
 711
 712 =item B<get_override_method_modifiers_map>
 713
 714 =back
 715
 716 =head1 BUGS
 717
 718 All complex software has bugs lurking in it, and this module is no
 719 exception. If you find a bug please either email me, or add the bug
 720 to cpan-RT.
 721
 722 =head1 AUTHOR
 723
 724 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 725
 726 =head1 COPYRIGHT AND LICENSE
 727
 728 Copyright 2006-2008 by Infinity Interactive, Inc.
 729
 730 L<http://www.iinteractive.com>
 731
 732 This library is free software; you can redistribute it and/or modify
 733 it under the same terms as Perl itself.
 734
 735 =cut