lib/Moose/Meta/Role.pm

   1
   2 package Moose::Meta::Role;
   3
   4 use strict;
   5 use warnings;
   6 use metaclass;
   7
   8 use Scalar::Util 'blessed';
   9 use Carp         'confess';
  10 use Devel::GlobalDestruction 'in_global_destruction';
  11
  12 our $VERSION   = '1.22';
  13 $VERSION = eval $VERSION;
  14 our $AUTHORITY = 'cpan:STEVAN';
  15
  16 use Moose::Meta::Class;
  17 use Moose::Meta::Role::Attribute;
  18 use Moose::Meta::Role::Method;
  19 use Moose::Meta::Role::Method::Required;
  20 use Moose::Meta::Role::Method::Conflicting;
  21 use Moose::Meta::Method::Meta;
  22 use Moose::Util qw( ensure_all_roles );
  23 use Class::MOP::MiniTrait;
  24
  25 use base 'Class::MOP::Module',
  26          'Class::MOP::Mixin::HasAttributes',
  27          'Class::MOP::Mixin::HasMethods';
  28
  29 Class::MOP::MiniTrait::apply(__PACKAGE__, 'Moose::Meta::Object::Trait');
  30
  31 ## ------------------------------------------------------------------
  32 ## NOTE:
  33 ## I normally don't do this, but I am doing
  34 ## a whole bunch of meta-programmin in this
  35 ## module, so it just makes sense. For a clearer
  36 ## picture of what is going on in the next
  37 ## several lines of code, look at the really
  38 ## big comment at the end of this file (right
  39 ## before the POD).
  40 ## - SL
  41 ## ------------------------------------------------------------------
  42
  43 my $META = __PACKAGE__->meta;
  44
  45 ## ------------------------------------------------------------------
  46 ## attributes ...
  47
  48 # NOTE:
  49 # since roles are lazy, we hold all the attributes
  50 # of the individual role in 'statis' until which
  51 # time when it is applied to a class. This means
  52 # keeping a lot of things in hash maps, so we are
  53 # using a little of that meta-programmin' magic
  54 # here an saving lots of extra typin. And since
  55 # many of these attributes above require similar
  56 # functionality to support them, so we again use
  57 # the wonders of meta-programmin' to deliver a
  58 # very compact solution to this normally verbose
  59 # problem.
  60 # - SL
  61
  62 foreach my $action (
  63     {
  64         name        => 'excluded_roles_map',
  65         attr_reader => 'get_excluded_roles_map' ,
  66         methods     => {
  67             add       => 'add_excluded_roles',
  68             get_keys  => 'get_excluded_roles_list',
  69             existence => 'excludes_role',
  70         }
  71     },
  72     {
  73         name        => 'required_methods',
  74         attr_reader => 'get_required_methods_map',
  75         methods     => {
  76             remove     => 'remove_required_methods',
  77             get_values => 'get_required_method_list',
  78             existence  => 'requires_method',
  79         }
  80     },
  81 ) {
  82
  83     my $attr_reader = $action->{attr_reader};
  84     my $methods     = $action->{methods};
  85
  86     # create the attribute
  87     $META->add_attribute($action->{name} => (
  88         reader  => $attr_reader,
  89         default => sub { {} }
  90     ));
  91
  92     # create some helper methods
  93     $META->add_method($methods->{add} => sub {
  94         my ($self, @values) = @_;
  95         $self->$attr_reader->{$_} = undef foreach @values;
  96     }) if exists $methods->{add};
  97
  98     $META->add_method($methods->{get_keys} => sub {
  99         my ($self) = @_;
 100         keys %{$self->$attr_reader};
 101     }) if exists $methods->{get_keys};
 102
 103     $META->add_method($methods->{get_values} => sub {
 104         my ($self) = @_;
 105         values %{$self->$attr_reader};
 106     }) if exists $methods->{get_values};
 107
 108     $META->add_method($methods->{get} => sub {
 109         my ($self, $name) = @_;
 110         $self->$attr_reader->{$name}
 111     }) if exists $methods->{get};
 112
 113     $META->add_method($methods->{existence} => sub {
 114         my ($self, $name) = @_;
 115         exists $self->$attr_reader->{$name} ? 1 : 0;
 116     }) if exists $methods->{existence};
 117
 118     $META->add_method($methods->{remove} => sub {
 119         my ($self, @values) = @_;
 120         delete $self->$attr_reader->{$_} foreach @values;
 121     }) if exists $methods->{remove};
 122 }
 123
 124 $META->add_attribute(
 125     'method_metaclass',
 126     reader  => 'method_metaclass',
 127     default => 'Moose::Meta::Role::Method',
 128 );
 129
 130 $META->add_attribute(
 131     'required_method_metaclass',
 132     reader  => 'required_method_metaclass',
 133     default => 'Moose::Meta::Role::Method::Required',
 134 );
 135
 136 $META->add_attribute(
 137     'conflicting_method_metaclass',
 138     reader  => 'conflicting_method_metaclass',
 139     default => 'Moose::Meta::Role::Method::Conflicting',
 140 );
 141
 142 $META->add_attribute(
 143     'application_to_class_class',
 144     reader  => 'application_to_class_class',
 145     default => 'Moose::Meta::Role::Application::ToClass',
 146 );
 147
 148 $META->add_attribute(
 149     'application_to_role_class',
 150     reader  => 'application_to_role_class',
 151     default => 'Moose::Meta::Role::Application::ToRole',
 152 );
 153
 154 $META->add_attribute(
 155     'application_to_instance_class',
 156     reader  => 'application_to_instance_class',
 157     default => 'Moose::Meta::Role::Application::ToInstance',
 158 );
 159
 160 # More or less copied from Moose::Meta::Class
 161 sub initialize {
 162     my $class = shift;
 163     my $pkg   = shift;
 164
 165     if (defined(my $meta = Class::MOP::get_metaclass_by_name($pkg))) {
 166         return $meta;
 167     }
 168
 169     my %options = @_;
 170
 171     my $meta = $class->SUPER::initialize(
 172         $pkg,
 173         'attribute_metaclass' => 'Moose::Meta::Role::Attribute',
 174         %options,
 175     );
 176
 177     Class::MOP::weaken_metaclass($pkg) if $options{weaken};
 178
 179     return $meta;
 180 }
 181
 182 sub reinitialize {
 183     my $self = shift;
 184     my $pkg  = shift;
 185
 186     my $meta = blessed $pkg ? $pkg : Class::MOP::class_of($pkg);
 187
 188     my %existing_classes;
 189     if ($meta) {
 190         %existing_classes = map { $_ => $meta->$_() } qw(
 191             attribute_metaclass
 192             method_metaclass
 193             wrapped_method_metaclass
 194             required_method_metaclass
 195             conflicting_method_metaclass
 196             application_to_class_class
 197             application_to_role_class
 198             application_to_instance_class
 199         );
 200     }
 201
 202     my %options = @_;
 203     $options{weaken} = Class::MOP::metaclass_is_weak($meta->name)
 204         if !exists $options{weaken}
 205         && blessed($meta)
 206         && $meta->isa('Moose::Meta::Role');
 207
 208     # don't need to remove generated metaobjects here yet, since we don't
 209     # yet generate anything in roles. this may change in the future though...
 210     # keep an eye on that
 211     my $new_meta = $self->SUPER::reinitialize(
 212         $pkg,
 213         %existing_classes,
 214         %options,
 215     );
 216     $new_meta->_restore_metaobjects_from($meta)
 217         if $meta && $meta->isa('Moose::Meta::Role');
 218     return $new_meta;
 219 }
 220
 221 sub _restore_metaobjects_from {
 222     my $self = shift;
 223     my ($old_meta) = @_;
 224
 225     $self->_restore_metamethods_from($old_meta);
 226     $self->_restore_metaattributes_from($old_meta);
 227
 228     for my $role ( @{ $old_meta->get_roles } ) {
 229         $self->add_role($role);
 230     }
 231 }
 232
 233 sub add_attribute {
 234     my $self = shift;
 235
 236     if (blessed $_[0] && ! $_[0]->isa('Moose::Meta::Role::Attribute') ) {
 237         my $class = ref $_[0];
 238         Moose->throw_error( "Cannot add a $class as an attribute to a role" );
 239     }
 240     elsif (!blessed($_[0]) && defined($_[0]) && $_[0] =~ /^\+(.*)/) {
 241         Moose->throw_error( "has '+attr' is not supported in roles" );
 242     }
 243
 244     return $self->SUPER::add_attribute(@_);
 245 }
 246
 247 sub _attach_attribute {
 248     my ( $self, $attribute ) = @_;
 249
 250     $attribute->attach_to_role($self);
 251 }
 252
 253 sub add_required_methods {
 254     my $self = shift;
 255
 256     for (@_) {
 257         my $method = $_;
 258         if (!blessed($method)) {
 259             $method = $self->required_method_metaclass->new(
 260                 name => $method,
 261             );
 262         }
 263         $self->get_required_methods_map->{$method->name} = $method;
 264     }
 265 }
 266
 267 sub add_conflicting_method {
 268     my $self = shift;
 269
 270     my $method;
 271     if (@_ == 1 && blessed($_[0])) {
 272         $method = shift;
 273     }
 274     else {
 275         $method = $self->conflicting_method_metaclass->new(@_);
 276     }
 277
 278     $self->add_required_methods($method);
 279 }
 280
 281 ## ------------------------------------------------------------------
 282 ## method modifiers
 283
 284 # NOTE:
 285 # the before/around/after method modifiers are
 286 # stored by name, but there can be many methods
 287 # then associated with that name. So again we have
 288 # lots of similar functionality, so we can do some
 289 # meta-programmin' and save some time.
 290 # - SL
 291
 292 foreach my $modifier_type (qw[ before around after ]) {
 293
 294     my $attr_reader = "get_${modifier_type}_method_modifiers_map";
 295
 296     # create the attribute ...
 297     $META->add_attribute("${modifier_type}_method_modifiers" => (
 298         reader  => $attr_reader,
 299         default => sub { {} }
 300     ));
 301
 302     # and some helper methods ...
 303     $META->add_method("get_${modifier_type}_method_modifiers" => sub {
 304         my ($self, $method_name) = @_;
 305         #return () unless exists $self->$attr_reader->{$method_name};
 306         my $mm = $self->$attr_reader->{$method_name};
 307         $mm ? @$mm : ();
 308     });
 309
 310     $META->add_method("has_${modifier_type}_method_modifiers" => sub {
 311         my ($self, $method_name) = @_;
 312         # NOTE:
 313         # for now we assume that if it exists,..
 314         # it has at least one modifier in it
 315         (exists $self->$attr_reader->{$method_name}) ? 1 : 0;
 316     });
 317
 318     $META->add_method("add_${modifier_type}_method_modifier" => sub {
 319         my ($self, $method_name, $method) = @_;
 320
 321         $self->$attr_reader->{$method_name} = []
 322             unless exists $self->$attr_reader->{$method_name};
 323
 324         my $modifiers = $self->$attr_reader->{$method_name};
 325
 326         # NOTE:
 327         # check to see that we aren't adding the
 328         # same code twice. We err in favor of the
 329         # first on here, this may not be as expected
 330         foreach my $modifier (@{$modifiers}) {
 331             return if $modifier == $method;
 332         }
 333
 334         push @{$modifiers} => $method;
 335     });
 336
 337 }
 338
 339 ## ------------------------------------------------------------------
 340 ## override method mofidiers
 341
 342 $META->add_attribute('override_method_modifiers' => (
 343     reader  => 'get_override_method_modifiers_map',
 344     default => sub { {} }
 345 ));
 346
 347 # NOTE:
 348 # these are a little different because there
 349 # can only be one per name, whereas the other
 350 # method modifiers can have multiples.
 351 # - SL
 352
 353 sub add_override_method_modifier {
 354     my ($self, $method_name, $method) = @_;
 355     (!$self->has_method($method_name))
 356         || Moose->throw_error("Cannot add an override of method '$method_name' " .
 357                    "because there is a local version of '$method_name'");
 358     $self->get_override_method_modifiers_map->{$method_name} = $method;
 359 }
 360
 361 sub has_override_method_modifier {
 362     my ($self, $method_name) = @_;
 363     # NOTE:
 364     # for now we assume that if it exists,..
 365     # it has at least one modifier in it
 366     (exists $self->get_override_method_modifiers_map->{$method_name}) ? 1 : 0;
 367 }
 368
 369 sub get_override_method_modifier {
 370     my ($self, $method_name) = @_;
 371     $self->get_override_method_modifiers_map->{$method_name};
 372 }
 373
 374 ## general list accessor ...
 375
 376 sub get_method_modifier_list {
 377     my ($self, $modifier_type) = @_;
 378     my $accessor = "get_${modifier_type}_method_modifiers_map";
 379     keys %{$self->$accessor};
 380 }
 381
 382 sub reset_package_cache_flag  { (shift)->{'_package_cache_flag'} = undef }
 383 sub update_package_cache_flag {
 384     my $self = shift;
 385     $self->{'_package_cache_flag'} = Class::MOP::check_package_cache_flag($self->name);
 386 }
 387
 388
 389 sub _meta_method_class { 'Moose::Meta::Method::Meta' }
 390
 391 ## ------------------------------------------------------------------
 392 ## subroles
 393
 394 $META->add_attribute('roles' => (
 395     reader  => 'get_roles',
 396     default => sub { [] }
 397 ));
 398
 399 sub add_role {
 400     my ($self, $role) = @_;
 401     (blessed($role) && $role->isa('Moose::Meta::Role'))
 402         || Moose->throw_error("Roles must be instances of Moose::Meta::Role");
 403     push @{$self->get_roles} => $role;
 404     $self->reset_package_cache_flag;
 405 }
 406
 407 sub calculate_all_roles {
 408     my $self = shift;
 409     my %seen;
 410     grep {
 411         !$seen{$_->name}++
 412     } ($self, map {
 413                   $_->calculate_all_roles
 414               } @{ $self->get_roles });
 415 }
 416
 417 sub does_role {
 418     my ($self, $role) = @_;
 419     (defined $role)
 420         || Moose->throw_error("You must supply a role name to look for");
 421     my $role_name = blessed $role ? $role->name : $role;
 422     # if we are it,.. then return true
 423     return 1 if $role_name eq $self->name;
 424     # otherwise.. check our children
 425     foreach my $role (@{$self->get_roles}) {
 426         return 1 if $role->does_role($role_name);
 427     }
 428     return 0;
 429 }
 430
 431 sub find_method_by_name { (shift)->get_method(@_) }
 432
 433 ## ------------------------------------------------------------------
 434 ## role construction
 435 ## ------------------------------------------------------------------
 436
 437 sub apply {
 438     my ($self, $other, %args) = @_;
 439
 440     (blessed($other))
 441         || Moose->throw_error("You must pass in an blessed instance");
 442
 443     my $application_class;
 444     if ($other->isa('Moose::Meta::Role')) {
 445         $application_class = $self->application_to_role_class;
 446     }
 447     elsif ($other->isa('Moose::Meta::Class')) {
 448         $application_class = $self->application_to_class_class;
 449     }
 450     else {
 451         $application_class = $self->application_to_instance_class;
 452     }
 453
 454     Class::MOP::load_class($application_class);
 455
 456     my $deprecation_check = 0;
 457
 458     if ( exists $args{excludes} && !exists $args{'-excludes'} ) {
 459         $args{'-excludes'} = delete $args{excludes};
 460         $deprecation_check = 1;
 461     }
 462     if ( exists $args{alias} && !exists $args{'-alias'} ) {
 463         $args{'-alias'} = delete $args{alias};
 464         $deprecation_check = 1;
 465     }
 466
 467     if ( $deprecation_check ) {
 468         Moose::Deprecated::deprecated(
 469             feature => 'alias or excludes',
 470             message =>
 471                 'The alias and excludes options for role application'.
 472                 ' have been renamed -alias and -excludes'.
 473                 " (${\$other->name} is consuming ${\$self->name}".
 474                 " - do you need to upgrade ${\$other->name}?)"
 475         );
 476     }
 477
 478     if ( exists $args{'-excludes'} ) {
 479         # I wish we had coercion here :)
 480         $args{'-excludes'} = (
 481             ref $args{'-excludes'} eq 'ARRAY'
 482             ? $args{'-excludes'}
 483             : [ $args{'-excludes'} ]
 484         );
 485     }
 486
 487     return $application_class->new(%args)->apply($self, $other, \%args);
 488 }
 489
 490 sub composition_class_roles { }
 491
 492 sub combine {
 493     my ($class, @role_specs) = @_;
 494
 495     require Moose::Meta::Role::Composite;
 496
 497     my (@roles, %role_params);
 498     while (@role_specs) {
 499         my ($role, $params) = @{ splice @role_specs, 0, 1 };
 500         my $requested_role
 501             = blessed $role
 502             ? $role
 503             : Class::MOP::class_of($role);
 504
 505         my $actual_role = $requested_role->_role_for_combination($params);
 506         push @roles => $actual_role;
 507
 508         next unless defined $params;
 509         $role_params{$actual_role->name} = $params;
 510     }
 511
 512     my $c = Moose::Meta::Role::Composite->new(roles => \@roles);
 513     return $c->apply_params(\%role_params);
 514 }
 515
 516 sub _role_for_combination {
 517     my ($self, $params) = @_;
 518     return $self;
 519 }
 520
 521 sub create {
 522     my ( $role, $package_name, %options ) = @_;
 523
 524     $options{package} = $package_name;
 525
 526     (ref $options{attributes} eq 'HASH')
 527         || confess "You must pass a HASH ref of attributes"
 528             if exists $options{attributes};
 529
 530     (ref $options{methods} eq 'HASH')
 531         || confess "You must pass a HASH ref of methods"
 532             if exists $options{methods};
 533
 534     $options{meta_name} = 'meta'
 535         unless exists $options{meta_name};
 536
 537     my (%initialize_options) = %options;
 538     delete @initialize_options{qw(
 539         package
 540         attributes
 541         methods
 542         meta_name
 543         version
 544         authority
 545     )};
 546
 547     my $meta = $role->initialize( $package_name => %initialize_options );
 548
 549     $meta->_instantiate_module( $options{version}, $options{authority} );
 550
 551     $meta->_add_meta_method($options{meta_name})
 552         if defined $options{meta_name};
 553
 554     if (exists $options{attributes}) {
 555         foreach my $attribute_name (keys %{$options{attributes}}) {
 556             my $attr = $options{attributes}->{$attribute_name};
 557             $meta->add_attribute(
 558                 $attribute_name => blessed $attr ? $attr : %{$attr} );
 559         }
 560     }
 561
 562     if (exists $options{methods}) {
 563         foreach my $method_name (keys %{$options{methods}}) {
 564             $meta->add_method($method_name, $options{methods}->{$method_name});
 565         }
 566     }
 567
 568     return $meta;
 569 }
 570
 571 sub consumers {
 572     my $self = shift;
 573     my @consumers;
 574     for my $meta (Class::MOP::get_all_metaclass_instances) {
 575         next if $meta->name eq $self->name;
 576         next unless $meta->isa('Moose::Meta::Class')
 577                  || $meta->isa('Moose::Meta::Role');
 578         push @consumers, $meta->name
 579             if $meta->does_role($self->name);
 580     }
 581     return @consumers;
 582 }
 583
 584 # anonymous roles. most of it is copied straight out of Class::MOP::Class.
 585 # an intrepid hacker might find great riches if he unifies this code with that
 586 # code in Class::MOP::Module or Class::MOP::Package
 587 {
 588     # NOTE:
 589     # this should be sufficient, if you have a
 590     # use case where it is not, write a test and
 591     # I will change it.
 592     my $ANON_ROLE_SERIAL = 0;
 593
 594     # NOTE:
 595     # we need a sufficiently annoying prefix
 596     # this should suffice for now, this is
 597     # used in a couple of places below, so
 598     # need to put it up here for now.
 599     my $ANON_ROLE_PREFIX = 'Moose::Meta::Role::__ANON__::SERIAL::';
 600
 601     sub is_anon_role {
 602         my $self = shift;
 603         no warnings 'uninitialized';
 604         $self->name =~ /^$ANON_ROLE_PREFIX/;
 605     }
 606
 607     sub create_anon_role {
 608         my ($role, %options) = @_;
 609         $options{weaken} = 1 unless exists $options{weaken};
 610         my $package_name = $ANON_ROLE_PREFIX . ++$ANON_ROLE_SERIAL;
 611         return $role->create($package_name, %options);
 612     }
 613
 614     # NOTE:
 615     # this will only get called for
 616     # anon-roles, all other calls
 617     # are assumed to occur during
 618     # global destruction and so don't
 619     # really need to be handled explicitly
 620     sub DESTROY {
 621         my $self = shift;
 622
 623         return if in_global_destruction(); # it'll happen soon anyway and this just makes things more complicated
 624
 625         no warnings 'uninitialized';
 626         return unless $self->name =~ /^$ANON_ROLE_PREFIX/;
 627
 628         # XXX: is this necessary for us? I don't understand what it's doing
 629         # -sartak
 630
 631         # Moose does a weird thing where it replaces the metaclass for
 632         # class when fixing metaclass incompatibility. In that case,
 633         # we don't want to clean out the namespace now. We can detect
 634         # that because Moose will explicitly update the singleton
 635         # cache in Class::MOP.
 636         #my $current_meta = Class::MOP::get_metaclass_by_name($self->name);
 637         #return if $current_meta ne $self;
 638
 639         my ($serial_id) = ($self->name =~ /^$ANON_ROLE_PREFIX(\d+)/);
 640         no strict 'refs';
 641         foreach my $key (keys %{$ANON_ROLE_PREFIX . $serial_id}) {
 642             delete ${$ANON_ROLE_PREFIX . $serial_id}{$key};
 643         }
 644         delete ${'main::' . $ANON_ROLE_PREFIX}{$serial_id . '::'};
 645     }
 646 }
 647
 648 #####################################################################
 649 ## NOTE:
 650 ## This is Moose::Meta::Role as defined by Moose (plus the use of
 651 ## MooseX::AttributeHelpers module). It is here as a reference to
 652 ## make it easier to see what is happening above with all the meta
 653 ## programming. - SL
 654 #####################################################################
 655 #
 656 # has 'roles' => (
 657 #     metaclass => 'Array',
 658 #     reader    => 'get_roles',
 659 #     isa       => 'ArrayRef[Moose::Meta::Role]',
 660 #     default   => sub { [] },
 661 #     provides  => {
 662 #         'push' => 'add_role',
 663 #     }
 664 # );
 665 #
 666 # has 'excluded_roles_map' => (
 667 #     metaclass => 'Hash',
 668 #     reader    => 'get_excluded_roles_map',
 669 #     isa       => 'HashRef[Str]',
 670 #     provides  => {
 671 #         # Not exactly set, cause it sets multiple
 672 #         'set'    => 'add_excluded_roles',
 673 #         'keys'   => 'get_excluded_roles_list',
 674 #         'exists' => 'excludes_role',
 675 #     }
 676 # );
 677 #
 678 # has 'required_methods' => (
 679 #     metaclass => 'Hash',
 680 #     reader    => 'get_required_methods_map',
 681 #     isa       => 'HashRef[Moose::Meta::Role::Method::Required]',
 682 #     provides  => {
 683 #         # not exactly set, or delete since it works for multiple
 684 #         'set'    => 'add_required_methods',
 685 #         'delete' => 'remove_required_methods',
 686 #         'keys'   => 'get_required_method_list',
 687 #         'exists' => 'requires_method',
 688 #     }
 689 # );
 690 #
 691 # # the before, around and after modifiers are
 692 # # HASH keyed by method-name, with ARRAY of
 693 # # CODE refs to apply in that order
 694 #
 695 # has 'before_method_modifiers' => (
 696 #     metaclass => 'Hash',
 697 #     reader    => 'get_before_method_modifiers_map',
 698 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 699 #     provides  => {
 700 #         'keys'   => 'get_before_method_modifiers',
 701 #         'exists' => 'has_before_method_modifiers',
 702 #         # This actually makes sure there is an
 703 #         # ARRAY at the given key, and pushed onto
 704 #         # it. It also checks for duplicates as well
 705 #         # 'add'  => 'add_before_method_modifier'
 706 #     }
 707 # );
 708 #
 709 # has 'after_method_modifiers' => (
 710 #     metaclass => 'Hash',
 711 #     reader    =>'get_after_method_modifiers_map',
 712 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 713 #     provides  => {
 714 #         'keys'   => 'get_after_method_modifiers',
 715 #         'exists' => 'has_after_method_modifiers',
 716 #         # This actually makes sure there is an
 717 #         # ARRAY at the given key, and pushed onto
 718 #         # it. It also checks for duplicates as well
 719 #         # 'add'  => 'add_after_method_modifier'
 720 #     }
 721 # );
 722 #
 723 # has 'around_method_modifiers' => (
 724 #     metaclass => 'Hash',
 725 #     reader    =>'get_around_method_modifiers_map',
 726 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 727 #     provides  => {
 728 #         'keys'   => 'get_around_method_modifiers',
 729 #         'exists' => 'has_around_method_modifiers',
 730 #         # This actually makes sure there is an
 731 #         # ARRAY at the given key, and pushed onto
 732 #         # it. It also checks for duplicates as well
 733 #         # 'add'  => 'add_around_method_modifier'
 734 #     }
 735 # );
 736 #
 737 # # override is similar to the other modifiers
 738 # # except that it is not an ARRAY of code refs
 739 # # but instead just a single name->code mapping
 740 #
 741 # has 'override_method_modifiers' => (
 742 #     metaclass => 'Hash',
 743 #     reader    =>'get_override_method_modifiers_map',
 744 #     isa       => 'HashRef[CodeRef]',
 745 #     provides  => {
 746 #         'keys'   => 'get_override_method_modifier',
 747 #         'exists' => 'has_override_method_modifier',
 748 #         'add'    => 'add_override_method_modifier', # checks for local method ..
 749 #     }
 750 # );
 751 #
 752 #####################################################################
 753
 754
 755 1;
 756
 757 __END__
 758
 759 =pod
 760
 761 =head1 NAME
 762
 763 Moose::Meta::Role - The Moose Role metaclass
 764
 765 =head1 DESCRIPTION
 766
 767 This class is a subclass of L<Class::MOP::Module> that provides
 768 additional Moose-specific functionality.
 769
 770 It's API looks a lot like L<Moose::Meta::Class>, but internally it
 771 implements many things differently. This may change in the future.
 772
 773 =head1 INHERITANCE
 774
 775 C<Moose::Meta::Role> is a subclass of L<Class::MOP::Module>.
 776
 777 =head1 METHODS
 778
 779 =head2 Construction
 780
 781 =over 4
 782
 783 =item B<< Moose::Meta::Role->initialize($role_name) >>
 784
 785 This method creates a new role object with the provided name.
 786
 787 =item B<< Moose::Meta::Role->combine( [ $role => { ... } ], [ $role ], ... ) >>
 788
 789 This method accepts a list of array references. Each array reference
 790 should contain a role name or L<Moose::Meta::Role> object as its first element. The second element is
 791 an optional hash reference. The hash reference can contain C<-excludes>
 792 and C<-alias> keys to control how methods are composed from the role.
 793
 794 The return value is a new L<Moose::Meta::Role::Composite> that
 795 represents the combined roles.
 796
 797 =item B<< $metarole->composition_class_roles >>
 798
 799 When combining multiple roles using C<combine>, this method is used to obtain a
 800 list of role names to be applied to the L<Moose::Meta::Role::Composite>
 801 instance returned by C<combine>. The default implementation returns an empty
 802 list. Extensions that need to hook into role combination may wrap this method
 803 to return additional role names.
 804
 805 =item B<< Moose::Meta::Role->create($name, %options) >>
 806
 807 This method is identical to the L<Moose::Meta::Class> C<create>
 808 method.
 809
 810 =item B<< Moose::Meta::Role->create_anon_role >>
 811
 812 This method is identical to the L<Moose::Meta::Class>
 813 C<create_anon_class> method.
 814
 815 =item B<< $metarole->is_anon_role >>
 816
 817 Returns true if the role is an anonymous role.
 818
 819 =item B<< $metarole->consumers >>
 820
 821 Returns a list of names of classes and roles which consume this role.
 822
 823 =back
 824
 825 =head2 Role application
 826
 827 =over 4
 828
 829 =item B<< $metarole->apply( $thing, @options ) >>
 830
 831 This method applies a role to the given C<$thing>. That can be another
 832 L<Moose::Meta::Role>, object, a L<Moose::Meta::Class> object, or a
 833 (non-meta) object instance.
 834
 835 The options are passed directly to the constructor for the appropriate
 836 L<Moose::Meta::Role::Application> subclass.
 837
 838 Note that this will apply the role even if the C<$thing> in question already
 839 C<does> this role.  L<Moose::Util/does_role> is a convenient wrapper for
 840 finding out if role application is necessary.
 841
 842 =back
 843
 844 =head2 Roles and other roles
 845
 846 =over 4
 847
 848 =item B<< $metarole->get_roles >>
 849
 850 This returns an array reference of roles which this role does. This
 851 list may include duplicates.
 852
 853 =item B<< $metarole->calculate_all_roles >>
 854
 855 This returns a I<unique> list of all roles that this role does, and
 856 all the roles that its roles do.
 857
 858 =item B<< $metarole->does_role($role) >>
 859
 860 Given a role I<name> or L<Moose::Meta::Role> object, returns true if this role
 861 does the given role.
 862
 863 =item B<< $metarole->add_role($role) >>
 864
 865 Given a L<Moose::Meta::Role> object, this adds the role to the list of
 866 roles that the role does.
 867
 868 =item B<< $metarole->get_excluded_roles_list >>
 869
 870 Returns a list of role names which this role excludes.
 871
 872 =item B<< $metarole->excludes_role($role_name) >>
 873
 874 Given a role I<name>, returns true if this role excludes the named
 875 role.
 876
 877 =item B<< $metarole->add_excluded_roles(@role_names) >>
 878
 879 Given one or more role names, adds those roles to the list of excluded
 880 roles.
 881
 882 =back
 883
 884 =head2 Methods
 885
 886 The methods for dealing with a role's methods are all identical in API
 887 and behavior to the same methods in L<Class::MOP::Class>.
 888
 889 =over 4
 890
 891 =item B<< $metarole->method_metaclass >>
 892
 893 Returns the method metaclass name for the role. This defaults to
 894 L<Moose::Meta::Role::Method>.
 895
 896 =item B<< $metarole->get_method($name) >>
 897
 898 =item B<< $metarole->has_method($name) >>
 899
 900 =item B<< $metarole->add_method( $name, $body ) >>
 901
 902 =item B<< $metarole->get_method_list >>
 903
 904 =item B<< $metarole->find_method_by_name($name) >>
 905
 906 These methods are all identical to the methods of the same name in
 907 L<Class::MOP::Package>
 908
 909 =back
 910
 911 =head2 Attributes
 912
 913 As with methods, the methods for dealing with a role's attribute are
 914 all identical in API and behavior to the same methods in
 915 L<Class::MOP::Class>.
 916
 917 However, attributes stored in this class are I<not> stored as
 918 objects. Rather, the attribute definition is stored as a hash
 919 reference. When a role is composed into a class, this hash reference
 920 is passed directly to the metaclass's C<add_attribute> method.
 921
 922 This is quite likely to change in the future.
 923
 924 =over 4
 925
 926 =item B<< $metarole->get_attribute($attribute_name) >>
 927
 928 =item B<< $metarole->has_attribute($attribute_name) >>
 929
 930 =item B<< $metarole->get_attribute_list >>
 931
 932 =item B<< $metarole->add_attribute($name, %options) >>
 933
 934 =item B<< $metarole->remove_attribute($attribute_name) >>
 935
 936 =back
 937
 938 =head2 Required methods
 939
 940 =over 4
 941
 942 =item B<< $metarole->get_required_method_list >>
 943
 944 Returns the list of methods required by the role.
 945
 946 =item B<< $metarole->requires_method($name) >>
 947
 948 Returns true if the role requires the named method.
 949
 950 =item B<< $metarole->add_required_methods(@names) >>
 951
 952 Adds the named methods to the role's list of required methods.
 953
 954 =item B<< $metarole->remove_required_methods(@names) >>
 955
 956 Removes the named methods from the role's list of required methods.
 957
 958 =item B<< $metarole->add_conflicting_method(%params) >>
 959
 960 Instantiate the parameters as a L<Moose::Meta::Role::Method::Conflicting>
 961 object, then add it to the required method list.
 962
 963 =back
 964
 965 =head2 Method modifiers
 966
 967 These methods act like their counterparts in L<Class::MOP::Class> and
 968 L<Moose::Meta::Class>.
 969
 970 However, method modifiers are simply stored internally, and are not
 971 applied until the role itself is applied to a class.
 972
 973 =over 4
 974
 975 =item B<< $metarole->add_after_method_modifier($method_name, $method) >>
 976
 977 =item B<< $metarole->add_around_method_modifier($method_name, $method) >>
 978
 979 =item B<< $metarole->add_before_method_modifier($method_name, $method) >>
 980
 981 =item B<< $metarole->add_override_method_modifier($method_name, $method) >>
 982
 983 These methods all add an appropriate modifier to the internal list of
 984 modifiers.
 985
 986 =item B<< $metarole->has_after_method_modifiers >>
 987
 988 =item B<< $metarole->has_around_method_modifiers >>
 989
 990 =item B<< $metarole->has_before_method_modifiers >>
 991
 992 =item B<< $metarole->has_override_method_modifier >>
 993
 994 Return true if the role has any modifiers of the given type.
 995
 996 =item B<< $metarole->get_after_method_modifiers($method_name) >>
 997
 998 =item B<< $metarole->get_around_method_modifiers($method_name) >>
 999
1000 =item B<< $metarole->get_before_method_modifiers($method_name) >>
1001
1002 Given a method name, returns a list of the appropriate modifiers for
1003 that method.
1004
1005 =item B<< $metarole->get_override_method_modifier($method_name) >>
1006
1007 Given a method name, returns the override method modifier for that
1008 method, if it has one.
1009
1010 =back
1011
1012 =head2 Introspection
1013
1014 =over 4
1015
1016 =item B<< Moose::Meta::Role->meta >>
1017
1018 This will return a L<Class::MOP::Class> instance for this class.
1019
1020 =back
1021
1022 =head1 BUGS
1023
1024 See L<Moose/BUGS> for details on reporting bugs.
1025
1026 =head1 AUTHOR
1027
1028 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1029
1030 =head1 COPYRIGHT AND LICENSE
1031
1032 Copyright 2006-2010 by Infinity Interactive, Inc.
1033
1034 L<http://www.iinteractive.com>
1035
1036 This library is free software; you can redistribute it and/or modify
1037 it under the same terms as Perl itself.
1038
1039 =cut