lib/Moose/Meta/Role/Application/ToClass.pm

   1 package Moose::Meta::Role::Application::ToClass;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 use Moose::Util  'english_list';
   8 use Scalar::Util 'weaken', 'blessed';
   9
  10 our $VERSION   = '0.90';
  11 $VERSION = eval $VERSION;
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 use base 'Moose::Meta::Role::Application';
  15
  16 __PACKAGE__->meta->add_attribute('role' => (
  17     reader => 'role',
  18 ));
  19
  20 __PACKAGE__->meta->add_attribute('class' => (
  21     reader => 'class',
  22 ));
  23
  24 sub apply {
  25     my ($self, $role, $class) = @_;
  26
  27     # We need weak_ref in CMOP :(
  28     weaken($self->{role}  = $role);
  29     weaken($self->{class} = $class);
  30
  31     $self->SUPER::apply($role, $class);
  32
  33     $class->add_role($role);
  34     $class->add_role_application($self);
  35 }
  36
  37 sub check_role_exclusions {
  38     my ($self, $role, $class) = @_;
  39     if ($class->excludes_role($role->name)) {
  40         $class->throw_error("Conflict detected: " . $class->name . " excludes role '" . $role->name . "'");
  41     }
  42     foreach my $excluded_role_name ($role->get_excluded_roles_list) {
  43         if ($class->does_role($excluded_role_name)) {
  44             $class->throw_error("The class " . $class->name . " does the excluded role '$excluded_role_name'");
  45         }
  46     }
  47 }
  48
  49 sub check_required_methods {
  50     my ($self, $role, $class) = @_;
  51
  52     my @missing;
  53     my @is_attr;
  54
  55     # NOTE:
  56     # we might need to move this down below the
  57     # the attributes so that we can require any
  58     # attribute accessors. However I am thinking
  59     # that maybe those are somehow exempt from
  60     # the require methods stuff.
  61     foreach my $required_method ($role->get_required_method_list) {
  62         my $required_method_name = $required_method->name;
  63
  64         if (!$class->find_method_by_name($required_method_name)) {
  65
  66             next if $self->is_aliased_method($required_method_name);
  67
  68             push @missing, $required_method;
  69         }
  70     }
  71
  72     return unless @missing;
  73
  74     my $error = '';
  75
  76     @missing = sort { $a->name cmp $b->name } @missing;
  77     my @conflicts = grep { $_->isa('Moose::Meta::Role::Method::Conflicting') } @missing;
  78
  79     if (@conflicts) {
  80         my $conflict = $conflicts[0];
  81         my $roles = $conflict->roles_as_english_list;
  82
  83         my @same_role_conflicts = grep { $_->roles_as_english_list eq $roles } @conflicts;
  84
  85         if (@same_role_conflicts == 1) {
  86             $error
  87                 .= "Due to a method name conflict in roles "
  88                 .  $roles
  89                 . ", the method '"
  90                 . $conflict->name
  91                 . "' must be implemented or excluded by '"
  92                 . $class->name
  93                 . q{'};
  94         }
  95         else {
  96             my $methods
  97                 = Moose::Util::english_list( map { q{'} . $_->name . q{'} } @same_role_conflicts );
  98
  99             $error
 100                 .= "Due to method name conflicts in roles "
 101                 .  $roles
 102                 . ", the methods "
 103                 . $methods
 104                 . " must be implemented or excluded by '"
 105                 . $class->name
 106                 . q{'};
 107         }
 108     }
 109     elsif (@missing) {
 110         my $noun = @missing == 1 ? 'method' : 'methods';
 111
 112         my $list
 113             = Moose::Util::english_list( map { q{'} . $_ . q{'} } @missing );
 114
 115         $error
 116             .= q{'}
 117             . $role->name
 118             . "' requires the $noun $list "
 119             . "to be implemented by '"
 120             . $class->name . q{'};
 121     }
 122
 123     $class->throw_error($error);
 124 }
 125
 126 sub check_required_attributes {
 127
 128 }
 129
 130 sub apply_attributes {
 131     my ($self, $role, $class) = @_;
 132     foreach my $attribute_name ($role->get_attribute_list) {
 133         # it if it has one already
 134         if ($class->has_attribute($attribute_name) &&
 135             # make sure we haven't seen this one already too
 136             $class->get_attribute($attribute_name) != $role->get_attribute($attribute_name)) {
 137             next;
 138         }
 139         else {
 140             $class->add_attribute(
 141                 $attribute_name,
 142                 $role->get_attribute($attribute_name)
 143             );
 144         }
 145     }
 146 }
 147
 148 sub apply_methods {
 149     my ($self, $role, $class) = @_;
 150     foreach my $method_name ($role->get_method_list) {
 151         next if $method_name eq 'meta';
 152
 153         unless ($self->is_method_excluded($method_name)) {
 154             # it if it has one already
 155             if ($class->has_method($method_name) &&
 156                 # and if they are not the same thing ...
 157                 $class->get_method($method_name)->body != $role->get_method($method_name)->body) {
 158                 next;
 159             }
 160             else {
 161                 # add it, although it could be overridden
 162                 $class->add_method(
 163                     $method_name,
 164                     $role->get_method($method_name)
 165                 );
 166             }
 167         }
 168
 169         if ($self->is_method_aliased($method_name)) {
 170             my $aliased_method_name = $self->get_method_aliases->{$method_name};
 171             # it if it has one already
 172             if ($class->has_method($aliased_method_name) &&
 173                 # and if they are not the same thing ...
 174                 $class->get_method($aliased_method_name)->body != $role->get_method($method_name)->body) {
 175                 $class->throw_error("Cannot create a method alias if a local method of the same name exists");
 176             }
 177             $class->add_method(
 178                 $aliased_method_name,
 179                 $role->get_method($method_name)
 180             );
 181         }
 182     }
 183     # we must reset the cache here since
 184     # we are just aliasing methods, otherwise
 185     # the modifiers go wonky.
 186     $class->reset_package_cache_flag;
 187 }
 188
 189 sub apply_override_method_modifiers {
 190     my ($self, $role, $class) = @_;
 191     foreach my $method_name ($role->get_method_modifier_list('override')) {
 192         # it if it has one already then ...
 193         if ($class->has_method($method_name)) {
 194             next;
 195         }
 196         else {
 197             # if this is not a role, then we need to
 198             # find the original package of the method
 199             # so that we can tell the class were to
 200             # find the right super() method
 201             my $method = $role->get_override_method_modifier($method_name);
 202             my ($package) = Class::MOP::get_code_info($method);
 203             # if it is a class, we just add it
 204             $class->add_override_method_modifier($method_name, $method, $package);
 205         }
 206     }
 207 }
 208
 209 sub apply_method_modifiers {
 210     my ($self, $modifier_type, $role, $class) = @_;
 211     my $add = "add_${modifier_type}_method_modifier";
 212     my $get = "get_${modifier_type}_method_modifiers";
 213     foreach my $method_name ($role->get_method_modifier_list($modifier_type)) {
 214         $class->$add(
 215             $method_name,
 216             $_
 217         ) foreach $role->$get($method_name);
 218     }
 219 }
 220
 221 1;
 222
 223 __END__
 224
 225 =pod
 226
 227 =head1 NAME
 228
 229 Moose::Meta::Role::Application::ToClass - Compose a role into a class
 230
 231 =head1 DESCRIPTION
 232
 233 =head2 METHODS
 234
 235 =over 4
 236
 237 =item B<new>
 238
 239 =item B<meta>
 240
 241 =item B<apply>
 242
 243 =item B<check_role_exclusions>
 244
 245 =item B<check_required_methods>
 246
 247 =item B<check_required_attributes>
 248
 249 =item B<apply_attributes>
 250
 251 =item B<apply_methods>
 252
 253 =item B<apply_method_modifiers>
 254
 255 =item B<apply_override_method_modifiers>
 256
 257 =back
 258
 259 =head1 BUGS
 260
 261 All complex software has bugs lurking in it, and this module is no
 262 exception. If you find a bug please either email me, or add the bug
 263 to cpan-RT.
 264
 265 =head1 AUTHOR
 266
 267 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 268
 269 =head1 COPYRIGHT AND LICENSE
 270
 271 Copyright 2006-2009 by Infinity Interactive, Inc.
 272
 273 L<http://www.iinteractive.com>
 274
 275 This library is free software; you can redistribute it and/or modify
 276 it under the same terms as Perl itself.
 277
 278 =cut
 279