lib/Moose/Meta/Role/Application/RoleSummation.pm

   1 package Moose::Meta::Role::Application::RoleSummation;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 use Scalar::Util 'blessed';
   8
   9 use Moose::Meta::Role::Composite;
  10
  11 our $VERSION   = '0.82';
  12 $VERSION = eval $VERSION;
  13 our $AUTHORITY = 'cpan:STEVAN';
  14
  15 use base 'Moose::Meta::Role::Application';
  16
  17 __PACKAGE__->meta->add_attribute('role_params' => (
  18     reader  => 'role_params',
  19     default => sub { {} }
  20 ));
  21
  22 sub get_exclusions_for_role {
  23     my ($self, $role) = @_;
  24     $role = $role->name if blessed $role;
  25     if ($self->role_params->{$role} && defined $self->role_params->{$role}->{excludes}) {
  26         if (ref $self->role_params->{$role}->{excludes} eq 'ARRAY') {
  27             return $self->role_params->{$role}->{excludes};
  28         }
  29         return [ $self->role_params->{$role}->{excludes} ];
  30     }
  31     return [];
  32 }
  33
  34 sub get_method_aliases_for_role {
  35     my ($self, $role) = @_;
  36     $role = $role->name if blessed $role;
  37     if ($self->role_params->{$role} && defined $self->role_params->{$role}->{alias}) {
  38         return $self->role_params->{$role}->{alias};
  39     }
  40     return {};
  41 }
  42
  43 sub is_method_excluded {
  44     my ($self, $role, $method_name) = @_;
  45     foreach ($self->get_exclusions_for_role($role->name)) {
  46         return 1 if $_ eq $method_name;
  47     }
  48     return 0;
  49 }
  50
  51 sub is_method_aliased {
  52     my ($self, $role, $method_name) = @_;
  53     exists $self->get_method_aliases_for_role($role->name)->{$method_name} ? 1 : 0
  54 }
  55
  56 sub is_aliased_method {
  57     my ($self, $role, $method_name) = @_;
  58     my %aliased_names = reverse %{$self->get_method_aliases_for_role($role->name)};
  59     exists $aliased_names{$method_name} ? 1 : 0;
  60 }
  61
  62 sub check_role_exclusions {
  63     my ($self, $c) = @_;
  64
  65     my %excluded_roles;
  66     for my $role (@{ $c->get_roles }) {
  67         my $name = $role->name;
  68
  69         for my $excluded ($role->get_excluded_roles_list) {
  70             push @{ $excluded_roles{$excluded} }, $name;
  71         }
  72     }
  73
  74     foreach my $role (@{$c->get_roles}) {
  75         foreach my $excluded (keys %excluded_roles) {
  76             next unless $role->does_role($excluded);
  77
  78             my @excluding = @{ $excluded_roles{$excluded} };
  79
  80             require Moose;
  81             Moose->throw_error(sprintf "Conflict detected: Role%s %s exclude%s role '%s'", (@excluding == 1 ? '' : 's'), join(', ', @excluding), (@excluding == 1 ? 's' : ''), $excluded);
  82         }
  83     }
  84
  85     $c->add_excluded_roles(keys %excluded_roles);
  86 }
  87
  88 sub check_required_methods {
  89     my ($self, $c) = @_;
  90
  91     my %all_required_methods =
  92         map { $_->name => $_ }
  93         map { $_->get_required_method_list }
  94         @{$c->get_roles};
  95
  96     foreach my $role (@{$c->get_roles}) {
  97         foreach my $required (keys %all_required_methods) {
  98
  99             delete $all_required_methods{$required}
 100                 if $role->has_method($required)
 101                 || $self->is_aliased_method($role, $required);
 102         }
 103     }
 104
 105     $c->add_required_methods(values %all_required_methods);
 106 }
 107
 108 sub check_required_attributes {
 109
 110 }
 111
 112 sub apply_attributes {
 113     my ($self, $c) = @_;
 114
 115     my @all_attributes = map {
 116         my $role = $_;
 117         map {
 118             +{
 119                 name => $_,
 120                 attr => $role->get_attribute($_),
 121             }
 122         } $role->get_attribute_list
 123     } @{$c->get_roles};
 124
 125     my %seen;
 126     foreach my $attr (@all_attributes) {
 127         if (exists $seen{$attr->{name}}) {
 128             if ( $seen{$attr->{name}} != $attr->{attr} ) {
 129                 require Moose;
 130                 Moose->throw_error("We have encountered an attribute conflict with '" . $attr->{name} . "' "
 131                                    . "during composition. This is fatal error and cannot be disambiguated.")
 132             }
 133         }
 134         $seen{$attr->{name}} = $attr->{attr};
 135     }
 136
 137     foreach my $attr (@all_attributes) {
 138         $c->add_attribute($attr->{name}, $attr->{attr});
 139     }
 140 }
 141
 142 sub apply_methods {
 143     my ($self, $c) = @_;
 144
 145     my @all_methods = map {
 146         my $role     = $_;
 147         my $aliases  = $self->get_method_aliases_for_role($role);
 148         my %excludes = map { $_ => undef } @{ $self->get_exclusions_for_role($role) };
 149         (
 150             (map {
 151                 exists $excludes{$_} ? () :
 152                 +{
 153                     role   => $role,
 154                     name   => $_,
 155                     method => $role->get_method($_),
 156                 }
 157             } $role->get_method_list),
 158             (map {
 159                 +{
 160                     role   => $role,
 161                     name   => $aliases->{$_},
 162                     method => $role->get_method($_),
 163                 }
 164             } keys %$aliases)
 165         );
 166     } @{$c->get_roles};
 167
 168     my (%seen, %method_map);
 169     foreach my $method (@all_methods) {
 170         my $seen = $seen{$method->{name}};
 171
 172         if ($seen) {
 173             if ($seen->{method}->body != $method->{method}->body) {
 174                 $c->add_conflicting_method(
 175                     name  => $method->{name},
 176                     roles => [$method->{role}->name, $seen->{role}->name],
 177                 );
 178
 179                 delete $method_map{$method->{name}};
 180                 next;
 181             }
 182         }
 183
 184         $seen{$method->{name}}       = $method;
 185         $method_map{$method->{name}} = $method->{method};
 186     }
 187
 188     $c->add_method($_ => $method_map{$_}) for keys %method_map;
 189 }
 190
 191 sub apply_override_method_modifiers {
 192     my ($self, $c) = @_;
 193
 194     my @all_overrides = map {
 195         my $role = $_;
 196         map {
 197             +{
 198                 name   => $_,
 199                 method => $role->get_override_method_modifier($_),
 200             }
 201         } $role->get_method_modifier_list('override');
 202     } @{$c->get_roles};
 203
 204     my %seen;
 205     foreach my $override (@all_overrides) {
 206         if ( $c->has_method($override->{name}) ){
 207             require Moose;
 208             Moose->throw_error( "Role '" . $c->name . "' has encountered an 'override' method conflict " .
 209                                 "during composition (A local method of the same name as been found). This " .
 210                                 "is fatal error." )
 211         }
 212         if (exists $seen{$override->{name}}) {
 213             if ( $seen{$override->{name}} != $override->{method} ) {
 214                 require Moose;
 215                 Moose->throw_error( "We have encountered an 'override' method conflict during " .
 216                                     "composition (Two 'override' methods of the same name encountered). " .
 217                                     "This is fatal error.")
 218             }
 219         }
 220         $seen{$override->{name}} = $override->{method};
 221     }
 222
 223     $c->add_override_method_modifier(
 224         $_->{name}, $_->{method}
 225     ) for @all_overrides;
 226
 227 }
 228
 229 sub apply_method_modifiers {
 230     my ($self, $modifier_type, $c) = @_;
 231     my $add = "add_${modifier_type}_method_modifier";
 232     my $get = "get_${modifier_type}_method_modifiers";
 233     foreach my $role (@{$c->get_roles}) {
 234         foreach my $method_name ($role->get_method_modifier_list($modifier_type)) {
 235             $c->$add(
 236                 $method_name,
 237                 $_
 238             ) foreach $role->$get($method_name);
 239         }
 240     }
 241 }
 242
 243 1;
 244
 245 __END__
 246
 247 =pod
 248
 249 =head1 NAME
 250
 251 Moose::Meta::Role::Application::RoleSummation - Combine two or more roles
 252
 253 =head1 DESCRIPTION
 254
 255 Summation composes two traits, forming the union of non-conflicting
 256 bindings and 'disabling' the conflicting bindings
 257
 258 =head2 METHODS
 259
 260 =over 4
 261
 262 =item B<new>
 263
 264 =item B<meta>
 265
 266 =item B<role_params>
 267
 268 =item B<get_exclusions_for_role>
 269
 270 =item B<get_method_aliases_for_role>
 271
 272 =item B<is_aliased_method>
 273
 274 =item B<is_method_aliased>
 275
 276 =item B<is_method_excluded>
 277
 278 =item B<apply>
 279
 280 =item B<check_role_exclusions>
 281
 282 =item B<check_required_methods>
 283
 284 =item B<check_required_attributes>
 285
 286 =item B<apply_attributes>
 287
 288 =item B<apply_methods>
 289
 290 =item B<apply_method_modifiers>
 291
 292 =item B<apply_override_method_modifiers>
 293
 294 =back
 295
 296 =head1 BUGS
 297
 298 All complex software has bugs lurking in it, and this module is no
 299 exception. If you find a bug please either email me, or add the bug
 300 to cpan-RT.
 301
 302 =head1 AUTHOR
 303
 304 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 305
 306 =head1 COPYRIGHT AND LICENSE
 307
 308 Copyright 2006-2009 by Infinity Interactive, Inc.
 309
 310 L<http://www.iinteractive.com>
 311
 312 This library is free software; you can redistribute it and/or modify
 313 it under the same terms as Perl itself.
 314
 315 =cut
 316