lib/Moose/Meta/Method/Constructor.pm

   1
   2 package Moose::Meta::Method::Constructor;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp         'confess';
   8 use Scalar::Util 'blessed', 'weaken', 'looks_like_number';
   9
  10 our $VERSION   = '0.05';
  11 our $AUTHORITY = 'cpan:STEVAN';
  12
  13 use base 'Moose::Meta::Method',
  14          'Class::MOP::Method::Generated';
  15
  16 sub new {
  17     my $class   = shift;
  18     my %options = @_;
  19
  20     (exists $options{options} && ref $options{options} eq 'HASH')
  21         || confess "You must pass a hash of options";
  22
  23     my $self = bless {
  24         # from our superclass
  25         '&!body'          => undef,
  26         # specific to this subclass
  27         '%!options'       => $options{options},
  28         '$!meta_instance' => $options{metaclass}->get_meta_instance,
  29         '@!attributes'    => [ $options{metaclass}->compute_all_applicable_attributes ],
  30         # ...
  31         '$!associated_metaclass' => $options{metaclass},
  32     } => $class;
  33
  34     # we don't want this creating
  35     # a cycle in the code, if not
  36     # needed
  37     weaken($self->{'$!associated_metaclass'});
  38
  39     $self->intialize_body;
  40
  41     return $self;
  42 }
  43
  44 ## accessors
  45
  46 sub options       { (shift)->{'%!options'}       }
  47 sub meta_instance { (shift)->{'$!meta_instance'} }
  48 sub attributes    { (shift)->{'@!attributes'}    }
  49
  50 sub associated_metaclass { (shift)->{'$!associated_metaclass'} }
  51
  52 ## method
  53
  54 sub intialize_body {
  55     my $self = shift;
  56     # TODO:
  57     # the %options should also include a both
  58     # a call 'initializer' and call 'SUPER::'
  59     # options, which should cover approx 90%
  60     # of the possible use cases (even if it
  61     # requires some adaption on the part of
  62     # the author, after all, nothing is free)
  63     my $source = 'sub {';
  64     $source .= "\n" . 'my $class = shift;';
  65
  66     $source .= "\n" . 'return $class->Moose::Object::new(@_)';
  67     $source .= "\n" . '    if $class ne \'' . $self->associated_metaclass->name . '\';';
  68
  69     $source .= "\n" . 'my %params = (scalar @_ == 1) ? %{$_[0]} : @_;';
  70
  71     $source .= "\n" . 'my $instance = ' . $self->meta_instance->inline_create_instance('$class');
  72
  73     $source .= ";\n" . (join ";\n" => map {
  74         $self->_generate_slot_initializer($_)
  75     } 0 .. (@{$self->attributes} - 1));
  76
  77     $source .= ";\n" . $self->_generate_BUILDALL();
  78
  79     $source .= ";\n" . 'return $instance';
  80     $source .= ";\n" . '}';
  81     warn $source if $self->options->{debug};
  82
  83     my $code;
  84     {
  85         # NOTE:
  86         # create the nessecary lexicals
  87         # to be picked up in the eval
  88         my $attrs = $self->attributes;
  89
  90         # We need to check if the attribute ->can('type_constraint')
  91         # since we may be trying to immutabilize a Moose meta class,
  92         # which in turn has attributes which are Class::MOP::Attribute
  93         # objects, rather than Moose::Meta::Attribute. And
  94         # Class::MOP::Attribute attributes have no type constraints.
  95         # However we need to make sure we leave an undef value there
  96         # because the inlined code is using the index of the attributes
  97         # to determine where to find the type constraint
  98
  99         my @type_constraints = map {
 100             $_->can('type_constraint') ? $_->type_constraint : undef
 101         } @$attrs;
 102
 103         my @type_constraint_bodies = map {
 104             defined $_ ? $_->_compiled_type_constraint : undef;
 105         } @type_constraints;
 106
 107         $code = eval $source;
 108         confess "Could not eval the constructor :\n\n$source\n\nbecause :\n\n$@" if $@;
 109     }
 110     $self->{'&!body'} = $code;
 111 }
 112
 113 sub _generate_BUILDALL {
 114     my $self = shift;
 115     my @BUILD_calls;
 116     foreach my $method (reverse $self->associated_metaclass->find_all_methods_by_name('BUILD')) {
 117         push @BUILD_calls => '$instance->' . $method->{class} . '::BUILD(\%params)';
 118     }
 119     return join ";\n" => @BUILD_calls;
 120 }
 121
 122 sub _generate_slot_initializer {
 123     my $self  = shift;
 124     my $index = shift;
 125
 126     my $attr = $self->attributes->[$index];
 127
 128     my @source = ('## ' . $attr->name);
 129
 130     my $is_moose = $attr->isa('Moose::Meta::Attribute'); # XXX FIXME
 131
 132     if ($is_moose && defined($attr->init_arg) && $attr->is_required && !$attr->has_default && !$attr->has_builder) {
 133         push @source => ('(exists $params{\'' . $attr->init_arg . '\'}) ' .
 134                         '|| confess "Attribute (' . $attr->name . ') is required";');
 135     }
 136
 137     if (($attr->has_default || $attr->has_builder) && !($is_moose && $attr->is_lazy)) {
 138
 139         if ( defined( my $init_arg = $attr->init_arg ) ) {
 140             push @source => 'if (exists $params{\'' . $init_arg . '\'}) {';
 141
 142                 push @source => ('my $val = $params{\'' . $init_arg . '\'};');
 143
 144                 if ($is_moose && $attr->has_type_constraint) {
 145                     if ($attr->should_coerce && $attr->type_constraint->has_coercion) {
 146                         push @source => $self->_generate_type_coercion($attr, '$type_constraints[' . $index . ']', '$val', '$val');
 147                     }
 148                     push @source => $self->_generate_type_constraint_check($attr, '$type_constraint_bodies[' . $index . ']', '$val');
 149                 }
 150                 push @source => $self->_generate_slot_assignment($attr, '$val');
 151
 152             push @source => "} else {";
 153         }
 154
 155             my $default;
 156             if ( $attr->has_default ) {
 157                 $default = $self->_generate_default_value($attr, $index);
 158             }
 159             else {
 160                my $builder = $attr->builder;
 161                $default = '$instance->' . $builder;
 162             }
 163             push @source => ('my $val = ' . $default . ';');
 164             push @source => $self->_generate_type_constraint_check(
 165                 $attr,
 166                 ('$type_constraint_bodies[' . $index . ']'),
 167                 '$val'
 168             ) if ($is_moose && $attr->has_type_constraint);
 169             push @source => $self->_generate_slot_assignment($attr, $default);
 170
 171         push @source => "}" if defined $attr->init_arg;
 172     }
 173     elsif ( defined( my $init_arg = $attr->init_arg ) ) {
 174         push @source => '(exists $params{\'' . $init_arg . '\'}) && do {';
 175
 176             push @source => ('my $val = $params{\'' . $init_arg . '\'};');
 177             if ($is_moose && $attr->has_type_constraint) {
 178                 if ($attr->should_coerce && $attr->type_constraint->has_coercion) {
 179                     push @source => $self->_generate_type_coercion($attr, '$type_constraints[' . $index . ']', '$val', '$val');
 180                 }
 181                 push @source => $self->_generate_type_constraint_check($attr, '$type_constraint_bodies[' . $index . ']', '$val');
 182             }
 183             push @source => $self->_generate_slot_assignment($attr, '$val');
 184
 185         push @source => "}";
 186     }
 187
 188     return join "\n" => @source;
 189 }
 190
 191 sub _generate_slot_assignment {
 192     my ($self, $attr, $value) = @_;
 193     my $source = (
 194         $self->meta_instance->inline_set_slot_value(
 195             '$instance',
 196             ("'" . $attr->name . "'"),
 197             $value
 198         ) . ';'
 199     );
 200
 201     my $is_moose = $attr->isa('Moose::Meta::Attribute'); # XXX FIXME
 202
 203     if ($is_moose && $attr->is_weak_ref) {
 204         $source .= (
 205             "\n" .
 206             $self->meta_instance->inline_weaken_slot_value(
 207                 '$instance',
 208                 ("'" . $attr->name . "'")
 209             ) .
 210             ' if ref ' . $value . ';'
 211         );
 212     }
 213
 214     return $source;
 215 }
 216
 217 sub _generate_type_coercion {
 218     my ($self, $attr, $type_constraint_name, $value_name, $return_value_name) = @_;
 219     return ($return_value_name . ' = ' . $type_constraint_name .  '->coerce(' . $value_name . ');');
 220 }
 221
 222 sub _generate_type_constraint_check {
 223     my ($self, $attr, $type_constraint_cv, $value_name) = @_;
 224     return (
 225         $type_constraint_cv . '->(' . $value_name . ')'
 226         . "\n\t" . '|| confess "Attribute (' . $attr->name . ') does not pass the type constraint ('
 227         . $attr->type_constraint->name
 228         . ') with " . (defined(' . $value_name . ') ? overload::StrVal(' . $value_name . ') : "undef");'
 229     );
 230 }
 231
 232 sub _generate_default_value {
 233     my ($self, $attr, $index) = @_;
 234     # NOTE:
 235     # default values can either be CODE refs
 236     # in which case we need to call them. Or
 237     # they can be scalars (strings/numbers)
 238     # in which case we can just deal with them
 239     # in the code we eval.
 240     if ($attr->is_default_a_coderef) {
 241         return '$attrs->[' . $index . ']->default($instance)';
 242     }
 243     else {
 244         my $default = $attr->default;
 245         # make sure to quote strings ...
 246         unless (looks_like_number($default)) {
 247             $default = "'$default'";
 248         }
 249
 250         return $default;
 251     }
 252 }
 253
 254 1;
 255
 256 __END__
 257
 258 =pod
 259
 260 =head1 NAME
 261
 262 Moose::Meta::Method::Constructor - Method Meta Object for constructors
 263
 264 =head1 DESCRIPTION
 265
 266 This is a subclass of L<Class::MOP::Method> which handles
 267 constructing an approprate Constructor methods. This is primarily
 268 used in the making of immutable metaclasses, otherwise it is
 269 not particularly useful.
 270
 271 =head1 METHODS
 272
 273 =over 4
 274
 275 =item B<new>
 276
 277 =item B<attributes>
 278
 279 =item B<meta_instance>
 280
 281 =item B<options>
 282
 283 =item B<intialize_body>
 284
 285 =item B<associated_metaclass>
 286
 287 =back
 288
 289 =head1 AUTHORS
 290
 291 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 292
 293 =head1 COPYRIGHT AND LICENSE
 294
 295 Copyright 2006-2008 by Infinity Interactive, Inc.
 296
 297 L<http://www.iinteractive.com>
 298
 299 This library is free software; you can redistribute it and/or modify
 300 it under the same terms as Perl itself.
 301
 302 =cut
 303